subprojects/gst-rtsp-server/meson.build

   1 project('gst-rtsp-server', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : ['warning_level=1', 'buildtype=debugoptimized'])
   5
   6 gst_version = meson.project_version()
   7 version_arr = gst_version.split('.')
   8 gst_version_major = version_arr[0].to_int()
   9 gst_version_minor = version_arr[1].to_int()
  10 gst_version_micro = version_arr[2].to_int()
  11  if version_arr.length() == 4
  12   gst_version_nano = version_arr[3].to_int()
  13 else
  14   gst_version_nano = 0
  15 endif
  16 gst_version_is_stable = gst_version_minor.is_even()
  17 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  18
  19 glib_req = '>= 2.62.0'
  20
  21 if gst_version_is_stable
  22   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23 else
  24   gst_req = '>= ' + gst_version
  25 endif
  26
  27 api_version = '1.0'
  28 soversion = 0
  29 # maintaining compatibility with the previous libtool versioning
  30 # current = minor * 100 + micro
  31 curversion = gst_version_minor * 100 + gst_version_micro
  32 libversion = '@0@.@1@.0'.format(soversion, curversion)
  33 osxversion = curversion + 1
  34
  35 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  36
  37 cc = meson.get_compiler('c')
  38
  39 cdata = configuration_data()
  40
  41 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  42   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  43 endif
  44
  45 # Symbol visibility
  46 if cc.get_id() == 'msvc'
  47   export_define = '__declspec(dllexport) extern'
  48 elif cc.has_argument('-fvisibility=hidden')
  49   add_project_arguments('-fvisibility=hidden', language: 'c')
  50   export_define = 'extern __attribute__ ((visibility ("default")))'
  51 else
  52   export_define = 'extern'
  53 endif
  54
  55 # Passing this through the command line would be too messy
  56 cdata.set('GST_API_EXPORT', export_define)
  57
  58 # Disable strict aliasing
  59 if cc.has_argument('-fno-strict-aliasing')
  60   add_project_arguments('-fno-strict-aliasing', language: 'c')
  61 endif
  62
  63 # Define G_DISABLE_DEPRECATED for development versions
  64 if gst_version_is_dev
  65   message('Disabling deprecated GLib API')
  66   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  67 endif
  68
  69 cast_checks = get_option('gobject-cast-checks')
  70 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  71   message('Disabling GLib cast checks')
  72   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  73 endif
  74
  75 glib_asserts = get_option('glib-asserts')
  76 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  77   message('Disabling GLib asserts')
  78   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  79 endif
  80
  81 glib_checks = get_option('glib-checks')
  82 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  83   message('Disabling GLib checks')
  84   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  85 endif
  86
  87 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-rtsp-server-1.0')
  88 cdata.set_quoted('PACKAGE', 'gst-rtsp-server')
  89 cdata.set_quoted('VERSION', gst_version)
  90 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  91 cdata.set_quoted('GST_API_VERSION', api_version)
  92 cdata.set_quoted('GST_LICENSE', 'LGPL')
  93
  94 # FIXME: ENABLE_NLS (currently also missing from autotools build)
  95 # cdata.set('ENABLE_NLS', true)
  96 # cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
  97
  98 # GStreamer package name and origin url
  99 gst_package_name = get_option('package-name')
 100 if gst_package_name == ''
 101   if gst_version_nano == 0
 102     gst_package_name = 'GStreamer RTSP Server Library source release'
 103   elif gst_version_nano == 1
 104     gst_package_name = 'GStreamer RTSP Server Library git'
 105   else
 106     gst_package_name = 'GStreamer RTSP Server Library prerelease'
 107   endif
 108 endif
 109 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 110 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 111
 112 rtspserver_args = ['-DHAVE_CONFIG_H']
 113
 114 warning_flags = [
 115   '-Wmissing-declarations',
 116   '-Wmissing-prototypes',
 117   '-Wredundant-decls',
 118   '-Wundef',
 119   '-Wwrite-strings',
 120   '-Wformat',
 121   '-Wformat-nonliteral',
 122   '-Wformat-security',
 123   '-Wold-style-definition',
 124   '-Waggregate-return',
 125   '-Winit-self',
 126   '-Wmissing-include-dirs',
 127   '-Waddress',
 128   '-Wno-multichar',
 129   '-Wvla',
 130   '-Wpointer-arith',
 131 ]
 132
 133 foreach extra_arg : warning_flags
 134   if cc.has_argument (extra_arg)
 135     add_project_arguments([extra_arg], language: 'c')
 136   endif
 137 endforeach
 138
 139 rtspserver_incs = include_directories('gst/rtsp-server', '.')
 140
 141 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 142   fallback : ['gstreamer', 'gst_dep'])
 143 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 144   fallback : ['gst-plugins-base', 'rtsp_dep'])
 145 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 146   fallback : ['gst-plugins-base', 'rtp_dep'])
 147 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 148   fallback : ['gst-plugins-base', 'sdp_dep'])
 149 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 150   fallback : ['gst-plugins-base', 'app_dep'])
 151 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 152   fallback : ['gstreamer', 'gst_net_dep'])
 153 if host_machine.system() != 'windows'
 154   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 155     required : get_option('tests'),
 156     fallback : ['gstreamer', 'gst_check_dep'])
 157 endif
 158
 159 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 160 if gst_dep.type_name() == 'internal'
 161   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 162 else
 163   # We can't check that in the case of subprojects as we won't
 164   # be able to build against an internal dependency (which is not built yet)
 165   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 166 endif
 167
 168 if gst_debug_disabled
 169   message('GStreamer debug system is disabled')
 170   add_project_arguments(cc.get_supported_arguments(['-Wno-unused']), language: 'c')
 171 else
 172   message('GStreamer debug system is enabled')
 173 endif
 174
 175 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 176 gnome = import('gnome')
 177 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 178 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 179     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 180     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 181     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 182     'gst_init(NULL,NULL);', '--quiet']
 183
 184 pkgconfig = import('pkgconfig')
 185 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 186 if get_option('default_library') == 'shared'
 187   # If we don't build static plugins there is no need to generate pc files
 188   plugins_pkgconfig_install_dir = disabler()
 189 endif
 190
 191 plugins = []
 192 pkgconfig_subdirs = ['gstreamer-1.0']
 193 static_build = get_option('default_library') == 'static'
 194 gst_libraries = []
 195
 196 subdir('gst')
 197 if not get_option('tests').disabled()
 198   subdir('tests')
 199 endif
 200 if not get_option('examples').disabled()
 201   subdir('examples')
 202 endif
 203 subdir('docs')
 204
 205 # Set release date
 206 if gst_version_nano == 0
 207   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 208   run_result = run_command(extract_release_date, gst_version, files('gst-rtsp-server.doap'), check: true)
 209   release_date = run_result.stdout().strip()
 210   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 211   message('Package release date: ' + release_date)
 212 endif
 213
 214 configure_file(output: 'config.h', configuration: cdata)
 215
 216 plugin_names = []
 217 gst_plugins = []
 218 foreach plugin: plugins
 219   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 220   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 221   meson.override_dependency(plugin.name(), dep)
 222   gst_plugins += [dep]
 223   if plugin.name().startswith('gst')
 224     plugin_names += [plugin.name().substring(3)]
 225   else
 226     plugin_names += [plugin.name()]
 227   endif
 228 endforeach
 229
 230 summary({
 231     'Plugins': plugin_names,
 232 }, list_sep: ', ')