subprojects/gst-rtsp-server/meson.build

   1 project('gst-rtsp-server', 'c',
   2   version : '1.21.2.1',
   3   meson_version : '>= 0.62',
   4   default_options : ['warning_level=1', 'buildtype=debugoptimized'])
   5
   6 gst_version = meson.project_version()
   7 version_arr = gst_version.split('.')
   8 gst_version_major = version_arr[0].to_int()
   9 gst_version_minor = version_arr[1].to_int()
  10 gst_version_micro = version_arr[2].to_int()
  11  if version_arr.length() == 4
  12   gst_version_nano = version_arr[3].to_int()
  13 else
  14   gst_version_nano = 0
  15 endif
  16 gst_version_is_stable = gst_version_minor.is_even()
  17 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  18
  19 glib_req = '>= 2.62.0'
  20
  21 if gst_version_is_stable
  22   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23 else
  24   gst_req = '>= ' + gst_version
  25 endif
  26
  27 api_version = '1.0'
  28 soversion = 0
  29 # maintaining compatibility with the previous libtool versioning
  30 # current = minor * 100 + micro
  31 curversion = gst_version_minor * 100 + gst_version_micro
  32 libversion = '@0@.@1@.0'.format(soversion, curversion)
  33 osxversion = curversion + 1
  34
  35 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  36
  37 cc = meson.get_compiler('c')
  38
  39 cdata = configuration_data()
  40
  41 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  42   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  43 endif
  44
  45 # glib doesn't support unloading, which means that unloading and reloading
  46 # any library that registers static types will fail
  47 if cc.has_link_argument('-Wl,-z,nodelete')
  48   add_project_link_arguments('-Wl,-z,nodelete', language: 'c')
  49 endif
  50
  51 # Symbol visibility
  52 if cc.get_id() == 'msvc'
  53   export_define = '__declspec(dllexport) extern'
  54 elif cc.has_argument('-fvisibility=hidden')
  55   add_project_arguments('-fvisibility=hidden', language: 'c')
  56   export_define = 'extern __attribute__ ((visibility ("default")))'
  57 else
  58   export_define = 'extern'
  59 endif
  60
  61 # Passing this through the command line would be too messy
  62 cdata.set('GST_API_EXPORT', export_define)
  63
  64 # Disable strict aliasing
  65 if cc.has_argument('-fno-strict-aliasing')
  66   add_project_arguments('-fno-strict-aliasing', language: 'c')
  67 endif
  68
  69 # Define G_DISABLE_DEPRECATED for development versions
  70 if gst_version_is_dev
  71   message('Disabling deprecated GLib API')
  72   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  73 endif
  74
  75 cast_checks = get_option('gobject-cast-checks')
  76 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  77   message('Disabling GLib cast checks')
  78   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  79 endif
  80
  81 glib_asserts = get_option('glib-asserts')
  82 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  83   message('Disabling GLib asserts')
  84   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  85 endif
  86
  87 glib_checks = get_option('glib-checks')
  88 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  89   message('Disabling GLib checks')
  90   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  91 endif
  92
  93 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-rtsp-server-1.0')
  94 cdata.set_quoted('PACKAGE', 'gst-rtsp-server')
  95 cdata.set_quoted('VERSION', gst_version)
  96 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  97 cdata.set_quoted('GST_API_VERSION', api_version)
  98 cdata.set_quoted('GST_LICENSE', 'LGPL')
  99
 100 # FIXME: ENABLE_NLS (currently also missing from autotools build)
 101 # cdata.set('ENABLE_NLS', true)
 102 # cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 103
 104 # GStreamer package name and origin url
 105 gst_package_name = get_option('package-name')
 106 if gst_package_name == ''
 107   if gst_version_nano == 0
 108     gst_package_name = 'GStreamer RTSP Server Library source release'
 109   elif gst_version_nano == 1
 110     gst_package_name = 'GStreamer RTSP Server Library git'
 111   else
 112     gst_package_name = 'GStreamer RTSP Server Library prerelease'
 113   endif
 114 endif
 115 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 116 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 117
 118 rtspserver_args = ['-DHAVE_CONFIG_H']
 119
 120 warning_flags = [
 121   '-Wmissing-declarations',
 122   '-Wmissing-prototypes',
 123   '-Wredundant-decls',
 124   '-Wundef',
 125   '-Wwrite-strings',
 126   '-Wformat',
 127   '-Wformat-nonliteral',
 128   '-Wformat-security',
 129   '-Wold-style-definition',
 130   '-Waggregate-return',
 131   '-Winit-self',
 132   '-Wmissing-include-dirs',
 133   '-Waddress',
 134   '-Wno-multichar',
 135   '-Wvla',
 136   '-Wpointer-arith',
 137 ]
 138
 139 foreach extra_arg : warning_flags
 140   if cc.has_argument (extra_arg)
 141     add_project_arguments([extra_arg], language: 'c')
 142   endif
 143 endforeach
 144
 145 rtspserver_incs = include_directories('gst/rtsp-server', '.')
 146
 147 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 148   fallback : ['gstreamer', 'gst_dep'])
 149 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 150   fallback : ['gst-plugins-base', 'rtsp_dep'])
 151 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 152   fallback : ['gst-plugins-base', 'rtp_dep'])
 153 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 154   fallback : ['gst-plugins-base', 'sdp_dep'])
 155 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 156   fallback : ['gst-plugins-base', 'app_dep'])
 157 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 158   fallback : ['gstreamer', 'gst_net_dep'])
 159 if host_machine.system() != 'windows'
 160   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 161     required : get_option('tests'),
 162     fallback : ['gstreamer', 'gst_check_dep'])
 163 endif
 164
 165 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 166 if gst_dep.type_name() == 'internal'
 167   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 168 else
 169   # We can't check that in the case of subprojects as we won't
 170   # be able to build against an internal dependency (which is not built yet)
 171   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 172 endif
 173
 174 if gst_debug_disabled
 175   message('GStreamer debug system is disabled')
 176   add_project_arguments(cc.get_supported_arguments(['-Wno-unused']), language: 'c')
 177 else
 178   message('GStreamer debug system is enabled')
 179 endif
 180
 181 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 182 gnome = import('gnome')
 183 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 184 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 185     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 186     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 187     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 188     'gst_init(NULL,NULL);', '--quiet']
 189
 190 pkgconfig = import('pkgconfig')
 191 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 192 if get_option('default_library') == 'shared'
 193   # If we don't build static plugins there is no need to generate pc files
 194   plugins_pkgconfig_install_dir = disabler()
 195 endif
 196
 197 plugins = []
 198 pkgconfig_subdirs = ['gstreamer-1.0']
 199 static_build = get_option('default_library') == 'static'
 200 gst_libraries = []
 201
 202 subdir('gst')
 203 if not get_option('tests').disabled()
 204   subdir('tests')
 205 endif
 206 if not get_option('examples').disabled()
 207   subdir('examples')
 208 endif
 209 subdir('docs')
 210
 211 # Set release date
 212 if gst_version_nano == 0
 213   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 214   run_result = run_command(extract_release_date, gst_version, files('gst-rtsp-server.doap'), check: true)
 215   release_date = run_result.stdout().strip()
 216   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 217   message('Package release date: ' + release_date)
 218 endif
 219
 220 configure_file(output: 'config.h', configuration: cdata)
 221
 222 plugin_names = []
 223 gst_plugins = []
 224 foreach plugin: plugins
 225   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 226   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 227   meson.override_dependency(plugin.name(), dep)
 228   gst_plugins += [dep]
 229   if plugin.name().startswith('gst')
 230     plugin_names += [plugin.name().substring(3)]
 231   else
 232     plugin_names += [plugin.name()]
 233   endif
 234 endforeach
 235
 236 summary({
 237     'Plugins': plugin_names,
 238 }, list_sep: ', ')