subprojects/gst-plugins-ugly/meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.22.7.1',
   3   meson_version : '>= 0.62',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 have_cxx = add_languages('cpp', native: false, required: false)
  21
  22 glib_req = '>= 2.62.0'
  23
  24 if gst_version_is_stable
  25   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26 else
  27   gst_req = '>= ' + gst_version
  28 endif
  29
  30 api_version = '1.0'
  31
  32 static_build = get_option('default_library') == 'static'
  33 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  34 plugins = []
  35
  36 cc = meson.get_compiler('c')
  37 if have_cxx
  38   cxx = meson.get_compiler('cpp')
  39 endif
  40
  41 if cc.get_id() == 'msvc'
  42   msvc_args = [
  43       # Ignore several spurious warnings for things gstreamer does very commonly
  44       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  45       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  46       # NOTE: Only add warnings here if you are sure they're spurious
  47       '/wd4018', # implicit signed/unsigned conversion
  48       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  49       '/wd4244', # lossy type conversion (e.g. double -> int)
  50       '/wd4305', # truncating type conversion (e.g. double -> float)
  51       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  52   ]
  53
  54   if gst_version_is_dev
  55     # Enable some warnings on MSVC to match GCC/Clang behaviour
  56     msvc_args += cc.get_supported_arguments([
  57       '/we4002', # too many actual parameters for macro 'identifier'
  58       '/we4003', # not enough actual parameters for macro 'identifier'
  59       '/we4013', # 'function' undefined; assuming extern returning int
  60       '/we4020', # 'function' : too many actual parameters
  61       '/we4027', # function declared without formal parameter list
  62       '/we4029', # declared formal parameter list different from definition
  63       '/we4033', # 'function' must return a value
  64       '/we4045', # 'array' : array bounds overflow
  65       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  66       '/we4053', # one void operand for '?:'
  67       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  68       '/we4098', # 'function' : void function returning a value
  69       '/we4101', # 'identifier' : unreferenced local variable
  70       '/we4189', # 'identifier' : local variable is initialized but not referenced
  71     ])
  72   endif
  73   if have_cxx
  74     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  75   else
  76     add_project_arguments(msvc_args, language: 'c')
  77   endif
  78   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  79   # are built with MinGW
  80   noseh_link_args = ['/SAFESEH:NO']
  81 else
  82   noseh_link_args = []
  83 endif
  84
  85 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  86   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  87 endif
  88 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  89   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  90 endif
  91
  92 # glib doesn't support unloading, which means that unloading and reloading
  93 # any library that registers static types will fail
  94 if cc.has_link_argument('-Wl,-z,nodelete')
  95   add_project_link_arguments('-Wl,-z,nodelete', language: 'c')
  96 endif
  97 if have_cxx and cxx.has_link_argument('-Wl,-z,nodelete')
  98   add_project_link_arguments('-Wl,-z,nodelete', language: 'cpp')
  99 endif
 100
 101 cdata = configuration_data()
 102 cdata.set('ENABLE_NLS', 1)
 103
 104 check_headers = [
 105   ['HAVE_DLFCN_H', 'dlfcn.h'],
 106   ['HAVE_INTTYPES_H', 'inttypes.h'],
 107   ['HAVE_MALLOC_H', 'malloc.h'],
 108   ['HAVE_MEMORY_H', 'memory.h'],
 109   ['HAVE_STDINT_H', 'stdint.h'],
 110   ['HAVE_STDLIB_H', 'stdlib.h'],
 111   ['HAVE_STRINGS_H', 'strings.h'],
 112   ['HAVE_STRING_H', 'string.h'],
 113   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 114   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 115   ['HAVE_UNISTD_H', 'unistd.h'],
 116   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 117 ]
 118
 119 foreach h : check_headers
 120   if cc.has_header(h.get(1))
 121     cdata.set(h.get(0), 1)
 122   endif
 123 endforeach
 124
 125 check_functions = [
 126   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
 127 ]
 128
 129 foreach f : check_functions
 130   if cc.has_function(f.get(1))
 131     cdata.set(f.get(0), 1)
 132   endif
 133 endforeach
 134
 135 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 136 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 137 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 138 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 139 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 140
 141 cdata.set_quoted('VERSION', gst_version)
 142 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 143 cdata.set_quoted('GST_LICENSE', 'LGPL')
 144 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 145 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 146
 147 # GStreamer package name and origin url
 148 gst_package_name = get_option('package-name')
 149 if gst_package_name == ''
 150   if gst_version_nano == 0
 151     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 152   elif gst_version_nano == 1
 153     gst_package_name = 'GStreamer Ugly Plug-ins git'
 154   else
 155     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 156   endif
 157 endif
 158 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 159 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 160
 161 # Mandatory GST deps
 162 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 163     fallback : ['gstreamer', 'gst_dep'])
 164 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 165     fallback : ['gst-plugins-base', 'app_dep'])
 166 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 167     fallback : ['gst-plugins-base', 'video_dep'])
 168 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 169     fallback : ['gst-plugins-base', 'pbutils_dep'])
 170 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 171     fallback : ['gst-plugins-base', 'tag_dep'])
 172 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 173     fallback : ['gst-plugins-base', 'fft_dep'])
 174 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 175     fallback : ['gst-plugins-base', 'audio_dep'])
 176 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 177   fallback : ['gstreamer', 'gst_base_dep'])
 178 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 179     fallback : ['gst-plugins-base', 'riff_dep'])
 180 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 181     fallback : ['gst-plugins-base', 'rtp_dep'])
 182 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 183   fallback : ['gstreamer', 'gst_net_dep'])
 184 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 185     fallback : ['gst-plugins-base', 'sdp_dep'])
 186 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 187     fallback : ['gst-plugins-base', 'rtsp_dep'])
 188 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 189     required : get_option('tests'),
 190     fallback : ['gstreamer', 'gst_check_dep'])
 191 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 192   fallback : ['gstreamer', 'gst_controller_dep'])
 193
 194 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 195     fallback : ['orc', 'orc_dep'])
 196 if orc_dep.found()
 197   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 198 else
 199   cdata.set('DISABLE_ORC', 1)
 200 endif
 201
 202 gmodule_dep = dependency('gmodule-no-export-2.0', version: glib_req)
 203
 204 if gmodule_dep.version().version_compare('< 2.67.4')
 205   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 206 endif
 207
 208 ugly_args = ['-DHAVE_CONFIG_H']
 209 configinc = include_directories('.')
 210 libsinc = include_directories('gst-libs')
 211
 212 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 213 if gst_dep.type_name() == 'internal'
 214   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 215 else
 216   # We can't check that in the case of subprojects as we won't
 217   # be able to build against an internal dependency (which is not built yet)
 218   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 219 endif
 220
 221 if gst_debug_disabled
 222   message('GStreamer debug system is disabled')
 223   if cc.has_argument('-Wno-unused')
 224     add_project_arguments('-Wno-unused', language: 'c')
 225   endif
 226   if have_cxx and cxx.has_argument ('-Wno-unused')
 227     add_project_arguments('-Wno-unused', language: 'cpp')
 228   endif
 229 else
 230   message('GStreamer debug system is enabled')
 231 endif
 232
 233 warning_flags = [
 234   '-Wmissing-declarations',
 235   '-Wredundant-decls',
 236   '-Wwrite-strings',
 237   '-Wformat',
 238   '-Wformat-nonliteral',
 239   '-Wformat-security',
 240   '-Winit-self',
 241   '-Wmissing-include-dirs',
 242   '-Waddress',
 243   '-Wno-multichar',
 244   '-Wvla',
 245   '-Wpointer-arith',
 246   '-Waggregate-return',
 247   '-fno-strict-aliasing',
 248   # Symbol visibility
 249   '-fvisibility=hidden',
 250 ]
 251
 252 warning_c_flags = [
 253   '-Wmissing-prototypes',
 254   '-Wold-style-definition',
 255   '-Wnested-externs'
 256 ]
 257
 258 foreach extra_arg : warning_flags
 259   if cc.has_argument (extra_arg)
 260     add_project_arguments([extra_arg], language: 'c')
 261   endif
 262   if have_cxx and cxx.has_argument (extra_arg)
 263     add_project_arguments([extra_arg], language: 'cpp')
 264   endif
 265 endforeach
 266
 267 foreach extra_arg : warning_c_flags
 268   if cc.has_argument (extra_arg)
 269     add_project_arguments([extra_arg], language: 'c')
 270   endif
 271 endforeach
 272
 273 # Define G_DISABLE_DEPRECATED for development versions
 274 if gst_version_is_dev
 275   message('Disabling deprecated GLib API')
 276   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 277 endif
 278
 279 cast_checks = get_option('gobject-cast-checks')
 280 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 281   message('Disabling GLib cast checks')
 282   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 283 endif
 284
 285 glib_asserts = get_option('glib-asserts')
 286 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 287   message('Disabling GLib asserts')
 288   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 289 endif
 290
 291 glib_checks = get_option('glib-checks')
 292 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 293   message('Disabling GLib checks')
 294   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 295 endif
 296
 297 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 298
 299 pkgconfig = import('pkgconfig')
 300 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 301 if get_option('default_library') == 'shared'
 302   # If we don't build static plugins there is no need to generate pc files
 303   plugins_pkgconfig_install_dir = disabler()
 304 endif
 305
 306 gpl_allowed = get_option('gpl').allowed()
 307
 308 python3 = import('python').find_installation()
 309
 310 subdir('gst')
 311 subdir('ext')
 312 subdir('tests')
 313
 314 # xgettext is optional (on Windows for instance)
 315 if find_program('xgettext', required : get_option('nls')).found()
 316   subdir('po')
 317 endif
 318 subdir('docs')
 319 subdir('scripts')
 320
 321 # Set release date
 322 if gst_version_nano == 0
 323   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 324   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'), check: true)
 325   release_date = run_result.stdout().strip()
 326   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 327   message('Package release date: ' + release_date)
 328 endif
 329
 330 configure_file(output : 'config.h', configuration : cdata)
 331
 332 meson.add_dist_script('scripts/gen-changelog.py', meson.project_name(), '1.20.0', meson.project_version())
 333
 334 plugin_names = []
 335 gst_plugins = []
 336 foreach plugin: plugins
 337   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 338   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 339   meson.override_dependency(plugin.name(), dep)
 340   gst_plugins += [dep]
 341   if plugin.name().startswith('gst')
 342     plugin_names += [plugin.name().substring(3)]
 343   else
 344     plugin_names += [plugin.name()]
 345   endif
 346 endforeach
 347
 348 summary({
 349     'Plugins': plugin_names,
 350       '(A)GPL license allowed': gpl_allowed,
 351 }, list_sep: ', ')