subprojects/gst-plugins-ugly/meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.22.7',
   3   meson_version : '>= 0.62',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 have_cxx = add_languages('cpp', native: false, required: false)
  21
  22 glib_req = '>= 2.62.0'
  23
  24 if gst_version_is_stable
  25   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26 else
  27   gst_req = '>= ' + gst_version
  28 endif
  29
  30 api_version = '1.0'
  31
  32 static_build = get_option('default_library') == 'static'
  33 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  34 plugins = []
  35
  36 cc = meson.get_compiler('c')
  37 if have_cxx
  38   cxx = meson.get_compiler('cpp')
  39 endif
  40
  41 if cc.get_id() == 'msvc'
  42   msvc_args = [
  43       # Ignore several spurious warnings for things gstreamer does very commonly
  44       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  45       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  46       # NOTE: Only add warnings here if you are sure they're spurious
  47       '/wd4018', # implicit signed/unsigned conversion
  48       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  49       '/wd4244', # lossy type conversion (e.g. double -> int)
  50       '/wd4305', # truncating type conversion (e.g. double -> float)
  51       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  52   ]
  53
  54   if gst_version_is_dev
  55     # Enable some warnings on MSVC to match GCC/Clang behaviour
  56     msvc_args += cc.get_supported_arguments([
  57       '/we4002', # too many actual parameters for macro 'identifier'
  58       '/we4003', # not enough actual parameters for macro 'identifier'
  59       '/we4013', # 'function' undefined; assuming extern returning int
  60       '/we4020', # 'function' : too many actual parameters
  61       '/we4027', # function declared without formal parameter list
  62       '/we4029', # declared formal parameter list different from definition
  63       '/we4033', # 'function' must return a value
  64       '/we4045', # 'array' : array bounds overflow
  65       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  66       '/we4053', # one void operand for '?:'
  67       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  68       '/we4098', # 'function' : void function returning a value
  69       '/we4101', # 'identifier' : unreferenced local variable
  70       '/we4189', # 'identifier' : local variable is initialized but not referenced
  71     ])
  72   endif
  73   if have_cxx
  74     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  75   else
  76     add_project_arguments(msvc_args, language: 'c')
  77   endif
  78   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  79   # are built with MinGW
  80   noseh_link_args = ['/SAFESEH:NO']
  81 else
  82   noseh_link_args = []
  83 endif
  84
  85 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  86   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  87 endif
  88 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  89   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  90 endif
  91
  92 # glib doesn't support unloading, which means that unloading and reloading
  93 # any library that registers static types will fail
  94 if cc.has_link_argument('-Wl,-z,nodelete')
  95   add_project_link_arguments('-Wl,-z,nodelete', language: 'c')
  96 endif
  97 if have_cxx and cxx.has_link_argument('-Wl,-z,nodelete')
  98   add_project_link_arguments('-Wl,-z,nodelete', language: 'cpp')
  99 endif
 100
 101 cdata = configuration_data()
 102 cdata.set('ENABLE_NLS', 1)
 103
 104 check_headers = [
 105   ['HAVE_DLFCN_H', 'dlfcn.h'],
 106   ['HAVE_INTTYPES_H', 'inttypes.h'],
 107   ['HAVE_MALLOC_H', 'malloc.h'],
 108   ['HAVE_MEMORY_H', 'memory.h'],
 109   ['HAVE_STDINT_H', 'stdint.h'],
 110   ['HAVE_STDLIB_H', 'stdlib.h'],
 111   ['HAVE_STRINGS_H', 'strings.h'],
 112   ['HAVE_STRING_H', 'string.h'],
 113   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 114   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 115   ['HAVE_UNISTD_H', 'unistd.h'],
 116   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 117 ]
 118
 119 foreach h : check_headers
 120   if cc.has_header(h.get(1))
 121     cdata.set(h.get(0), 1)
 122   endif
 123 endforeach
 124
 125 check_functions = [
 126   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
 127 ]
 128
 129 foreach f : check_functions
 130   if cc.has_function(f.get(1))
 131     cdata.set(f.get(0), 1)
 132   endif
 133 endforeach
 134
 135 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 136 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 137 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 138 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 139 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 140
 141 cdata.set_quoted('VERSION', gst_version)
 142 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 143 cdata.set_quoted('GST_LICENSE', 'LGPL')
 144 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 145 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 146
 147 # GStreamer package name and origin url
 148 gst_package_name = get_option('package-name')
 149 if gst_package_name == ''
 150   if gst_version_nano == 0
 151     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 152   elif gst_version_nano == 1
 153     gst_package_name = 'GStreamer Ugly Plug-ins git'
 154   else
 155     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 156   endif
 157 endif
 158 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 159 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 160
 161 # Mandatory GST deps
 162 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 163     fallback : ['gstreamer', 'gst_dep'])
 164 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 165     fallback : ['gst-plugins-base', 'app_dep'])
 166 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 167     fallback : ['gst-plugins-base', 'video_dep'])
 168 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 169     fallback : ['gst-plugins-base', 'pbutils_dep'])
 170 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 171     fallback : ['gst-plugins-base', 'tag_dep'])
 172 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 173     fallback : ['gst-plugins-base', 'fft_dep'])
 174 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 175     fallback : ['gst-plugins-base', 'audio_dep'])
 176 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 177   fallback : ['gstreamer', 'gst_base_dep'])
 178 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 179     fallback : ['gst-plugins-base', 'riff_dep'])
 180 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 181     fallback : ['gst-plugins-base', 'rtp_dep'])
 182 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 183   fallback : ['gstreamer', 'gst_net_dep'])
 184 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 185     fallback : ['gst-plugins-base', 'sdp_dep'])
 186 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 187     fallback : ['gst-plugins-base', 'rtsp_dep'])
 188 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 189     required : get_option('tests'),
 190     fallback : ['gstreamer', 'gst_check_dep'])
 191 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 192   fallback : ['gstreamer', 'gst_controller_dep'])
 193
 194 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 195     fallback : ['orc', 'orc_dep'])
 196 if orc_dep.found()
 197   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 198 else
 199   cdata.set('DISABLE_ORC', 1)
 200 endif
 201
 202 gmodule_dep = dependency('gmodule-no-export-2.0', version: glib_req)
 203
 204 if gmodule_dep.version().version_compare('< 2.67.4')
 205   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 206 endif
 207
 208 # TIZEN_BUILD_OPTION
 209 cdata.set('TIZEN_FEATURE_ASFDEMUX_CHECK_DATA_SIZE', true)
 210 cdata.set('TIZEN_FEATURE_ASFDEMUX_DISABLE_UNSUPPORTED_FORMAT', true)
 211 cdata.set('TIZEN_FEATURE_ASFDEMUX_POST_TAG_MSG', true)
 212
 213 if get_option('tv-profile')
 214   cdata.set('TIZEN_PROFILE_TV', true)
 215   cdata.set('TIZEN_FEATURE_TRUSTZONE', true)
 216 endif
 217 # TIZEN_BUILD_OPTION end
 218
 219 ugly_args = ['-DHAVE_CONFIG_H']
 220 configinc = include_directories('.')
 221 libsinc = include_directories('gst-libs')
 222
 223 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 224 if gst_dep.type_name() == 'internal'
 225   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 226 else
 227   # We can't check that in the case of subprojects as we won't
 228   # be able to build against an internal dependency (which is not built yet)
 229   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 230 endif
 231
 232 if gst_debug_disabled
 233   message('GStreamer debug system is disabled')
 234   if cc.has_argument('-Wno-unused')
 235     add_project_arguments('-Wno-unused', language: 'c')
 236   endif
 237   if have_cxx and cxx.has_argument ('-Wno-unused')
 238     add_project_arguments('-Wno-unused', language: 'cpp')
 239   endif
 240 else
 241   message('GStreamer debug system is enabled')
 242 endif
 243
 244 warning_flags = [
 245   '-Wmissing-declarations',
 246   '-Wredundant-decls',
 247   '-Wwrite-strings',
 248   '-Wformat',
 249   '-Wformat-nonliteral',
 250   '-Wformat-security',
 251   '-Winit-self',
 252   '-Wmissing-include-dirs',
 253   '-Waddress',
 254   '-Wno-multichar',
 255   '-Wvla',
 256   '-Wpointer-arith',
 257   '-Waggregate-return',
 258   '-fno-strict-aliasing',
 259   # Symbol visibility
 260   '-fvisibility=hidden',
 261 ]
 262
 263 warning_c_flags = [
 264   '-Wmissing-prototypes',
 265   '-Wold-style-definition',
 266   '-Wnested-externs'
 267 ]
 268
 269 foreach extra_arg : warning_flags
 270   if cc.has_argument (extra_arg)
 271     add_project_arguments([extra_arg], language: 'c')
 272   endif
 273   if have_cxx and cxx.has_argument (extra_arg)
 274     add_project_arguments([extra_arg], language: 'cpp')
 275   endif
 276 endforeach
 277
 278 foreach extra_arg : warning_c_flags
 279   if cc.has_argument (extra_arg)
 280     add_project_arguments([extra_arg], language: 'c')
 281   endif
 282 endforeach
 283
 284 # Define G_DISABLE_DEPRECATED for development versions
 285 if gst_version_is_dev
 286   message('Disabling deprecated GLib API')
 287   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 288 endif
 289
 290 cast_checks = get_option('gobject-cast-checks')
 291 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 292   message('Disabling GLib cast checks')
 293   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 294 endif
 295
 296 glib_asserts = get_option('glib-asserts')
 297 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 298   message('Disabling GLib asserts')
 299   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 300 endif
 301
 302 glib_checks = get_option('glib-checks')
 303 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 304   message('Disabling GLib checks')
 305   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 306 endif
 307
 308 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 309
 310 pkgconfig = import('pkgconfig')
 311 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 312 if get_option('default_library') == 'shared'
 313   # If we don't build static plugins there is no need to generate pc files
 314   plugins_pkgconfig_install_dir = disabler()
 315 endif
 316
 317 gpl_allowed = get_option('gpl').allowed()
 318
 319 python3 = import('python').find_installation()
 320
 321 subdir('gst')
 322 subdir('ext')
 323 subdir('tests')
 324
 325 # xgettext is optional (on Windows for instance)
 326 if find_program('xgettext', required : get_option('nls')).found()
 327   subdir('po')
 328 endif
 329 subdir('docs')
 330 subdir('scripts')
 331
 332 # Set release date
 333 if gst_version_nano == 0
 334   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 335   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'), check: true)
 336   release_date = run_result.stdout().strip()
 337   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 338   message('Package release date: ' + release_date)
 339 endif
 340
 341 configure_file(output : 'config.h', configuration : cdata)
 342
 343 meson.add_dist_script('scripts/gen-changelog.py', meson.project_name(), '1.20.0', meson.project_version())
 344
 345 plugin_names = []
 346 gst_plugins = []
 347 foreach plugin: plugins
 348   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 349   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 350   meson.override_dependency(plugin.name(), dep)
 351   gst_plugins += [dep]
 352   if plugin.name().startswith('gst')
 353     plugin_names += [plugin.name().substring(3)]
 354   else
 355     plugin_names += [plugin.name()]
 356   endif
 357 endforeach
 358
 359 summary({
 360     'Plugins': plugin_names,
 361       '(A)GPL license allowed': gpl_allowed,
 362 }, list_sep: ', ')