subprojects/gst-plugins-base/meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.19.2',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 have_cxx = add_languages('cpp', native: false, required: false)
  22
  23 if host_system in ['ios', 'darwin']
  24   have_objc = add_languages('objc', native: false)
  25 else
  26   have_objc = false
  27 endif
  28
  29 glib_req = '>= 2.56.0'
  30 orc_req = '>= 0.4.24'
  31 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  32
  33 api_version = '1.0'
  34 soversion = 0
  35 # maintaining compatibility with the previous libtool versioning
  36 # current = minor * 100 + micro
  37 curversion = gst_version_minor * 100 + gst_version_micro
  38 libversion = '@0@.@1@.0'.format(soversion, curversion)
  39 osxversion = curversion + 1
  40
  41 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  42 plugins = []
  43
  44 cc = meson.get_compiler('c')
  45
  46 if cc.get_id() == 'msvc'
  47   msvc_args = [
  48       # Ignore several spurious warnings for things gstreamer does very commonly
  49       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  50       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  51       # NOTE: Only add warnings here if you are sure they're spurious
  52       '/wd4018', # implicit signed/unsigned conversion
  53       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  54       '/wd4244', # lossy type conversion (e.g. double -> int)
  55       '/wd4305', # truncating type conversion (e.g. double -> float)
  56       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  57
  58       # Enable some warnings on MSVC to match GCC/Clang behaviour
  59       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  60       '/w14101', # 'identifier' : unreferenced local variable
  61       '/w14189', # 'identifier' : local variable is initialized but not referenced
  62   ]
  63   add_project_arguments(msvc_args, language: ['c', 'cpp'])
  64   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  65   # are built with MinGW
  66   noseh_link_args = ['/SAFESEH:NO']
  67 else
  68   noseh_link_args = []
  69 endif
  70
  71 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  72   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  73 endif
  74
  75 core_conf = configuration_data()
  76
  77 # Symbol visibility
  78 if cc.get_id() == 'msvc'
  79   export_define = '__declspec(dllexport) extern'
  80 elif cc.has_argument('-fvisibility=hidden')
  81   add_project_arguments('-fvisibility=hidden', language: 'c')
  82   if have_objc
  83     add_project_arguments('-fvisibility=hidden', language: 'objc')
  84   endif
  85   export_define = 'extern __attribute__ ((visibility ("default")))'
  86 else
  87   export_define = 'extern'
  88 endif
  89
  90 # Passing this through the command line would be too messy
  91 core_conf.set('GST_API_EXPORT', export_define)
  92
  93 # Disable strict aliasing
  94 if cc.has_argument('-fno-strict-aliasing')
  95   add_project_arguments('-fno-strict-aliasing', language: 'c')
  96 endif
  97
  98 # Define G_DISABLE_DEPRECATED for development versions
  99 if gst_version_is_dev
 100   message('Disabling deprecated GLib API')
 101   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 102 endif
 103
 104 cast_checks = get_option('gobject-cast-checks')
 105 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 106   message('Disabling GLib cast checks')
 107   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 108 endif
 109
 110 glib_asserts = get_option('glib-asserts')
 111 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 112   message('Disabling GLib asserts')
 113   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 114 endif
 115
 116 glib_checks = get_option('glib-checks')
 117 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 118   message('Disabling GLib checks')
 119   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 120 endif
 121
 122 # These are only needed/used by the ABI tests from core
 123 host_defines = [
 124   [ 'x86', 'HAVE_CPU_I386' ],
 125   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 126   [ 'arm', 'HAVE_CPU_ARM' ],
 127   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 128   [ 'mips', 'HAVE_CPU_MIPS' ],
 129   [ 'powerpc', 'HAVE_CPU_PPC' ],
 130   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 131   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 132   [ 'sparc', 'HAVE_CPU_SPARC' ],
 133   [ 'ia64', 'HAVE_CPU_IA64' ],
 134   [ 'hppa', 'HAVE_CPU_HPPA' ],
 135   [ 'm68k', 'HAVE_CPU_M68K' ],
 136   [ 's390', 'HAVE_CPU_S390' ],
 137 ]
 138 foreach h : host_defines
 139   if h.get(0) == host_machine.cpu_family()
 140     core_conf.set(h.get(1), 1)
 141   endif
 142 endforeach
 143 # FIXME: should really be called HOST_CPU or such
 144 core_conf.set_quoted('TARGET_CPU', host_machine.cpu())
 145
 146 check_headers = [
 147   ['HAVE_DLFCN_H', 'dlfcn.h'],
 148   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 149   ['HAVE_INTTYPES_H', 'inttypes.h'],
 150   ['HAVE_MEMORY_H', 'memory.h'],
 151   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 152   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 153   ['HAVE_PROCESS_H', 'process.h'],
 154   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 155   ['HAVE_STDINT_H', 'stdint.h'],
 156   ['HAVE_STRINGS_H', 'strings.h'],
 157   ['HAVE_STRING_H', 'string.h'],
 158   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 159   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 160   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 161   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 162   ['HAVE_UNISTD_H', 'unistd.h'],
 163   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 164   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 165   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 166 ]
 167 foreach h : check_headers
 168   if cc.has_header(h.get(1))
 169     core_conf.set(h.get(0), 1)
 170   endif
 171 endforeach
 172
 173 check_functions = [
 174   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 175   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 176   ['HAVE_LOCALTIME_R', 'localtime_r', '#include<time.h>'],
 177   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 178   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 179   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 180 ]
 181
 182 libm = cc.find_library('m', required : false)
 183 foreach f : check_functions
 184   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 185     core_conf.set(f.get(0), 1)
 186   endif
 187 endforeach
 188
 189 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 190 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 191 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 192 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 193 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 194
 195 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 196 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 197 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 198 core_conf.set_quoted('VERSION', gst_version)
 199 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 200 core_conf.set_quoted('GST_API_VERSION', api_version)
 201 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 202 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 203
 204 install_plugins_helper = get_option('install_plugins_helper')
 205 if install_plugins_helper == ''
 206   install_plugins_helper = join_paths(get_option('prefix'),
 207                                       get_option('libexecdir'),
 208                                       'gst-install-plugins-helper')
 209 endif
 210 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 211
 212 warning_flags = [
 213   '-Wmissing-declarations',
 214   '-Wredundant-decls',
 215   '-Wundef',
 216   '-Wwrite-strings',
 217   '-Wformat',
 218   '-Wformat-nonliteral',
 219   '-Wformat-security',
 220   '-Winit-self',
 221   '-Wmissing-include-dirs',
 222   '-Waddress',
 223   '-Wno-multichar',
 224   '-Wvla',
 225   '-Wpointer-arith',
 226 ]
 227
 228 warning_c_flags = [
 229   '-Wmissing-prototypes',
 230   '-Wdeclaration-after-statement',
 231 ]
 232
 233 warning_cxx_flags = [
 234   '-Waggregate-return',
 235 ]
 236
 237 if have_cxx
 238   cxx = meson.get_compiler('cpp')
 239   foreach extra_arg : warning_cxx_flags
 240     if cxx.has_argument (extra_arg)
 241       add_project_arguments([extra_arg], language: 'cpp')
 242     endif
 243   endforeach
 244 endif
 245
 246 foreach extra_arg : warning_flags
 247   if cc.has_argument (extra_arg)
 248     add_project_arguments([extra_arg], language: 'c')
 249   endif
 250   if have_cxx and cxx.has_argument (extra_arg)
 251     add_project_arguments([extra_arg], language: 'cpp')
 252   endif
 253 endforeach
 254
 255 foreach extra_arg : warning_c_flags
 256   if cc.has_argument (extra_arg)
 257     add_project_arguments([extra_arg], language: 'c')
 258   endif
 259 endforeach
 260
 261 # GStreamer package name and origin url
 262 gst_package_name = get_option('package-name')
 263 if gst_package_name == ''
 264   if gst_version_nano == 0
 265     gst_package_name = 'GStreamer Base Plug-ins source release'
 266   elif gst_version_nano == 1
 267     gst_package_name = 'GStreamer Base Plug-ins git'
 268   else
 269     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 270   endif
 271 endif
 272 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 273 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 274
 275 # FIXME: These should be configure options
 276 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 277 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 278
 279 # Set whether the audioresampling method should be detected at runtime
 280 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 281
 282 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 283 if get_option('default_library') == 'static'
 284   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 285 endif
 286
 287 # X11 checks are for sys/ and tests/
 288 x11_dep = dependency('x11', required : get_option('x11'))
 289 # GLib checks are for the entire project
 290 # Almost everything that uses glib also uses gobject
 291 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 292              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 293 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 294 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 295 giounix_dep = dependency('', required: false)
 296 if host_system != 'windows'
 297   giounix_dep = dependency('gio-unix-2.0', version : glib_req,
 298                            fallback: ['glib', 'libgiounix_dep'])
 299 endif
 300 gmodule_dep = dependency('gmodule-no-export-2.0',
 301                          fallback: ['glib', 'libgmodule_dep'])
 302
 303 # some of the examples can use gdk-pixbuf and GTK+3
 304 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 305 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 306 # TODO: https://github.com/mesonbuild/meson/issues/3941
 307 if not get_option('x11').disabled()
 308   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 309 else
 310   gtk_x11_dep = dependency('', required : false)
 311 endif
 312 # gtk+ quartz backend is only available on macOS
 313 if host_system == 'darwin'
 314   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 315 else
 316   gtk_quartz_dep = dependency('', required : false)
 317 endif
 318
 319 core_conf.set('HAVE_X11', x11_dep.found())
 320 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 321
 322 if gio_dep.type_name() == 'pkgconfig'
 323     core_conf.set_quoted('GIO_MODULE_DIR',
 324         gio_dep.get_pkgconfig_variable('giomoduledir'))
 325     core_conf.set_quoted('GIO_LIBDIR',
 326         gio_dep.get_pkgconfig_variable('libdir'))
 327     core_conf.set_quoted('GIO_PREFIX',
 328         gio_dep.get_pkgconfig_variable('prefix'))
 329 else
 330     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 331       get_option('libdir'), 'gio/modules'))
 332     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 333       get_option('libdir')))
 334     core_conf.set_quoted('GIO_PREFIX', join_paths(get_option('prefix')))
 335 endif
 336
 337 configinc = include_directories('.')
 338 libsinc = include_directories('gst-libs')
 339
 340 # To use the subproject make subprojects directory
 341 # and put gstreamer meson git there (symlinking is fine)
 342 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 343   fallback : ['gstreamer', 'gst_dep'])
 344 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 345   fallback : ['gstreamer', 'gst_base_dep'])
 346 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 347   fallback : ['gstreamer', 'gst_net_dep'])
 348 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 349   required : get_option('tests'),
 350   fallback : ['gstreamer', 'gst_check_dep'])
 351 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 352   fallback : ['gstreamer', 'gst_controller_dep'])
 353
 354 have_orcc = false
 355 orcc_args = []
 356 orc_targets = []
 357 # Used by various libraries/elements that use Orc code
 358 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 359     fallback : ['orc', 'orc_dep'])
 360 orcc = find_program('orcc', required : get_option('orc'))
 361 if orc_dep.found() and orcc.found()
 362   have_orcc = true
 363   orcc_args = [orcc, '--include', 'glib.h']
 364   core_conf.set('HAVE_ORC', 1)
 365 else
 366   message('Orc Compiler not found or disabled, will use backup C code')
 367   core_conf.set('DISABLE_ORC', 1)
 368 endif
 369
 370 # TIZEN_BUILD_OPTION
 371 core_conf.set('TIZEN_FEATURE_WAYLAND_ENHANCEMENT', true)
 372 core_conf.set('TIZEN_FEATURE_TYPEFIND_ENHANCEMENT', true)
 373 core_conf.set('TIZEN_FEATURE_AUDIODECODER_MODIFICATION', true)
 374 core_conf.set('TIZEN_FEATURE_DISABLE_MIME_TYPES', true)
 375 core_conf.set('TIZEN_FEATURE_VIDEO_MODIFICATION', true)
 376 core_conf.set('TIZEN_FEATURE_SUBPARSE_MODIFICATION', true)
 377 core_conf.set('TIZEN_FEATURE_SUBPARSE_DROP_OUT_OF_SEGMENT', true)
 378 core_conf.set('TIZEN_FEATURE_HLS_WEBVTT', true)
 379 core_conf.set('TIZEN_FEATURE_VOLUME_MODIFICATION', true)
 380 core_conf.set('TIZEN_FEATURE_FORCE_SW_DECODER', true)
 381 core_conf.set('TIZEN_FEATURE_U3_AVOID_DEADLOCK', true)
 382 core_conf.set('TIZEN_FEATURE_PLAYBIN3_MODIFICATION', true)
 383 core_conf.set('TIZEN_FEATURE_DISABLE_EOS_DROP', true)
 384
 385 tbm_dep = dependency('libtbm', required : get_option('tbm'))
 386 if tbm_dep.found()
 387   core_conf.set('USE_TBM', true)
 388 endif
 389
 390 if get_option('tv-profile')
 391   core_conf.set('TIZEN_TV_PROFILE', true)
 392   core_conf.set('TIZEN_FEATURE_TRUSTZONE', true)
 393 else
 394   core_conf.set('TIZEN_FEATURE_RESOURCE_MANAGER', true)
 395 endif
 396
 397 # TIZEN_BUILD_OPTION end
 398
 399 # Used to build SSE* things in audio-resampler
 400 sse_args = '-msse'
 401 sse2_args = '-msse2'
 402 sse41_args = '-msse4.1'
 403
 404 have_sse = cc.has_argument(sse_args)
 405 have_sse2 = cc.has_argument(sse2_args)
 406 have_sse41 = cc.has_argument(sse41_args)
 407
 408 if host_machine.cpu_family() == 'arm'
 409   if cc.compiles('''
 410 #include <arm_neon.h>
 411 int32x4_t testfunc(int16_t *a, int16_t *b) {
 412   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 413   return vmull_s16(vld1_s16(a), vld1_s16(b));
 414 }
 415 ''', name : 'NEON support')
 416     core_conf.set('HAVE_ARM_NEON', true)
 417   endif
 418 endif
 419
 420 if gst_dep.type_name() == 'internal'
 421     gst_proj = subproject('gstreamer')
 422
 423     if not gst_proj.get_variable('gst_debug')
 424         message('GStreamer debug system is disabled')
 425         add_project_arguments('-Wno-unused', language: 'c')
 426     else
 427         message('GStreamer debug system is enabled')
 428     endif
 429 else
 430     # We can't check that in the case of subprojects as we won't
 431     # be able to build against an internal dependency (which is not built yet)
 432     if not cc.compiles('''
 433 #include <gst/gstconfig.h>
 434 #ifdef GST_DISABLE_GST_DEBUG
 435 #error "debugging disabled, make compiler fail"
 436 #endif''' , dependencies: gst_dep)
 437         message('GStreamer debug system is disabled')
 438         add_project_arguments('-Wno-unused', language: 'c')
 439     else
 440         message('GStreamer debug system is enabled')
 441     endif
 442 endif
 443
 444 if cc.has_member('struct tcp_info', '__tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 445   core_conf.set('HAVE_BSD_TCP_INFO', true)
 446 endif
 447
 448 if cc.has_member('struct tcp_info', 'tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 449   core_conf.set('HAVE_LINUX_TCP_INFO', true)
 450 endif
 451
 452 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 453 gnome = import('gnome')
 454 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 455 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 456     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 457     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 458     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 459     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 460     'gst_init(NULL,NULL);', '--quiet']
 461
 462 pkgconfig = import('pkgconfig')
 463 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 464 if get_option('default_library') == 'shared'
 465   # If we don't build static plugins there is no need to generate pc files
 466   plugins_pkgconfig_install_dir = disabler()
 467 endif
 468
 469 pkgconfig_variables = ['exec_prefix=${prefix}',
 470     'toolsdir=${exec_prefix}/bin',
 471     'pluginsdir=${libdir}/gstreamer-1.0',
 472     'datarootdir=${prefix}/share',
 473     'datadir=${datarootdir}',
 474     'girdir=${datadir}/gir-1.0',
 475     'typelibdir=${libdir}/girepository-1.0',
 476     'libexecdir=${prefix}/libexec']
 477 pkgconfig_subdirs = ['gstreamer-1.0']
 478
 479 meson_pkg_config_file_fixup_script = find_program('scripts/meson-pkg-config-file-fixup.py')
 480
 481 python3 = import('python').find_installation()
 482 subdir('gst-libs')
 483 subdir('gst')
 484 subdir('ext')
 485 subdir('sys')
 486 if not get_option('tools').disabled()
 487   subdir('tools')
 488 endif
 489 subdir('tests')
 490
 491 # xgettext is optional (on Windows for instance)
 492 if find_program('xgettext', required : get_option('nls')).found()
 493   core_conf.set('ENABLE_NLS', 1)
 494   subdir('po')
 495 endif
 496 subdir('docs')
 497 subdir('scripts')
 498
 499 base_libraries = ['allocators', 'app', 'audio', 'fft', 'pbutils', 'riff', 'rtp', 'rtsp', 'sdp', 'tag', 'video']
 500 if build_gstgl
 501   base_libraries += 'gl'
 502 endif
 503
 504 pkgconfig_plugins_base_libs_variables = [
 505   'libraries=' + ' '.join(base_libraries),
 506 ]
 507
 508 pkgconfig.generate(
 509   libraries : [gst_dep],
 510   variables : pkgconfig_variables + pkgconfig_plugins_base_libs_variables,
 511   uninstalled_variables : pkgconfig_plugins_base_libs_variables,
 512   subdirs : pkgconfig_subdirs,
 513   name : 'gstreamer-plugins-base-1.0',
 514   description : 'Streaming media framework, base plugins libraries',
 515 )
 516
 517 # Desperate times, desperate measures... fix up escaping of our variables
 518 run_command(meson_pkg_config_file_fixup_script,
 519   'gstreamer-plugins-base-1.0', 'libraries',
 520   check: true)
 521
 522 if have_orcc
 523   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 524
 525   orc_update_targets = []
 526   foreach t : orc_targets
 527     orc_name = t.get('name')
 528     orc_file = t.get('orc-source')
 529     header = t.get('header')
 530     source = t.get('source')
 531     # alias_target() only works with build targets, so can't use run_target() here
 532     orc_update_targets += [
 533       custom_target('update-orc-@0@'.format(orc_name),
 534         input: [header, source],
 535         command: [update_orc_dist_files, orc_file, header, source],
 536         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 537     ]
 538   endforeach
 539
 540   if meson.version().version_compare('>= 0.52')
 541     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 542   endif
 543 endif
 544
 545 # Set release date
 546 if gst_version_nano == 0
 547   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 548   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-base.doap'))
 549   if run_result.returncode() == 0
 550     release_date = run_result.stdout().strip()
 551     core_conf.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 552     message('Package release date: ' + release_date)
 553   else
 554     # Error out if our release can't be found in the .doap file
 555     error(run_result.stderr())
 556   endif
 557 endif
 558
 559 if gio_dep.version().version_compare('< 2.67.4')
 560   core_conf.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 561 endif
 562
 563 # Use core_conf after all subdirs have set values
 564 configure_file(output : 'config.h', configuration : core_conf)
 565
 566 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 567
 568 if meson.version().version_compare('>= 0.54')
 569   plugin_names = []
 570   foreach plugin: plugins
 571     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 572     split = plugin.name().split('gst')
 573     if split.length() == 2
 574       plugin_names += [split[1]]
 575     else
 576       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 577       plugin_names += [plugin.name()]
 578     endif
 579   endforeach
 580   summary({'Plugins':plugin_names}, list_sep: ', ')
 581 endif