subprojects/gst-plugins-bad/gst-libs/gst/basecamerabinsrc/meson.build

   1 camerabin_sources = [
   2   'gstcamerabin-enum.c',
   3   'gstcamerabinpreview.c',
   4   'gstbasecamerasrc.c',
   5 ]
   6 camerabin_headers = [
   7   'basecamerabinsrc-prelude.h',
   8   'gstcamerabin-enum.h',
   9   'gstcamerabinpreview.h',
  10   'gstbasecamerasrc.h',
  11 ]
  12 install_headers(camerabin_headers, subdir : 'gstreamer-1.0/gst/basecamerabinsrc')
  13
  14 gstbasecamerabin = library('gstbasecamerabinsrc-' + api_version,
  15   camerabin_sources,
  16   c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API', '-DBUILDING_GST_BASE_CAMERA_BIN_SRC'],
  17   include_directories : [configinc, libsinc],
  18   version : libversion,
  19   soversion : soversion,
  20   darwin_versions : osxversion,
  21   install : true,
  22   dependencies : [gstapp_dep],
  23 )
  24
  25 _sources = []
  26 if build_gir
  27   basecamerabin_gir = gnome.generate_gir(gstbasecamerabin,
  28     sources : camerabin_sources + camerabin_headers,
  29     namespace : 'GstBadBaseCameraBin',
  30     nsversion : api_version,
  31     identifier_prefix : 'Gst',
  32     symbol_prefix : 'gst',
  33     export_packages : 'gstreamer-bad-base-camerabinsrc-1.0',
  34     includes : ['Gst-1.0', 'GstApp-1.0'],
  35     install : false, # Only for the documentation
  36     extra_args : gir_init_section + ['-DGST_USE_UNSTABLE_API'],
  37     dependencies : [gstapp_dep],
  38     build_by_default : true,
  39   )
  40   _sources += [basecamerabin_gir]
  41 endif
  42
  43 gstbasecamerabin_dep = declare_dependency(link_with : gstbasecamerabin,
  44   include_directories : [libsinc],
  45   dependencies : [gstapp_dep])