subprojects/gst-editing-services/tools/meson.build

   1 deps = [ges_dep, gstpbutils_dep, gio_dep, gstvideo_dep, gstaudio_dep]
   2
   3 ges_tool_args = [ges_c_args, '-UG_LOG_DOMAIN']
   4 if gstvalidate_dep.found()
   5   deps = deps + [gstvalidate_dep]
   6   ges_tool_args += ['-DGST_USE_UNSTABLE_API']
   7 endif
   8
   9 ges_launch = executable('ges-launch-@0@'.format(apiversion),
  10     'ges-validate.c', 'ges-launch.c', 'ges-launcher.c', 'utils.c', 'ges-launcher-kb.c',
  11     c_args : [ges_tool_args] + ['-DG_LOG_DOMAIN="ges-launch-@0@"'.format(apiversion)],
  12     dependencies : deps,
  13     install: true
  14 )
  15
  16 #install_man('ges-launch-1.0.1')
  17
  18 # bash completion
  19 bashcomp_option = get_option('bash-completion')
  20 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
  21 bash_completions_dir = ''
  22 bash_helpers_dir = ''
  23
  24 bashcomp_found = false
  25 if bashcomp_dep.found()
  26   bashcomp_found = true
  27   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
  28   bash_completions_dir = bashcomp_dep.get_variable('completionsdir', pkgconfig_define:  bashcomp_dir_override)
  29   if bash_completions_dir == ''
  30     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
  31     if bashcomp_option.enabled()
  32       error(msg)
  33     else
  34       message(msg)
  35     endif
  36     bashcomp_found = false
  37   endif
  38
  39   bash_helpers_dir = bashcomp_dep.get_variable('helpersdir', pkgconfig_define:  bashcomp_dir_override)
  40   if bash_helpers_dir == ''
  41     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
  42     if bashcomp_option.enabled()
  43       error(msg)
  44     else
  45       message(msg)
  46     endif
  47     bashcomp_found = false
  48   endif
  49
  50   if bashcomp_found
  51     install_data('../data/completions/ges-launch-1.0', install_dir : bash_completions_dir)
  52   endif
  53 endif