meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  26
  27 prefix = get_option('prefix')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48 endif
  49
  50 # Symbol visibility
  51 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  52 if have_visibility_hidden
  53   add_project_arguments('-fvisibility=hidden', language: 'c')
  54 endif
  55
  56 # Disable strict aliasing
  57 if cc.has_argument('-fno-strict-aliasing')
  58   add_project_arguments('-fno-strict-aliasing', language: 'c')
  59 endif
  60
  61 # Define G_DISABLE_DEPRECATED for development versions
  62 if gst_version_is_dev
  63   message('Disabling deprecated GLib API')
  64   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  65 endif
  66
  67 cast_checks = get_option('gobject-cast-checks')
  68 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  69   message('Disabling GLib cast checks')
  70   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  71 endif
  72
  73 glib_asserts = get_option('glib-asserts')
  74 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  75   message('Disabling GLib asserts')
  76   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  77 endif
  78
  79 cdata = configuration_data()
  80 cdata.set_quoted('GST_API_VERSION', apiversion)
  81 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  82 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  83 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  84 cdata.set_quoted('GST_API_VERSION', '1.0')
  85 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  86 cdata.set_quoted('GST_LICENSE', 'LGPL')
  87 cdata.set_quoted('PACKAGE', 'gstreamer')
  88 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  89 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  90 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  91 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  92 cdata.set_quoted('PACKAGE_URL', '')
  93 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  94 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  95 cdata.set_quoted('VERSION', gst_version)
  96 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  97 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  98 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  99   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 100 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 101
 102 mem_align_opt = get_option('memory-alignment')
 103 if mem_align_opt == 'malloc'
 104   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 105 elif mem_align_opt == 'pagesize'
 106   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 107 else
 108   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 109 endif
 110
 111 if host_system == 'darwin'
 112   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 113 endif
 114
 115 if gst_version_nano > 0
 116     # Have GST_ERROR message printed when running from git
 117     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 118 else
 119     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 120 endif
 121
 122 # GStreamer package name and origin url
 123 gst_package_name = get_option('package-name')
 124 if gst_package_name == ''
 125   if gst_version_nano == 0
 126     gst_package_name = 'GStreamer source release'
 127   elif gst_version_nano == 1
 128     gst_package_name = 'GStreamer git'
 129   else
 130     gst_package_name = 'GStreamer prerelease'
 131   endif
 132 endif
 133 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 134 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 135
 136 # These are only needed/used by the ABI tests
 137 host_defines = [
 138   [ 'x86', 'HAVE_CPU_I386' ],
 139   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 140   [ 'arm', 'HAVE_CPU_ARM' ],
 141   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 142   [ 'mips', 'HAVE_CPU_MIPS' ],
 143   [ 'powerpc', 'HAVE_CPU_PPC' ],
 144   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 145   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 146   [ 'sparc', 'HAVE_CPU_SPARC' ],
 147   [ 'ia64', 'HAVE_CPU_IA64' ],
 148   [ 'hppa', 'HAVE_CPU_HPPA' ],
 149   [ 'm68k', 'HAVE_CPU_M68K' ],
 150   [ 's390', 'HAVE_CPU_S390' ],
 151 ]
 152 foreach h : host_defines
 153   if h.get(0) == host_machine.cpu()
 154     cdata.set(h.get(1), 1)
 155   endif
 156 endforeach
 157 # FIXME: should really be called HOST_CPU or such
 158 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 159
 160 check_headers = [
 161   'dlfcn.h',
 162   'inttypes.h',
 163   'memory.h',
 164   'poll.h',
 165   'stdint.h',
 166   'stdio_ext.h',
 167   'strings.h',
 168   'string.h',
 169   'sys/param.h',
 170   'sys/poll.h',
 171   'sys/prctl.h',
 172   'sys/socket.h',
 173   'sys/stat.h',
 174   'sys/times.h',
 175   'sys/time.h',
 176   'sys/types.h',
 177   'sys/utsname.h',
 178   'sys/wait.h',
 179   'ucontext.h',
 180   'unistd.h',
 181   'valgrind/valgrind.h',
 182   'sys/resource.h',
 183 ]
 184
 185 if host_system == 'windows'
 186   check_headers += ['winsock2.h']
 187 endif
 188
 189 foreach h : check_headers
 190   if cc.has_header(h)
 191     define = 'HAVE_' + h.underscorify().to_upper()
 192     cdata.set(define, 1)
 193   endif
 194 endforeach
 195
 196 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 197   cdata.set('HAVE_TM_GMTOFF', 1)
 198 endif
 199
 200 check_functions = [
 201   'gmtime_r',
 202   'sigaction',
 203   'getrusage',
 204   'fseeko',
 205   'ftello',
 206   'poll',
 207   'ppoll',
 208   'pselect',
 209   'getpagesize',
 210   'clock_gettime',
 211   # These are needed by libcheck
 212   'getline',
 213   'mkstemp',
 214   'alarm',
 215   'gettimeofday',
 216 ]
 217
 218 foreach f : check_functions
 219   if cc.has_function(f)
 220     define = 'HAVE_' + f.underscorify().to_upper()
 221     cdata.set(define, 1)
 222   endif
 223 endforeach
 224
 225 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 226   cdata.set('HAVE_LOCALTIME_R', 1)
 227   # Needed by libcheck
 228   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 229 endif
 230
 231 if cc.links('''#include <pthread.h>
 232                int main() {
 233                  pthread_setname_np("example"); return 0;
 234                }''', name : 'pthread_setname_np(const char*)')
 235   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 236 endif
 237
 238 # Check for posix timers and the monotonic clock
 239 time_prefix = '#include <time.h>\n'
 240 if cdata.has('HAVE_UNISTD_H')
 241   time_prefix += '#include <unistd.h>'
 242 endif
 243
 244 posix_timers_src = time_prefix + '''
 245 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 246 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 247 #endif
 248 '''
 249 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 250   cdata.set('HAVE_POSIX_TIMERS', 1)
 251 endif
 252
 253 monotonic_clock_src = time_prefix + '''
 254 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 255 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 256 #endif
 257 '''
 258 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 259   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 260 endif
 261
 262 # Check for __uint128_t (gcc) by checking for 128-bit division
 263 uint128_t_src = '''int main() {
 264 static __uint128_t v1 = 100;
 265 static __uint128_t v2 = 10;
 266 static __uint128_t u;
 267 u = v1 / v2;
 268 }'''
 269 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 270   cdata.set('HAVE_UINT128_T', 1)
 271 endif
 272
 273 # All supported platforms have long long now
 274 cdata.set('HAVE_LONG_LONG', 1)
 275
 276 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 277 # building with MSVC
 278 if cc.get_id() == 'msvc'
 279   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 280 else
 281   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 282 endif
 283
 284 # -------------------------------------------------------------------------------------
 285 # config.h things needed by libcheck
 286 # -------------------------------------------------------------------------------------
 287 if cc.has_function('getpid')
 288   cdata.set('HAVE_GETPID', 1)
 289 elif host_system == 'windows' and cc.has_function('_getpid')
 290   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 291   cdata.set('HAVE__GETPID', 1)
 292 endif
 293 if cc.has_function('strdup')
 294   cdata.set('HAVE_DECL_STRDUP', 1)
 295 elif host_system == 'windows' and cc.has_function('_strdup')
 296   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 297 endif
 298 if host_system != 'windows'
 299   cdata.set('HAVE_FORK', 1)
 300 else
 301   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 302   cdata.set('HAVE_FORK', 0)
 303 endif
 304 if cc.has_function('strsignal')
 305   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 306 endif
 307 # Check for availability of types
 308 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 309   cdata.set('clockid_t', 'int')
 310 endif
 311 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 312   cdata.set('timer_t', 'int')
 313 endif
 314 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 315                       prefix : '#include <time.h>')
 316   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 317 endif
 318 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 319                       prefix : '#include <time.h>')
 320   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 321 endif
 322
 323 # Platform deps; only ws2_32 and execinfo for now
 324 platform_deps = []
 325 if host_system == 'windows'
 326   platform_deps = [cc.find_library('ws2_32')]
 327 endif
 328
 329 backtrace_deps = []
 330 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 331 dw_dep = dependency('libdw', required: get_option('libunwind'))
 332 backtrace_deps = [unwind_dep, dw_dep]
 333 if unwind_dep.found()
 334   cdata.set('HAVE_UNWIND', 1)
 335   if dw_dep.found()
 336     cdata.set('HAVE_DW', 1)
 337   else
 338     message('Support for backtraces is partial only.')
 339   endif
 340 else
 341   if cc.has_function('backtrace')
 342     cdata.set('HAVE_BACKTRACE', 1)
 343   else
 344       message('NO backtraces support.')
 345   endif
 346 endif
 347
 348 if cc.has_header('execinfo.h')
 349   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 350     cdata.set('HAVE_BACKTRACE', 1)
 351   else
 352     execinfo_dep = cc.find_library('execinfo', required : false)
 353     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 354       cdata.set('HAVE_BACKTRACE', 1)
 355       platform_deps += execinfo_dep
 356     endif
 357   endif
 358 endif
 359
 360 gst_debug = get_option('gst_debug')
 361 if not gst_debug
 362   add_project_arguments(['-Wno-unused'], language: 'c')
 363 endif
 364
 365 warning_flags = [
 366   '-Wmissing-declarations',
 367   '-Wmissing-prototypes',
 368   '-Wredundant-decls',
 369   '-Wundef',
 370   '-Wwrite-strings',
 371   '-Wformat',
 372   '-Wformat-nonliteral',
 373   '-Wformat-security',
 374   '-Wold-style-definition',
 375   '-Winit-self',
 376   '-Wmissing-include-dirs',
 377   '-Waddress',
 378   '-Waggregate-return',
 379   '-Wno-multichar',
 380   '-Wnested-externs',
 381   '-Wdeclaration-after-statement',
 382   '-Wvla',
 383   '-Wpointer-arith',
 384 ]
 385
 386 foreach extra_arg : warning_flags
 387   if cc.has_argument (extra_arg)
 388     add_project_arguments([extra_arg], language: 'c')
 389   endif
 390 endforeach
 391
 392 # Used by the gstutils test
 393 gmp_dep = cc.find_library('gmp', required : false)
 394 cdata.set('HAVE_GMP', gmp_dep.found())
 395 gsl_dep = cc.find_library('gsl', required : false)
 396 gslcblas_dep = cc.find_library('gslcblas', required : false)
 397 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 398 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 399
 400 # Used by gstinfo.c
 401 dl_dep = cc.find_library('dl', required : false)
 402 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 403 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 404 cdata.set('USE_POISONING', get_option('poisoning'))
 405
 406 configinc = include_directories('.')
 407 libsinc = include_directories('libs')
 408 privinc = include_directories('gst')
 409
 410 # Find dependencies
 411 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 412   fallback: ['glib', 'libglib_dep'])
 413 gobject_dep = dependency('gobject-2.0',
 414   fallback: ['glib', 'libgobject_dep'])
 415 gmodule_dep = dependency('gmodule-2.0',
 416   fallback: ['glib', 'libgmodule_dep'])
 417 if host_system == 'windows'
 418     gio_dep = dependency('gio-2.0',
 419         fallback: ['glib', 'libgio_dep'])
 420 else
 421     gio_dep = [dependency('gio-2.0',
 422                   fallback: ['glib', 'libgio_dep']),
 423                dependency('gio-unix-2.0',
 424                   fallback: ['glib', 'libgio_dep'])]
 425 endif
 426
 427 mathlib = cc.find_library('m', required : false)
 428 # Needed for timer_create/settime/delete
 429 # Also provides clock_gettime in glibc < 2.17
 430 rt_lib = cc.find_library('rt', required : false)
 431
 432 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 433 gnome = import('gnome')
 434
 435 build_gir = gir.found() and not meson.is_cross_build()
 436
 437 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 438     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 439     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 440     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 441     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 442     'gst_init(NULL,NULL);' ]
 443
 444 gst_c_args = ['-DHAVE_CONFIG_H']
 445
 446 # FIXME: This is only needed on windows and probably breaks when
 447 # default_library = 'both'. We should add this flag to static_c_args instead
 448 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 449 if get_option('default_library') == 'static'
 450   gst_c_args += ['-DGST_STATIC_COMPILATION']
 451 endif
 452
 453 # Used in gst/parse/meson.build and below
 454 python3 = import('python3').find_python()
 455
 456 bashcomp_option = get_option('bash-completion')
 457 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 458 bash_completions_dir = ''
 459 bash_helpers_dir = ''
 460
 461 bashcomp_found = false
 462 if bashcomp_dep.found()
 463   bashcomp_found = true
 464   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 465   if bash_completions_dir == ''
 466     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 467     if bashcomp_option.enabled()
 468       error(msg)
 469     else
 470       message(msg)
 471     endif
 472     bashcomp_found = false
 473   endif
 474
 475   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 476   if bash_helpers_dir == ''
 477     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 478     if bashcomp_option.enabled()
 479       error(msg)
 480     else
 481       message(msg)
 482     endif
 483     bashcomp_found = false
 484   endif
 485 endif
 486
 487 subdir('gst')
 488 subdir('libs')
 489 subdir('plugins')
 490 if not get_option('tools').disabled()
 491   subdir('tools')
 492 endif
 493 subdir('pkgconfig')
 494 subdir('tests')
 495 subdir('data')
 496
 497 # xgettext is optional (on Windows for instance)
 498 if find_program('xgettext', required : get_option('nls')).found()
 499   cdata.set('ENABLE_NLS', 1)
 500   subdir('po')
 501 endif
 502
 503 configure_file(output : 'config.h', configuration : cdata)
 504
 505 if build_machine.system() == 'windows'
 506   message('Disabling gtk-doc while building on Windows')
 507 else
 508   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 509     subdir('docs')
 510   else
 511     message('Not building documentation as gtk-doc was not found')
 512   endif
 513 endif
 514
 515 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 516
 517 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))