meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.42.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 orc_req = '>= 0.4.24'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25 soversion = 0
  26 # maintaining compatibility with the previous libtool versioning
  27 # current = minor * 100 + micro
  28 # FIXME: should be able to convert string to int somehow so we can just do maths
  29 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  30
  31 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  32
  33 cc = meson.get_compiler('c')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 # Symbol visibility
  54 if cc.has_argument('-fvisibility=hidden')
  55   add_project_arguments('-fvisibility=hidden', language: 'c')
  56 endif
  57
  58 # Disable strict aliasing
  59 if cc.has_argument('-fno-strict-aliasing')
  60   add_project_arguments('-fno-strict-aliasing', language: 'c')
  61 endif
  62
  63 core_conf = configuration_data()
  64 check_headers = [
  65   ['HAVE_DLFCN_H', 'dlfcn.h'],
  66   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  67   ['HAVE_INTTYPES_H', 'inttypes.h'],
  68   ['HAVE_MEMORY_H', 'memory.h'],
  69   ['HAVE_PROCESS_H', 'process.h'],
  70   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  71   ['HAVE_STDINT_H', 'stdint.h'],
  72   ['HAVE_STDLIB_H', 'stdlib.h'],
  73   ['HAVE_STRINGS_H', 'strings.h'],
  74   ['HAVE_STRING_H', 'string.h'],
  75   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  76   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  77   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  78   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  79   ['HAVE_UNISTD_H', 'unistd.h'],
  80   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  81   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  82   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
  83 ]
  84 foreach h : check_headers
  85   if cc.has_header(h.get(1))
  86     core_conf.set(h.get(0), 1)
  87   endif
  88 endforeach
  89
  90 check_functions = [
  91   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  92   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  93   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  94   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  95   ['HAVE_LOG2', 'log2', '#include<math.h>'],
  96 ]
  97
  98 libm = cc.find_library('m', required : false)
  99 foreach f : check_functions
 100   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 101     core_conf.set(f.get(0), 1)
 102   endif
 103 endforeach
 104
 105 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 106 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 107 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 108 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 109 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 110
 111 core_conf.set('GETTEXT_PACKAGE', '"gst-plugins-base-1.0"')
 112 core_conf.set('PACKAGE', '"gst-plugins-base"')
 113 core_conf.set('VERSION', '"@0@"'.format(gst_version))
 114 core_conf.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 115 core_conf.set('GST_API_VERSION', '"@0@"'.format(api_version))
 116 core_conf.set('GST_INSTALL_PLUGINS_HELPER', '"/FIXME"')
 117 core_conf.set('GST_DATADIR', '"/FIXME"')
 118 core_conf.set('GST_LICENSE', '"LGPL"')
 119
 120 warning_flags = [
 121   '-Wmissing-declarations',
 122   '-Wredundant-decls',
 123   '-Wundef',
 124   '-Wwrite-strings',
 125   '-Wformat',
 126   '-Wformat-nonliteral',
 127   '-Wformat-security',
 128   '-Winit-self',
 129   '-Wmissing-include-dirs',
 130   '-Waddress',
 131   '-Wno-multichar',
 132   '-Wvla',
 133   '-Wpointer-arith',
 134 ]
 135
 136 warning_c_flags = [
 137   '-Wmissing-prototypes',
 138   '-Wdeclaration-after-statement',
 139 ]
 140
 141 warning_cxx_flags = [
 142   '-Waggregate-return',
 143 ]
 144
 145 if have_cxx
 146   cxx = meson.get_compiler('cpp')
 147   foreach extra_arg : warning_cxx_flags
 148     if cxx.has_argument (extra_arg)
 149       add_project_arguments([extra_arg], language: 'cpp')
 150     endif
 151   endforeach
 152 endif
 153
 154 foreach extra_arg : warning_flags
 155   if cc.has_argument (extra_arg)
 156     add_project_arguments([extra_arg], language: 'c')
 157   endif
 158   if have_cxx and cxx.has_argument (extra_arg)
 159     add_project_arguments([extra_arg], language: 'cpp')
 160   endif
 161 endforeach
 162
 163 foreach extra_arg : warning_c_flags
 164   if cc.has_argument (extra_arg)
 165     add_project_arguments([extra_arg], language: 'c')
 166   endif
 167 endforeach
 168
 169 # GStreamer package name and origin url
 170 gst_package_name = get_option('with-package-name')
 171 if gst_package_name == ''
 172   if gst_version_nano == 0
 173     gst_package_name = 'GStreamer Base Plug-ins source release'
 174   elif gst_version_nano == 1
 175     gst_package_name = 'GStreamer Base Plug-ins git'
 176   else
 177     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 178   endif
 179 endif
 180 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 181 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 182
 183 # FIXME: These should be configure options
 184 core_conf.set('DEFAULT_VIDEOSINK', '"autovideosink"')
 185 core_conf.set('DEFAULT_AUDIOSINK', '"autoaudiosink"')
 186
 187 # Set whether the audioresampling method should be detected at runtime
 188 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 189
 190 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 191 if get_option('default_library') == 'static'
 192   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 193 endif
 194
 195 # X11 checks are for sys/ and tests/
 196 x11_dep = dependency('x11', required : false)
 197 # GLib checks are for the entire project
 198 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 199 # Almost everything that uses glib also uses gobject
 200 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 201              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 202 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 203
 204 # some of the examples want GTK+
 205 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : false)
 206 gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : false)
 207 gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : false)
 208 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : false)
 209
 210 core_conf.set('HAVE_X', x11_dep.found())
 211 core_conf.set('HAVE_GIO_UNIX_2_0',
 212     (gio_dep.type_name() != 'pkgconfig' and host_machine.system() != 'windows')
 213     or giounix_dep.found())
 214
 215 if gio_dep.type_name() == 'pkgconfig'
 216     core_conf.set_quoted('GIO_MODULE_DIR',
 217         gio_dep.get_pkgconfig_variable('giomoduledir'))
 218     core_conf.set_quoted('GIO_LIBDIR',
 219         gio_dep.get_pkgconfig_variable('libdir'))
 220     core_conf.set_quoted('GIO_PREFIX',
 221         gio_dep.get_pkgconfig_variable('prefix'))
 222 else
 223     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 224       get_option('libdir'), 'gio/modules'))
 225     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 226       get_option('libdir')))
 227     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 228 endif
 229
 230 configinc = include_directories('.')
 231 libsinc = include_directories('gst-libs')
 232
 233 # To use the subproject make subprojects directory
 234 # and put gstreamer meson git there (symlinking is fine)
 235 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 236   fallback : ['gstreamer', 'gst_dep'])
 237 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 238   fallback : ['gstreamer', 'gst_base_dep'])
 239 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 240   fallback : ['gstreamer', 'gst_net_dep'])
 241 if host_machine.system() != 'windows'
 242   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 243     fallback : ['gstreamer', 'gst_check_dep'])
 244 endif
 245 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 246   fallback : ['gstreamer', 'gst_controller_dep'])
 247
 248 have_orcc = false
 249 orcc_args = []
 250 if get_option('use_orc') != 'no'
 251   need_orc = get_option('use_orc') == 'yes'
 252   # Used by various libraries/elements that use Orc code
 253   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 254   orcc = find_program('orcc', required : need_orc)
 255   if orc_dep.found() and orcc.found()
 256     have_orcc = true
 257     orcc_args = [orcc, '--include', 'glib.h']
 258     core_conf.set('HAVE_ORC', 1)
 259   else
 260     message('Orc Compiler not found, will use backup C code')
 261     core_conf.set('DISABLE_ORC', 1)
 262   endif
 263 else
 264   core_conf.set('DISABLE_ORC', 1)
 265 endif
 266
 267 # Used to build SSE* things in audio-resampler
 268 sse_args = '-msse'
 269 sse2_args = '-msse2'
 270 sse41_args = '-msse4.1'
 271
 272 have_sse = cc.has_argument(sse_args)
 273 have_sse2 = cc.has_argument(sse2_args)
 274 have_sse41 = cc.has_argument(sse41_args)
 275
 276 if gst_dep.type_name() == 'internal'
 277     gst_proj = subproject('gstreamer')
 278
 279     if gst_proj.get_variable('disable_gst_debug')
 280         message('GStreamer debug system is disabled')
 281         add_project_arguments('-Wno-unused', language: 'c')
 282     else
 283         message('GStreamer debug system is enabled')
 284     endif
 285 else
 286     # We can't check that in the case of subprojects as we won't
 287     # be able to build against an internal dependency (which is not built yet)
 288     if not cc.compiles('''
 289 #include <gst/gstconfig.h>
 290 #ifdef GST_DISABLE_GST_DEBUG
 291 #error "debugging disabled, make compiler fail"
 292 #endif''' , dependencies: gst_dep)
 293         message('GStreamer debug system is disabled')
 294         add_project_arguments('-Wno-unused', language: 'c')
 295     else
 296         message('GStreamer debug system is enabled')
 297     endif
 298 endif
 299
 300 gir = find_program('g-ir-scanner', required : false)
 301 gnome = import('gnome')
 302 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 303 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 304     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 305     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 306     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 307     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 308     'gst_init(NULL,NULL);' ]
 309
 310 subdir('gst-libs')
 311 subdir('gst')
 312 subdir('ext')
 313 subdir('sys')
 314 subdir('tools')
 315 subdir('tests')
 316 subdir('pkgconfig')
 317
 318 # xgettext is optional (on Windows for instance)
 319 if find_program('xgettext', required : false).found()
 320   subdir('po')
 321 endif
 322
 323 if build_machine.system() == 'windows'
 324   message('Disabling gtk-doc while building on Windows')
 325 elif get_option('disable_gtkdoc')
 326   message('gtk-doc is disabled via options')
 327 else
 328   if find_program('gtkdoc-scan', required : false).found()
 329     subdir('docs')
 330   else
 331     message('Not building documentation as gtk-doc was not found')
 332   endif
 333 endif
 334
 335 # Use core_conf after all subdirs have set values
 336 configure_file(output : 'config.h', configuration : core_conf)
 337
 338 python3 = import('python3').find_python()
 339 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')