meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 orc_req = '>= 0.4.24'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25 soversion = 0
  26 # maintaining compatibility with the previous libtool versioning
  27 # current = minor * 100 + micro
  28 # FIXME: should be able to convert string to int somehow so we can just do maths
  29 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  30
  31 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  32
  33 cc = meson.get_compiler('c')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 # Symbol visibility
  54 if cc.has_argument('-fvisibility=hidden')
  55   add_project_arguments('-fvisibility=hidden', language: 'c')
  56 endif
  57
  58 # Disable strict aliasing
  59 if cc.has_argument('-fno-strict-aliasing')
  60   add_project_arguments('-fno-strict-aliasing', language: 'c')
  61 endif
  62
  63 core_conf = configuration_data()
  64 check_headers = [
  65   ['HAVE_DLFCN_H', 'dlfcn.h'],
  66   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  67   ['HAVE_INTTYPES_H', 'inttypes.h'],
  68   ['HAVE_MEMORY_H', 'memory.h'],
  69   ['HAVE_PROCESS_H', 'process.h'],
  70   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  71   ['HAVE_STDINT_H', 'stdint.h'],
  72   ['HAVE_STDLIB_H', 'stdlib.h'],
  73   ['HAVE_STRINGS_H', 'strings.h'],
  74   ['HAVE_STRING_H', 'string.h'],
  75   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  76   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  77   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  78   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  79   ['HAVE_UNISTD_H', 'unistd.h'],
  80   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  81   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  82 ]
  83 foreach h : check_headers
  84   if cc.has_header(h.get(1))
  85     core_conf.set(h.get(0), 1)
  86   endif
  87 endforeach
  88
  89 check_functions = [
  90   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  91   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  92   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  93   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  94   ['HAVE_LOG2', 'log2', '#include<math.h>'],
  95 ]
  96
  97 libm = cc.find_library('m', required : false)
  98 foreach f : check_functions
  99   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 100     core_conf.set(f.get(0), 1)
 101   endif
 102 endforeach
 103
 104 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 105 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 106 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 107 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 108 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 109
 110 core_conf.set('GETTEXT_PACKAGE', '"gst-plugins-base-1.0"')
 111 core_conf.set('PACKAGE', '"gst-plugins-base"')
 112 core_conf.set('VERSION', '"@0@"'.format(gst_version))
 113 core_conf.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 114 core_conf.set('GST_API_VERSION', '"@0@"'.format(api_version))
 115 core_conf.set('GST_INSTALL_PLUGINS_HELPER', '"/FIXME"')
 116 core_conf.set('GST_DATADIR', '"/FIXME"')
 117 core_conf.set('GST_LICENSE', '"LGPL"')
 118
 119 # GStreamer package name and origin url
 120 gst_package_name = get_option('with-package-name')
 121 if gst_package_name == ''
 122   if gst_version_nano == 0
 123     gst_package_name = 'GStreamer Base Plug-ins source release'
 124   elif gst_version_nano == 1
 125     gst_package_name = 'GStreamer Base Plug-ins git'
 126   else
 127     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 128   endif
 129 endif
 130 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 131 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 132
 133 # FIXME: These should be configure options
 134 core_conf.set('DEFAULT_VIDEOSINK', '"autovideosink"')
 135 core_conf.set('DEFAULT_AUDIOSINK', '"autoaudiosink"')
 136
 137 # Set whether the audioresampling method should be detected at runtime
 138 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 139
 140 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 141 if get_option('default_library') == 'static'
 142   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 143 endif
 144
 145 # X11 checks are for sys/ and tests/
 146 x11_dep = dependency('x11', required : false)
 147 # GLib checks are for the entire project
 148 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 149 # Almost everything that uses glib also uses gobject
 150 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 151              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 152 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 153
 154 core_conf.set('HAVE_X', x11_dep.found())
 155 core_conf.set('HAVE_GIO_UNIX_2_0',
 156     (gio_dep.type_name() != 'pkgconfig' and host_machine.system() != 'windows')
 157     or giounix_dep.found())
 158
 159 if gio_dep.type_name() == 'pkgconfig'
 160     core_conf.set_quoted('GIO_MODULE_DIR',
 161         gio_dep.get_pkgconfig_variable('giomoduledir'))
 162     core_conf.set_quoted('GIO_LIBDIR',
 163         gio_dep.get_pkgconfig_variable('libdir'))
 164     core_conf.set_quoted('GIO_PREFIX',
 165         gio_dep.get_pkgconfig_variable('prefix'))
 166 else
 167     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 168       get_option('libdir'), 'gio/modules'))
 169     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 170       get_option('libdir')))
 171     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 172 endif
 173
 174 configinc = include_directories('.')
 175 libsinc = include_directories('gst-libs')
 176
 177 # To use the subproject make subprojects directory
 178 # and put gstreamer meson git there (symlinking is fine)
 179 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 180   fallback : ['gstreamer', 'gst_dep'])
 181 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 182   fallback : ['gstreamer', 'gst_base_dep'])
 183 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 184   fallback : ['gstreamer', 'gst_net_dep'])
 185 if host_machine.system() != 'windows'
 186   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 187     fallback : ['gstreamer', 'gst_check_dep'])
 188 endif
 189 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 190   fallback : ['gstreamer', 'gst_controller_dep'])
 191
 192 # Used by the *_mkenum.py helper scripts
 193 glib_mkenums = find_program('glib-mkenums')
 194
 195 have_orcc = false
 196 orcc_args = []
 197 if get_option('use_orc') != 'no'
 198   need_orc = get_option('use_orc') == 'yes'
 199   # Used by various libraries/elements that use Orc code
 200   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 201   orcc = find_program('orcc', required : need_orc)
 202   if orc_dep.found() and orcc.found()
 203     have_orcc = true
 204     orcc_args = [orcc, '--include', 'glib.h']
 205     core_conf.set('HAVE_ORC', 1)
 206   else
 207     message('Orc Compiler not found, will use backup C code')
 208     core_conf.set('DISABLE_ORC', 1)
 209   endif
 210 else
 211   core_conf.set('DISABLE_ORC', 1)
 212 endif
 213
 214 # Used to build SSE* things in audio-resampler
 215 sse_args = '-msse'
 216 sse2_args = '-msse2'
 217 sse41_args = '-msse4.1'
 218
 219 have_sse = cc.has_argument(sse_args)
 220 have_sse2 = cc.has_argument(sse2_args)
 221 have_sse41 = cc.has_argument(sse41_args)
 222
 223 if gst_dep.type_name() == 'internal'
 224     gst_proj = subproject('gstreamer')
 225
 226     if gst_proj.get_variable('disable_gst_debug')
 227         message('GStreamer debug system is disabled')
 228         add_project_arguments('-Wno-unused', language: 'c')
 229     else
 230         message('GStreamer debug system is enabled')
 231     endif
 232 else
 233     # We can't check that in the case of subprojects as we won't
 234     # be able to build against an internal dependency (which is not built yet)
 235     if not cc.compiles('''
 236 #include <gst/gstconfig.h>
 237 #ifdef GST_DISABLE_GST_DEBUG
 238 #error "debugging disabled, make compiler fail"
 239 #endif''' , dependencies: gst_dep)
 240         message('GStreamer debug system is disabled')
 241         add_project_arguments('-Wno-unused', language: 'c')
 242     else
 243         message('GStreamer debug system is enabled')
 244     endif
 245 endif
 246
 247 gir = find_program('g-ir-scanner', required : false)
 248 gnome = import('gnome')
 249 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 250 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 251     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 252     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 253     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 254     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 255     'gst_init(NULL,NULL);' ]
 256
 257 subdir('gst-libs')
 258 subdir('gst')
 259 subdir('ext')
 260 subdir('sys')
 261 subdir('tools')
 262 subdir('tests')
 263 subdir('pkgconfig')
 264
 265 # xgettext is optional (on Windows for instance)
 266 if find_program('xgettext', required : false).found()
 267   subdir('po')
 268 endif
 269
 270 if build_machine.system() == 'windows'
 271   message('Disabling gtk-doc while building on Windows')
 272 elif get_option('disable_gtkdoc')
 273   message('gtk-doc is disabled via options')
 274 else
 275   if find_program('gtkdoc-scan', required : false).found()
 276     subdir('docs')
 277   else
 278     message('Not building documentation as gtk-doc was not found')
 279   endif
 280 endif
 281
 282 # Use core_conf after all subdirs have set values
 283 configure_file(output : 'config.h', configuration : core_conf)
 284
 285 python3 = import('python3').find_python()
 286 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')