meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 orc_req = '>= 0.4.24'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25 soversion = 0
  26 # maintaining compatibility with the previous libtool versioning
  27 # current = minor * 100 + micro
  28 # FIXME: should be able to convert string to int somehow so we can just do maths
  29 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  30
  31 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  32
  33 cc = meson.get_compiler('c')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  54   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  55 endif
  56
  57 # Symbol visibility
  58 if cc.has_argument('-fvisibility=hidden')
  59   add_project_arguments('-fvisibility=hidden', language: 'c')
  60 endif
  61
  62 # Disable strict aliasing
  63 if cc.has_argument('-fno-strict-aliasing')
  64   add_project_arguments('-fno-strict-aliasing', language: 'c')
  65 endif
  66
  67 core_conf = configuration_data()
  68 check_headers = [
  69   ['HAVE_DLFCN_H', 'dlfcn.h'],
  70   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  71   ['HAVE_INTTYPES_H', 'inttypes.h'],
  72   ['HAVE_MEMORY_H', 'memory.h'],
  73   ['HAVE_PROCESS_H', 'process.h'],
  74   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  75   ['HAVE_STDINT_H', 'stdint.h'],
  76   ['HAVE_STDLIB_H', 'stdlib.h'],
  77   ['HAVE_STRINGS_H', 'strings.h'],
  78   ['HAVE_STRING_H', 'string.h'],
  79   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  80   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  81   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  82   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  83   ['HAVE_UNISTD_H', 'unistd.h'],
  84   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  85   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  86   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
  87 ]
  88 foreach h : check_headers
  89   if cc.has_header(h.get(1))
  90     core_conf.set(h.get(0), 1)
  91   endif
  92 endforeach
  93
  94 check_functions = [
  95   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  96   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  97   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  98   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  99   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 100 ]
 101
 102 libm = cc.find_library('m', required : false)
 103 foreach f : check_functions
 104   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 105     core_conf.set(f.get(0), 1)
 106   endif
 107 endforeach
 108
 109 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 110 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 111 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 112 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 113 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 114
 115 if get_option('nls')
 116   core_conf.set('ENABLE_NLS', 1)
 117 endif
 118 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 119 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 120 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 121 core_conf.set_quoted('VERSION', gst_version)
 122 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 123 core_conf.set_quoted('GST_API_VERSION', api_version)
 124 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 125 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 126
 127 install_plugins_helper = get_option('install_plugins_helper')
 128 if install_plugins_helper == ''
 129   install_plugins_helper = join_paths(get_option('prefix'),
 130                                       get_option('libexecdir'),
 131                                       'gst-install-plugins-helper')
 132 endif
 133 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 134
 135 warning_flags = [
 136   '-Wmissing-declarations',
 137   '-Wredundant-decls',
 138   '-Wundef',
 139   '-Wwrite-strings',
 140   '-Wformat',
 141   '-Wformat-nonliteral',
 142   '-Wformat-security',
 143   '-Winit-self',
 144   '-Wmissing-include-dirs',
 145   '-Waddress',
 146   '-Wno-multichar',
 147   '-Wvla',
 148   '-Wpointer-arith',
 149 ]
 150
 151 warning_c_flags = [
 152   '-Wmissing-prototypes',
 153   '-Wdeclaration-after-statement',
 154 ]
 155
 156 warning_cxx_flags = [
 157   '-Waggregate-return',
 158 ]
 159
 160 if have_cxx
 161   cxx = meson.get_compiler('cpp')
 162   foreach extra_arg : warning_cxx_flags
 163     if cxx.has_argument (extra_arg)
 164       add_project_arguments([extra_arg], language: 'cpp')
 165     endif
 166   endforeach
 167 endif
 168
 169 foreach extra_arg : warning_flags
 170   if cc.has_argument (extra_arg)
 171     add_project_arguments([extra_arg], language: 'c')
 172   endif
 173   if have_cxx and cxx.has_argument (extra_arg)
 174     add_project_arguments([extra_arg], language: 'cpp')
 175   endif
 176 endforeach
 177
 178 foreach extra_arg : warning_c_flags
 179   if cc.has_argument (extra_arg)
 180     add_project_arguments([extra_arg], language: 'c')
 181   endif
 182 endforeach
 183
 184 # GStreamer package name and origin url
 185 gst_package_name = get_option('package-name')
 186 if gst_package_name == ''
 187   if gst_version_nano == 0
 188     gst_package_name = 'GStreamer Base Plug-ins source release'
 189   elif gst_version_nano == 1
 190     gst_package_name = 'GStreamer Base Plug-ins git'
 191   else
 192     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 193   endif
 194 endif
 195 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 196 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 197
 198 # FIXME: These should be configure options
 199 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 200 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 201
 202 # Set whether the audioresampling method should be detected at runtime
 203 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 204
 205 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 206 if get_option('default_library') == 'static'
 207   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 208 endif
 209
 210 # X11 checks are for sys/ and tests/
 211 x11_dep = dependency('x11', required : false)
 212 # GLib checks are for the entire project
 213 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 214 # Almost everything that uses glib also uses gobject
 215 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 216              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 217 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 218
 219 # some of the examples want GTK+
 220 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : false)
 221 gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : false)
 222 gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : false)
 223 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : false)
 224
 225 core_conf.set('HAVE_X', x11_dep.found())
 226 core_conf.set('HAVE_GIO_UNIX_2_0',
 227     (gio_dep.type_name() != 'pkgconfig' and host_machine.system() != 'windows')
 228     or giounix_dep.found())
 229
 230 if gio_dep.type_name() == 'pkgconfig'
 231     core_conf.set_quoted('GIO_MODULE_DIR',
 232         gio_dep.get_pkgconfig_variable('giomoduledir'))
 233     core_conf.set_quoted('GIO_LIBDIR',
 234         gio_dep.get_pkgconfig_variable('libdir'))
 235     core_conf.set_quoted('GIO_PREFIX',
 236         gio_dep.get_pkgconfig_variable('prefix'))
 237 else
 238     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 239       get_option('libdir'), 'gio/modules'))
 240     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 241       get_option('libdir')))
 242     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 243 endif
 244
 245 configinc = include_directories('.')
 246 libsinc = include_directories('gst-libs')
 247
 248 # To use the subproject make subprojects directory
 249 # and put gstreamer meson git there (symlinking is fine)
 250 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 251   fallback : ['gstreamer', 'gst_dep'])
 252 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 253   fallback : ['gstreamer', 'gst_base_dep'])
 254 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 255   fallback : ['gstreamer', 'gst_net_dep'])
 256 if host_machine.system() != 'windows'
 257   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 258     fallback : ['gstreamer', 'gst_check_dep'])
 259 endif
 260 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 261   fallback : ['gstreamer', 'gst_controller_dep'])
 262
 263 have_orcc = false
 264 orcc_args = []
 265 if get_option('orc') != 'no'
 266   need_orc = get_option('orc') == 'yes'
 267   # Used by various libraries/elements that use Orc code
 268   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 269   orcc = find_program('orcc', required : need_orc)
 270   if orc_dep.found() and orcc.found()
 271     have_orcc = true
 272     orcc_args = [orcc, '--include', 'glib.h']
 273     core_conf.set('HAVE_ORC', 1)
 274   else
 275     message('Orc Compiler not found, will use backup C code')
 276     core_conf.set('DISABLE_ORC', 1)
 277   endif
 278 else
 279   core_conf.set('DISABLE_ORC', 1)
 280 endif
 281
 282 # Used to build SSE* things in audio-resampler
 283 sse_args = '-msse'
 284 sse2_args = '-msse2'
 285 sse41_args = '-msse4.1'
 286
 287 have_sse = cc.has_argument(sse_args)
 288 have_sse2 = cc.has_argument(sse2_args)
 289 have_sse41 = cc.has_argument(sse41_args)
 290
 291 if gst_dep.type_name() == 'internal'
 292     gst_proj = subproject('gstreamer')
 293
 294     if not gst_proj.get_variable('gst_debug')
 295         message('GStreamer debug system is disabled')
 296         add_project_arguments('-Wno-unused', language: 'c')
 297     else
 298         message('GStreamer debug system is enabled')
 299     endif
 300 else
 301     # We can't check that in the case of subprojects as we won't
 302     # be able to build against an internal dependency (which is not built yet)
 303     if not cc.compiles('''
 304 #include <gst/gstconfig.h>
 305 #ifdef GST_DISABLE_GST_DEBUG
 306 #error "debugging disabled, make compiler fail"
 307 #endif''' , dependencies: gst_dep)
 308         message('GStreamer debug system is disabled')
 309         add_project_arguments('-Wno-unused', language: 'c')
 310     else
 311         message('GStreamer debug system is enabled')
 312     endif
 313 endif
 314
 315 gir = find_program('g-ir-scanner', required : false)
 316 gnome = import('gnome')
 317 build_gir = gir.found() and not meson.is_cross_build() and get_option('introspection')
 318 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 319     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 320     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 321     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 322     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 323     'gst_init(NULL,NULL);' ]
 324
 325 pkgconfig = import('pkgconfig')
 326 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 327 if get_option('default_library') == 'shared'
 328   # If we don't build static plugins there is no need to generate pc files
 329   plugins_pkgconfig_install_dir = disabler()
 330 endif
 331
 332 subdir('gst-libs')
 333 subdir('gst')
 334 subdir('ext')
 335 subdir('sys')
 336 subdir('tools')
 337 subdir('tests')
 338 subdir('pkgconfig')
 339
 340 # xgettext is optional (on Windows for instance)
 341 if get_option('nls') and find_program('xgettext', required : false).found()
 342   subdir('po')
 343 endif
 344
 345 if build_machine.system() == 'windows'
 346   message('Disabling gtk-doc while building on Windows')
 347 elif not get_option('gtk_doc')
 348   message('gtk-doc is disabled via options')
 349 else
 350   if find_program('gtkdoc-scan', required : false).found()
 351     subdir('docs')
 352   else
 353     message('Not building documentation as gtk-doc was not found')
 354   endif
 355 endif
 356
 357 # Use core_conf after all subdirs have set values
 358 configure_file(output : 'config.h', configuration : core_conf)
 359
 360 python3 = import('python3').find_python()
 361 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')