meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('default_library')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48 endif
  49
  50 # Symbol visibility
  51 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  52 if have_visibility_hidden
  53   add_project_arguments('-fvisibility=hidden', language: 'c')
  54 endif
  55
  56 # Disable strict aliasing
  57 if cc.has_argument('-fno-strict-aliasing')
  58   add_project_arguments('-fno-strict-aliasing', language: 'c')
  59 endif
  60
  61 cdata = configuration_data()
  62 cdata.set_quoted('GST_API_VERSION', apiversion)
  63 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  64 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  65 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  66 cdata.set_quoted('GST_API_VERSION', '1.0')
  67 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  68 cdata.set_quoted('GST_LICENSE', 'LGPL')
  69 cdata.set_quoted('PACKAGE', 'gstreamer')
  70 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  71 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  72 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  73 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  74 cdata.set_quoted('PACKAGE_URL', '')
  75 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  76 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  77 cdata.set_quoted('VERSION', gst_version)
  78 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  79 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  80 cdata.set('ENABLE_NLS', get_option('nls'))
  81 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  82 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  83 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  84   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  85
  86 if host_system == 'darwin'
  87   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
  88 endif
  89
  90 if gst_version_nano > 0
  91     # Have GST_ERROR message printed when running from git
  92     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  93 else
  94     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  95 endif
  96
  97 # GStreamer package name and origin url
  98 gst_package_name = get_option('package-name')
  99 if gst_package_name == ''
 100   if gst_version_nano == 0
 101     gst_package_name = 'GStreamer source release'
 102   elif gst_version_nano == 1
 103     gst_package_name = 'GStreamer git'
 104   else
 105     gst_package_name = 'GStreamer prerelease'
 106   endif
 107 endif
 108 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 109 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 110
 111 # These are only needed/used by the ABI tests
 112 host_defines = [
 113   [ 'x86', 'HAVE_CPU_I386' ],
 114   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 115   [ 'arm', 'HAVE_CPU_ARM' ],
 116   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 117   [ 'mips', 'HAVE_CPU_MIPS' ],
 118   [ 'powerpc', 'HAVE_CPU_PPC' ],
 119   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 120   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 121   [ 'sparc', 'HAVE_CPU_SPARC' ],
 122   [ 'ia64', 'HAVE_CPU_IA64' ],
 123   [ 'hppa', 'HAVE_CPU_HPPA' ],
 124   [ 'm68k', 'HAVE_CPU_M68K' ],
 125   [ 's390', 'HAVE_CPU_S390' ],
 126 ]
 127 foreach h : host_defines
 128   if h.get(0) == host_machine.cpu()
 129     cdata.set(h.get(1), 1)
 130   endif
 131 endforeach
 132 # FIXME: should really be called HOST_CPU or such
 133 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 134
 135 check_headers = [
 136   'dlfcn.h',
 137   'inttypes.h',
 138   'memory.h',
 139   'poll.h',
 140   'stdint.h',
 141   'stdio_ext.h',
 142   'strings.h',
 143   'string.h',
 144   'sys/param.h',
 145   'sys/poll.h',
 146   'sys/prctl.h',
 147   'sys/socket.h',
 148   'sys/stat.h',
 149   'sys/times.h',
 150   'sys/time.h',
 151   'sys/types.h',
 152   'sys/utsname.h',
 153   'sys/wait.h',
 154   'ucontext.h',
 155   'unistd.h',
 156   'valgrind/valgrind.h',
 157   'sys/resource.h',
 158 ]
 159
 160 if host_machine.system() == 'windows'
 161   check_headers += ['winsock2.h']
 162 endif
 163
 164 foreach h : check_headers
 165   if cc.has_header(h)
 166     define = 'HAVE_' + h.underscorify().to_upper()
 167     cdata.set(define, 1)
 168   endif
 169 endforeach
 170
 171 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 172   cdata.set('HAVE_TM_GMTOFF', 1)
 173 endif
 174
 175 check_functions = [
 176   'gmtime_r',
 177   'sigaction',
 178   'getrusage',
 179   'fseeko',
 180   'ftello',
 181   'poll',
 182   'ppoll',
 183   'pselect',
 184   'getpagesize',
 185   'clock_gettime',
 186   # These are needed by libcheck
 187   'getline',
 188   'mkstemp',
 189   'alarm',
 190   'gettimeofday',
 191 ]
 192
 193 foreach f : check_functions
 194   if cc.has_function(f)
 195     define = 'HAVE_' + f.underscorify().to_upper()
 196     cdata.set(define, 1)
 197   endif
 198 endforeach
 199
 200 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 201   cdata.set('HAVE_LOCALTIME_R', 1)
 202   # Needed by libcheck
 203   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 204 endif
 205
 206 if cc.links('''#include <pthread.h>
 207                int main() {
 208                  pthread_setname_np("example"); return 0;
 209                }''', name : 'pthread_setname_np(const char*)')
 210   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 211 endif
 212
 213 # Check for posix timers and the monotonic clock
 214 time_prefix = '#include <time.h>\n'
 215 if cdata.has('HAVE_UNISTD_H')
 216   time_prefix += '#include <unistd.h>'
 217 endif
 218
 219 posix_timers_src = time_prefix + '''
 220 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 221 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 222 #endif
 223 '''
 224 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 225   cdata.set('HAVE_POSIX_TIMERS', 1)
 226 endif
 227
 228 monotonic_clock_src = time_prefix + '''
 229 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 230 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 231 #endif
 232 '''
 233 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 234   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 235 endif
 236
 237 # Check for __uint128_t (gcc) by checking for 128-bit division
 238 uint128_t_src = '''int main() {
 239 static __uint128_t v1 = 100;
 240 static __uint128_t v2 = 10;
 241 static __uint128_t u;
 242 u = v1 / v2;
 243 }'''
 244 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 245   cdata.set('HAVE_UINT128_T', 1)
 246 endif
 247
 248 # All supported platforms have long long now
 249 cdata.set('HAVE_LONG_LONG', 1)
 250
 251 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 252 # building with MSVC
 253 if cc.get_id() == 'msvc'
 254   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 255 else
 256   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 257 endif
 258
 259 # -------------------------------------------------------------------------------------
 260 # config.h things needed by libcheck
 261 # -------------------------------------------------------------------------------------
 262 if cc.has_function('getpid')
 263   cdata.set('HAVE_GETPID', 1)
 264 elif host_system == 'windows' and cc.has_function('_getpid')
 265   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 266   cdata.set('HAVE__GETPID', 1)
 267 endif
 268 if cc.has_function('strdup')
 269   cdata.set('HAVE_DECL_STRDUP', 1)
 270 elif host_system == 'windows' and cc.has_function('_strdup')
 271   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 272 endif
 273 if host_machine.system() != 'windows'
 274   cdata.set('HAVE_FORK', 1)
 275 else
 276   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 277   cdata.set('HAVE_FORK', 0)
 278 endif
 279 if cc.has_function('strsignal')
 280   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 281 endif
 282 # Check for availability of types
 283 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 284   cdata.set('clockid_t', 'int')
 285 endif
 286 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 287   cdata.set('timer_t', 'int')
 288 endif
 289 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 290                       prefix : '#include <time.h>')
 291   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 292 endif
 293 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 294                       prefix : '#include <time.h>')
 295   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 296 endif
 297
 298 # Platform deps; only ws2_32 and execinfo for now
 299 platform_deps = []
 300 if host_machine.system() == 'windows'
 301   platform_deps = [cc.find_library('ws2_32')]
 302 endif
 303
 304 backtrace_deps = []
 305 if get_option('libunwind')
 306   unwind_dep = dependency('libunwind', required : false)
 307   dw_dep = dependency('libdw', required: false)
 308   backtrace_deps = [unwind_dep, dw_dep]
 309   if unwind_dep.found()
 310     cdata.set('HAVE_UNWIND', 1)
 311     if dw_dep.found()
 312       cdata.set('HAVE_DW', 1)
 313     else
 314       message('Support for backtraces is partial only.')
 315     endif
 316   else
 317     if cc.has_function('backtrace')
 318       cdata.set('HAVE_BACKTRACE', 1)
 319     else
 320         message('NO backtraces support.')
 321     endif
 322   endif
 323 endif
 324
 325 if cc.has_header('execinfo.h')
 326   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 327     cdata.set('HAVE_BACKTRACE', 1)
 328   else
 329     execinfo_dep = cc.find_library('execinfo', required : false)
 330     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 331       cdata.set('HAVE_BACKTRACE', 1)
 332       platform_deps += execinfo_dep
 333     endif
 334   endif
 335 endif
 336
 337 gst_debug = get_option('gst_debug')
 338 if not gst_debug
 339   add_project_arguments(['-Wno-unused'], language: 'c')
 340 endif
 341
 342 warning_flags = [
 343   '-Wmissing-declarations',
 344   '-Wmissing-prototypes',
 345   '-Wredundant-decls',
 346   '-Wundef',
 347   '-Wwrite-strings',
 348   '-Wformat',
 349   '-Wformat-nonliteral',
 350   '-Wformat-security',
 351   '-Wold-style-definition',
 352   '-Winit-self',
 353   '-Wmissing-include-dirs',
 354   '-Waddress',
 355   '-Waggregate-return',
 356   '-Wno-multichar',
 357   '-Wnested-externs',
 358   '-Wdeclaration-after-statement',
 359   '-Wvla',
 360   '-Wpointer-arith',
 361 ]
 362
 363 foreach extra_arg : warning_flags
 364   if cc.has_argument (extra_arg)
 365     add_project_arguments([extra_arg], language: 'c')
 366   endif
 367 endforeach
 368
 369 # Used by the gstutils test
 370 gmp_dep = cc.find_library('gmp', required : false)
 371 cdata.set('HAVE_GMP', gmp_dep.found())
 372 gsl_dep = cc.find_library('gsl', required : false)
 373 gslcblas_dep = cc.find_library('gslcblas', required : false)
 374 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 375 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 376
 377 # Used by gstinfo.c
 378 dl_dep = cc.find_library('dl', required : false)
 379 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 380
 381
 382 configinc = include_directories('.')
 383 libsinc = include_directories('libs')
 384 privinc = include_directories('gst')
 385
 386 # Find dependencies
 387 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 388   fallback: ['glib', 'libglib_dep'])
 389 gobject_dep = dependency('gobject-2.0',
 390   fallback: ['glib', 'libgobject_dep'])
 391 gmodule_dep = dependency('gmodule-2.0',
 392   fallback: ['glib', 'libgmodule_dep'])
 393 if host_machine.system() == 'windows'
 394     gio_dep = dependency('gio-2.0',
 395         fallback: ['glib', 'libgio_dep'])
 396 else
 397     gio_dep = [dependency('gio-2.0',
 398                   fallback: ['glib', 'libgio_dep']),
 399                dependency('gio-unix-2.0',
 400                   fallback: ['glib', 'libgio_dep'])]
 401 endif
 402
 403 mathlib = cc.find_library('m', required : false)
 404 # Needed for timer_create/settime/delete
 405 # Also provides clock_gettime in glibc < 2.17
 406 rt_lib = cc.find_library('rt', required : false)
 407
 408 gir = find_program('g-ir-scanner', required : false)
 409 gnome = import('gnome')
 410
 411 # Fixme, not very elegant.
 412 build_gir = gir.found() and not meson.is_cross_build() and get_option('introspection')
 413
 414 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 415     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 416     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 417     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 418     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 419     'gst_init(NULL,NULL);' ]
 420
 421 gst_c_args = ['-DHAVE_CONFIG_H']
 422
 423 # FIXME: This is only needed on windows and probably breaks when
 424 # libtype=='both'. We should add this flag to static_c_args instead when Meson
 425 # supports it: https://github.com/mesonbuild/meson/issues/3304
 426 if libtype == 'static'
 427   gst_c_args += ['-DGST_STATIC_COMPILATION']
 428 endif
 429
 430 # Used in gst/parse/meson.build and below
 431 python3 = import('python3').find_python()
 432
 433 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 434
 435 bashcomp_found = bashcomp_dep.found()
 436 bash_completions_dir = ''
 437 bash_helpers_dir = ''
 438
 439 if bashcomp_found
 440   # get_pkgconfig_variable() won't let us set the prefix
 441   pkgconfig = find_program('pkg-config')
 442
 443   runcmd = run_command(pkgconfig,
 444       '--define-variable=prefix=.',
 445       '--variable=completionsdir',
 446       'bash-completion')
 447
 448   if (runcmd.returncode() == 0)
 449     bash_completions_dir = runcmd.stdout().strip()
 450   else
 451     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 452     bashcomp_found = false
 453   endif
 454
 455   runcmd = run_command(pkgconfig,
 456       '--define-variable=prefix=.',
 457       '--variable=helpersdir',
 458       'bash-completion')
 459
 460   if (runcmd.returncode() == 0)
 461     bash_helpers_dir = runcmd.stdout().strip()
 462   else
 463     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 464     bashcomp_found = false
 465   endif
 466 endif
 467
 468 subdir('gst')
 469 subdir('libs')
 470 subdir('plugins')
 471 subdir('tools')
 472 subdir('pkgconfig')
 473 subdir('tests')
 474 subdir('data')
 475
 476 # xgettext is optional (on Windows for instance)
 477 if get_option('nls') and find_program('xgettext', required : false).found()
 478   subdir('po')
 479 endif
 480
 481 configure_file(output : 'config.h', configuration : cdata)
 482
 483 if build_machine.system() == 'windows'
 484   message('Disabling gtk-doc while building on Windows')
 485 elif not get_option('gtkdoc')
 486   message('gtk-doc is disabled via options')
 487 else
 488   if find_program('gtkdoc-scan', required : false).found()
 489     subdir('docs')
 490   else
 491     message('Not building documentation as gtk-doc was not found')
 492   endif
 493 endif
 494
 495 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 496
 497 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))