meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('default_library')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48 endif
  49
  50 # Symbol visibility
  51 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  52 if have_visibility_hidden
  53   add_project_arguments('-fvisibility=hidden', language: 'c')
  54 endif
  55
  56 # Disable strict aliasing
  57 if cc.has_argument('-fno-strict-aliasing')
  58   add_project_arguments('-fno-strict-aliasing', language: 'c')
  59 endif
  60
  61 cdata = configuration_data()
  62 cdata.set_quoted('GST_API_VERSION', apiversion)
  63 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  64 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  65 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  66 cdata.set_quoted('GST_API_VERSION', '1.0')
  67 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  68 cdata.set_quoted('GST_LICENSE', 'LGPL')
  69 cdata.set_quoted('PACKAGE', 'gstreamer')
  70 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  71 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  72 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  73 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  74 cdata.set_quoted('PACKAGE_URL', '')
  75 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  76 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  77 cdata.set_quoted('VERSION', gst_version)
  78 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  79 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  80 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  81 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  82 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  83   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  84
  85 if host_system == 'darwin'
  86   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
  87 endif
  88
  89 if gst_version_nano > 0
  90     # Have GST_ERROR message printed when running from git
  91     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  92 else
  93     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  94 endif
  95
  96 # GStreamer package name and origin url
  97 gst_package_name = get_option('package-name')
  98 if gst_package_name == ''
  99   if gst_version_nano == 0
 100     gst_package_name = 'GStreamer source release'
 101   elif gst_version_nano == 1
 102     gst_package_name = 'GStreamer git'
 103   else
 104     gst_package_name = 'GStreamer prerelease'
 105   endif
 106 endif
 107 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 108 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 109
 110 # These are only needed/used by the ABI tests
 111 host_defines = [
 112   [ 'x86', 'HAVE_CPU_I386' ],
 113   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 114   [ 'arm', 'HAVE_CPU_ARM' ],
 115   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 116   [ 'mips', 'HAVE_CPU_MIPS' ],
 117   [ 'powerpc', 'HAVE_CPU_PPC' ],
 118   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 119   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 120   [ 'sparc', 'HAVE_CPU_SPARC' ],
 121   [ 'ia64', 'HAVE_CPU_IA64' ],
 122   [ 'hppa', 'HAVE_CPU_HPPA' ],
 123   [ 'm68k', 'HAVE_CPU_M68K' ],
 124   [ 's390', 'HAVE_CPU_S390' ],
 125 ]
 126 foreach h : host_defines
 127   if h.get(0) == host_machine.cpu()
 128     cdata.set(h.get(1), 1)
 129   endif
 130 endforeach
 131 # FIXME: should really be called HOST_CPU or such
 132 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 133
 134 check_headers = [
 135   'dlfcn.h',
 136   'inttypes.h',
 137   'memory.h',
 138   'poll.h',
 139   'stdint.h',
 140   'stdio_ext.h',
 141   'strings.h',
 142   'string.h',
 143   'sys/param.h',
 144   'sys/poll.h',
 145   'sys/prctl.h',
 146   'sys/socket.h',
 147   'sys/stat.h',
 148   'sys/times.h',
 149   'sys/time.h',
 150   'sys/types.h',
 151   'sys/utsname.h',
 152   'sys/wait.h',
 153   'ucontext.h',
 154   'unistd.h',
 155   'valgrind/valgrind.h',
 156   'sys/resource.h',
 157 ]
 158
 159 if host_machine.system() == 'windows'
 160   check_headers += ['winsock2.h']
 161 endif
 162
 163 foreach h : check_headers
 164   if cc.has_header(h)
 165     define = 'HAVE_' + h.underscorify().to_upper()
 166     cdata.set(define, 1)
 167   endif
 168 endforeach
 169
 170 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 171   cdata.set('HAVE_TM_GMTOFF', 1)
 172 endif
 173
 174 check_functions = [
 175   'gmtime_r',
 176   'sigaction',
 177   'getrusage',
 178   'fseeko',
 179   'ftello',
 180   'poll',
 181   'ppoll',
 182   'pselect',
 183   'getpagesize',
 184   'clock_gettime',
 185   # These are needed by libcheck
 186   'getline',
 187   'mkstemp',
 188   'alarm',
 189   'gettimeofday',
 190 ]
 191
 192 foreach f : check_functions
 193   if cc.has_function(f)
 194     define = 'HAVE_' + f.underscorify().to_upper()
 195     cdata.set(define, 1)
 196   endif
 197 endforeach
 198
 199 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 200   cdata.set('HAVE_LOCALTIME_R', 1)
 201   # Needed by libcheck
 202   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 203 endif
 204
 205 if cc.links('''#include <pthread.h>
 206                int main() {
 207                  pthread_setname_np("example"); return 0;
 208                }''', name : 'pthread_setname_np(const char*)')
 209   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 210 endif
 211
 212 # Check for posix timers and the monotonic clock
 213 time_prefix = '#include <time.h>\n'
 214 if cdata.has('HAVE_UNISTD_H')
 215   time_prefix += '#include <unistd.h>'
 216 endif
 217
 218 posix_timers_src = time_prefix + '''
 219 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 220 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 221 #endif
 222 '''
 223 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 224   cdata.set('HAVE_POSIX_TIMERS', 1)
 225 endif
 226
 227 monotonic_clock_src = time_prefix + '''
 228 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 229 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 230 #endif
 231 '''
 232 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 233   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 234 endif
 235
 236 # Check for __uint128_t (gcc) by checking for 128-bit division
 237 uint128_t_src = '''int main() {
 238 static __uint128_t v1 = 100;
 239 static __uint128_t v2 = 10;
 240 static __uint128_t u;
 241 u = v1 / v2;
 242 }'''
 243 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 244   cdata.set('HAVE_UINT128_T', 1)
 245 endif
 246
 247 # All supported platforms have long long now
 248 cdata.set('HAVE_LONG_LONG', 1)
 249
 250 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 251 # building with MSVC
 252 if cc.get_id() == 'msvc'
 253   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 254 else
 255   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 256 endif
 257
 258 # -------------------------------------------------------------------------------------
 259 # config.h things needed by libcheck
 260 # -------------------------------------------------------------------------------------
 261 if cc.has_function('getpid')
 262   cdata.set('HAVE_GETPID', 1)
 263 elif host_system == 'windows' and cc.has_function('_getpid')
 264   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 265   cdata.set('HAVE__GETPID', 1)
 266 endif
 267 if cc.has_function('strdup')
 268   cdata.set('HAVE_DECL_STRDUP', 1)
 269 elif host_system == 'windows' and cc.has_function('_strdup')
 270   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 271 endif
 272 if host_machine.system() != 'windows'
 273   cdata.set('HAVE_FORK', 1)
 274 else
 275   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 276   cdata.set('HAVE_FORK', 0)
 277 endif
 278 if cc.has_function('strsignal')
 279   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 280 endif
 281 # Check for availability of types
 282 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 283   cdata.set('clockid_t', 'int')
 284 endif
 285 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 286   cdata.set('timer_t', 'int')
 287 endif
 288 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 289                       prefix : '#include <time.h>')
 290   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 291 endif
 292 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 293                       prefix : '#include <time.h>')
 294   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 295 endif
 296
 297 # Platform deps; only ws2_32 and execinfo for now
 298 platform_deps = []
 299 if host_machine.system() == 'windows'
 300   platform_deps = [cc.find_library('ws2_32')]
 301 endif
 302
 303 backtrace_deps = []
 304 if get_option('libunwind')
 305   unwind_dep = dependency('libunwind', required : false)
 306   dw_dep = dependency('libdw', required: false)
 307   backtrace_deps = [unwind_dep, dw_dep]
 308   if unwind_dep.found()
 309     cdata.set('HAVE_UNWIND', 1)
 310     if dw_dep.found()
 311       cdata.set('HAVE_DW', 1)
 312     else
 313       message('Support for backtraces is partial only.')
 314     endif
 315   else
 316     if cc.has_function('backtrace')
 317       cdata.set('HAVE_BACKTRACE', 1)
 318     else
 319         message('NO backtraces support.')
 320     endif
 321   endif
 322 endif
 323
 324 if cc.has_header('execinfo.h')
 325   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 326     cdata.set('HAVE_BACKTRACE', 1)
 327   else
 328     execinfo_dep = cc.find_library('execinfo', required : false)
 329     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 330       cdata.set('HAVE_BACKTRACE', 1)
 331       platform_deps += execinfo_dep
 332     endif
 333   endif
 334 endif
 335
 336 gst_debug = get_option('gst_debug')
 337 if not gst_debug
 338   add_project_arguments(['-Wno-unused'], language: 'c')
 339 endif
 340
 341 warning_flags = [
 342   '-Wmissing-declarations',
 343   '-Wmissing-prototypes',
 344   '-Wredundant-decls',
 345   '-Wundef',
 346   '-Wwrite-strings',
 347   '-Wformat',
 348   '-Wformat-nonliteral',
 349   '-Wformat-security',
 350   '-Wold-style-definition',
 351   '-Winit-self',
 352   '-Wmissing-include-dirs',
 353   '-Waddress',
 354   '-Waggregate-return',
 355   '-Wno-multichar',
 356   '-Wnested-externs',
 357   '-Wdeclaration-after-statement',
 358   '-Wvla',
 359   '-Wpointer-arith',
 360 ]
 361
 362 foreach extra_arg : warning_flags
 363   if cc.has_argument (extra_arg)
 364     add_project_arguments([extra_arg], language: 'c')
 365   endif
 366 endforeach
 367
 368 # Used by the gstutils test
 369 gmp_dep = cc.find_library('gmp', required : false)
 370 cdata.set('HAVE_GMP', gmp_dep.found())
 371 gsl_dep = cc.find_library('gsl', required : false)
 372 gslcblas_dep = cc.find_library('gslcblas', required : false)
 373 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 374 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 375
 376 # Used by gstinfo.c
 377 dl_dep = cc.find_library('dl', required : false)
 378 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 379
 380
 381 configinc = include_directories('.')
 382 libsinc = include_directories('libs')
 383 privinc = include_directories('gst')
 384
 385 # Find dependencies
 386 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 387   fallback: ['glib', 'libglib_dep'])
 388 gobject_dep = dependency('gobject-2.0',
 389   fallback: ['glib', 'libgobject_dep'])
 390 gmodule_dep = dependency('gmodule-2.0',
 391   fallback: ['glib', 'libgmodule_dep'])
 392 if host_machine.system() == 'windows'
 393     gio_dep = dependency('gio-2.0',
 394         fallback: ['glib', 'libgio_dep'])
 395 else
 396     gio_dep = [dependency('gio-2.0',
 397                   fallback: ['glib', 'libgio_dep']),
 398                dependency('gio-unix-2.0',
 399                   fallback: ['glib', 'libgio_dep'])]
 400 endif
 401
 402 mathlib = cc.find_library('m', required : false)
 403 # Needed for timer_create/settime/delete
 404 # Also provides clock_gettime in glibc < 2.17
 405 rt_lib = cc.find_library('rt', required : false)
 406
 407 gir = find_program('g-ir-scanner', required : false)
 408 gnome = import('gnome')
 409
 410 # Fixme, not very elegant.
 411 build_gir = gir.found() and not meson.is_cross_build() and get_option('introspection')
 412
 413 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 414     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 415     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 416     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 417     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 418     'gst_init(NULL,NULL);' ]
 419
 420 gst_c_args = ['-DHAVE_CONFIG_H']
 421
 422 # FIXME: This is only needed on windows and probably breaks when
 423 # libtype=='both'. We should add this flag to static_c_args instead when Meson
 424 # supports it: https://github.com/mesonbuild/meson/issues/3304
 425 if libtype == 'static'
 426   gst_c_args += ['-DGST_STATIC_COMPILATION']
 427 endif
 428
 429 # Used in gst/parse/meson.build and below
 430 python3 = import('python3').find_python()
 431
 432 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 433
 434 bashcomp_found = bashcomp_dep.found()
 435 bash_completions_dir = ''
 436 bash_helpers_dir = ''
 437
 438 if bashcomp_found
 439   # get_pkgconfig_variable() won't let us set the prefix
 440   pkgconfig = find_program('pkg-config')
 441
 442   runcmd = run_command(pkgconfig,
 443       '--define-variable=prefix=.',
 444       '--variable=completionsdir',
 445       'bash-completion')
 446
 447   if (runcmd.returncode() == 0)
 448     bash_completions_dir = runcmd.stdout().strip()
 449   else
 450     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 451     bashcomp_found = false
 452   endif
 453
 454   runcmd = run_command(pkgconfig,
 455       '--define-variable=prefix=.',
 456       '--variable=helpersdir',
 457       'bash-completion')
 458
 459   if (runcmd.returncode() == 0)
 460     bash_helpers_dir = runcmd.stdout().strip()
 461   else
 462     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 463     bashcomp_found = false
 464   endif
 465 endif
 466
 467 subdir('gst')
 468 subdir('libs')
 469 subdir('plugins')
 470 subdir('tools')
 471 subdir('pkgconfig')
 472 subdir('tests')
 473 subdir('data')
 474
 475 # xgettext is optional (on Windows for instance)
 476 if find_program('xgettext', required : false).found()
 477   subdir('po')
 478 endif
 479
 480 configure_file(output : 'config.h', configuration : cdata)
 481
 482 if build_machine.system() == 'windows'
 483   message('Disabling gtk-doc while building on Windows')
 484 elif not get_option('gtkdoc')
 485   message('gtk-doc is disabled via options')
 486 else
 487   if find_program('gtkdoc-scan', required : false).found()
 488     subdir('docs')
 489   else
 490     message('Not building documentation as gtk-doc was not found')
 491   endif
 492 endif
 493
 494 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 495
 496 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))