meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.16.2',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 # FIXME: automagic
  20 have_cxx = add_languages('cpp', required : false)
  21
  22 glib_req = '>= 2.40.0'
  23 orc_req = '>= 0.4.17'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27
  28 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  29
  30 cc = meson.get_compiler('c')
  31 host_system = host_machine.system()
  32
  33 if cc.get_id() == 'msvc'
  34   # Ignore several spurious warnings for things gstreamer does very commonly
  35   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37   # NOTE: Only add warnings here if you are sure they're spurious
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  44       language : 'c')
  45   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  46   # are built with MinGW
  47   noseh_link_args = ['/SAFESEH:NO']
  48 else
  49   noseh_link_args = []
  50 endif
  51
  52 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  53   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  54 endif
  55
  56 # Symbol visibility
  57 if cc.has_argument('-fvisibility=hidden')
  58   add_project_arguments('-fvisibility=hidden', language: 'c')
  59 endif
  60
  61 # Disable strict aliasing
  62 if cc.has_argument('-fno-strict-aliasing')
  63   add_project_arguments('-fno-strict-aliasing', language: 'c')
  64 endif
  65
  66 # Define G_DISABLE_DEPRECATED for development versions
  67 if gst_version_is_dev
  68   message('Disabling deprecated GLib API')
  69   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  70 endif
  71
  72 cast_checks = get_option('gobject-cast-checks')
  73 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  74   message('Disabling GLib cast checks')
  75   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  76 endif
  77
  78 glib_asserts = get_option('glib-asserts')
  79 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  80   message('Disabling GLib asserts')
  81   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  82 endif
  83
  84 glib_checks = get_option('glib-checks')
  85 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  86   message('Disabling GLib checks')
  87   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  88 endif
  89
  90 cdata = configuration_data()
  91
  92 check_headers = [
  93   ['HAVE_DLFCN_H', 'dlfcn.h'],
  94   ['HAVE_FCNTL_H', 'fcntl.h'],
  95   ['HAVE_INTTYPES_H', 'inttypes.h'],
  96   ['HAVE_MEMORY_H', 'memory.h'],
  97   ['HAVE_PROCESS_H', 'process.h'],
  98   ['HAVE_STDINT_H', 'stdint.h'],
  99   ['HAVE_STDLIB_H', 'stdlib.h'],
 100   ['HAVE_STRINGS_H', 'strings.h'],
 101   ['HAVE_STRING_H', 'string.h'],
 102   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
 103   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 104   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 105   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 106   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 107   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 108   ['HAVE_UNISTD_H', 'unistd.h'],
 109 ]
 110
 111 foreach h : check_headers
 112   if cc.has_header(h.get(1))
 113     cdata.set(h.get(0), 1)
 114   endif
 115 endforeach
 116
 117 check_functions = [
 118   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
 119   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
 120   ['HAVE_COSH', 'cosh', '#include<math.h>'],
 121 # check token HAVE_CPU_ALPHA
 122 # check token HAVE_CPU_ARM
 123 # check token HAVE_CPU_CRIS
 124 # check token HAVE_CPU_CRISV32
 125 # check token HAVE_CPU_HPPA
 126 # check token HAVE_CPU_I386
 127 # check token HAVE_CPU_IA64
 128 # check token HAVE_CPU_M68K
 129 # check token HAVE_CPU_MIPS
 130 # check token HAVE_CPU_PPC
 131 # check token HAVE_CPU_PPC64
 132 # check token HAVE_CPU_S390
 133 # check token HAVE_CPU_SPARC
 134 # check token HAVE_CPU_X86_64
 135   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 136 # check token HAVE_DIRECTSOUND
 137 # check token HAVE_EXPERIMENTAL
 138 # check token HAVE_EXTERNAL
 139 # check token HAVE_FPCLASS
 140 # check token HAVE_GCC_ASM
 141   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 142 # check token HAVE_GETTEXT
 143 # check token HAVE_GST_V4L2
 144   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 145 # check token HAVE_LIBV4L2
 146   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 147   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 148 # check token HAVE_OSX_AUDIO
 149 # check token HAVE_OSX_VIDEO
 150 # check token HAVE_RDTSC
 151   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 152 # check token HAVE_WAVEFORM
 153 ]
 154
 155 libm = cc.find_library('m', required : false)
 156
 157 foreach f : check_functions
 158   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 159     cdata.set(f.get(0), 1)
 160   endif
 161 endforeach
 162
 163 cdata.set('HAVE_IOS', host_system == 'ios')
 164
 165 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 166 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 167 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 168 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 169 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 170 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 171
 172 # Here be fixmes.
 173 # FIXME: check if this is correct
 174 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 175 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 176 cdata.set_quoted('VERSION', gst_version)
 177 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 178 cdata.set_quoted('GST_LICENSE', 'LGPL')
 179 cdata.set_quoted('PACKAGE', 'gst-plugins-good')
 180 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-good-1.0')
 181 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 182
 183 warning_flags = [
 184   '-Wmissing-declarations',
 185   '-Wredundant-decls',
 186   '-Wwrite-strings',
 187   '-Winit-self',
 188   '-Wmissing-include-dirs',
 189   '-Wno-multichar',
 190   '-Wvla',
 191   '-Wpointer-arith',
 192 ]
 193
 194 warning_c_flags = [
 195   '-Wmissing-prototypes',
 196   '-Wdeclaration-after-statement',
 197   '-Wold-style-definition',
 198   '-Waggregate-return',
 199 ]
 200
 201 if have_cxx
 202   cxx = meson.get_compiler('cpp')
 203 endif
 204
 205 foreach extra_arg : warning_flags
 206   if cc.has_argument (extra_arg)
 207     add_project_arguments([extra_arg], language: 'c')
 208   endif
 209   if have_cxx and cxx.has_argument (extra_arg)
 210     add_project_arguments([extra_arg], language: 'cpp')
 211   endif
 212 endforeach
 213
 214 foreach extra_arg : warning_c_flags
 215   if cc.has_argument (extra_arg)
 216     add_project_arguments([extra_arg], language: 'c')
 217   endif
 218 endforeach
 219
 220 # GStreamer package name and origin url
 221 gst_package_name = get_option('package-name')
 222 if gst_package_name == ''
 223   if gst_version_nano == 0
 224     gst_package_name = 'GStreamer Good Plug-ins source release'
 225   elif gst_version_nano == 1
 226     gst_package_name = 'GStreamer Good Plug-ins git'
 227   else
 228     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 229   endif
 230 endif
 231 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 232 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 233
 234 # Mandatory GST deps
 235 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 236   fallback : ['gstreamer', 'gst_dep'])
 237 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 238   fallback : ['gstreamer', 'gst_base_dep'])
 239 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 240   fallback : ['gstreamer', 'gst_net_dep'])
 241 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 242   fallback : ['gstreamer', 'gst_controller_dep'])
 243 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 244   required : get_option('tests'),
 245   fallback : ['gstreamer', 'gst_check_dep'])
 246 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 247     fallback : ['gst-plugins-base', 'pbutils_dep'])
 248 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 249     fallback : ['gst-plugins-base', 'allocators_dep'])
 250 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 251     fallback : ['gst-plugins-base', 'app_dep'])
 252 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 253     fallback : ['gst-plugins-base', 'audio_dep'])
 254 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 255     fallback : ['gst-plugins-base', 'fft_dep'])
 256 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 257     fallback : ['gst-plugins-base', 'riff_dep'])
 258 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 259     fallback : ['gst-plugins-base', 'rtp_dep'])
 260 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 261     fallback : ['gst-plugins-base', 'rtsp_dep'])
 262 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 263     fallback : ['gst-plugins-base', 'sdp_dep'])
 264 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 265     fallback : ['gst-plugins-base', 'tag_dep'])
 266 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 267     fallback : ['gst-plugins-base', 'video_dep'])
 268
 269 # GStreamer OpenGL
 270 # FIXME: automagic
 271 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 272     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
 273
 274 build_gstgl = gstgl_dep.found() # FIXME: add option?
 275
 276 if build_gstgl
 277   if gstgl_dep.type_name() == 'pkgconfig'
 278     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 279     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 280     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 281   else
 282     gstbase = subproject('gst-plugins-base')
 283     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 284     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 285     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 286   endif
 287
 288   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 289   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 290   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 291
 292   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 293     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 294   endforeach
 295
 296   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 297     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 298   endforeach
 299
 300   foreach api : ['gl', 'gles2']
 301     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 302   endforeach
 303 endif
 304
 305 zlib_dep = dependency('zlib', required : false)
 306 if not zlib_dep.found()
 307   zlib_dep = cc.find_library('z', required : false)
 308   if not zlib_dep.found() or not cc.has_header('zlib.h')
 309     zlib_dep = subproject('zlib').get_variable('zlib_dep')
 310   endif
 311 endif
 312 cdata.set('HAVE_ZLIB', true)
 313
 314 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 315              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 316 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 317
 318 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 319 configinc = include_directories('.')
 320 libsinc = include_directories('gst-libs')
 321
 322 have_orcc = false
 323 orcc_args = []
 324 # Used by various libraries/elements that use Orc code
 325 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 326     fallback : ['orc', 'orc_dep'])
 327 orcc = find_program('orcc', required : get_option('orc'))
 328 if orc_dep.found() and orcc.found()
 329   have_orcc = true
 330   orcc_args = [orcc, '--include', 'glib.h']
 331   cdata.set('HAVE_ORC', 1)
 332 else
 333   message('Orc Compiler not found, will use backup C code')
 334   cdata.set('DISABLE_ORC', 1)
 335 endif
 336
 337 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 338 if gst_dep.type_name() == 'internal'
 339   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 340 else
 341   # We can't check that in the case of subprojects as we won't
 342   # be able to build against an internal dependency (which is not built yet)
 343   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 344 endif
 345
 346 if gst_debug_disabled
 347   message('GStreamer debug system is disabled')
 348   if cc.has_argument('-Wno-unused')
 349     add_project_arguments('-Wno-unused', language: 'c')
 350   endif
 351   if have_cxx and cxx.has_argument ('-Wno-unused')
 352     add_project_arguments('-Wno-unused', language: 'cpp')
 353   endif
 354 else
 355   message('GStreamer debug system is enabled')
 356 endif
 357
 358 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 359
 360 pkgconfig = import('pkgconfig')
 361 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 362 if get_option('default_library') == 'shared'
 363   # If we don't build static plugins there is no need to generate pc files
 364   plugins_pkgconfig_install_dir = disabler()
 365 endif
 366
 367 subdir('gst')
 368 subdir('sys')
 369 subdir('ext')
 370 subdir('tests')
 371 subdir('pkgconfig')
 372
 373 # xgettext is optional (on Windows for instance)
 374 if find_program('xgettext', required : get_option('nls')).found()
 375   cdata.set('ENABLE_NLS', 1)
 376   subdir('po')
 377 endif
 378
 379 configure_file(output : 'config.h', configuration : cdata)
 380
 381 python3 = import('python').find_installation()
 382 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')