configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.11.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 1100, 0, 1100)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_TRACER_HOOKS,[tracing subsystem hooks])
  91 AM_CONDITIONAL(GST_DISABLE_GST_TRACER_HOOKS, test "x$GST_DISABLE_GST_TRACER_HOOKS" = "xyes")
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  93 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  94 if test "x$GST_DISABLE_PARSE" = xyes; then
  95   AC_DEFINE(GST_DISABLE_PARSE, 1,
  96     [Define if pipeline parsing code is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  99 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
 100 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
 101   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 102     [Define if option parsing is disabled])
 103 fi
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 105 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 106 dnl define a substitution to use in docs/gst/gstreamer.types
 107 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 108 then
 109   GST_REGISTRY_DOC_TYPES="%"
 110 else
 111   GST_REGISTRY_DOC_TYPES=
 112 fi
 113 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 AG_GST_PKG_CONFIG_PATH
 129
 130 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 131   ["${srcdir}/gstreamer.doap"],
 132   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 133
 134 # We only use this when building with MSVC, which is only done with the
 135 # alternate Meson build system files
 136 GSTCONFIG_BUILT_WITH_MSVC=0
 137 AC_SUBST(GSTCONFIG_BUILT_WITH_MSVC)
 138
 139 dnl check for bash completion
 140 AC_ARG_WITH([bash-completion-dir],
 141     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 142         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 143     [],
 144     [with_bash_completion_dir=yes])
 145
 146 if test "x$with_bash_completion_dir" = "xyes"
 147 then
 148     extra_args=
 149
 150     if test "x$prefix" != "xNONE"
 151     then
 152         extra_args="--define-variable=prefix=\"$prefix\""
 153     fi
 154
 155     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 156         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 157         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 158     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 159         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 160         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 161 else
 162     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 163     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 164 fi
 165
 166 AC_SUBST([BASH_COMPLETION_DIR])
 167 AC_SUBST([BASH_HELPERS_DIR])
 168 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 169
 170 dnl build static plugins or not
 171 AC_MSG_CHECKING([whether to build static plugins or not])
 172 AC_ARG_ENABLE(
 173   static-plugins,
 174   AC_HELP_STRING(
 175     [--enable-static-plugins],
 176     [build static plugins @<:@default=no@:>@]),
 177   [AS_CASE(
 178     [$enableval], [no], [], [yes], [],
 179     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 180   [enable_static_plugins=no])
 181 AC_MSG_RESULT([$enable_static_plugins])
 182 if test "x$enable_static_plugins" = xyes; then
 183   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 184     [Define if static plugins should be built])
 185   GST_PLUGIN_LIBTOOLFLAGS=""
 186 else
 187   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 188 fi
 189 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 190 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 191
 192 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 193 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 194 if test x$enable_static = xyes -a x$enable_shared = xno; then
 195   GST_OBJ_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 196 fi
 197
 198 dnl building of tests
 199 AC_ARG_ENABLE(tests,
 200   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 201   [
 202     case "${enableval}" in
 203       yes) BUILD_TESTS=yes ;;
 204       no)  BUILD_TESTS=no ;;
 205       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 206     esac
 207   ],
 208 [BUILD_TESTS=yes]) dnl Default value
 209 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 210
 211 dnl tests known to fail
 212 AC_ARG_ENABLE(failing-tests,
 213   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 214   [
 215     case "${enableval}" in
 216       yes) BUILD_FAILING_TESTS=yes ;;
 217       no)  BUILD_FAILING_TESTS=no ;;
 218       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 219     esac
 220   ],
 221   [BUILD_FAILING_TESTS=no]) dnl Default value
 222 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 223 if test x$BUILD_FAILING_TESTS = xyes; then
 224   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 225 else
 226   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 227 fi
 228
 229 dnl building of benchmarks
 230 AC_ARG_ENABLE(benchmarks,
 231   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 232   [
 233     case "${enableval}" in
 234       yes) BUILD_BENCHMARKS=yes ;;
 235       no)  BUILD_BENCHMARKS=no ;;
 236       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 237     esac
 238   ],
 239 [BUILD_BENCHMARKS=yes]) dnl Default value
 240 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 241
 242 dnl building of tools
 243 AC_ARG_ENABLE(tools,
 244   AS_HELP_STRING([--disable-tools],[disable building tools]),
 245   [
 246     case "${enableval}" in
 247       yes) BUILD_TOOLS=yes ;;
 248       no)  BUILD_TOOLS=no ;;
 249       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 250     esac
 251   ],
 252 [BUILD_TOOLS=yes]) dnl Default value
 253 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 254
 255 dnl poison destroyed objects
 256 AC_ARG_ENABLE(poisoning,
 257   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 258   [
 259     case "${enableval}" in
 260       yes) USE_POISONING=yes ;;
 261       no)  USE_POISONING=no ;;
 262       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 263     esac
 264   ],
 265   [USE_POISONING=no]) dnl Default value
 266 if test "x$USE_POISONING" = xyes; then
 267   AC_DEFINE(USE_POISONING, 1,
 268     [Define if we should poison deallocated memory])
 269 fi
 270
 271 dnl PTP support parts
 272 AC_MSG_CHECKING([whether PTP support can be enabled])
 273 case "$host_os" in
 274   *android*)
 275     dnl Can't run on Android because of permissions
 276     HAVE_PTP=no
 277     ;;
 278   mingw*|pw32*|cygwin*)
 279     dnl Not ported to Windows yet
 280     HAVE_PTP=no
 281     ;;
 282   darwin*)
 283     dnl Can't run on iOS because of permissions
 284     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 285     ;;
 286   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 287     HAVE_PTP=yes
 288     ;;
 289   *)
 290     HAVE_PTP=no
 291     ;;
 292 esac
 293 AC_MSG_RESULT([$HAVE_PTP])
 294
 295 dnl user/group to change to in gst-ptp-helper
 296 AC_ARG_WITH([ptp-helper-setuid-user],
 297   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 298   [
 299     if test "x$withval" != "x"
 300     then
 301       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 302     fi
 303   ], []
 304 )
 305
 306 dnl group/group to change to in gst-ptp-helper
 307 AC_ARG_WITH([ptp-helper-setuid-group],
 308   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 309   [
 310     if test "x$withval" != "x"
 311     then
 312       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 313     fi
 314   ], []
 315 )
 316
 317 AC_ARG_WITH(
 318   ptp-helper-permissions,
 319   AC_HELP_STRING(
 320     [--with-ptp-helper-permissions],
 321     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 322     [],
 323     [with_ptp_helper_permissions=auto])
 324
 325 gst_ptp_have_cap=no
 326 AG_GST_CHECK_LIBHEADER(CAP, cap,
 327                        cap_init, ,
 328                        sys/capability.h,
 329                        CAP_LIBS="-lcap"
 330                        AC_SUBST(CAP_LIBS)
 331                        gst_ptp_have_cap=yes)
 332
 333 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 334
 335 if test "x$HAVE_PTP" = "xyes"; then
 336 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 337
 338 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 339 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 340     [[
 341         #include <sys/ioctl.h>
 342         #include <net/if.h>
 343     ]],
 344     [[
 345         struct ifreq ifr;
 346         struct ifconf ifc;
 347         ioctl(0, SIOCGIFCONF, &ifc);
 348         ioctl(0, SIOCGIFFLAGS, &ifr);
 349         ioctl(0, SIOCGIFHWADDR, &ifr);
 350         int dummy = ifr.ifr_hwaddr.sa_data[0];
 351     ]])], [
 352         AC_MSG_RESULT(yes)
 353         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 354     ], [
 355         AC_MSG_RESULT(no)
 356 ])
 357
 358 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 359 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 360     [[
 361         #include <ifaddrs.h>
 362         #include <net/if.h>
 363         #include <net/if_dl.h>
 364     ]],
 365     [[
 366         struct ifaddrs *ifaddr;
 367         getifaddrs(&ifaddr);
 368         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 369     ]])], [
 370         AC_MSG_RESULT(yes)
 371         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 372     ], [
 373         AC_MSG_RESULT(no)
 374     ])
 375
 376 AC_MSG_CHECKING([how to install gst-ptp-helper])
 377 if test "x$with_ptp_helper_permissions" = "xauto"; then
 378     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 379         with_ptp_helper_permissions="capabilities"
 380     else
 381         with_ptp_helper_permissions="setuid-root"
 382     fi
 383 fi
 384 AC_MSG_RESULT([$with_ptp_helper_permissions])
 385
 386 case "$with_ptp_helper_permissions" in
 387   none)
 388     ;;
 389   setuid-root)
 390      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 391         [Use setuid-root for permissions in PTP helper])
 392     ;;
 393   capabilities)
 394      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 395         [Use capabilities for permissions in PTP helper])
 396     ;;
 397   *)
 398     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 399     ;;
 400 esac
 401
 402 fi
 403
 404 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 405 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 406 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 407
 408 dnl *** checks for platform ***
 409
 410 dnl * hardware/architecture *
 411
 412 dnl common/m4/gst-arch.m4
 413 dnl check CPU type
 414 AG_GST_ARCH
 415 dnl substitution for win32/common/config.h
 416 HOST_CPU=$host_cpu
 417 AC_SUBST(HOST_CPU)
 418
 419 dnl check for platform specific settings
 420 AG_GST_PLATFORM
 421
 422 dnl * software *
 423
 424 dnl check for large file support
 425 dnl affected plugins must include config.h
 426 AC_SYS_LARGEFILE
 427
 428 dnl *** checks for programs ***
 429
 430 dnl find a compiler
 431 AC_PROG_CC
 432 AC_PROG_CC_STDC
 433
 434 dnl check if the compiler supports '-c' and '-o' options
 435 AM_PROG_CC_C_O
 436
 437 dnl find an assembler
 438 AM_PROG_AS
 439
 440 dnl determine if c++ is available on this system
 441 AC_PROG_CXX
 442 dnl CXX may be set to some default even if no c++ compiler is available
 443 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 444 AC_LANG_PUSH([C++])
 445 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 446 AC_LANG_POP([C++])
 447 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 448 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 449
 450 dnl Perl is used in building documentation and in the version checks
 451 AC_PATH_PROG(PERL_PATH, perl, no)
 452 if test x$PERL_PATH = xno; then
 453   AC_MSG_ERROR(Could not find perl)
 454 fi
 455
 456 dnl we require flex and bison for building the parser
 457 if test "x$GST_DISABLE_PARSE" != xyes; then
 458   AG_GST_BISON_CHECK
 459   AG_GST_FLEX_CHECK
 460 fi
 461
 462 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 463 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 464
 465 dnl check for gobject-introspection
 466 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 467
 468 dnl check for documentation tools
 469 GTK_DOC_CHECK([1.12])
 470 AG_GST_PLUGIN_DOCS([1.12])
 471
 472 dnl *** checks for libraries ***
 473
 474 dnl check for libm, for sin()
 475 LT_LIB_M
 476 AC_SUBST(LIBM)
 477
 478 dnl *** checks for header files ***
 479
 480 dnl check if we have ANSI C header files
 481 AC_HEADER_STDC
 482
 483 dnl Check for ucontext.h
 484 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 485
 486 dnl Check for sys/socket.h
 487 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 488 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 489
 490 dnl check for sys/times.h for tests/examples/adapter/
 491 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 492 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 493 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 494
 495 dnl Check for process.h for getpid() on win32
 496 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 497
 498 dnl Check for sys/utsname.h for uname
 499 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 500
 501 dnl Check for stdio_ext.f for __fbufsize
 502 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 503
 504 dnl check for pthreads
 505 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 506 dnl which later checks use in their test code
 507 AX_PTHREAD()
 508 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 509
 510 dnl check for sys/prctl for setting thread name on Linux
 511 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 512
 513 dnl check for pthread_setname_np(const char*)
 514 dnl which is present on OS X 10.6, iOS 3.2 and above
 515 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 516 AC_LINK_IFELSE(
 517     [AC_LANG_PROGRAM(
 518         [#include <pthread.h>],
 519         [pthread_setname_np("example")])],
 520     [AC_MSG_RESULT(yes)
 521      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 522         [Have function pthread_setname_np(const char*)])],
 523     [AC_MSG_RESULT(no)])
 524
 525 dnl check for sys/uio.h for writev()
 526 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 527
 528 dnl Check for valgrind.h
 529 dnl separate from HAVE_VALGRIND because you can have the program, but not
 530 dnl the dev package
 531 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 532
 533 dnl used in gst/gstpoll.c
 534 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 535 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 536 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 537   WIN32_LIBS="-lws2_32"
 538   AC_SUBST(WIN32_LIBS)
 539 fi
 540
 541 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 542 if test "x$BUILD_TESTS" = "xyes"; then
 543   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 544                          __gmpz_init_set_d, ,
 545                          gmp.h,
 546                          GMP_LIBS="-lgmp"
 547                          AC_SUBST(GMP_LIBS)
 548                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 549   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 550                          gsl_rng_uniform_int, -lgslcblas,
 551                          gsl/gsl_rng.h,
 552                          GSL_LIBS="-lgsl -lgslcblas"
 553                          AC_SUBST(GSL_LIBS)
 554                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 555 fi
 556
 557 dnl *** checks for types/defines ***
 558
 559 dnl *** checks for structures ***
 560
 561 dnl *** checks for compiler characteristics ***
 562
 563 dnl check if the compiler supports __uint128_t (gcc)
 564 dnl Actually check for 128-bit division, since that's what we use
 565 dnl uint128_t for.
 566 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 567     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 568       static __uint128_t v1 = 100;
 569       static __uint128_t v2 = 10;
 570       static __uint128_t u;
 571       u = v1 / v2;
 572     ]])],[
 573       gst_cv_uint128_t=yes
 574     ],[
 575       gst_cv_uint128_t=no
 576     ])
 577 )
 578 if test x$gst_cv_uint128_t = xyes; then
 579   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 580 fi
 581
 582 dnl *** checking for tm_gmtoff ***
 583 AC_MSG_CHECKING([for tm_gmtoff])
 584 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 585         #include <time.h>
 586         int main(void) {
 587           struct tm t;
 588           t.tm_gmtoff = 0;
 589           exit(0);
 590         }]])],
 591   [have_tm_gmtoff=yes
 592    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 593   [have_tm_gmtoff=no],
 594   [have_tm_gmtoff="no (cross compiling)"])
 595 AC_MSG_RESULT($have_tm_gmtoff)
 596
 597
 598 dnl *** checks for library functions ***
 599
 600 AC_CHECK_FUNCS([strcasestr])
 601
 602 AC_CHECK_FUNCS([gmtime_r])
 603 AC_CHECK_FUNCS([localtime_r])
 604 AC_CHECK_FUNCS([sigaction])
 605 AC_CHECK_FUNCS([getrusage])
 606 AM_CONDITIONAL(HAVE_GETRUSAGE, test "x$ac_cv_func_getrusage" = "xyes")
 607 AC_CHECK_HEADERS([sys/resource.h])
 608
 609 dnl check for fseeko()
 610 AC_FUNC_FSEEKO
 611 dnl check for ftello()
 612 AC_CHECK_FUNCS([ftello])
 613
 614 AC_CHECK_FUNCS([fgetpos])
 615 AC_CHECK_FUNCS([fsetpos])
 616
 617 dnl check for poll(), ppoll() and pselect()
 618 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 619 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 620 AC_CHECK_FUNCS([poll])
 621 AC_CHECK_FUNCS([ppoll])
 622 AC_CHECK_FUNCS([pselect])
 623
 624 dnl check for socketpair()
 625 AC_CHECK_FUNC(socketpair, [], [
 626   AC_CHECK_LIB(socket, socketpair, [
 627     SOCKET_LIBS="-lsocket"
 628     AC_SUBST(SOCKET_LIBS)
 629   ])
 630 ])
 631
 632 dnl ****************************************
 633 dnl *** GLib POLL* compatibility defines ***
 634 dnl ****************************************
 635
 636 AC_MSG_CHECKING([for broken poll])
 637 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 638         #include <stdlib.h>
 639         #include <fcntl.h>
 640         #ifdef HAVE_SYS_POLL_H
 641         #include <sys/poll.h>
 642         #endif
 643         #ifdef HAVE_POLL_H
 644         #include <poll.h>
 645         #endif
 646         int main(void) {
 647           struct pollfd fds[1];
 648           int fd;
 649           fd = open("/dev/null", 1);
 650           fds[0].fd = fd;
 651           fds[0].events = POLLIN;
 652           fds[0].revents = 0;
 653           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 654                 exit(1);  /* Does not work for devices -- fail */
 655           }
 656           exit(0);
 657         }]])],
 658   [broken_poll=no],
 659   [broken_poll=yes
 660    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 661   [broken_poll="no (cross compiling)"])
 662 AC_MSG_RESULT($broken_poll)
 663
 664 dnl check for mmap()
 665 AC_FUNC_MMAP
 666 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 667
 668 dnl check for posix_memalign(), getpagesize()
 669 AC_CHECK_FUNCS([posix_memalign])
 670 AC_CHECK_FUNCS([getpagesize])
 671
 672 dnl Check for POSIX timers
 673 CLOCK_GETTIME_FOUND="no"
 674 AC_CHECK_FUNC(clock_gettime, [CLOCK_GETTIME_FOUND="yes"], [
 675   AC_CHECK_LIB(rt, clock_gettime, [
 676     CLOCK_GETTIME_FOUND="yes"
 677     LIBS="$LIBS -lrt"
 678   ], [
 679     AC_CHECK_LIB(pthread, clock_gettime, [
 680       CLOCK_GETTIME_FOUND="yes"
 681       LIBS="$LIBS -lpthread"
 682     ])
 683   ])
 684 ])
 685
 686 # With XCode 8, clock_gettime will be incorrectly detected as being available
 687 # regardless of what version of OS X you target because the symbol is available
 688 # in the .tbd file as a weak symbol.
 689 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 690 #
 691 # We cannot simply do AC_CHECK_FUNCS with -Wl,-no_weak_imports because the
 692 # autoconf check does its own prototype declaration that doesn't trigger that
 693 # compiler flag.
 694 #
 695 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 696 # actually available, so we can unconditionally disable it for older versions.
 697 case "$host_os" in
 698   darwin*)
 699     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 700 #include <AvailabilityMacros.h>
 701 #include <TargetConditionals.h>
 702 #if defined(TARGET_OS_MAC)
 703 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 704 #    error "Not compiling for OS X 10.12 or later"
 705 #  endif
 706 #else
 707 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 708 #    error "Not compiling for iOS 10.0 or later"
 709 #  endif
 710 #endif
 711     ]])], [], [
 712     if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 713       AC_MSG_NOTICE([Disabling incorrectly detected clock_gettime on OS X])
 714     fi
 715     CLOCK_GETTIME_FOUND="no"
 716     ])
 717     ;;
 718 esac
 719
 720 if test "$CLOCK_GETTIME_FOUND" = "yes"; then
 721   AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Have clock_gettime])
 722 fi
 723
 724 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 725     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 726 #include <time.h>
 727 #ifdef HAVE_UNISTD_H
 728 #include <unistd.h>
 729 #endif
 730     ]], [[
 731 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 732 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 733 #endif
 734     ]])],[
 735       gst_cv_posix_timers=yes
 736     ],[
 737       gst_cv_posix_timers=no
 738     ])
 739 )
 740
 741 if test "$gst_cv_posix_timers" = "yes"; then
 742   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 743   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 744 else
 745   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 746 fi
 747 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 748 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 749
 750 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 751     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 752 #include <time.h>
 753 #ifdef HAVE_UNISTD_H
 754 #include <unistd.h>
 755 #endif
 756     ]], [[
 757 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 758 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 759 #endif
 760     ]])],[
 761       gst_cv_monotonic_clock=yes
 762     ],[
 763       gst_cv_monotonic_clock=no
 764     ])
 765 )
 766
 767 if test "$gst_cv_monotonic_clock" = "yes"; then
 768   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 769   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 770 else
 771   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 772 fi
 773 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 774 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 775
 776 dnl Check for a way to display the function name in debug output
 777 AG_GST_CHECK_FUNCTION
 778
 779 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 780 save_cflags="$CFLAGS"
 781 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 782 AC_CHECK_LIB(dl, dladdr,
 783    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 784    LIBS="$LIBS -ldl")
 785 CFLAGS="$save_cflags"
 786
 787 dnl Check printf stuff
 788 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 789   AC_TYPE_LONG_LONG_INT
 790   AC_TYPE_UNSIGNED_LONG_LONG_INT
 791
 792   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 793     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 794   fi
 795
 796   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 797   gl_AC_HEADER_INTTYPES_H
 798
 799   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 800   gl_AC_HEADER_STDINT_H
 801
 802   AC_CHECK_TYPES(ptrdiff_t)
 803
 804   AC_TYPE_INTMAX_T
 805   AC_TYPE_SIZE_T
 806 fi
 807
 808 dnl *** checks for dependency libraries ***
 809
 810 dnl GLib
 811 GLIB_REQ=2.40.0
 812 AG_GST_GLIB_CHECK([$GLIB_REQ])
 813
 814 dnl Check for documentation xrefs
 815 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 816 AC_SUBST(GLIB_PREFIX)
 817
 818 dnl GTK is optional and only used in examples
 819 HAVE_GTK=no
 820 GTK_REQ=3.10
 821 if test "x$BUILD_EXAMPLES" = "xyes"; then
 822   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 823   AC_SUBST(GTK_LIBS)
 824   AC_SUBST(GTK_CFLAGS)
 825 fi
 826 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 827
 828 dnl libunwind is optionally used by the leaks tracer
 829 PKG_CHECK_MODULES(UNWIND, libunwind, HAVE_UNWIND=yes, HAVE_UNWIND=no)
 830 if test "x$HAVE_UNWIND" = "xyes"; then
 831   AC_DEFINE(HAVE_UNWIND, 1, [libunwind available])
 832 fi
 833
 834 dnl libdw is optionally used to add source lines and numbers to backtraces
 835 PKG_CHECK_MODULES(DW, libdw, HAVE_DW=yes, HAVE_DW=no)
 836 if test "x$HAVE_DW" = "xyes"; then
 837   AC_DEFINE(HAVE_DW, 1, [libdw available])
 838 fi
 839
 840 dnl Check for backtrace() from libc
 841 AC_CHECK_FUNC(backtrace, [
 842   AC_CHECK_HEADERS([execinfo.h], [
 843     AC_DEFINE(HAVE_BACKTRACE,1,[Have backtrace])
 844   ], [], [])
 845 ])
 846
 847 dnl building of unit test libraries
 848 AC_ARG_ENABLE(check,
 849   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 850   [
 851     case "${enableval}" in
 852       yes) BUILD_CHECK=yes ;;
 853       no)  BUILD_CHECK=no ;;
 854       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 855     esac
 856   ], [
 857     dnl Default value
 858     case $host_os in
 859       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 860       *) BUILD_CHECK=yes ;;
 861     esac
 862 ])
 863 dnl bit of a misnomer, but keep the conditional named like this so we don't
 864 dnl have to change too much elsewhere
 865 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 866
 867 dnl configure the desired memory alignment
 868 AC_ARG_WITH([memory-alignment],
 869   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 870   [
 871     if test "x$withval" = "xyes"
 872     then
 873       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 874     else
 875       case "${withval}" in
 876         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 877         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 878         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 879       esac
 880     fi
 881   ], [
 882     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 883   ]
 884 )
 885
 886 dnl Check for -Bsymbolic-functions linker flag used to avoid
 887 dnl intra-library PLT jumps, if available.
 888 AC_ARG_ENABLE(Bsymbolic,
 889               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 890               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 891                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 892                LDFLAGS=-Wl,-Bsymbolic-functions
 893                LIBS=
 894                AC_TRY_LINK([], [return 0],
 895                            AC_MSG_RESULT(yes)
 896                            enable_Bsymbolic=yes,
 897                            AC_MSG_RESULT(no)
 898                            enable_Bsymbolic=no)
 899                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 900
 901
 902 dnl *** set variables based on configure arguments
 903
 904 dnl set license and copyright notice
 905 GST_LICENSE="LGPL"
 906 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 907 AC_SUBST(GST_LICENSE)
 908
 909 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 910 AS_AC_EXPAND(LIBDIR, $libdir)
 911 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 912 AS_AC_EXPAND(DATADIR, $datadir)
 913 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 914
 915 dnl set location of plugin directory
 916 AG_GST_SET_PLUGINDIR
 917
 918 dnl make sure it doesn't complain about unused variables if debugging is disabled
 919 NO_WARNINGS=""
 920 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 921   NO_WARNINGS="-Wno-unused"
 922 fi
 923
 924 dnl define an ERROR_CFLAGS Makefile variable
 925 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 926
 927 dnl special warning flags for gst/printf
 928 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 929 AC_SUBST(PRINTF_CFLAGS)
 930
 931 dnl define correct level for debugging messages
 932 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 933
 934 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 935
 936 dnl Overview:
 937 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 938 dnl GST_ALL_*:          vars shared by all built objects
 939 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 940 dnl GST_OBJ_*:          additional vars to link to the core library
 941 dnl                     include GST_ALL_*
 942 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 943 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 944
 945 dnl GST_OPTION_CFLAGS
 946 if test "x$USE_DEBUG" = xyes; then
 947    PROFILE_CFLAGS="-g"
 948 fi
 949 AC_SUBST(PROFILE_CFLAGS)
 950
 951 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 952 # functionality from the API that gstreamer uses
 953 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 954 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 955   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 956   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 957 else
 958   DEPRECATED_CFLAGS=""
 959 fi
 960 AC_SUBST(DEPRECATED_CFLAGS)
 961
 962 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 963 dnl make DEPRECATED_CFLAGS=''
 964 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 965 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 966 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 967 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 968 AC_SUBST(GST_OPTION_CFLAGS)
 969 AC_SUBST(GST_OPTION_CXXFLAGS)
 970
 971 dnl GST_ALL_*
 972 dnl vars common to for all internal objects (core libs, elements, applications)
 973 dnl CFLAGS:
 974 dnl - src and build dirs need to be added because every piece that gets built
 975 dnl   will need the GStreamer source and generated headers
 976 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 977 dnl       from LibXML except for in the core library
 978 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 979 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 980
 981 dnl FIXME: check if LTLIBINTL is needed everywhere
 982 dnl I presume it is given that it contains the symbols that _() stuff maps to
 983 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 984
 985 dnl LDFLAGS really should only contain flags, not libs - they get added before
 986 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 987 GST_ALL_LDFLAGS="-no-undefined"
 988 if test "x${enable_Bsymbolic}" = "xyes"; then
 989   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 990 fi
 991
 992 AC_SUBST(GST_ALL_CFLAGS)
 993 AC_SUBST(GST_ALL_CXXFLAGS)
 994 AC_SUBST(GST_ALL_LIBS)
 995 AC_SUBST(GST_ALL_LDFLAGS)
 996
 997 dnl GST_LIB_LDFLAGS
 998 dnl linker flags shared by all libraries
 999 dnl LDFLAGS modifier defining exported symbols from built libraries
1000 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
1001 AC_SUBST(GST_LIB_LDFLAGS)
1002
1003 dnl GST_OBJ_*
1004 dnl default vars for all internal objects built on libgstreamer
1005 dnl includes GST_ALL_*
1006 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS) $GST_OBJ_STATIC_CFLAGS"
1007 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS) $GST_OBJ_STATIC_CFLAGS"
1008 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
1009 AC_SUBST(GST_OBJ_CFLAGS)
1010 AC_SUBST(GST_OBJ_CXXFLAGS)
1011 AC_SUBST(GST_OBJ_LIBS)
1012
1013 dnl GST_PLUGIN_LDFLAGS
1014 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
1015 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1016 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
1017
1018 dnl plugin scanner locations
1019 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
1020 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
1021     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
1022 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
1023
1024 dnl ptp helper locations
1025 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
1026 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
1027     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
1028 AC_SUBST(GST_PTP_HELPER_INSTALLED)
1029
1030 dnl things for our internal libcheck (must be called even if building
1031 dnl libcheck is disabled because it defines conditionals)
1032 AG_GST_CHECK_CHECKS
1033
1034 AC_CONFIG_FILES(
1035 Makefile
1036 data/Makefile
1037 gst/Makefile
1038 gst/gstconfig.h
1039 gst/gstversion.h
1040 gst/parse/Makefile
1041 gst/printf/Makefile
1042 libs/Makefile
1043 libs/gst/Makefile
1044 libs/gst/base/Makefile
1045 libs/gst/check/Makefile
1046 libs/gst/check/libcheck/Makefile
1047 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
1048 libs/gst/controller/Makefile
1049 libs/gst/helpers/Makefile
1050 libs/gst/net/Makefile
1051 plugins/Makefile
1052 plugins/elements/Makefile
1053 plugins/tracers/Makefile
1054 po/Makefile.in
1055 tests/Makefile
1056 tests/benchmarks/Makefile
1057 tests/check/Makefile
1058 tests/misc/Makefile
1059 tests/examples/Makefile
1060 tests/examples/adapter/Makefile
1061 tests/examples/controller/Makefile
1062 tests/examples/stepping/Makefile
1063 tests/examples/helloworld/Makefile
1064 tests/examples/memory/Makefile
1065 tests/examples/netclock/Makefile
1066 tests/examples/ptp/Makefile
1067 tests/examples/streamiddemux/Makefile
1068 tests/examples/streams/Makefile
1069 tools/Makefile
1070 common/Makefile
1071 common/m4/Makefile
1072 docs/Makefile
1073 docs/design/Makefile
1074 docs/gst/Makefile
1075 docs/gst/gstreamer.types
1076 docs/libs/Makefile
1077 docs/plugins/Makefile
1078 docs/slides/Makefile
1079 docs/xsl/Makefile
1080 docs/version.entities
1081 m4/Makefile
1082 pkgconfig/Makefile
1083 stamp.h
1084 pkgconfig/gstreamer.pc
1085 pkgconfig/gstreamer-uninstalled.pc
1086 pkgconfig/gstreamer-base.pc
1087 pkgconfig/gstreamer-base-uninstalled.pc
1088 pkgconfig/gstreamer-check.pc
1089 pkgconfig/gstreamer-check-uninstalled.pc
1090 pkgconfig/gstreamer-controller.pc
1091 pkgconfig/gstreamer-controller-uninstalled.pc
1092 pkgconfig/gstreamer-net.pc
1093 pkgconfig/gstreamer-net-uninstalled.pc
1094 gstreamer.spec
1095 )
1096
1097 dnl Create the config.h file for Visual Studio builds
1098 dnl Beware of spaces and /'s in some of the shell variable contents.
1099 sed \
1100     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1101     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1102     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1103     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1104     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1105     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1106     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1107     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1108     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1109     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1110     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1111     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1112     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1113     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1114     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1115     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1116     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1117     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1118     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1119     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1120     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
1121     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1122     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1123     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
1124     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1125     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
1126     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1127     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1128     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1129     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
1130     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
1131     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1132     config.h.in >win32/common/config.h-new
1133
1134 AC_OUTPUT
1135
1136 dnl negate for output
1137 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1138 if test "x${GST_DISABLE_GST_TRACER_HOOKS}" = "xno"; then enable_gst_tracer_hooks="yes"; fi
1139 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1140 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1141 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1142 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1143
1144 echo "
1145
1146 Configuration
1147         Version                    : ${VERSION}
1148         Source code location       : ${srcdir}
1149         Prefix                     : ${prefix}
1150         Compiler                   : ${CC}
1151         Package name               : ${GST_PACKAGE_NAME}
1152         Package origin             : ${GST_PACKAGE_ORIGIN}
1153
1154         API Documentation          : ${enable_gtk_doc}
1155
1156         Debug logging              : ${enable_gst_debug}
1157         Tracing subsystem hooks    : ${enable_gst_tracer_hooks}
1158         Command-line parser        : ${enable_parse}
1159         Option parsing in gst_init : ${enable_option_parsing}
1160         Plugin registry            : ${enable_registry}
1161         Plugin support             : ${enable_plugin}
1162         Static plugins             : ${enable_static_plugins}
1163         Unit testing support       : ${BUILD_CHECK}
1164         PTP clock support          : ${HAVE_PTP}
1165         libunwind support          : ${HAVE_UNWIND}
1166         libdw support              : ${HAVE_DW}
1167
1168         Debug                      : ${USE_DEBUG}
1169         Profiling                  : ${USE_PROFILING}
1170
1171         Building benchmarks        : ${BUILD_BENCHMARKS}
1172         Building examples          : ${BUILD_EXAMPLES}
1173         Building test apps         : ${BUILD_TESTS}
1174         Building tests that fail   : ${BUILD_FAILING_TESTS}
1175         Building tools             : ${BUILD_TOOLS}
1176 "