configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.15.2.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1502, 0, 1502)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.15.2.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl For Requires.private in pkg-config files
 284 ORC_PC=
 285 if test x"$HAVE_ORC" = "xyes"; then
 286     ORC_PC="orc-0.4"
 287 fi
 288 AC_SUBST(ORC_PC)
 289
 290 dnl checks for gstreamer
 291 dnl uninstalled is selected preferentially -- see pkg-config(1)
 292 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 293 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 294 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 295 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 296 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 297 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 298
 299 dnl Check for documentation xrefs
 300 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 301 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 302 AC_SUBST(GLIB_PREFIX)
 303 AC_SUBST(GST_PREFIX)
 304
 305 dnl check for gudev
 306 PKG_CHECK_MODULES(G_UDEV, gudev-1.0 , [
 307         AC_DEFINE([HAVE_GUDEV], 1, [Define if gudev is installed])
 308         HAVE_GUDEV="yes" ],
 309         [HAVE_GUDEV="no"])
 310
 311 AG_GST_GL_CHECKS
 312
 313 dnl GTK is optional and only used in examples
 314 HAVE_GTK=no
 315 HAVE_GTK_X11=no
 316 HAVE_GDK_PIXBUF=no
 317 GTK_REQ=3.10
 318 if test "x$BUILD_EXAMPLES" = "xyes"; then
 319   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 320   dnl some examples need gtk+-x11
 321   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 322   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 323   AC_SUBST(GTK_LIBS)
 324   AC_SUBST(GTK_CFLAGS)
 325
 326   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 327   AC_SUBST(GDK_PIXBUF_LIBS)
 328   AC_SUBST(GDK_PIXBUF_CFLAGS)
 329 fi
 330 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 331 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 332 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 333 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 334
 335 HAVE_QT=no
 336 HAVE_QT_MOC=no
 337 dnl QT is optional and only used in examples
 338 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 339   HAVE_QT=yes
 340 ], [
 341   HAVE_QT=no
 342 ])
 343 if test "x$HAVE_QT" = "xyes"; then
 344   AC_CHECK_TOOL(QT_MOC, moc)
 345   AC_MSG_CHECKING([for Qt5 moc])
 346   mocversion=`$QT_MOC -v 2>&1`
 347   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 348   if test x"$mocversiongrep" != x"$mocversion"; then
 349     AC_MSG_RESULT([no])
 350     # moc was not the qt5 one, try with moc-qt5
 351     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 352     AC_MSG_CHECKING([for Qt5 moc-qt5])
 353     mocversion=`$QT_MOC -v 2>&1`
 354     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 355     if test x"$mocversiongrep" != x"$mocversion"; then
 356       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 357       AC_MSG_CHECKING([for qtchooser])
 358       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 359       mocversion=`$qt5tooldir/moc -v 2>&1`
 360       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 361       if test x"$mocversiongrep" != x"$mocversion"; then
 362         # no valid moc found
 363         QT_MOC="no"
 364       else
 365         QT_MOC=$qt5tooldir/moc
 366       fi
 367     else
 368       QT_MOC=$QT_MOC
 369     fi
 370   fi
 371   AC_SUBST(QT_MOC)
 372   AC_MSG_RESULT([$QT_MOC])
 373 fi
 374 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 375 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 376
 377 dnl Check for OpenGL example dependencies (clutter, sdl, etc.)
 378 AG_GST_GL_EXAMPLES_CHECKS
 379
 380 dnl chck for linux headers needed by the joystick seek example
 381 AC_COMPILE_IFELSE(
 382 [
 383   AC_LANG_PROGRAM([
 384     #include <linux/input.h>
 385     #include <linux/joystick.h>
 386   ],[
 387     struct js_event js;
 388     js.type = JS_EVENT_AXIS;
 389   ])
 390 ], [
 391   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 392 ], [
 393   HAVE_LINUX_JOYSTICK_HEADERS="no"
 394 ])
 395 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 396
 397 dnl Check for -Bsymbolic-functions linker flag used to avoid
 398 dnl intra-library PLT jumps, if available.
 399 AC_ARG_ENABLE(Bsymbolic,
 400               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 401               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 402                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 403                LDFLAGS=-Wl,-Bsymbolic-functions
 404                LIBS=
 405                AC_TRY_LINK([], [return 0],
 406                            AC_MSG_RESULT(yes)
 407                            enable_Bsymbolic=yes,
 408                            AC_MSG_RESULT(no)
 409                            enable_Bsymbolic=no)
 410                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 411
 412
 413 dnl *** set variables based on configure arguments ***
 414
 415 dnl set license and copyright notice
 416 GST_LICENSE="LGPL"
 417 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 418 AC_SUBST(GST_LICENSE)
 419
 420 dnl set location of plugin directory
 421 AG_GST_SET_PLUGINDIR
 422
 423 dnl set release date/time
 424 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 425   ["${srcdir}/gst-plugins-base.doap"],
 426   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 427
 428 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 429 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 430 if test x$enable_static = xyes -a x$enable_shared = xno; then
 431   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 432 fi
 433
 434 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 435 dnl make sure it doesn't complain about unused variables if debugging is disabled
 436 NO_WARNINGS=""
 437 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 438
 439 dnl define an ERROR_CFLAGS Makefile variable
 440 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 441 dnl -Waggregate-return - xcb_intern_atom() returns an aggregate value
 442 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 443     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 444     -Wwrite-strings  -Wformat-nonliteral -Wformat-security
 445     -Winit-self -Wmissing-include-dirs -Waddress
 446     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 447
 448 dnl define an ERROR_CXXFLAGS Makefile variable
 449 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 450     -Wmissing-declarations -Wredundant-decls -Wundef
 451     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 452     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 453     -Wno-multichar $NO_WARNINGS])
 454
 455 dnl define correct level for debugging messages
 456 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 457
 458 dnl used in examples
 459 AG_GST_DEFAULT_ELEMENTS
 460
 461 dnl needed for encoding-target
 462 GST_DATADIR="$GST_PREFIX/share"
 463 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 464 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 465
 466 dnl behaviour of speex based audio resampler
 467 AC_MSG_CHECKING(which audio resample format to use for integer)
 468 AC_ARG_WITH([audioresample_format],
 469         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 470         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 471 AC_MSG_RESULT($ac_cv_audioresample_format)
 472 case $ac_cv_audioresample_format in
 473   int)
 474     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 475     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 476   ;;
 477   float)
 478     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 479     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 480   ;;
 481   auto)
 482     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 483     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 484 esac
 485
 486 dnl Check for mmap (needed by allocators library)
 487 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 488
 489 dnl Check for DMABuf synchronization ioctl (needed for DMABuf CPU access)
 490 AC_CHECK_HEADERS([linux/dma-buf.h], [])
 491
 492 dnl *** plug-ins to include ***
 493
 494 dnl these are all the gst plug-ins, compilable without additional libs
 495 AG_GST_CHECK_PLUGIN(adder)
 496 AG_GST_CHECK_PLUGIN(app)
 497 AG_GST_CHECK_PLUGIN(audioconvert)
 498 AG_GST_CHECK_PLUGIN(audiomixer)
 499 AG_GST_CHECK_PLUGIN(audiorate)
 500 AG_GST_CHECK_PLUGIN(audiotestsrc)
 501 AG_GST_CHECK_PLUGIN(compositor)
 502 AG_GST_CHECK_PLUGIN(encoding)
 503 AG_GST_CHECK_PLUGIN(videoconvert)
 504 AG_GST_CHECK_PLUGIN(gio)
 505 AG_GST_CHECK_PLUGIN(overlaycomposition)
 506 AG_GST_CHECK_PLUGIN(playback)
 507 AG_GST_CHECK_PLUGIN(audioresample)
 508 AG_GST_CHECK_PLUGIN(rawparse)
 509 AG_GST_CHECK_PLUGIN(subparse)
 510 AG_GST_CHECK_PLUGIN(tcp)
 511 AG_GST_CHECK_PLUGIN(typefind)
 512 AG_GST_CHECK_PLUGIN(videotestsrc)
 513 AG_GST_CHECK_PLUGIN(videorate)
 514 AG_GST_CHECK_PLUGIN(videoscale)
 515 AG_GST_CHECK_PLUGIN(volume)
 516
 517 dnl iso-codes is optional, used by libgsttag
 518 AC_ARG_ENABLE(iso-codes,
 519 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 520 [case "${enableval}" in
 521   yes) enable_iso_codes=yes ;;
 522   no)  enable_iso_codes=no ;;
 523   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 524 esac
 525 ],
 526 [enable_iso_codes=yes]) dnl Default value
 527
 528 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 529 if test "x$enable_iso_codes" = "xyes"; then
 530   AC_MSG_RESULT([yes])
 531   have_iso_codes=no
 532   AC_MSG_CHECKING([whether iso-codes are available on this system])
 533   if $PKG_CONFIG iso-codes; then
 534     AC_MSG_RESULT([yes])
 535     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 536     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 537       AC_MSG_RESULT([yes])
 538       AC_MSG_CHECKING([for iso-codes prefix])
 539       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 540       if test -d "$ISO_CODES_PREFIX"; then
 541         AC_MSG_RESULT([yes])
 542         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 543         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 544         ISO_639_DOMAIN="iso_639"
 545         AC_MSG_CHECKING([ISO_639_DOMAIN])
 546         AC_MSG_RESULT([$ISO_639_DOMAIN])
 547         have_iso_codes=yes
 548         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 549         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 550         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 551         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 552       else
 553         AC_MSG_RESULT([no])
 554       fi
 555     else
 556       AC_MSG_RESULT([no])
 557     fi
 558   else
 559     AC_MSG_RESULT([no])
 560   fi
 561   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 562 else
 563   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 564   AM_CONDITIONAL(USE_ISO_CODES, false)
 565 fi
 566
 567 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 569 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 570   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 571       HAVE_ZLIB="yes"
 572     ], [
 573       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 574         HAVE_ZLIB="yes"
 575         ZLIB_LIBS="-lz"
 576         AC_SUBST(ZLIB_LIBS)
 577       ])
 578     ])
 579 ])
 580
 581 dnl *** sys plug-ins ***
 582
 583 echo
 584 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 585 echo
 586
 587 dnl *** X11 ***
 588 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 589 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 590                   [ximagesink], [
 591   AG_GST_PKG_CHECK_MODULES(X, x11)
 592 ])
 593
 594 dnl Check for Xv extension
 595 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 596 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 597                   [xvimagesink], [
 598   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 599 ])
 600
 601 dnl check for X Shm
 602 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 603 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 604   if test x$HAVE_X = xyes; then
 605     PKG_CHECK_MODULES(XSHM, xext, [
 606       AC_CHECK_LIB(Xext, XShmAttach, [
 607         HAVE_XSHM="yes"
 608       ], [
 609         HAVE_XSHM="no"
 610         XSHM_LIBS=""
 611       ], [ $X_LIBS ])
 612     ], [
 613       HAVE_XSHM="no"
 614     ])
 615   fi
 616 ], , [
 617   AC_SUBST(HAVE_XSHM)
 618   AC_SUBST(XSHM_LIBS)
 619 ])
 620
 621 dnl *** ext plug-ins ***
 622 dnl keep this list sorted alphabetically !
 623
 624 if test "x$BUILD_EXTERNAL" = "xyes"; then
 625
 626 echo
 627 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 628 echo
 629
 630 dnl *** alsa ***
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 632 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 633   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 634     HAVE_ALSA="yes"
 635     AC_SUBST(ALSA_CFLAGS)
 636     AC_SUBST(ALSA_LIBS)
 637   ], [
 638     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 639   ])
 640 ])
 641
 642 dnl *** CDParanoia ***
 643 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 644 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 645 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 646   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 647     HAVE_CDPARANOIA="yes"
 648   ], [
 649     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 650                         cdda_open, -lm,
 651                         cdda_interface.h,
 652                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 653                         HEADER_DIR="no"
 654                         FOUND_CDPARANOIA="yes")
 655     if test "x$FOUND_CDPARANOIA" != "xyes";
 656     then
 657       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 658                           cdda_open, -lm,
 659                           cdda/cdda_interface.h,
 660                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 661                           HEADER_DIR="yes"
 662                           FOUND_CDPARANOIA="yes")
 663     fi
 664     if test "x$HEADER_DIR" = "xyes";
 665     then
 666       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 667                          defined if cdda headers are in a cdda/ directory)
 668     fi
 669     if test "x$FOUND_CDPARANOIA" = "xyes";
 670     then
 671       AC_CHECK_LIB(cdda_paranoia,
 672                    paranoia_cachemodel_size,
 673                    : ,
 674                    HAVE_CDPARANOIA=no,
 675                  [-lcdda_interface])
 676     fi
 677
 678     AC_SUBST(CDPARANOIA_LIBS)
 679   ])
 680 ])
 681 dnl FIXME : add second check somehow if that is necessary
 682 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 683 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 684
 685 dnl *** gl ***
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_GL, true)
 687 AG_GST_CHECK_FEATURE(GL, [gl elements], gl, [
 688   HAVE_GL="no"
 689
 690   if test x"$USE_OPENGL" = x"yes" -o x"$USE_GLES2" = x"yes"; then
 691     HAVE_GL="yes"
 692     AG_GST_GL_PLUGIN_CHECKS
 693   fi
 694 ])
 695
 696 dnl *** ivorbis ***
 697 dnl AM_PATH_IVORBIS only takes two options
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 699 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 700   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 701   if test $HAVE_IVORBIS = no
 702   then
 703     IVORBIS_LIBS=
 704     IVORBIS_CFLAGS=
 705     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 706       [IVORBIS_LIBS=-lvorbisidec
 707       HAVE_IVORBIS=yes
 708       case $host in
 709       arm-*-*)
 710         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 711       esac
 712       ],
 713       HAVE_IVORBIS=no)
 714     AC_SUBST(IVORBIS_LIBS)
 715     AC_SUBST(IVORBIS_CFLAGS)
 716   else
 717     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 718       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 719       USE_TREMOLO=no)
 720   fi
 721 ])
 722
 723 dnl *** libvisual ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 725 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 726   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 727   if test x$HAVE_LIBVISUAL = xyes; then
 728     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 729   fi
 730   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 731   if test x$LIBVIS_PLUGINSDIR != x; then
 732     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 733         "$LIBVIS_PLUGINSDIR",
 734         [directory in which the detected libvisual's plugins are located])
 735   fi
 736 ])
 737
 738 dnl *** ogg ***
 739 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 740 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 741   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 742 ])
 743
 744 dnl *** Opus ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 746 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 747   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 748           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 749           HAVE_OPUS="yes"
 750   ], [
 751           HAVE_OPUS="no"
 752   ])
 753   AC_SUBST(OPUS_CFLAGS)
 754   AC_SUBST(OPUS_LIBS)
 755 ])
 756
 757 dnl *** pango ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 759 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 760   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 761 ])
 762
 763 dnl *** theora ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 765 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 766   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 767 ])
 768
 769 dnl *** vorbis ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 771 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 772   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 773 ])
 774
 775 if test "x$HAVE_VORBIS" = "xyes"; then
 776   ac_cflags_save="$CFLAGS"
 777   AC_COMPILE_IFELSE([
 778     AC_LANG_PROGRAM([[
 779 #include <vorbis/codec.h>
 780                      ]],[[
 781 vorbis_dsp_state *v;
 782
 783 vorbis_synthesis_restart (v);
 784                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 785   if test "x$HAVE_VSR" = "xyes"; then
 786     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 787                        [defined if vorbis_synthesis_restart is present])
 788   fi
 789   CFLAGS="$ac_cflags_save"
 790 fi
 791
 792 else
 793
 794 dnl not building plugins with external dependencies,
 795 dnl but we still need to set the conditionals
 796 AM_CONDITIONAL(USE_ALSA, false)
 797 AM_CONDITIONAL(USE_CDPARANOIA, false)
 798 AM_CONDITIONAL(USE_GL, false)
 799 AM_CONDITIONAL(USE_IVORBIS, false)
 800 AM_CONDITIONAL(USE_LIBVISUAL, false)
 801 AM_CONDITIONAL(USE_OGG, false)
 802 AM_CONDITIONAL(USE_OPUS, false)
 803 AM_CONDITIONAL(USE_PANGO, false)
 804 AM_CONDITIONAL(USE_THEORA, false)
 805 AM_CONDITIONAL(USE_VORBIS, false)
 806
 807 fi dnl of EXT plugins
 808
 809 AM_CONDITIONAL(HAVE_GRAPHENE, test "x$HAVE_GRAPHENE" = "xyes")
 810 AM_CONDITIONAL(HAVE_PNG, test "x$HAVE_PNG" = "xyes")
 811 AM_CONDITIONAL(HAVE_JPEG, test "x$HAVE_JPEG" = "xyes")
 812
 813 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 814 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 815     HAVE_GIO_UNIX_2_0="yes",
 816     HAVE_GIO_UNIX_2_0="no")
 817 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 818
 819 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 820
 821 dnl Overview:
 822 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 823 dnl GST_*:              flags shared by built objects to link against GStreamer
 824 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 825 dnl                          (compare to other modules) or for i18n
 826 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 827 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 828 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 829 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 830
 831 dnl GST_OPTION_CFLAGS
 832 if test "x$USE_DEBUG" = xyes; then
 833    PROFILE_CFLAGS="-g"
 834 fi
 835 AC_SUBST(PROFILE_CFLAGS)
 836
 837 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 838   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 839   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 840 else
 841   DEPRECATED_CFLAGS=""
 842 fi
 843 AC_SUBST(DEPRECATED_CFLAGS)
 844
 845 VISIBILITY_CFLAGS=""
 846 AS_COMPILER_FLAG([-fvisibility=hidden], [
 847   VISIBILITY_CFLAGS="-fvisibility=hidden"
 848   AC_DEFINE(GST_API_EXPORT, [extern __attribute__ ((visibility ("default")))], [public symbol export define])
 849 ], [
 850   VISIBILITY_CFLAGS=""
 851   AC_DEFINE(GST_API_EXPORT, [extern], [public symbol export define])
 852 ])
 853 AC_SUBST(VISIBILITY_CFLAGS)
 854
 855 VISIBILITY_CXXFLAGS=""
 856 if test "x$HAVE_CXX" = "xyes"; then
 857   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 858 fi
 859 AC_SUBST(VISIBILITY_CXXFLAGS)
 860
 861 dnl disable strict aliasing
 862 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 863 AC_SUBST(EXTRA_CFLAGS)
 864
 865 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 866 dnl at make time with e.g. make ERROR_CFLAGS=""
 867 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 868 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 869 AC_SUBST(GST_OPTION_CFLAGS)
 870 AC_SUBST(GST_OPTION_CXXFLAGS)
 871
 872 dnl our libraries need to be versioned correctly
 873 AC_SUBST(GST_LT_LDFLAGS)
 874
 875 dnl GST_PLUGINS_BASE_CFLAGS
 876 dnl prefer internal headers to already installed ones
 877 dnl also add builddir include for enumtypes and marshal
 878 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 879 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 880
 881 dnl FIXME: do we want to rename to GST_ALL_* ?
 882 dnl add GST_OPTION_CFLAGS, but overridable
 883 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 884 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 885 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 886 AC_SUBST(GST_CFLAGS)
 887 AC_SUBST(GST_CXXFLAGS)
 888 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 889 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 890 AC_SUBST(GST_LIBS)
 891
 892 dnl LDFLAGS really should only contain flags, not libs - they get added before
 893 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 894 GST_ALL_LDFLAGS="-no-undefined"
 895 if test "x${enable_Bsymbolic}" = "xyes"; then
 896   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 897 fi
 898 AC_SUBST(GST_ALL_LDFLAGS)
 899
 900 dnl GST_LIB_LDFLAGS
 901 dnl linker flags shared by all libraries
 902 dnl LDFLAGS modifier defining exported symbols from built libraries
 903 dnl (export _gst_foo but not __gst_foo)
 904 GST_LIB_LDFLAGS=""
 905 AC_SUBST(GST_LIB_LDFLAGS)
 906
 907 dnl this really should only contain flags, not libs - they get added before
 908 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 909 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 910 AC_SUBST(GST_PLUGIN_LDFLAGS)
 911
 912 dnl *** output files ***
 913
 914 $MKDIR_P tests/check/orc
 915
 916 AC_CONFIG_FILES(
 917 Makefile
 918 gst/Makefile
 919 gst/adder/Makefile
 920 gst/app/Makefile
 921 gst/audioconvert/Makefile
 922 gst/audiomixer/Makefile
 923 gst/audiorate/Makefile
 924 gst/audioresample/Makefile
 925 gst/audiotestsrc/Makefile
 926 gst/compositor/Makefile
 927 gst/encoding/Makefile
 928 gst/videoconvert/Makefile
 929 gst/gio/Makefile
 930 gst/overlaycomposition/Makefile
 931 gst/pbtypes/Makefile
 932 gst/playback/Makefile
 933 gst/rawparse/Makefile
 934 gst/subparse/Makefile
 935 gst/tcp/Makefile
 936 gst/typefind/Makefile
 937 gst/videotestsrc/Makefile
 938 gst/videorate/Makefile
 939 gst/videoscale/Makefile
 940 gst/volume/Makefile
 941 sys/Makefile
 942 sys/ximage/Makefile
 943 sys/xvimage/Makefile
 944 ext/Makefile
 945 ext/alsa/Makefile
 946 ext/cdparanoia/Makefile
 947 ext/gl/Makefile
 948 ext/libvisual/Makefile
 949 ext/ogg/Makefile
 950 ext/opus/Makefile
 951 ext/pango/Makefile
 952 ext/theora/Makefile
 953 ext/vorbis/Makefile
 954 gst-libs/Makefile
 955 gst-libs/gst/Makefile
 956 gst-libs/gst/allocators/Makefile
 957 gst-libs/gst/audio/Makefile
 958 gst-libs/gst/app/Makefile
 959 gst-libs/gst/fft/Makefile
 960 gst-libs/gst/gl/Makefile
 961 gst-libs/gst/gl/android/Makefile
 962 gst-libs/gst/gl/cocoa/Makefile
 963 gst-libs/gst/gl/dispmanx/Makefile
 964 gst-libs/gst/gl/glprototypes/Makefile
 965 gst-libs/gst/gl/eagl/Makefile
 966 gst-libs/gst/gl/egl/Makefile
 967 gst-libs/gst/gl/wayland/Makefile
 968 gst-libs/gst/gl/win32/Makefile
 969 gst-libs/gst/gl/x11/Makefile
 970 gst-libs/gst/gl/viv-fb/Makefile
 971 gst-libs/gst/gl/gbm/Makefile
 972 gst-libs/gst/riff/Makefile
 973 gst-libs/gst/rtp/Makefile
 974 gst-libs/gst/rtsp/Makefile
 975 gst-libs/gst/sdp/Makefile
 976 gst-libs/gst/tag/Makefile
 977 gst-libs/gst/pbutils/Makefile
 978 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 979 gst-libs/gst/video/Makefile
 980 tools/Makefile
 981 pkgconfig/Makefile
 982 pkgconfig/gstreamer-allocators.pc
 983 pkgconfig/gstreamer-allocators-uninstalled.pc
 984 pkgconfig/gstreamer-audio.pc
 985 pkgconfig/gstreamer-audio-uninstalled.pc
 986 pkgconfig/gstreamer-app.pc
 987 pkgconfig/gstreamer-app-uninstalled.pc
 988 pkgconfig/gstreamer-fft.pc
 989 pkgconfig/gstreamer-fft-uninstalled.pc
 990 pkgconfig/gstreamer-pbutils.pc
 991 pkgconfig/gstreamer-pbutils-uninstalled.pc
 992 pkgconfig/gstreamer-riff.pc
 993 pkgconfig/gstreamer-riff-uninstalled.pc
 994 pkgconfig/gstreamer-rtp.pc
 995 pkgconfig/gstreamer-rtp-uninstalled.pc
 996 pkgconfig/gstreamer-rtsp.pc
 997 pkgconfig/gstreamer-rtsp-uninstalled.pc
 998 pkgconfig/gstreamer-sdp.pc
 999 pkgconfig/gstreamer-sdp-uninstalled.pc
1000 pkgconfig/gstreamer-tag.pc
1001 pkgconfig/gstreamer-tag-uninstalled.pc
1002 pkgconfig/gstreamer-video.pc
1003 pkgconfig/gstreamer-video-uninstalled.pc
1004 pkgconfig/gstreamer-gl.pc
1005 pkgconfig/gstreamer-gl-uninstalled.pc
1006 pkgconfig/gstreamer-plugins-base.pc
1007 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1008 tests/Makefile
1009 tests/check/Makefile
1010 tests/examples/Makefile
1011 tests/examples/app/Makefile
1012 tests/examples/audio/Makefile
1013 tests/examples/compositor/Makefile
1014 tests/examples/decodebin_next/Makefile
1015 tests/examples/dynamic/Makefile
1016 tests/examples/encoding/Makefile
1017 tests/examples/fft/Makefile
1018 tests/examples/gio/Makefile
1019 tests/examples/gl/Makefile
1020 tests/examples/gl/generic/Makefile
1021 tests/examples/gl/generic/cube/Makefile
1022 tests/examples/gl/generic/doublecube/Makefile
1023 tests/examples/gl/generic/recordgraphic/Makefile
1024 tests/examples/gl/generic/cubeyuv/Makefile
1025 tests/examples/gl/qt/Makefile
1026 tests/examples/gl/gtk/Makefile
1027 tests/examples/gl/gtk/fxtest/Makefile
1028 tests/examples/gl/gtk/3dvideo/Makefile
1029 tests/examples/gl/gtk/switchvideooverlay/Makefile
1030 tests/examples/gl/gtk/filternovideooverlay/Makefile
1031 tests/examples/gl/gtk/filtervideooverlay/Makefile
1032 tests/examples/gl/cocoa/Makefile
1033 tests/examples/gl/sdl/Makefile
1034 tests/examples/overlay/Makefile
1035 tests/examples/overlaycomposition/Makefile
1036 tests/examples/seek/Makefile
1037 tests/examples/snapshot/Makefile
1038 tests/examples/playback/Makefile
1039 tests/examples/playrec/Makefile
1040 tests/files/Makefile
1041 tests/icles/Makefile
1042 tests/icles/playback/Makefile
1043 docs/Makefile
1044 docs/libs/Makefile
1045 docs/plugins/Makefile
1046 docs/version.entities
1047 po/Makefile.in
1048 common/Makefile
1049 common/m4/Makefile
1050 m4/Makefile
1051 )
1052 AC_OUTPUT
1053
1054 AG_GST_OUTPUT_PLUGINS
1055 ORC_OUTPUT
1056