configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.6.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 601, 0, 601)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.6.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for tv profile
 157
 158 AC_ARG_ENABLE(tv, AC_HELP_STRING([--enable-tv], [enable tv profile]),
 159         [
 160           case "${enableval}" in
 161            yes) TV_PROFILE=yes ;;
 162            no)  TV_PROFILE=no ;;
 163            *)   AC_MSG_ERROR(bad value ${enableval} for --enable-tv) ;;
 164           esac
 165         ],
 166         [TV_PROFILE=no])
 167 AM_CONDITIONAL([TV_PROFILE], [test "x$TV_PROFILE" = "xyes"])
 168
 169 dnl check for tbm buffer
 170
 171 AC_ARG_ENABLE(tbmbuf, AC_HELP_STRING([--enable-use-tbmbuf], [use tbm buf]),
 172         [
 173           case "${enableval}" in
 174            yes) BOARD_USE_TBM_BUF=yes ;;
 175            no)  BOARD_USE_TBM_BUF=no ;;
 176            *)   AC_MSG_ERROR(bad value ${enableval} for --enable-use-tbmbuf) ;;
 177           esac
 178         ],
 179         [BOARD_USE_TBM_BUF=yes])
 180 AM_CONDITIONAL([BOARD_USE_TBM_BUF], [test "x$BOARD_USE_TBM_BUF" = "xyes"])
 181
 182 dnl check for gobject-introspection
 183 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 184
 185 dnl check for documentation tools
 186 GTK_DOC_CHECK([1.12])
 187 AG_GST_PLUGIN_DOCS([1.12])
 188
 189 dnl *** checks for libraries ***
 190
 191 dnl libm, for sin() etc.
 192 LT_LIB_M
 193 AC_SUBST(LIBM)
 194
 195 dnl *** checks for header files ***
 196
 197 dnl check if we have ANSI C header files
 198 AC_HEADER_STDC
 199
 200 dnl check for GCC specific SSE headers
 201 dnl these are used by the speex resampler code
 202 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 203
 204 dnl used in gst/tcp
 205 AC_CHECK_HEADERS([sys/socket.h],
 206   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 207 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 208
 209 dnl used in gst-libs/gst/rtsp
 210 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 211 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 212 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 213   WIN32_LIBS="-lws2_32"
 214   AC_SUBST(WIN32_LIBS)
 215 fi
 216
 217 dnl used in gst-libs/gst/pbutils and associated unit test
 218 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 219
 220 dnl checks for ARM NEON support
 221 dnl this instruction set is used by the speex resampler code
 222 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 223 AC_LINK_IFELSE([
 224 AC_LANG_PROGRAM([[
 225   #include <arm_neon.h>
 226   int32x4_t testfunc(int16_t *a, int16_t *b) {
 227       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 228       return vmull_s16(vld1_s16(a), vld1_s16(b));
 229   }
 230 ]])],
 231 [
 232   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 233   AC_MSG_RESULT(yes)
 234 ],
 235 [
 236   AC_MSG_RESULT(no)
 237 ])
 238
 239 dnl also, Windows does not have long long
 240 AX_CREATE_STDINT_H
 241
 242 dnl *** checks for functions ***
 243 AC_CHECK_FUNCS([localtime_r gmtime_r])
 244
 245 dnl *** checks for math functions ***
 246 LIBS_SAVE=$LIBS
 247 LIBS="$LIBS $LIBM"
 248 AC_CHECK_FUNCS(log2)
 249 LIBS=$LIBS_SAVE
 250
 251 dnl *** checks for types/defines ***
 252
 253 dnl *** checks for structures ***
 254
 255 dnl *** checks for compiler characteristics ***
 256
 257 dnl *** checks for library functions ***
 258
 259 dnl check for fseeko()
 260 AC_FUNC_FSEEKO
 261
 262 dnl Check for fast float to int casting as defined in C99
 263 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 264 save_libs=$LIBS
 265 LIBS="$LIBS $LIBM"
 266 #AC_C99_FUNC_LRINT
 267 #AC_C99_FUNC_LRINTF
 268 LIBS=$save_libs
 269
 270 dnl Check for a way to display the function name in debug output
 271 AG_GST_CHECK_FUNCTION
 272
 273 dnl *** checks for dependency libraries ***
 274
 275 dnl GLib
 276 GLIB_REQ=2.32
 277 AG_GST_GLIB_CHECK([$GLIB_REQ])
 278
 279 ORC_CHECK([0.4.23])
 280
 281 dnl checks for gstreamer
 282 dnl uninstalled is selected preferentially -- see pkg-config(1)
 283 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 284 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 285 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 286 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 288 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 289
 290 dnl Check for documentation xrefs
 291 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 292 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 293 AC_SUBST(GLIB_PREFIX)
 294 AC_SUBST(GST_PREFIX)
 295
 296 dnl GTK is optional and only used in examples
 297 HAVE_GTK=no
 298 HAVE_GTK_X11=no
 299 GTK_REQ=3.10
 300 if test "x$BUILD_EXAMPLES" = "xyes"; then
 301   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 302   dnl some examples need gtk+-x11
 303   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 304   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 305   AC_SUBST(GTK_LIBS)
 306   AC_SUBST(GTK_CFLAGS)
 307 fi
 308 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 309 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 310 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 311
 312 HAVE_QT=no
 313 HAVE_QT_MOC=no
 314 dnl QT is optional and only used in examples
 315 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 316   HAVE_QT=yes
 317 ], [
 318   HAVE_QT=no
 319 ])
 320 if test "x$HAVE_QT" = "xyes"; then
 321   AC_CHECK_TOOL(QT_MOC, moc)
 322   AC_MSG_CHECKING([for Qt5 moc])
 323   mocversion=`$QT_MOC -v 2>&1`
 324   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 325   if test x"$mocversiongrep" != x"$mocversion"; then
 326     AC_MSG_RESULT([no])
 327     # moc was not the qt5 one, try with moc-qt5
 328     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 329     AC_MSG_CHECKING([for Qt5 moc-qt5])
 330     mocversion=`$QT_MOC -v 2>&1`
 331     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 332     if test x"$mocversiongrep" != x"$mocversion"; then
 333       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 334       AC_MSG_CHECKING([for qtchooser])
 335       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 336       mocversion=`$qt5tooldir/moc -v 2>&1`
 337       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 338       if test x"$mocversiongrep" != x"$mocversion"; then
 339         # no valid moc found
 340         QT_MOC="no"
 341       else
 342         QT_MOC=$qt5tooldir/moc
 343       fi
 344     else
 345       QT_MOC=$QT_MOC
 346     fi
 347   fi
 348   AC_SUBST(QT_MOC)
 349   AC_MSG_RESULT([$QT_MOC])
 350 fi
 351 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 352 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 353
 354 dnl chck for linux headers needed by the joystick seek example
 355 AC_COMPILE_IFELSE(
 356 [
 357   AC_LANG_PROGRAM([
 358     #include <linux/input.h>
 359     #include <linux/joystick.h>
 360   ],[
 361     struct js_event js;
 362     js.type = JS_EVENT_AXIS;
 363   ])
 364 ], [
 365   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 366 ], [
 367   HAVE_LINUX_JOYSTICK_HEADERS="no"
 368 ])
 369 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 370
 371 dnl Check for -Bsymbolic-functions linker flag used to avoid
 372 dnl intra-library PLT jumps, if available.
 373 AC_ARG_ENABLE(Bsymbolic,
 374               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 375               [SAVED_LDFLAGS="${LDFLAGS}"
 376                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 377                LDFLAGS=-Wl,-Bsymbolic-functions
 378                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 379                            AC_MSG_RESULT(yes)
 380                            enable_Bsymbolic=yes],[
 381                            AC_MSG_RESULT(no)
 382                            enable_Bsymbolic=no])
 383                LDFLAGS="${SAVED_LDFLAGS}"])
 384
 385
 386 dnl *** set variables based on configure arguments ***
 387
 388 dnl set license and copyright notice
 389 GST_LICENSE="LGPL"
 390 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 391 AC_SUBST(GST_LICENSE)
 392
 393 dnl set location of plugin directory
 394 AG_GST_SET_PLUGINDIR
 395
 396 dnl set release date/time
 397 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 398   ["${srcdir}/gst-plugins-base.doap"],
 399   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 400
 401 dnl build static plugins or not
 402 AC_MSG_CHECKING([whether to build static plugins or not])
 403 AC_ARG_ENABLE(
 404   static-plugins,
 405   AC_HELP_STRING(
 406     [--enable-static-plugins],
 407     [build static plugins @<:@default=no@:>@]),
 408   [AS_CASE(
 409     [$enableval], [no], [], [yes], [],
 410     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 411   [enable_static_plugins=no])
 412 AC_MSG_RESULT([$enable_static_plugins])
 413 if test "x$enable_static_plugins" = xyes; then
 414   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 415     [Define if static plugins should be built])
 416   GST_PLUGIN_LIBTOOLFLAGS=""
 417 else
 418   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 419 fi
 420 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 421 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 422
 423 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 424 dnl make sure it doesn't complain about unused variables if debugging is disabled
 425 NO_WARNINGS=""
 426 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 427
 428 dnl define an ERROR_CFLAGS Makefile variable
 429 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 430 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 431     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 432     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 433     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 434     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 435
 436 dnl define an ERROR_CXXFLAGS Makefile variable
 437 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 438     -Wmissing-declarations -Wredundant-decls -Wundef
 439     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 440     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 441     -Wno-multichar $NO_WARNINGS])
 442
 443 dnl define correct level for debugging messages
 444 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 445
 446 dnl used in examples
 447 AG_GST_DEFAULT_ELEMENTS
 448
 449 dnl needed for encoding-target
 450 GST_DATADIR="$GST_PREFIX/share"
 451 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 452 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 453
 454 dnl behaviour of speex based audio resampler
 455 AC_MSG_CHECKING(which audio resample format to use for integer)
 456 AC_ARG_WITH([audioresample_format],
 457         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 458         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 459 AC_MSG_RESULT($ac_cv_audioresample_format)
 460 case $ac_cv_audioresample_format in
 461   int)
 462     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 463     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 464   ;;
 465   float)
 466     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 467     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 468   ;;
 469   auto)
 470     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 471     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 472 esac
 473
 474 dnl Check for mmap (needed by allocators library)
 475 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 476
 477 dnl *** plug-ins to include ***
 478
 479 dnl these are all the gst plug-ins, compilable without additional libs
 480 AG_GST_CHECK_PLUGIN(adder)
 481 AG_GST_CHECK_PLUGIN(app)
 482 AG_GST_CHECK_PLUGIN(audioconvert)
 483 AG_GST_CHECK_PLUGIN(audiorate)
 484 AG_GST_CHECK_PLUGIN(audiotestsrc)
 485 AG_GST_CHECK_PLUGIN(encoding)
 486 AG_GST_CHECK_PLUGIN(videoconvert)
 487 AG_GST_CHECK_PLUGIN(gio)
 488 AG_GST_CHECK_PLUGIN(playback)
 489 AG_GST_CHECK_PLUGIN(audioresample)
 490 AG_GST_CHECK_PLUGIN(subparse)
 491 AG_GST_CHECK_PLUGIN(tcp)
 492 AG_GST_CHECK_PLUGIN(typefind)
 493 AG_GST_CHECK_PLUGIN(videotestsrc)
 494 AG_GST_CHECK_PLUGIN(videorate)
 495 AG_GST_CHECK_PLUGIN(videoscale)
 496 AG_GST_CHECK_PLUGIN(volume)
 497
 498 dnl iso-codes is optional, used by libgsttag
 499 AC_ARG_ENABLE(iso-codes,
 500 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 501 [case "${enableval}" in
 502   yes) enable_iso_codes=yes ;;
 503   no)  enable_iso_codes=no ;;
 504   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 505 esac
 506 ],
 507 [enable_iso_codes=yes]) dnl Default value
 508
 509 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 510 if test "x$enable_iso_codes" = "xyes"; then
 511   AC_MSG_RESULT([yes])
 512   have_iso_codes=no
 513   AC_MSG_CHECKING([whether iso-codes are available on this system])
 514   if $PKG_CONFIG iso-codes; then
 515     AC_MSG_RESULT([yes])
 516     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 517     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 518       AC_MSG_RESULT([yes])
 519       AC_MSG_CHECKING([for iso-codes prefix])
 520       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 521       if test -d "$ISO_CODES_PREFIX"; then
 522         AC_MSG_RESULT([yes])
 523         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 524         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 525         ISO_639_DOMAIN="iso_639"
 526         AC_MSG_CHECKING([ISO_639_DOMAIN])
 527         AC_MSG_RESULT([$ISO_639_DOMAIN])
 528         have_iso_codes=yes
 529         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 530         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 531         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 532         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 533       else
 534         AC_MSG_RESULT([no])
 535       fi
 536     else
 537       AC_MSG_RESULT([no])
 538     fi
 539   else
 540     AC_MSG_RESULT([no])
 541   fi
 542   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 543 else
 544   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 545   AM_CONDITIONAL(USE_ISO_CODES, false)
 546 fi
 547
 548 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 549 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 550 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 551   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 552       HAVE_ZLIB="yes"
 553     ], [
 554       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 555         HAVE_ZLIB="yes"
 556         ZLIB_LIBS="-lz"
 557         AC_SUBST(ZLIB_LIBS)
 558       ])
 559     ])
 560 ])
 561
 562 dnl *** sys plug-ins ***
 563
 564 echo
 565 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 566 echo
 567
 568 dnl *** X11 ***
 569 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 570 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 571                   [ximagesink], [
 572   AG_GST_PKG_CHECK_MODULES(X, x11)
 573 ])
 574
 575 dnl Check for Xv extension
 576 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 577 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 578                   [xvimagesink], [
 579   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 580 ])
 581
 582 dnl check for X Shm
 583 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 584 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 585   if test x$HAVE_X = xyes; then
 586     PKG_CHECK_MODULES(XSHM, xext, [
 587       AC_CHECK_LIB(Xext, XShmAttach, [
 588         HAVE_XSHM="yes"
 589       ], [
 590         HAVE_XSHM="no"
 591         XSHM_LIBS=""
 592       ], [ $X_LIBS ])
 593     ], [
 594       HAVE_XSHM="no"
 595     ])
 596   fi
 597 ], , [
 598   AC_SUBST(HAVE_XSHM)
 599   AC_SUBST(XSHM_LIBS)
 600 ])
 601
 602 dnl *** ext plug-ins ***
 603 dnl keep this list sorted alphabetically !
 604
 605 if test "x$BUILD_EXTERNAL" = "xyes"; then
 606
 607 echo
 608 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 609 echo
 610
 611 dnl *** alsa ***
 612 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 613 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 614   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 615     HAVE_ALSA="yes"
 616     AC_SUBST(ALSA_CFLAGS)
 617     AC_SUBST(ALSA_LIBS)
 618   ], [
 619     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 620   ])
 621 ])
 622
 623 dnl *** CDParanoia ***
 624 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 626 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 627   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 628     HAVE_CDPARANOIA="yes"
 629   ], [
 630     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 631                         cdda_open, -lm,
 632                         cdda_interface.h,
 633                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 634                         HEADER_DIR="no"
 635                         FOUND_CDPARANOIA="yes")
 636     if test "x$FOUND_CDPARANOIA" != "xyes";
 637     then
 638       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 639                           cdda_open, -lm,
 640                           cdda/cdda_interface.h,
 641                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 642                           HEADER_DIR="yes"
 643                           FOUND_CDPARANOIA="yes")
 644     fi
 645     if test "x$HEADER_DIR" = "xyes";
 646     then
 647       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 648                          defined if cdda headers are in a cdda/ directory)
 649     fi
 650     if test "x$FOUND_CDPARANOIA" = "xyes";
 651     then
 652       AC_CHECK_LIB(cdda_paranoia,
 653                    paranoia_cachemodel_size,
 654                    : ,
 655                    HAVE_CDPARANOIA=no,
 656                  [-lcdda_interface])
 657     fi
 658
 659     AC_SUBST(CDPARANOIA_LIBS)
 660   ])
 661 ])
 662 dnl FIXME : add second check somehow if that is necessary
 663 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 664 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 665
 666 dnl *** ivorbis ***
 667 dnl AM_PATH_IVORBIS only takes two options
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 669 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 670   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 671   if test $HAVE_IVORBIS = no
 672   then
 673     IVORBIS_LIBS=
 674     IVORBIS_CFLAGS=
 675     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 676       [IVORBIS_LIBS=-lvorbisidec
 677       HAVE_IVORBIS=yes
 678       case $host in
 679       arm-*-*)
 680         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 681       esac
 682       ],
 683       HAVE_IVORBIS=no)
 684     AC_SUBST(IVORBIS_LIBS)
 685     AC_SUBST(IVORBIS_CFLAGS)
 686   else
 687     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 688       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 689       USE_TREMOLO=no)
 690   fi
 691 ])
 692
 693 dnl *** libvisual ***
 694 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 695 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 696   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 697   if test x$HAVE_LIBVISUAL = xyes; then
 698     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 699   fi
 700   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 701   if test x$LIBVIS_PLUGINSDIR != x; then
 702     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 703         "$LIBVIS_PLUGINSDIR",
 704         [directory in which the detected libvisual's plugins are located])
 705   fi
 706 ])
 707
 708 dnl *** ogg ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 710 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 711   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 712 ])
 713
 714 dnl *** pango ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 716 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 717   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 718 ])
 719
 720 dnl *** theora ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 722 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 723   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 724 ])
 725
 726 dnl *** vorbis ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 728 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 729   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 730 ])
 731
 732 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 733 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO_UNIX_2_0, true)
 734 AG_GST_CHECK_FEATURE(GIO_UNIX_2_0, [glib GIO unix], gio-unix-2.0, [
 735   AG_GST_PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24)
 736 ])
 737
 738 if test "x$HAVE_VORBIS" = "xyes"; then
 739   ac_cflags_save="$CFLAGS"
 740   AC_COMPILE_IFELSE([
 741     AC_LANG_PROGRAM([[
 742 #include <vorbis/codec.h>
 743                      ]],[[
 744 vorbis_dsp_state *v;
 745
 746 vorbis_synthesis_restart (v);
 747                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 748   if test "x$HAVE_VSR" = "xyes"; then
 749     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 750                        [defined if vorbis_synthesis_restart is present])
 751   fi
 752   CFLAGS="$ac_cflags_save"
 753 fi
 754
 755 else
 756
 757 dnl not building plugins with external dependencies,
 758 dnl but we still need to set the conditionals
 759 AM_CONDITIONAL(USE_ALSA, false)
 760 AM_CONDITIONAL(USE_CDPARANOIA, false)
 761 AM_CONDITIONAL(USE_IVORBIS, false)
 762 AM_CONDITIONAL(USE_LIBVISUAL, false)
 763 AM_CONDITIONAL(USE_OGG, false)
 764 AM_CONDITIONAL(USE_PANGO, false)
 765 AM_CONDITIONAL(USE_THEORA, false)
 766 AM_CONDITIONAL(USE_VORBIS, false)
 767
 768 fi dnl of EXT plugins
 769
 770 dnl seeking needs freetype, so check for it here
 771 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 772   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 773 ])
 774 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 775 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 776 AC_SUBST(FT2_CFLAGS)
 777 AC_SUBST(FT2_LIBS)
 778
 779 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 780
 781 dnl Overview:
 782 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 783 dnl GST_*:              flags shared by built objects to link against GStreamer
 784 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 785 dnl                          (compare to other modules) or for i18n
 786 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 787 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 788 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 789 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 790
 791 dnl GST_OPTION_CFLAGS
 792 if test "x$USE_DEBUG" = xyes; then
 793    PROFILE_CFLAGS="-g"
 794 fi
 795 AC_SUBST(PROFILE_CFLAGS)
 796
 797 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 798   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 799   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 800 else
 801   DEPRECATED_CFLAGS=""
 802 fi
 803 AC_SUBST(DEPRECATED_CFLAGS)
 804
 805 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 806 dnl at make time with e.g. make ERROR_CFLAGS=""
 807 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 808 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 809 AC_SUBST(GST_OPTION_CFLAGS)
 810 AC_SUBST(GST_OPTION_CXXFLAGS)
 811
 812 dnl our libraries need to be versioned correctly
 813 AC_SUBST(GST_LT_LDFLAGS)
 814
 815 dnl GST_PLUGINS_BASE_CFLAGS
 816 dnl prefer internal headers to already installed ones
 817 dnl also add builddir include for enumtypes and marshal
 818 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 819 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 820
 821 dnl FIXME: do we want to rename to GST_ALL_* ?
 822 dnl add GST_OPTION_CFLAGS, but overridable
 823 GST_CFLAGS="$GST_CFLAGS"
 824 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 825 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 826 AC_SUBST(GST_CFLAGS)
 827 AC_SUBST(GST_CXXFLAGS)
 828 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 829 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 830 AC_SUBST(GST_LIBS)
 831
 832 dnl LDFLAGS really should only contain flags, not libs - they get added before
 833 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 834 GST_ALL_LDFLAGS="-no-undefined"
 835 if test "x${enable_Bsymbolic}" = "xyes"; then
 836   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 837 fi
 838 AC_SUBST(GST_ALL_LDFLAGS)
 839
 840 dnl GST_LIB_LDFLAGS
 841 dnl linker flags shared by all libraries
 842 dnl LDFLAGS modifier defining exported symbols from built libraries
 843 dnl (export _gst_foo but not __gst_foo)
 844 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 845 AC_SUBST(GST_LIB_LDFLAGS)
 846
 847 dnl this really should only contain flags, not libs - they get added before
 848 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 849 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 850 AC_SUBST(GST_PLUGIN_LDFLAGS)
 851
 852 dnl use tbm
 853 PKG_CHECK_MODULES(TBM, libdrm libtbm)
 854 AC_SUBST(TBM_CFLAGS)
 855 AC_SUBST(TBM_LIBS)
 856
 857 dnl use  mm-common
 858 PKG_CHECK_MODULES(MMCOMMON,mm-common)
 859 AC_SUBST(MMCOMMON_CFLAGS)
 860
 861 dnl *** output files ***
 862
 863 $MKDIR_P tests/check/orc
 864
 865 AC_CONFIG_FILES(
 866 Makefile
 867 gst-plugins-base.spec
 868 gst/Makefile
 869 gst/adder/Makefile
 870 gst/app/Makefile
 871 gst/audioconvert/Makefile
 872 gst/audiorate/Makefile
 873 gst/audiotestsrc/Makefile
 874 gst/encoding/Makefile
 875 gst/videoconvert/Makefile
 876 gst/gio/Makefile
 877 gst/playback/Makefile
 878 gst/audioresample/Makefile
 879 gst/subparse/Makefile
 880 gst/tcp/Makefile
 881 gst/typefind/Makefile
 882 gst/videotestsrc/Makefile
 883 gst/videorate/Makefile
 884 gst/videoscale/Makefile
 885 gst/volume/Makefile
 886 sys/Makefile
 887 sys/ximage/Makefile
 888 sys/xvimage/Makefile
 889 ext/Makefile
 890 ext/alsa/Makefile
 891 ext/cdparanoia/Makefile
 892 ext/libvisual/Makefile
 893 ext/ogg/Makefile
 894 ext/pango/Makefile
 895 ext/theora/Makefile
 896 ext/vorbis/Makefile
 897 gst-libs/Makefile
 898 gst-libs/gst/Makefile
 899 gst-libs/gst/allocators/Makefile
 900 gst-libs/gst/audio/Makefile
 901 gst-libs/gst/app/Makefile
 902 gst-libs/gst/fft/Makefile
 903 gst-libs/gst/riff/Makefile
 904 gst-libs/gst/rtp/Makefile
 905 gst-libs/gst/rtsp/Makefile
 906 gst-libs/gst/sdp/Makefile
 907 gst-libs/gst/tag/Makefile
 908 gst-libs/gst/pbutils/Makefile
 909 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 910 gst-libs/gst/video/Makefile
 911 tools/Makefile
 912 pkgconfig/Makefile
 913 pkgconfig/gstreamer-allocators.pc
 914 pkgconfig/gstreamer-allocators-uninstalled.pc
 915 pkgconfig/gstreamer-audio.pc
 916 pkgconfig/gstreamer-audio-uninstalled.pc
 917 pkgconfig/gstreamer-app.pc
 918 pkgconfig/gstreamer-app-uninstalled.pc
 919 pkgconfig/gstreamer-fft.pc
 920 pkgconfig/gstreamer-fft-uninstalled.pc
 921 pkgconfig/gstreamer-pbutils.pc
 922 pkgconfig/gstreamer-pbutils-uninstalled.pc
 923 pkgconfig/gstreamer-riff.pc
 924 pkgconfig/gstreamer-riff-uninstalled.pc
 925 pkgconfig/gstreamer-rtp.pc
 926 pkgconfig/gstreamer-rtp-uninstalled.pc
 927 pkgconfig/gstreamer-rtsp.pc
 928 pkgconfig/gstreamer-rtsp-uninstalled.pc
 929 pkgconfig/gstreamer-sdp.pc
 930 pkgconfig/gstreamer-sdp-uninstalled.pc
 931 pkgconfig/gstreamer-tag.pc
 932 pkgconfig/gstreamer-tag-uninstalled.pc
 933 pkgconfig/gstreamer-video.pc
 934 pkgconfig/gstreamer-video-uninstalled.pc
 935 pkgconfig/gstreamer-plugins-base.pc
 936 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 937 tests/Makefile
 938 tests/check/Makefile
 939 tests/examples/Makefile
 940 tests/examples/app/Makefile
 941 tests/examples/audio/Makefile
 942 tests/examples/dynamic/Makefile
 943 tests/examples/encoding/Makefile
 944 tests/examples/fft/Makefile
 945 tests/examples/gio/Makefile
 946 tests/examples/overlay/Makefile
 947 tests/examples/seek/Makefile
 948 tests/examples/snapshot/Makefile
 949 tests/examples/playback/Makefile
 950 tests/examples/playrec/Makefile
 951 tests/files/Makefile
 952 tests/icles/Makefile
 953 tests/icles/playback/Makefile
 954 docs/Makefile
 955 docs/design/Makefile
 956 docs/libs/Makefile
 957 docs/plugins/Makefile
 958 docs/version.entities
 959 po/Makefile.in
 960 common/Makefile
 961 common/m4/Makefile
 962 m4/Makefile
 963 )
 964
 965 dnl Create the config.h file for Visual Studio builds
 966 dnl Beware of spaces and /'s in some of the shell variable contents.
 967 sed \
 968     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 969     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 970     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 971     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 972     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 973     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 974     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 975     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 976     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 977     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 978     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 979     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 980     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 981     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 982     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 983     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 984     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 985     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 986     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 987     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 988     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 989     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 990     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 991     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 992     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 993     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 994     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 995     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 996     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 997     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 998     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 999     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1000     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1001     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1002     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1003     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1004     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1005     config.h.in >win32/common/config.h-new
1006
1007
1008
1009 AC_OUTPUT
1010
1011 AG_GST_OUTPUT_PLUGINS
1012 ORC_OUTPUT
1013