configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.14.0],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1400, 0, 1400)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.14.0
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl For Requires.private in pkg-config files
 284 ORC_PC=
 285 if test x"$HAVE_ORC" = "xyes"; then
 286     ORC_PC="orc-0.4"
 287 fi
 288 AC_SUBST(ORC_PC)
 289
 290 dnl checks for gstreamer
 291 dnl uninstalled is selected preferentially -- see pkg-config(1)
 292 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 293 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 294 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 295 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 296 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 297 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 298
 299 dnl Check for documentation xrefs
 300 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 301 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 302 AC_SUBST(GLIB_PREFIX)
 303 AC_SUBST(GST_PREFIX)
 304
 305 dnl check for gudev
 306 PKG_CHECK_MODULES(G_UDEV, gudev-1.0 , [
 307         AC_DEFINE([HAVE_GUDEV], 1, [Define if gudev is installed])
 308         HAVE_GUDEV="yes" ],
 309         [HAVE_GUDEV="no"])
 310
 311 AG_GST_GL_CHECKS
 312
 313 dnl GTK is optional and only used in examples
 314 HAVE_GTK=no
 315 HAVE_GTK_X11=no
 316 HAVE_GDK_PIXBUF=no
 317 GTK_REQ=3.10
 318 if test "x$BUILD_EXAMPLES" = "xyes"; then
 319   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 320   dnl some examples need gtk+-x11
 321   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 322   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 323   AC_SUBST(GTK_LIBS)
 324   AC_SUBST(GTK_CFLAGS)
 325
 326   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 327   AC_SUBST(GDK_PIXBUF_LIBS)
 328   AC_SUBST(GDK_PIXBUF_CFLAGS)
 329 fi
 330 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 331 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 332 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 333 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 334
 335 HAVE_QT=no
 336 HAVE_QT_MOC=no
 337 dnl QT is optional and only used in examples
 338 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 339   HAVE_QT=yes
 340 ], [
 341   HAVE_QT=no
 342 ])
 343 if test "x$HAVE_QT" = "xyes"; then
 344   AC_CHECK_TOOL(QT_MOC, moc)
 345   AC_MSG_CHECKING([for Qt5 moc])
 346   mocversion=`$QT_MOC -v 2>&1`
 347   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 348   if test x"$mocversiongrep" != x"$mocversion"; then
 349     AC_MSG_RESULT([no])
 350     # moc was not the qt5 one, try with moc-qt5
 351     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 352     AC_MSG_CHECKING([for Qt5 moc-qt5])
 353     mocversion=`$QT_MOC -v 2>&1`
 354     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 355     if test x"$mocversiongrep" != x"$mocversion"; then
 356       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 357       AC_MSG_CHECKING([for qtchooser])
 358       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 359       mocversion=`$qt5tooldir/moc -v 2>&1`
 360       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 361       if test x"$mocversiongrep" != x"$mocversion"; then
 362         # no valid moc found
 363         QT_MOC="no"
 364       else
 365         QT_MOC=$qt5tooldir/moc
 366       fi
 367     else
 368       QT_MOC=$QT_MOC
 369     fi
 370   fi
 371   AC_SUBST(QT_MOC)
 372   AC_MSG_RESULT([$QT_MOC])
 373 fi
 374 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 375 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 376
 377 dnl Check for OpenGL example dependencies (clutter, sdl, etc.)
 378 AG_GST_GL_EXAMPLES_CHECKS
 379
 380 dnl chck for linux headers needed by the joystick seek example
 381 AC_COMPILE_IFELSE(
 382 [
 383   AC_LANG_PROGRAM([
 384     #include <linux/input.h>
 385     #include <linux/joystick.h>
 386   ],[
 387     struct js_event js;
 388     js.type = JS_EVENT_AXIS;
 389   ])
 390 ], [
 391   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 392 ], [
 393   HAVE_LINUX_JOYSTICK_HEADERS="no"
 394 ])
 395 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 396
 397 dnl Check for -Bsymbolic-functions linker flag used to avoid
 398 dnl intra-library PLT jumps, if available.
 399 AC_ARG_ENABLE(Bsymbolic,
 400               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 401               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 402                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 403                LDFLAGS=-Wl,-Bsymbolic-functions
 404                LIBS=
 405                AC_TRY_LINK([], [return 0],
 406                            AC_MSG_RESULT(yes)
 407                            enable_Bsymbolic=yes,
 408                            AC_MSG_RESULT(no)
 409                            enable_Bsymbolic=no)
 410                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 411
 412
 413 dnl *** set variables based on configure arguments ***
 414
 415 dnl set license and copyright notice
 416 GST_LICENSE="LGPL"
 417 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 418 AC_SUBST(GST_LICENSE)
 419
 420 dnl set location of plugin directory
 421 AG_GST_SET_PLUGINDIR
 422
 423 dnl set release date/time
 424 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 425   ["${srcdir}/gst-plugins-base.doap"],
 426   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 427
 428 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 429 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 430 if test x$enable_static = xyes -a x$enable_shared = xno; then
 431   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 432 fi
 433
 434 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 435 dnl make sure it doesn't complain about unused variables if debugging is disabled
 436 NO_WARNINGS=""
 437 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 438
 439 dnl define an ERROR_CFLAGS Makefile variable
 440 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 441 dnl -Waggregate-return - xcb_intern_atom() returns an aggregate value
 442 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 443     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 444     -Wwrite-strings  -Wformat-nonliteral -Wformat-security
 445     -Winit-self -Wmissing-include-dirs -Waddress
 446     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 447
 448 dnl define an ERROR_CXXFLAGS Makefile variable
 449 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 450     -Wmissing-declarations -Wredundant-decls -Wundef
 451     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 452     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 453     -Wno-multichar $NO_WARNINGS])
 454
 455 dnl define correct level for debugging messages
 456 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 457
 458 dnl used in examples
 459 AG_GST_DEFAULT_ELEMENTS
 460
 461 dnl needed for encoding-target
 462 GST_DATADIR="$GST_PREFIX/share"
 463 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 464 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 465
 466 dnl behaviour of speex based audio resampler
 467 AC_MSG_CHECKING(which audio resample format to use for integer)
 468 AC_ARG_WITH([audioresample_format],
 469         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 470         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 471 AC_MSG_RESULT($ac_cv_audioresample_format)
 472 case $ac_cv_audioresample_format in
 473   int)
 474     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 475     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 476   ;;
 477   float)
 478     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 479     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 480   ;;
 481   auto)
 482     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 483     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 484 esac
 485
 486 dnl Check for mmap (needed by allocators library)
 487 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 488
 489 dnl *** plug-ins to include ***
 490
 491 dnl these are all the gst plug-ins, compilable without additional libs
 492 AG_GST_CHECK_PLUGIN(adder)
 493 AG_GST_CHECK_PLUGIN(app)
 494 AG_GST_CHECK_PLUGIN(audioconvert)
 495 AG_GST_CHECK_PLUGIN(audiomixer)
 496 AG_GST_CHECK_PLUGIN(audiorate)
 497 AG_GST_CHECK_PLUGIN(audiotestsrc)
 498 AG_GST_CHECK_PLUGIN(encoding)
 499 AG_GST_CHECK_PLUGIN(videoconvert)
 500 AG_GST_CHECK_PLUGIN(gio)
 501 AG_GST_CHECK_PLUGIN(playback)
 502 AG_GST_CHECK_PLUGIN(audioresample)
 503 AG_GST_CHECK_PLUGIN(rawparse)
 504 AG_GST_CHECK_PLUGIN(subparse)
 505 AG_GST_CHECK_PLUGIN(tcp)
 506 AG_GST_CHECK_PLUGIN(typefind)
 507 AG_GST_CHECK_PLUGIN(videotestsrc)
 508 AG_GST_CHECK_PLUGIN(videorate)
 509 AG_GST_CHECK_PLUGIN(videoscale)
 510 AG_GST_CHECK_PLUGIN(volume)
 511
 512 dnl iso-codes is optional, used by libgsttag
 513 AC_ARG_ENABLE(iso-codes,
 514 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 515 [case "${enableval}" in
 516   yes) enable_iso_codes=yes ;;
 517   no)  enable_iso_codes=no ;;
 518   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 519 esac
 520 ],
 521 [enable_iso_codes=yes]) dnl Default value
 522
 523 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 524 if test "x$enable_iso_codes" = "xyes"; then
 525   AC_MSG_RESULT([yes])
 526   have_iso_codes=no
 527   AC_MSG_CHECKING([whether iso-codes are available on this system])
 528   if $PKG_CONFIG iso-codes; then
 529     AC_MSG_RESULT([yes])
 530     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 531     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 532       AC_MSG_RESULT([yes])
 533       AC_MSG_CHECKING([for iso-codes prefix])
 534       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 535       if test -d "$ISO_CODES_PREFIX"; then
 536         AC_MSG_RESULT([yes])
 537         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 538         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 539         ISO_639_DOMAIN="iso_639"
 540         AC_MSG_CHECKING([ISO_639_DOMAIN])
 541         AC_MSG_RESULT([$ISO_639_DOMAIN])
 542         have_iso_codes=yes
 543         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 544         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 545         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 546         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 547       else
 548         AC_MSG_RESULT([no])
 549       fi
 550     else
 551       AC_MSG_RESULT([no])
 552     fi
 553   else
 554     AC_MSG_RESULT([no])
 555   fi
 556   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 557 else
 558   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 559   AM_CONDITIONAL(USE_ISO_CODES, false)
 560 fi
 561
 562 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 564 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 565   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 566       HAVE_ZLIB="yes"
 567     ], [
 568       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 569         HAVE_ZLIB="yes"
 570         ZLIB_LIBS="-lz"
 571         AC_SUBST(ZLIB_LIBS)
 572       ])
 573     ])
 574 ])
 575
 576 dnl *** sys plug-ins ***
 577
 578 echo
 579 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 580 echo
 581
 582 dnl *** X11 ***
 583 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 584 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 585                   [ximagesink], [
 586   AG_GST_PKG_CHECK_MODULES(X, x11)
 587 ])
 588
 589 dnl Check for Xv extension
 590 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 591 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 592                   [xvimagesink], [
 593   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 594 ])
 595
 596 dnl check for X Shm
 597 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 598 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 599   if test x$HAVE_X = xyes; then
 600     PKG_CHECK_MODULES(XSHM, xext, [
 601       AC_CHECK_LIB(Xext, XShmAttach, [
 602         HAVE_XSHM="yes"
 603       ], [
 604         HAVE_XSHM="no"
 605         XSHM_LIBS=""
 606       ], [ $X_LIBS ])
 607     ], [
 608       HAVE_XSHM="no"
 609     ])
 610   fi
 611 ], , [
 612   AC_SUBST(HAVE_XSHM)
 613   AC_SUBST(XSHM_LIBS)
 614 ])
 615
 616 dnl *** ext plug-ins ***
 617 dnl keep this list sorted alphabetically !
 618
 619 if test "x$BUILD_EXTERNAL" = "xyes"; then
 620
 621 echo
 622 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 623 echo
 624
 625 dnl *** alsa ***
 626 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 627 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 628   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 629     HAVE_ALSA="yes"
 630     AC_SUBST(ALSA_CFLAGS)
 631     AC_SUBST(ALSA_LIBS)
 632   ], [
 633     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 634   ])
 635 ])
 636
 637 dnl *** CDParanoia ***
 638 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 639 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 640 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 641   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 642     HAVE_CDPARANOIA="yes"
 643   ], [
 644     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 645                         cdda_open, -lm,
 646                         cdda_interface.h,
 647                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 648                         HEADER_DIR="no"
 649                         FOUND_CDPARANOIA="yes")
 650     if test "x$FOUND_CDPARANOIA" != "xyes";
 651     then
 652       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 653                           cdda_open, -lm,
 654                           cdda/cdda_interface.h,
 655                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 656                           HEADER_DIR="yes"
 657                           FOUND_CDPARANOIA="yes")
 658     fi
 659     if test "x$HEADER_DIR" = "xyes";
 660     then
 661       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 662                          defined if cdda headers are in a cdda/ directory)
 663     fi
 664     if test "x$FOUND_CDPARANOIA" = "xyes";
 665     then
 666       AC_CHECK_LIB(cdda_paranoia,
 667                    paranoia_cachemodel_size,
 668                    : ,
 669                    HAVE_CDPARANOIA=no,
 670                  [-lcdda_interface])
 671     fi
 672
 673     AC_SUBST(CDPARANOIA_LIBS)
 674   ])
 675 ])
 676 dnl FIXME : add second check somehow if that is necessary
 677 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 678 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 679
 680 dnl *** gl ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_GL, true)
 682 AG_GST_CHECK_FEATURE(GL, [gl elements], gl, [
 683   HAVE_GL="no"
 684
 685   if test x"$USE_OPENGL" = x"yes" -o x"$USE_GLES2" = x"yes"; then
 686     HAVE_GL="yes"
 687     AG_GST_GL_PLUGIN_CHECKS
 688   fi
 689 ])
 690
 691 dnl *** ivorbis ***
 692 dnl AM_PATH_IVORBIS only takes two options
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 694 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 695   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 696   if test $HAVE_IVORBIS = no
 697   then
 698     IVORBIS_LIBS=
 699     IVORBIS_CFLAGS=
 700     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 701       [IVORBIS_LIBS=-lvorbisidec
 702       HAVE_IVORBIS=yes
 703       case $host in
 704       arm-*-*)
 705         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 706       esac
 707       ],
 708       HAVE_IVORBIS=no)
 709     AC_SUBST(IVORBIS_LIBS)
 710     AC_SUBST(IVORBIS_CFLAGS)
 711   else
 712     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 713       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 714       USE_TREMOLO=no)
 715   fi
 716 ])
 717
 718 dnl *** libvisual ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 720 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 721   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 722   if test x$HAVE_LIBVISUAL = xyes; then
 723     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 724   fi
 725   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 726   if test x$LIBVIS_PLUGINSDIR != x; then
 727     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 728         "$LIBVIS_PLUGINSDIR",
 729         [directory in which the detected libvisual's plugins are located])
 730   fi
 731 ])
 732
 733 dnl *** ogg ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 735 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 736   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 737 ])
 738
 739 dnl *** Opus ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 741 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 742   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 743           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 744           HAVE_OPUS="yes"
 745   ], [
 746           HAVE_OPUS="no"
 747   ])
 748   AC_SUBST(OPUS_CFLAGS)
 749   AC_SUBST(OPUS_LIBS)
 750 ])
 751
 752 dnl *** pango ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 754 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 755   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 756 ])
 757
 758 dnl *** theora ***
 759 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 760 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 761   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 762 ])
 763
 764 dnl *** vorbis ***
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 766 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 767   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 768 ])
 769
 770 if test "x$HAVE_VORBIS" = "xyes"; then
 771   ac_cflags_save="$CFLAGS"
 772   AC_COMPILE_IFELSE([
 773     AC_LANG_PROGRAM([[
 774 #include <vorbis/codec.h>
 775                      ]],[[
 776 vorbis_dsp_state *v;
 777
 778 vorbis_synthesis_restart (v);
 779                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 780   if test "x$HAVE_VSR" = "xyes"; then
 781     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 782                        [defined if vorbis_synthesis_restart is present])
 783   fi
 784   CFLAGS="$ac_cflags_save"
 785 fi
 786
 787 else
 788
 789 dnl not building plugins with external dependencies,
 790 dnl but we still need to set the conditionals
 791 AM_CONDITIONAL(USE_ALSA, false)
 792 AM_CONDITIONAL(USE_CDPARANOIA, false)
 793 AM_CONDITIONAL(USE_GL, false)
 794 AM_CONDITIONAL(USE_IVORBIS, false)
 795 AM_CONDITIONAL(USE_LIBVISUAL, false)
 796 AM_CONDITIONAL(USE_OGG, false)
 797 AM_CONDITIONAL(USE_OPUS, false)
 798 AM_CONDITIONAL(USE_PANGO, false)
 799 AM_CONDITIONAL(USE_THEORA, false)
 800 AM_CONDITIONAL(USE_VORBIS, false)
 801
 802 fi dnl of EXT plugins
 803
 804 AM_CONDITIONAL(HAVE_GRAPHENE, test "x$HAVE_GRAPHENE" = "xyes")
 805 AM_CONDITIONAL(HAVE_PNG, test "x$HAVE_PNG" = "xyes")
 806 AM_CONDITIONAL(HAVE_JPEG, test "x$HAVE_JPEG" = "xyes")
 807
 808 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 809 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 810     HAVE_GIO_UNIX_2_0="yes",
 811     HAVE_GIO_UNIX_2_0="no")
 812 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 813
 814 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 815
 816 dnl Overview:
 817 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 818 dnl GST_*:              flags shared by built objects to link against GStreamer
 819 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 820 dnl                          (compare to other modules) or for i18n
 821 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 822 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 823 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 824 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 825
 826 dnl GST_OPTION_CFLAGS
 827 if test "x$USE_DEBUG" = xyes; then
 828    PROFILE_CFLAGS="-g"
 829 fi
 830 AC_SUBST(PROFILE_CFLAGS)
 831
 832 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 833   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 834   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 835 else
 836   DEPRECATED_CFLAGS=""
 837 fi
 838 AC_SUBST(DEPRECATED_CFLAGS)
 839
 840 VISIBILITY_CFLAGS=""
 841 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 842 AC_SUBST(VISIBILITY_CFLAGS)
 843
 844 VISIBILITY_CXXFLAGS=""
 845 if test "x$HAVE_CXX" = "xyes"; then
 846   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 847 fi
 848 AC_SUBST(VISIBILITY_CXXFLAGS)
 849
 850 dnl disable strict aliasing
 851 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 852 AC_SUBST(EXTRA_CFLAGS)
 853
 854 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 855 dnl at make time with e.g. make ERROR_CFLAGS=""
 856 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 857 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 858 AC_SUBST(GST_OPTION_CFLAGS)
 859 AC_SUBST(GST_OPTION_CXXFLAGS)
 860
 861 dnl our libraries need to be versioned correctly
 862 AC_SUBST(GST_LT_LDFLAGS)
 863
 864 dnl GST_PLUGINS_BASE_CFLAGS
 865 dnl prefer internal headers to already installed ones
 866 dnl also add builddir include for enumtypes and marshal
 867 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 868 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 869
 870 dnl FIXME: do we want to rename to GST_ALL_* ?
 871 dnl add GST_OPTION_CFLAGS, but overridable
 872 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 873 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 874 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 875 AC_SUBST(GST_CFLAGS)
 876 AC_SUBST(GST_CXXFLAGS)
 877 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 878 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 879 AC_SUBST(GST_LIBS)
 880
 881 dnl LDFLAGS really should only contain flags, not libs - they get added before
 882 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 883 GST_ALL_LDFLAGS="-no-undefined"
 884 if test "x${enable_Bsymbolic}" = "xyes"; then
 885   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 886 fi
 887 AC_SUBST(GST_ALL_LDFLAGS)
 888
 889 dnl GST_LIB_LDFLAGS
 890 dnl linker flags shared by all libraries
 891 dnl LDFLAGS modifier defining exported symbols from built libraries
 892 dnl (export _gst_foo but not __gst_foo)
 893 GST_LIB_LDFLAGS=""
 894 AC_SUBST(GST_LIB_LDFLAGS)
 895
 896 dnl this really should only contain flags, not libs - they get added before
 897 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 898 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 899 AC_SUBST(GST_PLUGIN_LDFLAGS)
 900
 901 dnl *** output files ***
 902
 903 $MKDIR_P tests/check/orc
 904
 905 AC_CONFIG_FILES(
 906 Makefile
 907 gst/Makefile
 908 gst/adder/Makefile
 909 gst/app/Makefile
 910 gst/audioconvert/Makefile
 911 gst/audiomixer/Makefile
 912 gst/audiorate/Makefile
 913 gst/audioresample/Makefile
 914 gst/audiotestsrc/Makefile
 915 gst/encoding/Makefile
 916 gst/videoconvert/Makefile
 917 gst/gio/Makefile
 918 gst/pbtypes/Makefile
 919 gst/playback/Makefile
 920 gst/rawparse/Makefile
 921 gst/subparse/Makefile
 922 gst/tcp/Makefile
 923 gst/typefind/Makefile
 924 gst/videotestsrc/Makefile
 925 gst/videorate/Makefile
 926 gst/videoscale/Makefile
 927 gst/volume/Makefile
 928 sys/Makefile
 929 sys/ximage/Makefile
 930 sys/xvimage/Makefile
 931 ext/Makefile
 932 ext/alsa/Makefile
 933 ext/cdparanoia/Makefile
 934 ext/gl/Makefile
 935 ext/libvisual/Makefile
 936 ext/ogg/Makefile
 937 ext/opus/Makefile
 938 ext/pango/Makefile
 939 ext/theora/Makefile
 940 ext/vorbis/Makefile
 941 gst-libs/Makefile
 942 gst-libs/gst/Makefile
 943 gst-libs/gst/allocators/Makefile
 944 gst-libs/gst/audio/Makefile
 945 gst-libs/gst/app/Makefile
 946 gst-libs/gst/fft/Makefile
 947 gst-libs/gst/gl/Makefile
 948 gst-libs/gst/gl/android/Makefile
 949 gst-libs/gst/gl/cocoa/Makefile
 950 gst-libs/gst/gl/dispmanx/Makefile
 951 gst-libs/gst/gl/glprototypes/Makefile
 952 gst-libs/gst/gl/eagl/Makefile
 953 gst-libs/gst/gl/egl/Makefile
 954 gst-libs/gst/gl/wayland/Makefile
 955 gst-libs/gst/gl/win32/Makefile
 956 gst-libs/gst/gl/x11/Makefile
 957 gst-libs/gst/gl/viv-fb/Makefile
 958 gst-libs/gst/gl/gbm/Makefile
 959 gst-libs/gst/riff/Makefile
 960 gst-libs/gst/rtp/Makefile
 961 gst-libs/gst/rtsp/Makefile
 962 gst-libs/gst/sdp/Makefile
 963 gst-libs/gst/tag/Makefile
 964 gst-libs/gst/pbutils/Makefile
 965 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 966 gst-libs/gst/video/Makefile
 967 tools/Makefile
 968 pkgconfig/Makefile
 969 pkgconfig/gstreamer-allocators.pc
 970 pkgconfig/gstreamer-allocators-uninstalled.pc
 971 pkgconfig/gstreamer-audio.pc
 972 pkgconfig/gstreamer-audio-uninstalled.pc
 973 pkgconfig/gstreamer-app.pc
 974 pkgconfig/gstreamer-app-uninstalled.pc
 975 pkgconfig/gstreamer-fft.pc
 976 pkgconfig/gstreamer-fft-uninstalled.pc
 977 pkgconfig/gstreamer-pbutils.pc
 978 pkgconfig/gstreamer-pbutils-uninstalled.pc
 979 pkgconfig/gstreamer-riff.pc
 980 pkgconfig/gstreamer-riff-uninstalled.pc
 981 pkgconfig/gstreamer-rtp.pc
 982 pkgconfig/gstreamer-rtp-uninstalled.pc
 983 pkgconfig/gstreamer-rtsp.pc
 984 pkgconfig/gstreamer-rtsp-uninstalled.pc
 985 pkgconfig/gstreamer-sdp.pc
 986 pkgconfig/gstreamer-sdp-uninstalled.pc
 987 pkgconfig/gstreamer-tag.pc
 988 pkgconfig/gstreamer-tag-uninstalled.pc
 989 pkgconfig/gstreamer-video.pc
 990 pkgconfig/gstreamer-video-uninstalled.pc
 991 pkgconfig/gstreamer-gl.pc
 992 pkgconfig/gstreamer-gl-uninstalled.pc
 993 pkgconfig/gstreamer-plugins-base.pc
 994 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 995 tests/Makefile
 996 tests/check/Makefile
 997 tests/examples/Makefile
 998 tests/examples/app/Makefile
 999 tests/examples/audio/Makefile
1000 tests/examples/decodebin_next/Makefile
1001 tests/examples/dynamic/Makefile
1002 tests/examples/encoding/Makefile
1003 tests/examples/fft/Makefile
1004 tests/examples/gio/Makefile
1005 tests/examples/gl/Makefile
1006 tests/examples/gl/generic/Makefile
1007 tests/examples/gl/generic/cube/Makefile
1008 tests/examples/gl/generic/doublecube/Makefile
1009 tests/examples/gl/generic/recordgraphic/Makefile
1010 tests/examples/gl/generic/cubeyuv/Makefile
1011 tests/examples/gl/qt/Makefile
1012 tests/examples/gl/gtk/Makefile
1013 tests/examples/gl/gtk/fxtest/Makefile
1014 tests/examples/gl/gtk/3dvideo/Makefile
1015 tests/examples/gl/gtk/switchvideooverlay/Makefile
1016 tests/examples/gl/gtk/filternovideooverlay/Makefile
1017 tests/examples/gl/gtk/filtervideooverlay/Makefile
1018 tests/examples/gl/cocoa/Makefile
1019 tests/examples/gl/sdl/Makefile
1020 tests/examples/gl/clutter/Makefile
1021 tests/examples/overlay/Makefile
1022 tests/examples/seek/Makefile
1023 tests/examples/snapshot/Makefile
1024 tests/examples/playback/Makefile
1025 tests/examples/playrec/Makefile
1026 tests/files/Makefile
1027 tests/icles/Makefile
1028 tests/icles/playback/Makefile
1029 docs/Makefile
1030 docs/libs/Makefile
1031 docs/plugins/Makefile
1032 docs/version.entities
1033 po/Makefile.in
1034 common/Makefile
1035 common/m4/Makefile
1036 m4/Makefile
1037 )
1038 AC_OUTPUT
1039
1040 AG_GST_OUTPUT_PLUGINS
1041 ORC_OUTPUT
1042