configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT([GStreamer],[1.7.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gstreamer])
   8 AG_GST_INIT
   9
  10 dnl initialize automake (we require GNU make)
  11 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  12
  13 dnl define PACKAGE_VERSION_* variables
  14 AS_VERSION
  15
  16 dnl check if this is a release version
  17 AS_NANO(GST_GIT="no", GST_GIT="yes")
  18
  19 dnl can autoconf find the source ?
  20 AC_CONFIG_SRCDIR([gst/gst.c])
  21
  22 dnl define the output header for config
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  26 AM_MAINTAINER_MODE([enable])
  27
  28 dnl sets host_* variables
  29 AC_CANONICAL_HOST
  30
  31 dnl use pretty build output by default
  32 AM_SILENT_RULES([yes])
  33
  34 dnl GStreamer versioning, this is mostly informational
  35 GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  36 GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  37 GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  38 GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  39 AC_SUBST(GST_VERSION_MAJOR)
  40 AC_SUBST(GST_VERSION_MINOR)
  41 AC_SUBST(GST_VERSION_MICRO)
  42 AC_SUBST(GST_VERSION_NANO)
  43
  44 dnl our libraries and install dirs use GST_API_VERSION in the filename
  45 dnl to allow side-by-side installation of different API versions
  46 GST_API_VERSION=1.0
  47 AC_SUBST(GST_API_VERSION)
  48 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  49   [GStreamer API Version])
  50
  51 dnl CURRENT, REVISION, AGE
  52 dnl - library source changed -> increment REVISION
  53 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  54 dnl - interfaces added -> increment AGE
  55 dnl - interfaces removed -> AGE = 0
  56 dnl
  57 dnl Keep CURRENT as MINOR * 100 + MICRO
  58 dnl Ex : 1.0.0 => 0
  59 dnl      1.0.3 => 3
  60 dnl      1.1.0 => 100
  61 dnl      1.2.5 => 205
  62 dnl      1.10.9 (who knows) => 1009
  63 dnl
  64 dnl sets GST_LT_LDFLAGS
  65 AS_LIBTOOL(GST, 700, 0, 700)
  66
  67 dnl *** autotools stuff ****
  68
  69 dnl allow for different autotools
  70 AS_AUTOTOOLS_ALTERNATE
  71
  72 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  73 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  74
  75 dnl set up gettext
  76 dnl the version check needs to stay here because autopoint greps for it
  77 AM_GNU_GETTEXT_VERSION([0.17])
  78 AM_GNU_GETTEXT([external])
  79 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  80
  81 dnl *** check for arguments to configure ***
  82
  83 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  84
  85 dnl subsystems - can influence other decisions so needs to be high up
  86 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  87 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  88 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  89 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  90 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  91 if test "x$GST_DISABLE_PARSE" = xyes; then
  92   AC_DEFINE(GST_DISABLE_PARSE, 1,
  93     [Define if pipeline parsing code is disabled])
  94 fi
  95 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  96 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  97 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  98   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  99     [Define if option parsing is disabled])
 100 fi
 101 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 102 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 103 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 104 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 105 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 106 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 107 dnl define a substitution to use in docs/gst/gstreamer.types
 108 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 109 then
 110   GST_REGISTRY_DOC_TYPES="%"
 111 else
 112   GST_REGISTRY_DOC_TYPES=
 113 fi
 114 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 115 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 116 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 117
 118 AG_GST_ARG_DEBUG
 119 AG_GST_ARG_PROFILING
 120 AG_GST_ARG_VALGRIND
 121 AG_GST_ARG_GCOV
 122
 123 AG_GST_ARG_EXAMPLES
 124
 125 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 126 AG_GST_ARG_WITH_PACKAGE_NAME
 127 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 128
 129 AG_GST_PKG_CONFIG_PATH
 130
 131 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 132   ["${srcdir}/gstreamer.doap"],
 133   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 134
 135 dnl check for bash completion
 136 AC_ARG_WITH([bash-completion-dir],
 137     AS_HELP_STRING([--with-bash-completion-dir[=PATH]],
 138         [Install the bash auto-completion script in this directory. @<:@default=yes@:>@]),
 139     [],
 140     [with_bash_completion_dir=yes])
 141
 142 if test "x$with_bash_completion_dir" = "xyes"
 143 then
 144     extra_args=
 145
 146     if test "x$prefix" != "xNONE"
 147     then
 148         extra_args="--define-variable=prefix=\"$prefix\""
 149     fi
 150
 151     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 152         [BASH_COMPLETION_DIR="`eval pkg-config $extra_args --variable=completionsdir bash-completion`"],
 153         [BASH_COMPLETION_DIR="$datadir/bash-completion/completions"])
 154     PKG_CHECK_MODULES([BASH_COMPLETION], [bash-completion >= 2.0],
 155         [BASH_HELPERS_DIR="`eval pkg-config $extra_args --variable=helpersdir bash-completion`"],
 156         [BASH_HELPERS_DIR="$datadir/bash-completion/helpers"])
 157 else
 158     BASH_COMPLETION_DIR="$with_bash_completion_dir/completions"
 159     BASH_HELPERS_DIR="$with_bash_completion_dir/helpers"
 160 fi
 161
 162 AC_SUBST([BASH_COMPLETION_DIR])
 163 AC_SUBST([BASH_HELPERS_DIR])
 164 AM_CONDITIONAL([ENABLE_BASH_COMPLETION],[test "x$with_bash_completion_dir" != "xno"])
 165
 166 dnl build static plugins or not
 167 AC_MSG_CHECKING([whether to build static plugins or not])
 168 AC_ARG_ENABLE(
 169   static-plugins,
 170   AC_HELP_STRING(
 171     [--enable-static-plugins],
 172     [build static plugins @<:@default=no@:>@]),
 173   [AS_CASE(
 174     [$enableval], [no], [], [yes], [],
 175     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 176   [enable_static_plugins=no])
 177 AC_MSG_RESULT([$enable_static_plugins])
 178 if test "x$enable_static_plugins" = xyes; then
 179   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 180     [Define if static plugins should be built])
 181   GST_PLUGIN_LIBTOOLFLAGS=""
 182 else
 183   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 184 fi
 185 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 186 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 187
 188 dnl building of tests
 189 AC_ARG_ENABLE(tests,
 190   AS_HELP_STRING([--disable-tests],[disable building test apps]),
 191   [
 192     case "${enableval}" in
 193       yes) BUILD_TESTS=yes ;;
 194       no)  BUILD_TESTS=no ;;
 195       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 196     esac
 197   ],
 198 [BUILD_TESTS=yes]) dnl Default value
 199 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 200
 201 dnl tests known to fail
 202 AC_ARG_ENABLE(failing-tests,
 203   AS_HELP_STRING([--disable-failing-tests],[disable building tests known to fail]),
 204   [
 205     case "${enableval}" in
 206       yes) BUILD_FAILING_TESTS=yes ;;
 207       no)  BUILD_FAILING_TESTS=no ;;
 208       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 209     esac
 210   ],
 211   [BUILD_FAILING_TESTS=no]) dnl Default value
 212 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 213 if test x$BUILD_FAILING_TESTS = xyes; then
 214   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 215 else
 216   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 217 fi
 218
 219 dnl building of benchmarks
 220 AC_ARG_ENABLE(benchmarks,
 221   AS_HELP_STRING([--disable-benchmarks],[disable building benchmarks apps]),
 222   [
 223     case "${enableval}" in
 224       yes) BUILD_BENCHMARKS=yes ;;
 225       no)  BUILD_BENCHMARKS=no ;;
 226       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 227     esac
 228   ],
 229 [BUILD_BENCHMARKS=yes]) dnl Default value
 230 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 231
 232 dnl building of tools
 233 AC_ARG_ENABLE(tools,
 234   AS_HELP_STRING([--disable-tools],[disable building tools]),
 235   [
 236     case "${enableval}" in
 237       yes) BUILD_TOOLS=yes ;;
 238       no)  BUILD_TOOLS=no ;;
 239       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 240     esac
 241   ],
 242 [BUILD_TOOLS=yes]) dnl Default value
 243 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 244
 245 dnl poison destroyed objects
 246 AC_ARG_ENABLE(poisoning,
 247   AS_HELP_STRING([--enable-poisoning],[enable poisoning of deallocated objects]),
 248   [
 249     case "${enableval}" in
 250       yes) USE_POISONING=yes ;;
 251       no)  USE_POISONING=no ;;
 252       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 253     esac
 254   ],
 255   [USE_POISONING=no]) dnl Default value
 256 if test "x$USE_POISONING" = xyes; then
 257   AC_DEFINE(USE_POISONING, 1,
 258     [Define if we should poison deallocated memory])
 259 fi
 260
 261 dnl PTP support parts
 262 AC_MSG_CHECKING([whether PTP support can be enabled])
 263 case "$host_os" in
 264   *android*)
 265     dnl Can't run on Android because of permissions
 266     HAVE_PTP=no
 267     ;;
 268   mingw*|pw32*|cygwin*)
 269     dnl Not ported to Windows yet
 270     HAVE_PTP=no
 271     ;;
 272   darwin*)
 273     dnl Can't run on iOS because of permissions
 274     AC_CHECK_HEADER(MobileCoreServices/MobileCoreServices.h, HAVE_PTP="no", HAVE_PTP="yes", [-])
 275     ;;
 276   linux*|darwin*|solaris*|netbsd*|freebsd*|openbsd*|kfreebsd*|dragonfly*|gnu*)
 277     HAVE_PTP=yes
 278     ;;
 279   *)
 280     HAVE_PTP=no
 281     ;;
 282 esac
 283 AC_MSG_RESULT([$HAVE_PTP])
 284
 285 dnl user/group to change to in gst-ptp-helper
 286 AC_ARG_WITH([ptp-helper-setuid-user],
 287   AS_HELP_STRING([--with-ptp-helper-setuid-user],[User to switch to when installing gst-ptp-helper setuid root]),
 288   [
 289     if test "x$withval" != "x"
 290     then
 291       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_USER, "$withval", [PTP helper setuid user])
 292     fi
 293   ], []
 294 )
 295
 296 dnl group/group to change to in gst-ptp-helper
 297 AC_ARG_WITH([ptp-helper-setuid-group],
 298   AS_HELP_STRING([--with-ptp-helper-setuid-group],[Group to switch to when installing gst-ptp-helper setuid root]),
 299   [
 300     if test "x$withval" != "x"
 301     then
 302       AC_DEFINE_UNQUOTED(HAVE_PTP_HELPER_SETUID_GROUP, "$withval", [PTP helper setuid group])
 303     fi
 304   ], []
 305 )
 306
 307 AC_ARG_WITH(
 308   ptp-helper-permissions,
 309   AC_HELP_STRING(
 310     [--with-ptp-helper-permissions],
 311     [how to gain PTP permissions (none, setuid-root, capabilities, auto)]),
 312     [],
 313     [with_ptp_helper_permissions=auto])
 314
 315 gst_ptp_have_cap=no
 316 AG_GST_CHECK_LIBHEADER(CAP, cap,
 317                        cap_init, ,
 318                        sys/capability.h,
 319                        CAP_LIBS="-lcap"
 320                        AC_SUBST(CAP_LIBS)
 321                        gst_ptp_have_cap=yes)
 322
 323 AC_PATH_PROG([SETCAP], [setcap], [no], [$PATH:/usr/bin:/bin:/usr/sbin:/sbin])
 324
 325 if test "x$HAVE_PTP" = "xyes"; then
 326 AC_DEFINE(HAVE_PTP, 1, [PTP support available])
 327
 328 AC_MSG_CHECKING([for SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR])
 329 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 330     [[
 331         #include <sys/ioctl.h>
 332         #include <net/if.h>
 333     ]],
 334     [[
 335         struct ifreq ifr;
 336         struct ifconf ifc;
 337         ioctl(0, SIOCGIFCONF, &ifc);
 338         ioctl(0, SIOCGIFFLAGS, &ifr);
 339         ioctl(0, SIOCGIFHWADDR, &ifr);
 340         int dummy = ifr.ifr_hwaddr.sa_data[0];
 341     ]])], [
 342         AC_MSG_RESULT(yes)
 343         AC_DEFINE(HAVE_SIOCGIFCONF_SIOCGIFFLAGS_SIOCGIFHWADDR, 1, [SIOCGIFCONF, SIOCGIFFLAGS and SIOCGIFHWADDR is available])
 344     ], [
 345         AC_MSG_RESULT(no)
 346 ])
 347
 348 AC_MSG_CHECKING([for getifaddrs() and AF_LINK])
 349 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 350     [[
 351         #include <ifaddrs.h>
 352         #include <net/if.h>
 353         #include <net/if_dl.h>
 354     ]],
 355     [[
 356         struct ifaddrs *ifaddr;
 357         getifaddrs(&ifaddr);
 358         int dummy = (ifaddr->ifa_flags & IFF_LOOPBACK) && ifaddr->ifa_addr->sa_family != AF_LINK;
 359     ]])], [
 360         AC_MSG_RESULT(yes)
 361         AC_DEFINE(HAVE_GETIFADDRS_AF_LINK, 1, [getifaddrs() and AF_LINK is available])
 362     ], [
 363         AC_MSG_RESULT(no)
 364     ])
 365
 366 AC_MSG_CHECKING([how to install gst-ptp-helper])
 367 if test "x$with_ptp_helper_permissions" = "xauto"; then
 368     if test "x$gst_ptp_have_cap" = "xyes" -a "x$SETCAP" != "xno"; then
 369         with_ptp_helper_permissions="capabilities"
 370     else
 371         with_ptp_helper_permissions="setuid-root"
 372     fi
 373 fi
 374 AC_MSG_RESULT([$with_ptp_helper_permissions])
 375
 376 case "$with_ptp_helper_permissions" in
 377   none)
 378     ;;
 379   setuid-root)
 380      AC_DEFINE(HAVE_PTP_HELPER_SETUID, 1,
 381         [Use setuid-root for permissions in PTP helper])
 382     ;;
 383   capabilities)
 384      AC_DEFINE(HAVE_PTP_HELPER_CAPABILITIES, 1,
 385         [Use capabilities for permissions in PTP helper])
 386     ;;
 387   *)
 388     AC_MSG_ERROR(Invalid parameter [$with_ptp_helper_permissions])
 389     ;;
 390 esac
 391
 392 fi
 393
 394 AM_CONDITIONAL(HAVE_PTP, test "x$HAVE_PTP" = "xyes")
 395 AM_CONDITIONAL(HAVE_PTP_HELPER_SETUID, test "x$with_ptp_helper_permissions" = "xsetuid-root")
 396 AM_CONDITIONAL(HAVE_PTP_HELPER_CAPABILITIES, test "x$with_ptp_helper_permissions" = "xcapabilities")
 397
 398 dnl *** checks for platform ***
 399
 400 dnl * hardware/architecture *
 401
 402 dnl common/m4/gst-arch.m4
 403 dnl check CPU type
 404 AG_GST_ARCH
 405 dnl substitution for win32/common/config.h
 406 HOST_CPU=$host_cpu
 407 AC_SUBST(HOST_CPU)
 408
 409 dnl common/m4/gst-arch.m4
 410 dnl check for unaligned access
 411 AG_GST_UNALIGNED_ACCESS
 412 dnl create a configure variable for gst/gstconfig.h
 413 if test x${as_cv_unaligned_access} = xyes ; then
 414   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 415 else
 416   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 417 fi
 418 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 419
 420 dnl check for platform specific settings
 421 AG_GST_PLATFORM
 422
 423 dnl * software *
 424
 425 dnl check for large file support
 426 dnl affected plugins must include config.h
 427 AC_SYS_LARGEFILE
 428
 429 dnl *** checks for programs ***
 430
 431 dnl find a compiler
 432 AC_PROG_CC
 433 AC_PROG_CC_STDC
 434
 435 dnl check if the compiler supports '-c' and '-o' options
 436 AM_PROG_CC_C_O
 437
 438 dnl find an assembler
 439 AM_PROG_AS
 440
 441 dnl determine if c++ is available on this system
 442 AC_PROG_CXX
 443 dnl CXX may be set to some default even if no c++ compiler is available
 444 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 445 AC_LANG_PUSH([C++])
 446 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 447 AC_LANG_POP([C++])
 448 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 449 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 450
 451 dnl Perl is used in building documentation and in the version checks
 452 AC_PATH_PROG(PERL_PATH, perl, no)
 453 if test x$PERL_PATH = xno; then
 454   AC_MSG_ERROR(Could not find perl)
 455 fi
 456
 457 dnl we require flex and bison for building the parser
 458 if test "x$GST_DISABLE_PARSE" != xyes; then
 459   AG_GST_BISON_CHECK
 460   AG_GST_FLEX_CHECK
 461 fi
 462
 463 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 464 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 465
 466 dnl check for gobject-introspection
 467 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 468
 469 dnl check for documentation tools
 470 AG_GST_DOCBOOK_CHECK
 471 GTK_DOC_CHECK([1.12])
 472 AG_GST_PLUGIN_DOCS([1.12])
 473
 474 dnl *** checks for libraries ***
 475
 476 dnl check for libm, for sin()
 477 LT_LIB_M
 478 AC_SUBST(LIBM)
 479
 480 dnl *** checks for header files ***
 481
 482 dnl check if we have ANSI C header files
 483 AC_HEADER_STDC
 484
 485 dnl Check for ucontext.h
 486 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 487
 488 dnl Check for sys/socket.h
 489 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 490 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 491
 492 dnl check for sys/times.h for tests/examples/adapter/
 493 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 494 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 495 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 496
 497 dnl Check for process.h for getpid() on win32
 498 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 499
 500 dnl Check for sys/utsname.h for uname
 501 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 502
 503 dnl Check for stdio_ext.f for __fbufsize
 504 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 505
 506 dnl check for pthreads
 507 dnl without arguments AX_PTHREAD() will do AC_DEFINE(HAVE_PTHREAD)
 508 dnl which later checks use in their test code
 509 AX_PTHREAD()
 510 AM_CONDITIONAL(HAVE_PTHREAD, test "x$ax_pthread_ok" = "xyes")
 511
 512 dnl check for sys/prctl for setting thread name on Linux
 513 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 514
 515 dnl check for pthread_setname_np(const char*)
 516 dnl which is present on OS X 10.6, iOS 3.2 and above
 517 AC_MSG_CHECKING(for pthread_setname_np(const char*))
 518 AC_LINK_IFELSE(
 519     [AC_LANG_PROGRAM(
 520         [#include <pthread.h>],
 521         [pthread_setname_np("example")])],
 522     [AC_MSG_RESULT(yes)
 523      AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
 524         [Have function pthread_setname_np(const char*)])],
 525     [AC_MSG_RESULT(no)])
 526
 527 dnl check for sys/uio.h for writev()
 528 AC_CHECK_HEADERS([sys/uio.h], [], [], [AC_INCLUDES_DEFAULT])
 529
 530 dnl Check for valgrind.h
 531 dnl separate from HAVE_VALGRIND because you can have the program, but not
 532 dnl the dev package
 533 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 534
 535 dnl used in gst/gstpoll.c
 536 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 537 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 538 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 539   WIN32_LIBS="-lws2_32"
 540   AC_SUBST(WIN32_LIBS)
 541 fi
 542
 543 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 544 if test "x$BUILD_TESTS" = "xyes"; then
 545   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 546                          __gmpz_init_set_d, ,
 547                          gmp.h,
 548                          GMP_LIBS="-lgmp"
 549                          AC_SUBST(GMP_LIBS)
 550                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 551   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 552                          gsl_rng_uniform_int, -lgslcblas,
 553                          gsl/gsl_rng.h,
 554                          GSL_LIBS="-lgsl -lgslcblas"
 555                          AC_SUBST(GSL_LIBS)
 556                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 557 fi
 558
 559 dnl *** checks for types/defines ***
 560
 561 dnl *** checks for structures ***
 562
 563 dnl *** checks for compiler characteristics ***
 564
 565 dnl check if the compiler supports __uint128_t (gcc)
 566 dnl Actually check for 128-bit division, since that's what we use
 567 dnl uint128_t for.
 568 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 569     AC_LINK_IFELSE([AC_LANG_PROGRAM([[ ]], [[
 570       static __uint128_t v1 = 100;
 571       static __uint128_t v2 = 10;
 572       static __uint128_t u;
 573       u = v1 / v2;
 574     ]])],[
 575       gst_cv_uint128_t=yes
 576     ],[
 577       gst_cv_uint128_t=no
 578     ])
 579 )
 580 if test x$gst_cv_uint128_t = xyes; then
 581   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 582 fi
 583
 584 dnl *** checking for tm_gmtoff ***
 585 AC_MSG_CHECKING([for tm_gmtoff])
 586 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 587         #include <time.h>
 588         int main(void) {
 589           struct tm t;
 590           t.tm_gmtoff = 0;
 591           exit(0);
 592         }]])],
 593   [have_tm_gmtoff=yes
 594    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 595   [have_tm_gmtoff=no],
 596   [have_tm_gmtoff="no (cross compiling)"])
 597 AC_MSG_RESULT($have_tm_gmtoff)
 598
 599
 600 dnl *** checks for library functions ***
 601
 602 AC_CHECK_FUNCS([strcasestr])
 603
 604 AC_CHECK_FUNCS([gmtime_r])
 605 AC_CHECK_FUNCS([localtime_r])
 606 AC_CHECK_FUNCS([sigaction])
 607
 608 dnl check for fseeko()
 609 AC_FUNC_FSEEKO
 610 dnl check for ftello()
 611 AC_CHECK_FUNCS([ftello])
 612
 613 AC_CHECK_FUNCS([fgetpos])
 614 AC_CHECK_FUNCS([fsetpos])
 615
 616 dnl check for poll(), ppoll() and pselect()
 617 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 618 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 619 AC_CHECK_FUNCS([poll])
 620 AC_CHECK_FUNCS([ppoll])
 621 AC_CHECK_FUNCS([pselect])
 622
 623 dnl check for socketpair()
 624 AC_CHECK_FUNC(socketpair, [], [
 625   AC_CHECK_LIB(socket, socketpair, [
 626     SOCKET_LIBS="-lsocket"
 627     AC_SUBST(SOCKET_LIBS)
 628   ])
 629 ])
 630
 631 dnl ****************************************
 632 dnl *** GLib POLL* compatibility defines ***
 633 dnl ****************************************
 634
 635 AC_MSG_CHECKING([for broken poll])
 636 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 637         #include <stdlib.h>
 638         #include <fcntl.h>
 639         #ifdef HAVE_SYS_POLL_H
 640         #include <sys/poll.h>
 641         #endif
 642         #ifdef HAVE_POLL_H
 643         #include <poll.h>
 644         #endif
 645         int main(void) {
 646           struct pollfd fds[1];
 647           int fd;
 648           fd = open("/dev/null", 1);
 649           fds[0].fd = fd;
 650           fds[0].events = POLLIN;
 651           fds[0].revents = 0;
 652           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 653                 exit(1);  /* Does not work for devices -- fail */
 654           }
 655           exit(0);
 656         }]])],
 657   [broken_poll=no],
 658   [broken_poll=yes
 659    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 660   [broken_poll="no (cross compiling)"])
 661 AC_MSG_RESULT($broken_poll)
 662
 663 dnl check for mmap()
 664 AC_FUNC_MMAP
 665 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 666
 667 dnl check for posix_memalign(), getpagesize()
 668 AC_CHECK_FUNCS([posix_memalign])
 669 AC_CHECK_FUNCS([getpagesize])
 670
 671 dnl Check for POSIX timers
 672 AC_CHECK_FUNCS(clock_gettime, [], [
 673   AC_CHECK_LIB(rt, clock_gettime, [
 674     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 675     LIBS="$LIBS -lrt"
 676   ], [
 677     AC_CHECK_LIB(pthread, clock_gettime, [
 678       AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 679       LIBS="$LIBS -lpthread"
 680     ])
 681   ])
 682 ])
 683
 684 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 685     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 686 #include <time.h>
 687 #ifdef HAVE_UNISTD_H
 688 #include <unistd.h>
 689 #endif
 690     ]], [[
 691 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 692 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 693 #endif
 694     ]])],[
 695       gst_cv_posix_timers=yes
 696     ],[
 697       gst_cv_posix_timers=no
 698     ])
 699 )
 700
 701 if test "$gst_cv_posix_timers" = "yes"; then
 702   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 703   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 704 else
 705   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 706 fi
 707 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 708 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 709
 710 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 711     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 712 #include <time.h>
 713 #ifdef HAVE_UNISTD_H
 714 #include <unistd.h>
 715 #endif
 716     ]], [[
 717 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 718 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 719 #endif
 720     ]])],[
 721       gst_cv_monotonic_clock=yes
 722     ],[
 723       gst_cv_monotonic_clock=no
 724     ])
 725 )
 726
 727 if test "$gst_cv_monotonic_clock" = "yes"; then
 728   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 729   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 730 else
 731   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 732 fi
 733 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 734 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 735
 736 dnl Check for a way to display the function name in debug output
 737 AG_GST_CHECK_FUNCTION
 738
 739 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 740 save_cflags="$CFLAGS"
 741 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 742 AC_CHECK_LIB(dl, dladdr,
 743    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 744    LIBS="$LIBS -ldl")
 745 CFLAGS="$save_cflags"
 746
 747 dnl Check printf stuff
 748 if test "x${GST_DISABLE_GST_DEBUG}" != "xyes"; then
 749   AC_TYPE_LONG_LONG_INT
 750   AC_TYPE_UNSIGNED_LONG_LONG_INT
 751
 752   if test x$ac_cv_type_long_long_int$ac_cv_type_unsigned_long_long_int = xyesyes; then
 753     AC_DEFINE([HAVE_LONG_LONG], [1], [Define to 1 if the system has the type long long])
 754   fi
 755
 756   dnl /usr/share/aclocal/inttypes_h.m4 - ships with gettext apparently
 757   gl_AC_HEADER_INTTYPES_H
 758
 759   dnl /usr/share/aclocal/stdint_h.m4 - ships with gettext apparently
 760   gl_AC_HEADER_STDINT_H
 761
 762   AC_CHECK_TYPES(ptrdiff_t)
 763
 764   AC_TYPE_INTMAX_T
 765   AC_TYPE_SIZE_T
 766 fi
 767
 768 dnl *** checks for dependency libraries ***
 769
 770 dnl GLib
 771 GLIB_REQ=2.40.0
 772 AG_GST_GLIB_CHECK([$GLIB_REQ])
 773
 774 dnl Check for documentation xrefs
 775 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 776 AC_SUBST(GLIB_PREFIX)
 777
 778 dnl GTK is optional and only used in examples
 779 HAVE_GTK=no
 780 GTK_REQ=3.10
 781 if test "x$BUILD_EXAMPLES" = "xyes"; then
 782   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 783   AC_SUBST(GTK_LIBS)
 784   AC_SUBST(GTK_CFLAGS)
 785 fi
 786 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 787
 788 dnl building of unit test libraries
 789 AC_ARG_ENABLE(check,
 790   AS_HELP_STRING([--disable-check],[disable building unit test libraries]),
 791   [
 792     case "${enableval}" in
 793       yes) BUILD_CHECK=yes ;;
 794       no)  BUILD_CHECK=no ;;
 795       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 796     esac
 797   ], [
 798     dnl Default value
 799     case $host_os in
 800       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 801       *) BUILD_CHECK=yes ;;
 802     esac
 803 ])
 804 dnl bit of a misnomer, but keep the conditional named like this so we don't
 805 dnl have to change too much elsewhere
 806 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 807
 808 dnl configure the desired memory alignment
 809 AC_ARG_WITH([memory-alignment],
 810   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 811   [
 812     if test "x$withval" = "xyes"
 813     then
 814       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 815     else
 816       case "${withval}" in
 817         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 818         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 819         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 820       esac
 821     fi
 822   ], [
 823     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 824   ]
 825 )
 826
 827 dnl Check for -Bsymbolic-functions linker flag used to avoid
 828 dnl intra-library PLT jumps, if available.
 829 AC_ARG_ENABLE(Bsymbolic,
 830               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 831               [SAVED_LDFLAGS="${LDFLAGS}"
 832                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 833                LDFLAGS=-Wl,-Bsymbolic-functions
 834                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 835                            AC_MSG_RESULT(yes)
 836                            enable_Bsymbolic=yes],[
 837                            AC_MSG_RESULT(no)
 838                            enable_Bsymbolic=no])
 839                LDFLAGS="${SAVED_LDFLAGS}"])
 840
 841
 842 dnl *** set variables based on configure arguments
 843
 844 dnl set license and copyright notice
 845 GST_LICENSE="LGPL"
 846 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 847 AC_SUBST(GST_LICENSE)
 848
 849 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 850 AS_AC_EXPAND(LIBDIR, $libdir)
 851 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 852 AS_AC_EXPAND(DATADIR, $datadir)
 853 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 854
 855 dnl set location of plugin directory
 856 AG_GST_SET_PLUGINDIR
 857
 858 dnl make sure it doesn't complain about unused variables if debugging is disabled
 859 NO_WARNINGS=""
 860 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 861   NO_WARNINGS="-Wno-unused"
 862 fi
 863
 864 dnl define an ERROR_CFLAGS Makefile variable
 865 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 866
 867 dnl special warning flags for gst/printf
 868 AS_COMPILER_FLAG([-Wno-format-nonliteral], [PRINTF_CFLAGS="-Wno-format-nonliteral"])
 869 AC_SUBST(PRINTF_CFLAGS)
 870
 871 dnl define correct level for debugging messages
 872 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 873
 874 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 875
 876 dnl Overview:
 877 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 878 dnl GST_ALL_*:          vars shared by all built objects
 879 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 880 dnl GST_OBJ_*:          additional vars to link to the core library
 881 dnl                     include GST_ALL_*
 882 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 883 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 884
 885 dnl GST_OPTION_CFLAGS
 886 if test "x$USE_DEBUG" = xyes; then
 887    PROFILE_CFLAGS="-g"
 888 fi
 889 AC_SUBST(PROFILE_CFLAGS)
 890
 891 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 892 # functionality from the API that gstreamer uses
 893 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 894 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 895   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 896   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 897 else
 898   DEPRECATED_CFLAGS=""
 899 fi
 900 AC_SUBST(DEPRECATED_CFLAGS)
 901
 902 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 903 dnl make DEPRECATED_CFLAGS=''
 904 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 905 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 906 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 907 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 908 AC_SUBST(GST_OPTION_CFLAGS)
 909 AC_SUBST(GST_OPTION_CXXFLAGS)
 910
 911 dnl GST_ALL_*
 912 dnl vars common to for all internal objects (core libs, elements, applications)
 913 dnl CFLAGS:
 914 dnl - src and build dirs need to be added because every piece that gets built
 915 dnl   will need the GStreamer source and generated headers
 916 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 917 dnl       from LibXML except for in the core library
 918 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 919 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 920
 921 dnl FIXME: check if LTLIBINTL is needed everywhere
 922 dnl I presume it is given that it contains the symbols that _() stuff maps to
 923 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 924
 925 dnl LDFLAGS really should only contain flags, not libs - they get added before
 926 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 927 GST_ALL_LDFLAGS="-no-undefined"
 928 if test "x${enable_Bsymbolic}" = "xyes"; then
 929   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 930 fi
 931
 932 AC_SUBST(GST_ALL_CFLAGS)
 933 AC_SUBST(GST_ALL_CXXFLAGS)
 934 AC_SUBST(GST_ALL_LIBS)
 935 AC_SUBST(GST_ALL_LDFLAGS)
 936
 937 dnl GST_LIB_LDFLAGS
 938 dnl linker flags shared by all libraries
 939 dnl LDFLAGS modifier defining exported symbols from built libraries
 940 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 941 AC_SUBST(GST_LIB_LDFLAGS)
 942
 943 dnl GST_OBJ_*
 944 dnl default vars for all internal objects built on libgstreamer
 945 dnl includes GST_ALL_*
 946 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 947 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 948 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 949 AC_SUBST(GST_OBJ_CFLAGS)
 950 AC_SUBST(GST_OBJ_CXXFLAGS)
 951 AC_SUBST(GST_OBJ_LIBS)
 952
 953 dnl GST_PLUGIN_LDFLAGS
 954 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 955 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 956 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 957
 958 dnl plugin scanner locations
 959 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 960 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 961     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 962 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 963
 964 dnl ptp helper locations
 965 AS_AC_EXPAND(GST_PTP_HELPER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-ptp-helper)
 966 AC_DEFINE_UNQUOTED(GST_PTP_HELPER_INSTALLED,
 967     "$GST_PTP_HELPER_INSTALLED", [location of the installed gst-ptp-helper])
 968 AC_SUBST(GST_PTP_HELPER_INSTALLED)
 969
 970 dnl things for our internal libcheck (must be called even if building
 971 dnl libcheck is disabled because it defines conditionals)
 972 AG_GST_CHECK_CHECKS()
 973
 974 AC_CONFIG_FILES(
 975 Makefile
 976 data/Makefile
 977 gst/Makefile
 978 gst/gstconfig.h
 979 gst/gstversion.h
 980 gst/parse/Makefile
 981 gst/printf/Makefile
 982 libs/Makefile
 983 libs/gst/Makefile
 984 libs/gst/base/Makefile
 985 libs/gst/check/Makefile
 986 libs/gst/check/libcheck/Makefile
 987 libs/gst/check/internal-check.h:libs/gst/check/libcheck/check.h.in
 988 libs/gst/controller/Makefile
 989 libs/gst/helpers/Makefile
 990 libs/gst/net/Makefile
 991 plugins/Makefile
 992 plugins/elements/Makefile
 993 po/Makefile.in
 994 tests/Makefile
 995 tests/benchmarks/Makefile
 996 tests/check/Makefile
 997 tests/misc/Makefile
 998 tests/examples/Makefile
 999 tests/examples/adapter/Makefile
1000 tests/examples/controller/Makefile
1001 tests/examples/stepping/Makefile
1002 tests/examples/helloworld/Makefile
1003 tests/examples/manual/Makefile
1004 tests/examples/memory/Makefile
1005 tests/examples/netclock/Makefile
1006 tests/examples/ptp/Makefile
1007 tests/examples/streamiddemux/Makefile
1008 tests/examples/streams/Makefile
1009 tools/Makefile
1010 common/Makefile
1011 common/m4/Makefile
1012 docs/Makefile
1013 docs/design/Makefile
1014 docs/faq/Makefile
1015 docs/gst/Makefile
1016 docs/gst/gstreamer.types
1017 docs/libs/Makefile
1018 docs/plugins/Makefile
1019 docs/manual/Makefile
1020 docs/pwg/Makefile
1021 docs/slides/Makefile
1022 docs/xsl/Makefile
1023 docs/version.entities
1024 m4/Makefile
1025 pkgconfig/Makefile
1026 stamp.h
1027 pkgconfig/gstreamer.pc
1028 pkgconfig/gstreamer-uninstalled.pc
1029 pkgconfig/gstreamer-base.pc
1030 pkgconfig/gstreamer-base-uninstalled.pc
1031 pkgconfig/gstreamer-check.pc
1032 pkgconfig/gstreamer-check-uninstalled.pc
1033 pkgconfig/gstreamer-controller.pc
1034 pkgconfig/gstreamer-controller-uninstalled.pc
1035 pkgconfig/gstreamer-net.pc
1036 pkgconfig/gstreamer-net-uninstalled.pc
1037 gstreamer.spec
1038 )
1039
1040 dnl Create the config.h file for Visual Studio builds
1041 dnl Beware of spaces and /'s in some of the shell variable contents.
1042 sed \
1043     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1044     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1045     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1046     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1047     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1048     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1049     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1050     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1051     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1052     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1053     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1054     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1055     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1056     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1057     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1058     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1059     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1060     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1061     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1062     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1063     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
1064     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1065     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1066     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
1067     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1068     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
1069     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1070     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1071     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1072     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
1073     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
1074     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1075     config.h.in >win32/common/config.h-new
1076
1077 AC_OUTPUT
1078
1079 dnl negate for output
1080 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
1081 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
1082 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
1083 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
1084 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
1085 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
1086 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
1087
1088 echo "
1089
1090 Configuration
1091         Version                    : ${VERSION}
1092         Source code location       : ${srcdir}
1093         Prefix                     : ${prefix}
1094         Compiler                   : ${CC}
1095         Package name               : ${GST_PACKAGE_NAME}
1096         Package origin             : ${GST_PACKAGE_ORIGIN}
1097
1098         Documentation (manuals)    : ${enable_docbook}
1099         Documentation (API)        : ${enable_gtk_doc}
1100
1101         Debug Logging              : ${enable_gst_debug}
1102         Command-line parser        : ${enable_parse}
1103         Option parsing in gst_init : ${enable_option_parsing}
1104         Tracing subsystem          : ${enable_trace}
1105         Allocation tracing         : ${enable_alloc_trace}
1106         Plugin registry            : ${enable_registry}
1107         Plugin support             : ${enable_plugin}
1108         Static plugins             : ${enable_static_plugins}
1109         Unit testing support       : ${BUILD_CHECK}
1110         PTP clock support          : ${HAVE_PTP}
1111
1112         Debug                      : ${USE_DEBUG}
1113         Profiling                  : ${USE_PROFILING}
1114
1115         Building benchmarks        : ${BUILD_BENCHMARKS}
1116         Building examples          : ${BUILD_EXAMPLES}
1117         Building test apps         : ${BUILD_TESTS}
1118         Building tests that fail   : ${BUILD_FAILING_TESTS}
1119         Building tools             : ${BUILD_TOOLS}
1120 "