configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.13.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1300, 0, 1300)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.13.0.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for gobject-introspection
 158 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 159
 160 dnl check for documentation tools
 161 GTK_DOC_CHECK([1.12])
 162 AG_GST_PLUGIN_DOCS([1.12])
 163
 164 dnl *** checks for libraries ***
 165
 166 dnl libm, for sin() etc.
 167 LT_LIB_M
 168 AC_SUBST(LIBM)
 169
 170 dnl check for pthreads
 171 AX_PTHREAD
 172
 173 dnl *** checks for header files ***
 174
 175 dnl check if we have ANSI C header files
 176 AC_HEADER_STDC
 177
 178 dnl check for GCC specific SSE headers
 179 dnl these are used by the speex resampler code
 180 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 181
 182 dnl also check which architecture we're on for building files with intrinsics
 183 dnl separately
 184 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 185 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 186
 187 dnl check for -m* compiler flags too
 188 SSE_CFLAGS="-msse"
 189 SSE2_CFLAGS="-msse2"
 190 SSE41_CFLAGS="-msse4.1"
 191
 192 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 193 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 194 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 195
 196 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 197
 198 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 199 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 200 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 201
 202 AC_SUBST(SSE_CFLAGS)
 203 AC_SUBST(SSE2_CFLAGS)
 204 AC_SUBST(SSE41_CFLAGS)
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/rtsp
 212 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 213 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 214 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 215   WIN32_LIBS="-lws2_32"
 216   AC_SUBST(WIN32_LIBS)
 217 fi
 218
 219 dnl used in gst-libs/gst/pbutils and associated unit test
 220 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 221
 222 dnl checks for ARM NEON support
 223 dnl this instruction set is used by the speex resampler code
 224 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 225 AC_LINK_IFELSE([
 226 AC_LANG_PROGRAM([[
 227   #include <arm_neon.h>
 228   int32x4_t testfunc(int16_t *a, int16_t *b) {
 229       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 230       return vmull_s16(vld1_s16(a), vld1_s16(b));
 231   }
 232 ]])],
 233 [
 234   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 235   AC_MSG_RESULT(yes)
 236 ],
 237 [
 238   AC_MSG_RESULT(no)
 239 ])
 240
 241 dnl also, Windows does not have long long
 242 AX_CREATE_STDINT_H
 243
 244 dnl *** checks for functions ***
 245 AC_CHECK_FUNCS([localtime_r gmtime_r])
 246
 247 dnl *** checks for math functions ***
 248 LIBS_SAVE=$LIBS
 249 LIBS="$LIBS $LIBM"
 250 AC_CHECK_FUNCS(log2)
 251 LIBS=$LIBS_SAVE
 252
 253 dnl *** checks for types/defines ***
 254
 255 dnl *** checks for structures ***
 256
 257 dnl *** checks for compiler characteristics ***
 258
 259 dnl *** checks for library functions ***
 260
 261 dnl check for fseeko()
 262 AC_FUNC_FSEEKO
 263
 264 dnl Check for fast float to int casting as defined in C99
 265 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 266 save_libs=$LIBS
 267 LIBS="$LIBS $LIBM"
 268 AC_C99_FUNC_LRINT
 269 AC_C99_FUNC_LRINTF
 270 LIBS=$save_libs
 271
 272 dnl Check for a way to display the function name in debug output
 273 AG_GST_CHECK_FUNCTION
 274
 275 dnl *** checks for dependency libraries ***
 276
 277 dnl GLib
 278 GLIB_REQ=2.40.0
 279 AG_GST_GLIB_CHECK([$GLIB_REQ])
 280
 281 ORC_CHECK([0.4.24])
 282
 283 dnl checks for gstreamer
 284 dnl uninstalled is selected preferentially -- see pkg-config(1)
 285 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 286 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 287 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 288 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 289 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 290 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 291
 292 dnl Check for documentation xrefs
 293 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 294 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 295 AC_SUBST(GLIB_PREFIX)
 296 AC_SUBST(GST_PREFIX)
 297
 298 AG_GST_GL_CHECKS
 299
 300 dnl GTK is optional and only used in examples
 301 HAVE_GTK=no
 302 HAVE_GTK_X11=no
 303 HAVE_GDK_PIXBUF=no
 304 GTK_REQ=3.10
 305 if test "x$BUILD_EXAMPLES" = "xyes"; then
 306   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 307   dnl some examples need gtk+-x11
 308   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 309   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 310   AC_SUBST(GTK_LIBS)
 311   AC_SUBST(GTK_CFLAGS)
 312
 313   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 314   AC_SUBST(GDK_PIXBUF_LIBS)
 315   AC_SUBST(GDK_PIXBUF_CFLAGS)
 316 fi
 317 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 318 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 319 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 320 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 321
 322 HAVE_QT=no
 323 HAVE_QT_MOC=no
 324 dnl QT is optional and only used in examples
 325 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 326   HAVE_QT=yes
 327 ], [
 328   HAVE_QT=no
 329 ])
 330 if test "x$HAVE_QT" = "xyes"; then
 331   AC_CHECK_TOOL(QT_MOC, moc)
 332   AC_MSG_CHECKING([for Qt5 moc])
 333   mocversion=`$QT_MOC -v 2>&1`
 334   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 335   if test x"$mocversiongrep" != x"$mocversion"; then
 336     AC_MSG_RESULT([no])
 337     # moc was not the qt5 one, try with moc-qt5
 338     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 339     AC_MSG_CHECKING([for Qt5 moc-qt5])
 340     mocversion=`$QT_MOC -v 2>&1`
 341     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 342     if test x"$mocversiongrep" != x"$mocversion"; then
 343       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 344       AC_MSG_CHECKING([for qtchooser])
 345       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 346       mocversion=`$qt5tooldir/moc -v 2>&1`
 347       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 348       if test x"$mocversiongrep" != x"$mocversion"; then
 349         # no valid moc found
 350         QT_MOC="no"
 351       else
 352         QT_MOC=$qt5tooldir/moc
 353       fi
 354     else
 355       QT_MOC=$QT_MOC
 356     fi
 357   fi
 358   AC_SUBST(QT_MOC)
 359   AC_MSG_RESULT([$QT_MOC])
 360 fi
 361 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 362 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 363
 364 dnl Check for OpenGL example dependencies (clutter, sdl, etc.)
 365 AG_GST_GL_EXAMPLES_CHECKS
 366
 367 dnl chck for linux headers needed by the joystick seek example
 368 AC_COMPILE_IFELSE(
 369 [
 370   AC_LANG_PROGRAM([
 371     #include <linux/input.h>
 372     #include <linux/joystick.h>
 373   ],[
 374     struct js_event js;
 375     js.type = JS_EVENT_AXIS;
 376   ])
 377 ], [
 378   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 379 ], [
 380   HAVE_LINUX_JOYSTICK_HEADERS="no"
 381 ])
 382 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 383
 384 dnl Check for -Bsymbolic-functions linker flag used to avoid
 385 dnl intra-library PLT jumps, if available.
 386 AC_ARG_ENABLE(Bsymbolic,
 387               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 388               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 389                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 390                LDFLAGS=-Wl,-Bsymbolic-functions
 391                LIBS=
 392                AC_TRY_LINK([], [return 0],
 393                            AC_MSG_RESULT(yes)
 394                            enable_Bsymbolic=yes,
 395                            AC_MSG_RESULT(no)
 396                            enable_Bsymbolic=no)
 397                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 398
 399
 400 dnl *** set variables based on configure arguments ***
 401
 402 dnl set license and copyright notice
 403 GST_LICENSE="LGPL"
 404 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 405 AC_SUBST(GST_LICENSE)
 406
 407 dnl set location of plugin directory
 408 AG_GST_SET_PLUGINDIR
 409
 410 dnl set release date/time
 411 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 412   ["${srcdir}/gst-plugins-base.doap"],
 413   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 414
 415 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 416 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 417 if test x$enable_static = xyes -a x$enable_shared = xno; then
 418   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 419 fi
 420
 421 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 422 dnl make sure it doesn't complain about unused variables if debugging is disabled
 423 NO_WARNINGS=""
 424 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 425
 426 dnl define an ERROR_CFLAGS Makefile variable
 427 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 428 dnl -Waggregate-return - xcb_intern_atom() returns an aggregate value
 429 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 430     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 431     -Wwrite-strings  -Wformat-nonliteral -Wformat-security
 432     -Winit-self -Wmissing-include-dirs -Waddress
 433     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 434
 435 dnl define an ERROR_CXXFLAGS Makefile variable
 436 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 437     -Wmissing-declarations -Wredundant-decls -Wundef
 438     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 439     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 440     -Wno-multichar $NO_WARNINGS])
 441
 442 dnl define correct level for debugging messages
 443 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 444
 445 dnl used in examples
 446 AG_GST_DEFAULT_ELEMENTS
 447
 448 dnl needed for encoding-target
 449 GST_DATADIR="$GST_PREFIX/share"
 450 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 451 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 452
 453 dnl behaviour of speex based audio resampler
 454 AC_MSG_CHECKING(which audio resample format to use for integer)
 455 AC_ARG_WITH([audioresample_format],
 456         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 457         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 458 AC_MSG_RESULT($ac_cv_audioresample_format)
 459 case $ac_cv_audioresample_format in
 460   int)
 461     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 462     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 463   ;;
 464   float)
 465     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 466     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 467   ;;
 468   auto)
 469     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 470     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 471 esac
 472
 473 dnl Check for mmap (needed by allocators library)
 474 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 475
 476 dnl *** plug-ins to include ***
 477
 478 dnl these are all the gst plug-ins, compilable without additional libs
 479 AG_GST_CHECK_PLUGIN(adder)
 480 AG_GST_CHECK_PLUGIN(app)
 481 AG_GST_CHECK_PLUGIN(audioconvert)
 482 AG_GST_CHECK_PLUGIN(audiomixer)
 483 AG_GST_CHECK_PLUGIN(audiorate)
 484 AG_GST_CHECK_PLUGIN(audiotestsrc)
 485 AG_GST_CHECK_PLUGIN(encoding)
 486 AG_GST_CHECK_PLUGIN(videoconvert)
 487 AG_GST_CHECK_PLUGIN(gio)
 488 AG_GST_CHECK_PLUGIN(playback)
 489 AG_GST_CHECK_PLUGIN(audioresample)
 490 AG_GST_CHECK_PLUGIN(rawparse)
 491 AG_GST_CHECK_PLUGIN(subparse)
 492 AG_GST_CHECK_PLUGIN(tcp)
 493 AG_GST_CHECK_PLUGIN(typefind)
 494 AG_GST_CHECK_PLUGIN(videotestsrc)
 495 AG_GST_CHECK_PLUGIN(videorate)
 496 AG_GST_CHECK_PLUGIN(videoscale)
 497 AG_GST_CHECK_PLUGIN(volume)
 498
 499 dnl iso-codes is optional, used by libgsttag
 500 AC_ARG_ENABLE(iso-codes,
 501 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 502 [case "${enableval}" in
 503   yes) enable_iso_codes=yes ;;
 504   no)  enable_iso_codes=no ;;
 505   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 506 esac
 507 ],
 508 [enable_iso_codes=yes]) dnl Default value
 509
 510 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 511 if test "x$enable_iso_codes" = "xyes"; then
 512   AC_MSG_RESULT([yes])
 513   have_iso_codes=no
 514   AC_MSG_CHECKING([whether iso-codes are available on this system])
 515   if $PKG_CONFIG iso-codes; then
 516     AC_MSG_RESULT([yes])
 517     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 518     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 519       AC_MSG_RESULT([yes])
 520       AC_MSG_CHECKING([for iso-codes prefix])
 521       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 522       if test -d "$ISO_CODES_PREFIX"; then
 523         AC_MSG_RESULT([yes])
 524         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 525         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 526         ISO_639_DOMAIN="iso_639"
 527         AC_MSG_CHECKING([ISO_639_DOMAIN])
 528         AC_MSG_RESULT([$ISO_639_DOMAIN])
 529         have_iso_codes=yes
 530         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 531         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 532         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 533         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 534       else
 535         AC_MSG_RESULT([no])
 536       fi
 537     else
 538       AC_MSG_RESULT([no])
 539     fi
 540   else
 541     AC_MSG_RESULT([no])
 542   fi
 543   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 544 else
 545   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 546   AM_CONDITIONAL(USE_ISO_CODES, false)
 547 fi
 548
 549 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 551 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 552   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 553       HAVE_ZLIB="yes"
 554     ], [
 555       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 556         HAVE_ZLIB="yes"
 557         ZLIB_LIBS="-lz"
 558         AC_SUBST(ZLIB_LIBS)
 559       ])
 560     ])
 561 ])
 562
 563 dnl *** sys plug-ins ***
 564
 565 echo
 566 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 567 echo
 568
 569 dnl *** X11 ***
 570 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 571 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 572                   [ximagesink], [
 573   AG_GST_PKG_CHECK_MODULES(X, x11)
 574 ])
 575
 576 dnl Check for Xv extension
 577 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 578 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 579                   [xvimagesink], [
 580   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 581 ])
 582
 583 dnl check for X Shm
 584 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 585 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 586   if test x$HAVE_X = xyes; then
 587     PKG_CHECK_MODULES(XSHM, xext, [
 588       AC_CHECK_LIB(Xext, XShmAttach, [
 589         HAVE_XSHM="yes"
 590       ], [
 591         HAVE_XSHM="no"
 592         XSHM_LIBS=""
 593       ], [ $X_LIBS ])
 594     ], [
 595       HAVE_XSHM="no"
 596     ])
 597   fi
 598 ], , [
 599   AC_SUBST(HAVE_XSHM)
 600   AC_SUBST(XSHM_LIBS)
 601 ])
 602
 603 dnl *** ext plug-ins ***
 604 dnl keep this list sorted alphabetically !
 605
 606 if test "x$BUILD_EXTERNAL" = "xyes"; then
 607
 608 echo
 609 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 610 echo
 611
 612 dnl *** alsa ***
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 614 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 615   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 616     HAVE_ALSA="yes"
 617     AC_SUBST(ALSA_CFLAGS)
 618     AC_SUBST(ALSA_LIBS)
 619   ], [
 620     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 621   ])
 622 ])
 623
 624 dnl *** CDParanoia ***
 625 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 626 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 627 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 628   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 629     HAVE_CDPARANOIA="yes"
 630   ], [
 631     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 632                         cdda_open, -lm,
 633                         cdda_interface.h,
 634                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 635                         HEADER_DIR="no"
 636                         FOUND_CDPARANOIA="yes")
 637     if test "x$FOUND_CDPARANOIA" != "xyes";
 638     then
 639       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 640                           cdda_open, -lm,
 641                           cdda/cdda_interface.h,
 642                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 643                           HEADER_DIR="yes"
 644                           FOUND_CDPARANOIA="yes")
 645     fi
 646     if test "x$HEADER_DIR" = "xyes";
 647     then
 648       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 649                          defined if cdda headers are in a cdda/ directory)
 650     fi
 651     if test "x$FOUND_CDPARANOIA" = "xyes";
 652     then
 653       AC_CHECK_LIB(cdda_paranoia,
 654                    paranoia_cachemodel_size,
 655                    : ,
 656                    HAVE_CDPARANOIA=no,
 657                  [-lcdda_interface])
 658     fi
 659
 660     AC_SUBST(CDPARANOIA_LIBS)
 661   ])
 662 ])
 663 dnl FIXME : add second check somehow if that is necessary
 664 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 665 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 666
 667 dnl *** gl ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_GL, true)
 669 AG_GST_CHECK_FEATURE(GL, [gl elements], gl, [
 670   HAVE_GL="no"
 671
 672   if test x"$USE_OPENGL" = x"yes" -o x"$USE_GLES2" = x"yes"; then
 673     HAVE_GL="yes"
 674     AG_GST_GL_PLUGIN_CHECKS
 675   fi
 676 ])
 677
 678 dnl *** ivorbis ***
 679 dnl AM_PATH_IVORBIS only takes two options
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 681 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 682   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 683   if test $HAVE_IVORBIS = no
 684   then
 685     IVORBIS_LIBS=
 686     IVORBIS_CFLAGS=
 687     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 688       [IVORBIS_LIBS=-lvorbisidec
 689       HAVE_IVORBIS=yes
 690       case $host in
 691       arm-*-*)
 692         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 693       esac
 694       ],
 695       HAVE_IVORBIS=no)
 696     AC_SUBST(IVORBIS_LIBS)
 697     AC_SUBST(IVORBIS_CFLAGS)
 698   else
 699     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 700       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 701       USE_TREMOLO=no)
 702   fi
 703 ])
 704
 705 dnl *** libvisual ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 707 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 708   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 709   if test x$HAVE_LIBVISUAL = xyes; then
 710     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 711   fi
 712   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 713   if test x$LIBVIS_PLUGINSDIR != x; then
 714     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 715         "$LIBVIS_PLUGINSDIR",
 716         [directory in which the detected libvisual's plugins are located])
 717   fi
 718 ])
 719
 720 dnl *** ogg ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 722 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 723   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 724 ])
 725
 726 dnl *** Opus ***
 727 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 728 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 729   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 730           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 731           HAVE_OPUS="yes"
 732   ], [
 733           HAVE_OPUS="no"
 734   ])
 735   AC_SUBST(OPUS_CFLAGS)
 736   AC_SUBST(OPUS_LIBS)
 737 ])
 738
 739 dnl *** pango ***
 740 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 741 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 742   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 743 ])
 744
 745 dnl *** theora ***
 746 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 747 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 748   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 749 ])
 750
 751 dnl *** vorbis ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 753 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 754   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 755 ])
 756
 757 if test "x$HAVE_VORBIS" = "xyes"; then
 758   ac_cflags_save="$CFLAGS"
 759   AC_COMPILE_IFELSE([
 760     AC_LANG_PROGRAM([[
 761 #include <vorbis/codec.h>
 762                      ]],[[
 763 vorbis_dsp_state *v;
 764
 765 vorbis_synthesis_restart (v);
 766                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 767   if test "x$HAVE_VSR" = "xyes"; then
 768     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 769                        [defined if vorbis_synthesis_restart is present])
 770   fi
 771   CFLAGS="$ac_cflags_save"
 772 fi
 773
 774 else
 775
 776 dnl not building plugins with external dependencies,
 777 dnl but we still need to set the conditionals
 778 AM_CONDITIONAL(USE_ALSA, false)
 779 AM_CONDITIONAL(USE_CDPARANOIA, false)
 780 AM_CONDITIONAL(USE_GL, false)
 781 AM_CONDITIONAL(USE_IVORBIS, false)
 782 AM_CONDITIONAL(USE_LIBVISUAL, false)
 783 AM_CONDITIONAL(USE_OGG, false)
 784 AM_CONDITIONAL(USE_OPUS, false)
 785 AM_CONDITIONAL(USE_PANGO, false)
 786 AM_CONDITIONAL(USE_THEORA, false)
 787 AM_CONDITIONAL(USE_VORBIS, false)
 788
 789 fi dnl of EXT plugins
 790
 791 AM_CONDITIONAL(HAVE_GRAPHENE, test "x$HAVE_GRAPHENE" = "xyes")
 792 AM_CONDITIONAL(HAVE_PNG, test "x$HAVE_PNG" = "xyes")
 793 AM_CONDITIONAL(HAVE_JPEG, test "x$HAVE_JPEG" = "xyes")
 794
 795 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 796 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 797     HAVE_GIO_UNIX_2_0="yes",
 798     HAVE_GIO_UNIX_2_0="no")
 799 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 800
 801 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 802
 803 dnl Overview:
 804 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 805 dnl GST_*:              flags shared by built objects to link against GStreamer
 806 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 807 dnl                          (compare to other modules) or for i18n
 808 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 809 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 810 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 811 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 812
 813 dnl GST_OPTION_CFLAGS
 814 if test "x$USE_DEBUG" = xyes; then
 815    PROFILE_CFLAGS="-g"
 816 fi
 817 AC_SUBST(PROFILE_CFLAGS)
 818
 819 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 820   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 821   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 822 else
 823   DEPRECATED_CFLAGS=""
 824 fi
 825 AC_SUBST(DEPRECATED_CFLAGS)
 826
 827 VISIBILITY_CFLAGS=""
 828 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 829 AC_SUBST(VISIBILITY_CFLAGS)
 830
 831 VISIBILITY_CXXFLAGS=""
 832 if test "x$HAVE_CXX" = "xyes"; then
 833   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 834 fi
 835 AC_SUBST(VISIBILITY_CXXFLAGS)
 836
 837 dnl disable strict aliasing
 838 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 839 AC_SUBST(EXTRA_CFLAGS)
 840
 841 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 842 dnl at make time with e.g. make ERROR_CFLAGS=""
 843 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 844 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 845 AC_SUBST(GST_OPTION_CFLAGS)
 846 AC_SUBST(GST_OPTION_CXXFLAGS)
 847
 848 dnl our libraries need to be versioned correctly
 849 AC_SUBST(GST_LT_LDFLAGS)
 850
 851 dnl GST_PLUGINS_BASE_CFLAGS
 852 dnl prefer internal headers to already installed ones
 853 dnl also add builddir include for enumtypes and marshal
 854 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 855 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 856
 857 dnl FIXME: do we want to rename to GST_ALL_* ?
 858 dnl add GST_OPTION_CFLAGS, but overridable
 859 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 860 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 861 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 862 AC_SUBST(GST_CFLAGS)
 863 AC_SUBST(GST_CXXFLAGS)
 864 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 865 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 866 AC_SUBST(GST_LIBS)
 867
 868 dnl LDFLAGS really should only contain flags, not libs - they get added before
 869 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 870 GST_ALL_LDFLAGS="-no-undefined"
 871 if test "x${enable_Bsymbolic}" = "xyes"; then
 872   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 873 fi
 874 AC_SUBST(GST_ALL_LDFLAGS)
 875
 876 dnl GST_LIB_LDFLAGS
 877 dnl linker flags shared by all libraries
 878 dnl LDFLAGS modifier defining exported symbols from built libraries
 879 dnl (export _gst_foo but not __gst_foo)
 880 GST_LIB_LDFLAGS=""
 881 AC_SUBST(GST_LIB_LDFLAGS)
 882
 883 dnl this really should only contain flags, not libs - they get added before
 884 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 885 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 886 AC_SUBST(GST_PLUGIN_LDFLAGS)
 887
 888 dnl *** output files ***
 889
 890 $MKDIR_P tests/check/orc
 891
 892 AC_CONFIG_FILES(
 893 Makefile
 894 gst/Makefile
 895 gst/adder/Makefile
 896 gst/app/Makefile
 897 gst/audioconvert/Makefile
 898 gst/audiomixer/Makefile
 899 gst/audiorate/Makefile
 900 gst/audioresample/Makefile
 901 gst/audiotestsrc/Makefile
 902 gst/encoding/Makefile
 903 gst/videoconvert/Makefile
 904 gst/gio/Makefile
 905 gst/pbtypes/Makefile
 906 gst/playback/Makefile
 907 gst/rawparse/Makefile
 908 gst/subparse/Makefile
 909 gst/tcp/Makefile
 910 gst/typefind/Makefile
 911 gst/videotestsrc/Makefile
 912 gst/videorate/Makefile
 913 gst/videoscale/Makefile
 914 gst/volume/Makefile
 915 sys/Makefile
 916 sys/ximage/Makefile
 917 sys/xvimage/Makefile
 918 ext/Makefile
 919 ext/alsa/Makefile
 920 ext/cdparanoia/Makefile
 921 ext/gl/Makefile
 922 ext/libvisual/Makefile
 923 ext/ogg/Makefile
 924 ext/opus/Makefile
 925 ext/pango/Makefile
 926 ext/theora/Makefile
 927 ext/vorbis/Makefile
 928 gst-libs/Makefile
 929 gst-libs/gst/Makefile
 930 gst-libs/gst/allocators/Makefile
 931 gst-libs/gst/audio/Makefile
 932 gst-libs/gst/app/Makefile
 933 gst-libs/gst/fft/Makefile
 934 gst-libs/gst/gl/Makefile
 935 gst-libs/gst/gl/android/Makefile
 936 gst-libs/gst/gl/cocoa/Makefile
 937 gst-libs/gst/gl/dispmanx/Makefile
 938 gst-libs/gst/gl/glprototypes/Makefile
 939 gst-libs/gst/gl/eagl/Makefile
 940 gst-libs/gst/gl/egl/Makefile
 941 gst-libs/gst/gl/wayland/Makefile
 942 gst-libs/gst/gl/win32/Makefile
 943 gst-libs/gst/gl/x11/Makefile
 944 gst-libs/gst/gl/viv-fb/Makefile
 945 gst-libs/gst/riff/Makefile
 946 gst-libs/gst/rtp/Makefile
 947 gst-libs/gst/rtsp/Makefile
 948 gst-libs/gst/sdp/Makefile
 949 gst-libs/gst/tag/Makefile
 950 gst-libs/gst/pbutils/Makefile
 951 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 952 gst-libs/gst/video/Makefile
 953 tools/Makefile
 954 pkgconfig/Makefile
 955 pkgconfig/gstreamer-allocators.pc
 956 pkgconfig/gstreamer-allocators-uninstalled.pc
 957 pkgconfig/gstreamer-audio.pc
 958 pkgconfig/gstreamer-audio-uninstalled.pc
 959 pkgconfig/gstreamer-app.pc
 960 pkgconfig/gstreamer-app-uninstalled.pc
 961 pkgconfig/gstreamer-fft.pc
 962 pkgconfig/gstreamer-fft-uninstalled.pc
 963 pkgconfig/gstreamer-pbutils.pc
 964 pkgconfig/gstreamer-pbutils-uninstalled.pc
 965 pkgconfig/gstreamer-riff.pc
 966 pkgconfig/gstreamer-riff-uninstalled.pc
 967 pkgconfig/gstreamer-rtp.pc
 968 pkgconfig/gstreamer-rtp-uninstalled.pc
 969 pkgconfig/gstreamer-rtsp.pc
 970 pkgconfig/gstreamer-rtsp-uninstalled.pc
 971 pkgconfig/gstreamer-sdp.pc
 972 pkgconfig/gstreamer-sdp-uninstalled.pc
 973 pkgconfig/gstreamer-tag.pc
 974 pkgconfig/gstreamer-tag-uninstalled.pc
 975 pkgconfig/gstreamer-video.pc
 976 pkgconfig/gstreamer-video-uninstalled.pc
 977 pkgconfig/gstreamer-gl.pc
 978 pkgconfig/gstreamer-gl-uninstalled.pc
 979 pkgconfig/gstreamer-plugins-base.pc
 980 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 981 tests/Makefile
 982 tests/check/Makefile
 983 tests/examples/Makefile
 984 tests/examples/app/Makefile
 985 tests/examples/audio/Makefile
 986 tests/examples/decodebin_next/Makefile
 987 tests/examples/dynamic/Makefile
 988 tests/examples/encoding/Makefile
 989 tests/examples/fft/Makefile
 990 tests/examples/gio/Makefile
 991 tests/examples/gl/Makefile
 992 tests/examples/gl/generic/Makefile
 993 tests/examples/gl/generic/cube/Makefile
 994 tests/examples/gl/generic/doublecube/Makefile
 995 tests/examples/gl/generic/recordgraphic/Makefile
 996 tests/examples/gl/generic/cubeyuv/Makefile
 997 tests/examples/gl/qt/Makefile
 998 tests/examples/gl/gtk/Makefile
 999 tests/examples/gl/gtk/fxtest/Makefile
1000 tests/examples/gl/gtk/3dvideo/Makefile
1001 tests/examples/gl/gtk/switchvideooverlay/Makefile
1002 tests/examples/gl/gtk/filternovideooverlay/Makefile
1003 tests/examples/gl/gtk/filtervideooverlay/Makefile
1004 tests/examples/gl/cocoa/Makefile
1005 tests/examples/gl/sdl/Makefile
1006 tests/examples/gl/clutter/Makefile
1007 tests/examples/overlay/Makefile
1008 tests/examples/seek/Makefile
1009 tests/examples/snapshot/Makefile
1010 tests/examples/playback/Makefile
1011 tests/examples/playrec/Makefile
1012 tests/files/Makefile
1013 tests/icles/Makefile
1014 tests/icles/playback/Makefile
1015 docs/Makefile
1016 docs/libs/Makefile
1017 docs/plugins/Makefile
1018 docs/version.entities
1019 po/Makefile.in
1020 common/Makefile
1021 common/m4/Makefile
1022 m4/Makefile
1023 )
1024 AC_OUTPUT
1025
1026 AG_GST_OUTPUT_PLUGINS
1027 ORC_OUTPUT
1028