configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.16.2],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl PKG_CONFIG_SYSROOT_DIR is a valid environment variable
  34 m4_pattern_allow(PKG_CONFIG_SYSROOT_DIR)
  35
  36 dnl use pretty build output with automake >= 1.11
  37 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  38   [AM_DEFAULT_VERBOSITY=1
  39    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  40
  41 dnl our libraries and install dirs use GST_API_VERSION in the filename
  42 dnl to allow side-by-side installation of different API versions
  43 GST_API_VERSION=1.0
  44 AC_SUBST(GST_API_VERSION)
  45 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  46   [GStreamer API Version])
  47
  48 AG_GST_LIBTOOL_PREPARE
  49 AS_LIBTOOL(GST, 1602, 0, 1602)
  50
  51 dnl *** required versions of GStreamer stuff ***
  52 GST_REQ=1.16.2
  53 GSTPB_REQ=1.16.2
  54
  55 dnl *** autotools stuff ****
  56
  57 dnl allow for different autotools
  58 AS_AUTOTOOLS_ALTERNATE
  59
  60 dnl Add parameters for aclocal
  61 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  62
  63 dnl set up gettext
  64 dnl the version check needs to stay here because autopoint greps for it
  65 AM_GNU_GETTEXT_VERSION([0.17])
  66 AM_GNU_GETTEXT([external])
  67 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  68
  69 dnl *** check for arguments to configure ***
  70
  71 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  72 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 AG_GST_PKG_CONFIG_PATH
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** software ***
 105
 106 dnl check for large file support
 107 dnl affected plugins must include config.h
 108 AC_SYS_LARGEFILE
 109
 110 dnl *** checks for programs ***
 111
 112 dnl find a compiler
 113 AC_PROG_CC
 114 AC_PROG_CC_STDC
 115
 116 dnl determine c++ compiler
 117 AC_PROG_CXX
 118 dnl determine if c++ is available on this system
 119 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 120
 121 dnl determine c++ preprocessor
 122 dnl FIXME: do we need this ?
 123 AC_PROG_CXXCPP
 124
 125 AC_PROG_OBJC
 126
 127 dnl check if the compiler supports '-c' and '-o' options
 128 AM_PROG_CC_C_O
 129
 130 dnl find an assembler
 131 AM_PROG_AS
 132
 133 dnl check if the compiler supports do while(0) macros
 134 AG_GST_CHECK_DOWHILE_MACROS
 135
 136 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 137 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 138
 139 dnl check for documentation tools
 140 GTK_DOC_CHECK([1.12])
 141 AG_GST_PLUGIN_DOCS([1.12])
 142
 143 dnl *** checks for libraries ***
 144
 145 dnl check for libm, for sin()
 146 LT_LIB_M
 147 AC_SUBST(LIBM)
 148
 149 AC_CHECK_FUNCS(clock_gettime, [], [
 150   AC_CHECK_LIB(rt, clock_gettime, [
 151     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 152     LIBRT="-lrt"
 153     AC_SUBST([LIBRT])
 154   ])
 155 ])
 156
 157 dnl check for pthreads
 158 AX_PTHREAD
 159
 160 dnl *** checks for header files ***
 161
 162 dnl check if we have ANSI C header files
 163 AC_HEADER_STDC
 164
 165 dnl used by ext/wavpack
 166 AX_CREATE_STDINT_H
 167
 168 dnl used in gst/udp
 169 AC_CHECK_HEADERS([sys/time.h])
 170
 171 dnl used in gst/udp
 172 AC_CHECK_HEADERS([sys/socket.h])
 173
 174 dnl *** checks for types/defines ***
 175
 176 dnl Check for FIONREAD ioctl declaration.  This check is needed
 177 dnl for the UDP plugin to build on Solaris
 178 GST_CHECK_FIONREAD
 179
 180 dnl *** checks for structures ***
 181
 182 dnl *** checks for compiler characteristics ***
 183
 184 dnl check if we have GCC inline-asm
 185 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 186 if test x$HAVE_GCC_ASM = xyes ; then
 187   AC_DEFINE(HAVE_GCC_ASM, 1,
 188     [Define if compiler supports gcc inline assembly])
 189 fi
 190 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 191
 192 dnl *** checks for library functions ***
 193
 194 LIBS_SAVE=$LIBS
 195 LIBS="$LIBS $LIBM"
 196 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 197 LIBS=$LIBS_SAVE
 198
 199 dnl Check whether isinf() is defined by math.h
 200 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 201     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 202 if test "$ac_cv_have_isinf" = "yes"
 203 then
 204     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 205 fi
 206
 207 dnl Check for mmap (needed by electricfence plugin)
 208 AC_FUNC_MMAP
 209 AC_CHECK_SIZEOF([off_t])
 210 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 211
 212 dnl Check for mmap (needed by electricfence plugin)
 213
 214 AC_CHECK_TYPE([struct ip_mreqn], [
 215               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 216               [#include <netinet/in.h>])
 217
 218 dnl *** checks for dependency libraries ***
 219
 220
 221 dnl GLib
 222 GLIB_REQ=2.40.0
 223 AG_GST_GLIB_CHECK([$GLIB_REQ])
 224
 225 dnl Orc
 226 ORC_CHECK([0.4.17])
 227
 228 dnl checks for gstreamer
 229 dnl uninstalled is selected preferentially -- see pkg-config(1)
 230 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 231 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 232 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 233 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 234 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 235 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 236
 237 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 238 if test -z $GST_TOOLS_DIR; then
 239   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 240 fi
 241 AC_SUBST(GST_TOOLS_DIR)
 242
 243 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 244 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 245
 246 AG_GST_PKG_CHECK_MODULES(GST_GL, gstreamer-gl-[$GST_API_VERSION], [$GST_REQ], no)
 247
 248 dnl FIXME: if uninstalled setup we might not want to pick up an installed gst-gl?
 249 if test "x$HAVE_GST_GL" = "xyes"; then
 250
 251   AC_MSG_CHECKING([GStreamer OpenGL window systems ...])
 252   GST_GL_WINSYS=`$PKG_CONFIG --variable=gl_winsys gstreamer-gl-1.0`
 253   AC_MSG_RESULT([$GST_GL_WINSYS])
 254   GST_GL_HAVE_WINDOW_X11=""
 255   GST_GL_HAVE_WINDOW_WAYLAND=""
 256   GST_GL_HAVE_WINDOW_ANDROID=""
 257   GST_GL_HAVE_WINDOW_COCOA=""
 258   GST_GL_HAVE_WINDOW_EAGL=""
 259   case "$GST_GL_WINSYS" in  *x11*) GST_GL_HAVE_WINDOW_X11="1" ;; esac
 260   case "$GST_GL_WINSYS" in  *wayland*) GST_GL_HAVE_WINDOW_WAYLAND="1" ;; esac
 261   case "$GST_GL_WINSYS" in  *android*) GST_GL_HAVE_WINDOW_ANDROID="1" ;; esac
 262   case "$GST_GL_WINSYS" in  *cocoa*) GST_GL_HAVE_WINDOW_COCOA="1" ;; esac
 263   case "$GST_GL_WINSYS" in  *eagl*) GST_GL_HAVE_WINDOW_EAGL="1" ;; esac
 264
 265   AC_MSG_CHECKING([GStreamer OpenGL platforms ...])
 266   GST_GL_PLATFORMS=`$PKG_CONFIG --variable=gl_platforms gstreamer-gl-1.0`
 267   AC_MSG_RESULT([$GST_GL_PLATFORMS])
 268   GST_GL_HAVE_PLATFORM_GLX=""
 269   GST_GL_HAVE_PLATFORM_EGL=""
 270   GST_GL_HAVE_PLATFORM_CGL=""
 271   GST_GL_HAVE_PLATFORM_EAGL=""
 272   case "$GST_GL_PLATFORMS" in  *glx*) GST_GL_HAVE_PLATFORM_GLX="1" ;; esac
 273   case "$GST_GL_PLATFORMS" in  *egl*) GST_GL_HAVE_PLATFORM_EGL="1" ;; esac
 274   case "$GST_GL_PLATFORMS" in  *cgl*) GST_GL_HAVE_PLATFORM_CGL="1" ;; esac
 275   case "$GST_GL_PLATFORMS" in  *eagl*) GST_GL_HAVE_PLATFORM_EAGL="1" ;; esac
 276
 277   AC_MSG_CHECKING([GStreamer OpenGL apis ...])
 278   GST_GL_APIS=`$PKG_CONFIG --variable=gl_apis gstreamer-gl-1.0`
 279   AC_MSG_RESULT([$GST_GL_APIS])
 280   GST_GL_HAVE_API_GLES2=""
 281   GST_GL_HAVE_API_GL=""
 282   case "$GST_GL_APIS" in  *gles2*) GST_GL_HAVE_API_GLES2="1" ;; esac
 283   case "$GST_GL_APIS" in "gl"|"gl "*|*" gl"|*" gl "*) GST_GL_HAVE_API_GL="1" ;; esac
 284 fi
 285
 286 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 287
 288 dnl Check for documentation xrefs
 289 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 290 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 291 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 292 AC_SUBST(GLIB_PREFIX)
 293 AC_SUBST(GST_PREFIX)
 294 AC_SUBST(GSTPB_PREFIX)
 295
 296 dnl GTK is optional and used in examples
 297 HAVE_GTK=no
 298 GTK_REQ=3.0.0
 299 if test "x$BUILD_EXAMPLES" = "xyes"; then
 300   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 301   dnl some examples need gtk+-x11
 302   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 303   AC_SUBST(GTK_LIBS)
 304   AC_SUBST(GTK_CFLAGS)
 305 fi
 306 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 307 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 308
 309 AC_ARG_ENABLE(pcmdump, AC_HELP_STRING([--enable-pcmdump], [pcm dump]),
 310   [
 311     case "${enableval}" in
 312       yes) PCM_DUMP_ENABLE=yes ;;
 313       no)  PCM_DUMP_ENABLE=no ;;
 314       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-pcmdump) ;;
 315     esac
 316   ],
 317   [PCM_DUMP_ENABLE=no])
 318 AM_CONDITIONAL([PCM_DUMP_ENABLE], [test "x$PCM_DUMP_ENABLE" = "xyes"])
 319
 320 if test "x$PCM_DUMP_ENABLE" = "xyes"; then
 321 PKG_CHECK_MODULES(VCONF, vconf)
 322 AC_SUBST(VCONF_CFLAGS)
 323 AC_SUBST(VCONF_LIBS)
 324 fi
 325
 326 PKG_CHECK_MODULES(GIO, gio-2.0)
 327 AC_SUBST(GIO_CFLAGS)
 328 AC_SUBST(GIO_LIBS)
 329
 330 dnl Check for -Bsymbolic-functions linker flag used to avoid
 331 dnl intra-library PLT jumps, if available.
 332 AC_ARG_ENABLE(Bsymbolic,
 333               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 334               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 335                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 336                LDFLAGS=-Wl,-Bsymbolic-functions
 337                LIBS=
 338                AC_TRY_LINK([], [return 0],
 339                            AC_MSG_RESULT(yes)
 340                            enable_Bsymbolic=yes,
 341                            AC_MSG_RESULT(no)
 342                            enable_Bsymbolic=no)
 343                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 344
 345 dnl *** set variables based on configure arguments ***
 346
 347 dnl set license and copyright notice
 348 GST_LICENSE="LGPL"
 349 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 350 AC_SUBST(GST_LICENSE)
 351
 352 dnl set location of plugin directory
 353 AG_GST_SET_PLUGINDIR
 354
 355 dnl set release date/time
 356 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 357   ["${srcdir}/gst-plugins-good.doap"],
 358   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 359
 360 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 361 dnl make sure it doesn't complain about unused variables if debugging is disabled
 362 NO_WARNINGS=""
 363 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 364
 365 dnl define an ERROR_CFLAGS Makefile variable
 366 dnl -Wundef: too many broken headers
 367 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 368       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 369       -Wwrite-strings -Wold-style-definition -Waggregate-return
 370       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 371       -Wnested-externs $NO_WARNINGS])
 372
 373 dnl define an ERROR_CXXFLAGS Makefile variable
 374 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 375         -Wmissing-declarations -Wredundant-decls
 376         -Wwrite-strings
 377         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 378         $NO_WARNINGS])
 379
 380 dnl define an ERROR_OBJCFLAGS Makefile variable
 381 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 382       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 383       -Wwrite-strings -Wold-style-definition
 384       -Winit-self -Wmissing-include-dirs -Wno-multichar
 385       -Wnested-externs $NO_WARNINGS])
 386
 387 dnl define correct level for debugging messages
 388 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 389
 390 dnl used in examples
 391 AG_GST_DEFAULT_ELEMENTS
 392
 393 dnl *** plug-ins to include ***
 394
 395 dnl these are all the gst plug-ins, compilable without additional libs
 396 dnl videofilter is at the top because others depend on it
 397 AG_GST_CHECK_PLUGIN(alpha)
 398 AG_GST_CHECK_PLUGIN(apetag)
 399 AG_GST_CHECK_PLUGIN(audiofx)
 400 AG_GST_CHECK_PLUGIN(audioparsers)
 401 AG_GST_CHECK_PLUGIN(auparse)
 402 AG_GST_CHECK_PLUGIN(autodetect)
 403 AG_GST_CHECK_PLUGIN(avi)
 404 AG_GST_CHECK_PLUGIN(cutter)
 405 AG_GST_CHECK_PLUGIN(debugutils)
 406 AG_GST_CHECK_PLUGIN(deinterlace)
 407 AG_GST_CHECK_PLUGIN(dtmf)
 408 AG_GST_CHECK_PLUGIN(effectv)
 409 AG_GST_CHECK_PLUGIN(equalizer)
 410 AG_GST_CHECK_PLUGIN(flv)
 411 AG_GST_CHECK_PLUGIN(flx)
 412 AG_GST_CHECK_PLUGIN(goom)
 413 AG_GST_CHECK_PLUGIN(goom2k1)
 414 AG_GST_CHECK_PLUGIN(icydemux)
 415 AG_GST_CHECK_PLUGIN(id3demux)
 416 AG_GST_CHECK_PLUGIN(imagefreeze)
 417 AG_GST_CHECK_PLUGIN(interleave)
 418 AG_GST_CHECK_PLUGIN(isomp4)
 419 AG_GST_CHECK_PLUGIN(law)
 420 AG_GST_CHECK_PLUGIN(level)
 421 AG_GST_CHECK_PLUGIN(matroska)
 422 AG_GST_CHECK_PLUGIN(monoscope)
 423 AG_GST_CHECK_PLUGIN(multifile)
 424 AG_GST_CHECK_PLUGIN(multipart)
 425 AG_GST_CHECK_PLUGIN(replaygain)
 426 AG_GST_CHECK_PLUGIN(rtp)
 427 AG_GST_CHECK_PLUGIN(rtpmanager)
 428 AG_GST_CHECK_PLUGIN(rtsp)
 429 AG_GST_CHECK_PLUGIN(shapewipe)
 430 AG_GST_CHECK_PLUGIN(smpte)
 431 AG_GST_CHECK_PLUGIN(spectrum)
 432 AG_GST_CHECK_PLUGIN(udp)
 433 AG_GST_CHECK_PLUGIN(videobox)
 434 AG_GST_CHECK_PLUGIN(videocrop)
 435 AG_GST_CHECK_PLUGIN(videofilter)
 436 AG_GST_CHECK_PLUGIN(videomixer)
 437 AG_GST_CHECK_PLUGIN(wavenc)
 438 AG_GST_CHECK_PLUGIN(wavparse)
 439 AG_GST_CHECK_PLUGIN(y4m)
 440
 441 dnl disable experimental plug-ins
 442 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 443   AG_GST_DISABLE_PLUGIN(monoscope)
 444 fi
 445
 446 dnl *** sys plug-ins ***
 447
 448 echo
 449 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 450 echo
 451
 452 dnl DirectSound
 453 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 454 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 455   HAVE_DIRECTSOUND="no"
 456   save_CFLAGS="$CFLAGS"
 457   save_LDFLAGS="$LDFLAGS"
 458   save_LIBS="$LIBS"
 459   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 460   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 461   LIBS="$LIBS -ldsound -ldxerr9 -luser32 -lole32"
 462   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 463   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 464 #include <windows.h>
 465 #include <dxerr9.h>
 466 #include <dsound.h>
 467 ]], [[
 468   DXGetErrorString9 (0);
 469   DirectSoundCreate(NULL, NULL, NULL);
 470   CLSIDFromString(NULL, NULL);
 471 ]])
 472 ],
 473     [HAVE_DIRECTSOUND="yes"],
 474     [HAVE_DIRECTSOUND="no"])
 475   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 476   CFLAGS=$save_CFLAGS
 477   LDFLAGS=$save_LDFLAGS
 478   LIBS=$save_LIBS
 479
 480   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 481     dnl this is much more than we want
 482     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32 -lole32"
 483     AC_SUBST(DIRECTSOUND_CFLAGS)
 484     AC_SUBST(DIRECTSOUND_LDFLAGS)
 485     AC_SUBST(DIRECTSOUND_LIBS)
 486   fi
 487   AC_SUBST(HAVE_DIRECTSOUND)
 488 ])
 489
 490 dnl *** Win32 WaveOut ***
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 492 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 493   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 494 ])
 495
 496 dnl *** OSS audio *** (Linux, *BSD)
 497 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 498 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 499  HAVE_OSS="yes"
 500 dnl Linux and newer BSD versions :
 501  AC_CHECK_HEADER(sys/soundcard.h, [
 502    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 503    ] , [
 504 dnl Some old BSD versions and also newer OpenBSD versions :
 505    AC_CHECK_HEADER(soundcard.h, [
 506      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 507      ], [
 508   dnl Some old BSD versions :
 509      AC_CHECK_HEADER(machine/soundcard.h, [
 510        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 511          [Define if OSS includes are in /machine/])
 512        ], [
 513        HAVE_OSS="no"
 514      ])
 515    ])
 516  ])
 517 ])
 518
 519 dnl *** oss4 ***
 520 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 521 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 522   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 523   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 524       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 525       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 526 ])
 527
 528 dnl *** OSX Audio ***
 529 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 530 HAVE_IOS="no"
 531 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 532   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 533     [HAVE_OSX_AUDIO="yes"],
 534     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 535     [
 536       HAVE_OSX_AUDIO="yes"
 537       HAVE_IOS="yes"
 538     ], [
 539       HAVE_OSX_AUDIO="no"
 540       HAVE_IOS="no"
 541     ])]
 542   )
 543 ])
 544 if test "x$HAVE_IOS" = "xyes"; then
 545   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 546 fi
 547 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 548
 549 dnl *** OS X video ***
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 551 HAVE_OSX_VIDEO="no"
 552 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 553   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 554
 555   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 556   dnl also require Snow Leopard or newer
 557
 558   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 559         #include <AvailabilityMacros.h>
 560         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 561         #error Too old OSX version
 562         #endif
 563       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 564 ])
 565
 566 dnl *** Video 4 Linux 2 ***
 567 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 568 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 569 HAVE_GST_V4L2=no
 570 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 571   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 572   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 573   [
 574     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ],
 575     [
 576       AC_CHECK_HEADER(sys/videoio.h, [ HAVE_GST_V4L2=yes ])
 577     ])
 578   ])
 579   if test "x$HAVE_VIDEODEV" = "xno"; then
 580      AC_MSG_WARN([video4linux2 was not found])
 581   fi
 582 ])
 583
 584 # Optional gudev for device probing
 585 AC_ARG_WITH([gudev],
 586   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 587   [],
 588   [with_gudev=check])
 589 if test x$HAVE_GST_V4L2 = xyes; then
 590   if test x$with_gudev != xno; then
 591     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 592       [ AC_DEFINE(HAVE_GUDEV, 1,
 593           [Whether gudev is available for device detection])
 594       ],
 595       [true])
 596   fi
 597 fi
 598
 599 AC_SUBST(GUDEV_CFLAGS)
 600 AC_SUBST(GUDEV_LIBS)
 601
 602 # Make libv4l2 non-automagic
 603 AC_ARG_WITH([libv4l2],
 604   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 605   [],
 606   [with_libv4l2=check])
 607 if test x$HAVE_GST_V4L2 = xyes; then
 608   if test x$with_libv4l2 != xno; then
 609       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 610           [ have_libv4l2=yes
 611             AC_DEFINE(HAVE_LIBV4L2, 1,
 612                 [Whether libv4l2 is available for video buffer conversion])
 613           ], [
 614           have_libv4l2=no
 615           ])
 616   else
 617     have_libv4l2=no
 618   fi
 619 fi
 620
 621 dnl Allow enabling v4l2 device probing
 622 default_v4l2_probe=no
 623 AS_CASE([$host],
 624     [*-*linux*],
 625       [AS_CASE([$host_cpu],
 626         [arm*], [
 627           default_v4l2_probe=yes],
 628         [aarch64*], [
 629           default_v4l2_probe=yes])])
 630 AC_ARG_ENABLE(
 631   v4l2-probe,
 632   AC_HELP_STRING(
 633     [--enable-v4l2-probe],
 634     [enable V4L2 plugin to probe devices]),
 635   [], [enable_v4l2_probe=$default_v4l2_probe])
 636 if test "x$enable_v4l2_probe" = "xyes"; then
 637   AC_DEFINE(GST_V4L2_ENABLE_PROBE, 1,
 638     [Define if Video4Linux probe shall be run at plugin load])
 639 fi
 640
 641 dnl Check for X11
 642 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 643 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 644                   [ximagesrc], [
 645   AG_GST_CHECK_X
 646
 647   if test "x$HAVE_X" = "xyes"
 648   then
 649     dnl check for Xfixes
 650     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 651     if test "x$HAVE_XFIXES" = "xyes"
 652     then
 653         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 654     fi
 655     AC_SUBST(XFIXES_LIBS)
 656     AC_SUBST(XFIXES_CFLAGS)
 657
 658     dnl check for Xdamage
 659     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 660     if test "x$HAVE_XDAMAGE" = "xyes"
 661     then
 662         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 663     fi
 664     AC_SUBST(XDAMAGE_LIBS)
 665     AC_SUBST(XDAMAGE_CFLAGS)
 666   fi
 667 ])
 668
 669 dnl FIXME: this should be rolled into the test above, it's just an additional
 670 dnl feature of the ximagesrc plug-in
 671 dnl This is the same as in gst-plugins-base
 672 dnl check for X Shm
 673 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 674 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 675   if test x$HAVE_X = xyes; then
 676     AC_CHECK_LIB(Xext, XShmAttach,
 677                  HAVE_XSHM="yes", HAVE_XSHM="no",
 678                  $X_LIBS)
 679     if test "x$HAVE_XSHM" = "xyes"; then
 680       XSHM_LIBS="-lXext"
 681     else
 682       dnl On AIX, it is in XextSam instead, but we still need -lXext
 683       AC_CHECK_LIB(XextSam, XShmAttach,
 684                    HAVE_XSHM="yes", HAVE_XSHM="no",
 685                    $X_LIBS)
 686       if test "x$HAVE_XSHM" = "xyes"; then
 687         XSHM_LIBS="-lXext -lXextSam"
 688       fi
 689     fi
 690   fi
 691 ], ,[
 692   AC_SUBST(HAVE_XSHM)
 693   AC_SUBST(XSHM_LIBS)
 694 ])
 695
 696 dnl *** ext plug-ins ***
 697 dnl keep this list sorted alphabetically !
 698
 699 if test "x$BUILD_EXTERNAL" = "xyes"; then
 700
 701 echo
 702 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 703 echo
 704
 705 dnl *** aalib ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 707 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 708   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 709 ])
 710
 711 dnl *** cairo ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 713 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 714   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 715 ])
 716
 717 dnl *** FLAC ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 719 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 720   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 721 ])
 722
 723 dnl *** GDK pixbuf ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 725 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 726   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 727 ])
 728
 729 dnl *** gtk+ ***
 730 HAVE_GTK3_GL="no"
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_GTK3, true)
 732 AG_GST_CHECK_FEATURE(GTK3, [Gtk+ elements], gtk, [
 733   PKG_CHECK_MODULES(GTK3, gtk+-3.0, [
 734     AC_DEFINE([HAVE_GTK3], 1, [Define if Gtk+ 3.0 is installed])
 735     HAVE_GTK3="yes"
 736   ], [
 737     HAVE_GTK3="no"
 738   ])
 739   PKG_CHECK_MODULES(GTK3_GL, gtk+-3.0 >= 3.15.0, [
 740     GDK_WINDOWING="no"
 741     if test "x$GST_GL_HAVE_WINDOW_X11" = "x1" -a "x$GST_GL_HAVE_PLATFORM_GLX" = "x1"; then
 742       PKG_CHECK_MODULES(GTK3_X11, gtk+-x11-3.0, [
 743         GTK3_CFLAGS="$GTK3_CFLAGS $GTK3_X11_CFLAGS"
 744         GTK3_LIBS="$GTK3_LIBS $GTK3_X11_LIBS"
 745         GDK_WINDOWING="yes"
 746       ], [AC_MSG_NOTICE([Could not find Gtk X11 integration])])
 747     fi
 748     if test "x$GST_GL_HAVE_WINDOW_WAYLAND" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EGL" = "x1"; then
 749       PKG_CHECK_MODULES(GTK3_WAYLAND, gtk+-wayland-3.0, [
 750         GTK3_CFLAGS="$GTK3_CFLAGS $GTK3_WAYLAND_CFLAGS"
 751         GTK3_LIBS="$GTK3_LIBS $GTK3_WAYLAND_LIBS"
 752         GDK_WINDOWING="yes"
 753       ], [AC_MSG_NOTICE([Could not find Gtk Wayland integration])])
 754     fi
 755     if test "x$GDK_WINDOWING" = "xyes" -a "x$HAVE_GST_GL" = "xyes"; then
 756       AC_DEFINE([HAVE_GTK3_GL], 1, [Define if Gtk+ 3.0 GL is installed])
 757       HAVE_GTK3_GL="yes"
 758     fi
 759   ], [
 760       HAVE_GTK3_GL="no"
 761   ])
 762 ])
 763 AM_CONDITIONAL(USE_GTK3_GL, test "x$HAVE_GTK3_GL" = "xyes")
 764
 765 dnl *** Jack ***
 766 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 767 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 768   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 769   AC_SUBST(JACK_CFLAGS)
 770   AC_SUBST(JACK_LIBS)
 771
 772   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 773   if test x$HAVE_JACK_0_120_1 = xyes; then
 774     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 775   fi
 776   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 777   if test x$HAVE_JACK_1_9_7 = xyes; then
 778     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 779   fi
 780
 781 ])
 782
 783 dnl *** jpeg ***
 784 dnl FIXME: we could use header checks here as well IMO
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 786 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 787   AC_ARG_WITH(jpeg-mmx,
 788     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 789   OLD_LIBS="$LIBS"
 790   if test x$with_jpeg_mmx != x; then
 791     LIBS="$LIBS -L$with_jpeg_mmx"
 792   fi
 793   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 794   JPEG_LIBS="$LIBS -ljpeg-mmx"
 795   LIBS="$OLD_LIBS"
 796   if test x$HAVE_JPEG != xyes; then
 797     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 798     JPEG_LIBS="-ljpeg"
 799   fi
 800   AC_SUBST(JPEG_LIBS)
 801 ])
 802
 803 dnl *** lame ***
 804 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 805 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 806   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 807   [
 808     HAVE_LAME="yes"
 809     LAME_LIBS="-lmp3lame $LIBM"
 810     dnl is lame presets available
 811     LAME_CFLAGS=""
 812     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[ int preset = MEDIUM ]])],[LAME_CFLAGS="-DGSTLAME_PRESET"],[LAME_CFLAGS=""
 813     ])
 814     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <lame/lame.h>]], [[
 815         void *ptr = &lame_set_VBR_quality
 816       ]])],[LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],[LAME_CFLAGS="$LAME_CFLAGS"
 817     ])
 818   AC_SUBST(LAME_CFLAGS)
 819   AC_SUBST(LAME_LIBS)
 820   ])
 821 ])
 822
 823 dnl *** libcaca ***
 824 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 825 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 826   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 827 ])
 828
 829 dnl *** libdv ***
 830 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 831 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 832   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 833 ])
 834
 835 dnl *** libpng ***
 836 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 837 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 838   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 839   if test $HAVE_LIBPNG = "yes"; then
 840     PKG_CHECK_MODULES(LIBPNG_1_5, libpng >= 1.5.1, [
 841         AC_DEFINE(HAVE_LIBPNG_1_5, 1, [Defined if libpng version is 1.5.1 or newer])
 842       ], [true])
 843   fi
 844 ])
 845
 846 dnl *** mpg123 ***
 847 translit(dnm, m, l) AM_CONDITIONAL(USE_MPG123, true)
 848 AG_GST_CHECK_FEATURE(MPG123, [mpg123 audio decoder], mpg123, [
 849   PKG_CHECK_MODULES(MPG123, libmpg123 >= 1.13, HAVE_MPG123="yes", HAVE_MPG123="no")
 850   AC_SUBST(MPG123_CFLAGS)
 851   AC_SUBST(MPG123_LIBS)
 852 ])
 853
 854 dnl *** pulseaudio ***
 855 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 856 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 857
 858   dnl used in ext/pulse/pulseutil.c
 859   AC_CHECK_HEADERS([process.h])
 860
 861   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 862 ])
 863
 864 dnl *** dv1394 ***
 865 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 866 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 867   dnl first test for libraw1394 >= 2.0.0
 868   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 869   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 870   dnl now see how far we got
 871   if test x$HAVE_RAW1394 = xyes && \
 872      test x$HAVE_LIBIEC61883 = xyes; then
 873        AG_GST_CHECK_LIBHEADER(AVC1394,
 874         avc1394, avc1394_send_command, $RAW1394_LIBS,
 875         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 876        AG_GST_CHECK_LIBHEADER(ROM1394,
 877         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 878         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 879        if test x$HAVE_AVC1394 = xyes && \
 880           test x$HAVE_AVC1394 = xyes && \
 881           test x$HAVE_ROM1394 = xyes; then
 882           HAVE_DV1394=yes
 883           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 884           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 885           AC_SUBST(DV1394_CFLAGS)
 886           AC_SUBST(DV1394_LIBS)
 887         fi
 888   else
 889        if test x$HAVE_RAW1394 = xno; then
 890           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 891           AG_GST_CHECK_LIBHEADER(AVC1394,
 892            avc1394, avc1394_send_command, $RAW1394_LIBS,
 893            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 894           AG_GST_CHECK_LIBHEADER(ROM1394,
 895            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 896            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 897           if test x$HAVE_RAW1394 = xyes && \
 898              test x$HAVE_AVC1394 = xyes && \
 899              test x$HAVE_ROM1394 = xyes; then
 900              HAVE_DV1394=yes
 901              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 902              DV1394_CFLAGS="$RAW1394_CFLAGS"
 903              if test x$HAVE_LIBIEC61883 = xyes; then
 904                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 905                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 906              fi
 907              AC_SUBST(DV1394_CFLAGS)
 908              AC_SUBST(DV1394_LIBS)
 909            fi
 910          fi
 911   fi
 912 ])
 913 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 914
 915 dnl *** Qt ***
 916 translit(dnm, m, l) AM_CONDITIONAL(USE_QT, true)
 917 AG_GST_CHECK_FEATURE(QT, [Qt elements], qt, [
 918   PKG_CHECK_MODULES(QT, Qt5Core Qt5Gui Qt5Qml Qt5Quick >= 5.4.0, [
 919       QT_PATH=`$PKG_CONFIG --variable=exec_prefix Qt5Core`
 920       QT_HOST_PATH=`$PKG_CONFIG --variable=host_bins Qt5Core`
 921       AC_ARG_WITH([moc],
 922            AS_HELP_STRING([--with-moc], [Set location of qt moc tool]),
 923            [MOC=$withval])
 924       AC_PATH_PROGS(MOC, [moc-qt5 moc], [moc], ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
 925       AC_ARG_WITH([rcc],
 926            AS_HELP_STRING([--with-rcc], [Set location of qt rcc tool]),
 927            [RCC=$withval])
 928       AC_PATH_PROGS(RCC, [rcc-qt5 rcc], [rcc], ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
 929       AC_ARG_WITH([uic],
 930                AS_HELP_STRING([--with-uic], [Set location of qt uic tool]),
 931                [UIC=$withval])
 932       AC_PATH_PROGS(UIC, [uic-qt5 uic], [uic], ["${QT_HOST_PATH}" "${QT_PATH}/bin"])
 933       if test "x$MOC" = "x" || test "x$UIC" = "x" || test "x$RCC" = "x"; then
 934         AC_MSG_WARN([One of the required qt build programs was not found])
 935         HAVE_QT="no"
 936       else
 937         HAVE_QT="yes"
 938         HAVE_QT_WINDOWING="no"
 939         QT_VERSION="`$PKG_CONFIG --define-prefix --modversion Qt5Core`"
 940         QPA_INCLUDE_PATH=`$PKG_CONFIG --variable=includedir Qt5Core`/QtGui/${QT_VERSION}/QtGui
 941         AS_IF([test -f "$PKG_CONFIG_SYSROOT_DIR/$QPA_INCLUDE_PATH/qpa/qplatformnativeinterface.h"], [
 942           QT_CFLAGS="$QT_CFLAGS -I$PKG_CONFIG_SYSROOT_DIR/$QPA_INCLUDE_PATH"
 943           HAVE_QT_QPA_HEADER="yes"
 944           AC_DEFINE([HAVE_QT_QPA_HEADER], [], [Define if the Qt QPA header is installed])
 945         ], [AC_MSG_NOTICE([Cannot find QPA])])
 946         if test "x$GST_GL_HAVE_WINDOW_X11" = "x1" -a "x$GST_GL_HAVE_PLATFORM_GLX" = "x1" || test "x$GST_GL_HAVE_WINDOW_X11" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EGL" = "x1"; then
 947           PKG_CHECK_MODULES(QT_X11, Qt5X11Extras, [
 948             AC_DEFINE([HAVE_QT_X11], [], [Define if Qt X11 integration is installed])
 949             QT_CFLAGS="$QT_CFLAGS $QT_X11_CFLAGS"
 950             QT_LIBS="$QT_LIBS $QT_X11_LIBS"
 951             HAVE_QT_WINDOWING="yes"
 952           ], [AC_MSG_NOTICE([Could not find Qt X11 integration])])
 953         fi
 954         if test "x$GST_GL_HAVE_WINDOW_WAYLAND" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EGL" = "x1" -a "x$HAVE_QT_QPA_HEADER" = "xyes"; then
 955           PKG_CHECK_MODULES(QT_WAYLAND, Qt5WaylandClient, [
 956             AC_DEFINE([HAVE_QT_WAYLAND], [],
 957                 [Define if Qt Wayland integration is installed])
 958             QT_CFLAGS="$QT_CFLAGS $QT_WAYLAND_CFLAGS"
 959             QT_LIBS="$QT_LIBS $QT_WAYLAND_LIBS"
 960             HAVE_QT_WINDOWING="yes"
 961           ], [AC_MSG_NOTICE([Could not find Qt Wayland integration])])
 962         fi
 963         if test "x$GST_GL_HAVE_PLATFORM_EGL" = "x1"; then
 964           if test "x$GST_GL_HAVE_WINDOW_ANDROID" = "x1"; then
 965             PKG_CHECK_MODULES(QT_ANDROID, Qt5AndroidExtras, [
 966               # c++ on android requires a standard library and there are multiple
 967               # choices.  cerbero provides a pkg-config file the describes a choice
 968               # so try to use that.  Outside cerbero one has to pass these flags
 969               # manually for the library one is using
 970               PKG_CHECK_MODULES(GNUSTL, gnustl, [
 971                 QT_CFLAGS="$QT_CFLAGS $GNUSTL_CFLAGS"
 972                 QT_LIBS="$QT_LIBS $GNUSTL_LIBS"
 973                 ], [
 974                 AC_MSG_NOTICE([Could not find Standard C++ library])])
 975               AC_DEFINE([HAVE_QT_ANDROID], [],
 976                 [Define if Qt Android integration is installed])
 977               QT_CFLAGS="$QT_CFLAGS $QT_ANDROID_CFLAGS"
 978               QT_LIBS="$QT_LIBS $QT_ANDROID_LIBS"
 979               HAVE_QT_WINDOWING="yes"
 980             ], [AC_MSG_NOTICE([Could not find Qt Android integration])])
 981           else
 982               AC_DEFINE([HAVE_QT_EGLFS], [],
 983                 [Define if Qt eglfs integration is installed])
 984               HAVE_QT_WINDOWING="yes"
 985           fi
 986         fi
 987         if test "x$GST_GL_HAVE_WINDOW_COCOA" = "x1" -a "x$GST_GL_HAVE_PLATFORM_CGL" = "x1"; then
 988           PKG_CHECK_MODULES(QT_MAC, Qt5MacExtras, [
 989             AC_DEFINE([HAVE_QT_MAC], [],
 990                 [Define if Qt Mac integration is installed])
 991             QT_LIBDIR=`$PKG_CONFIG --variable=libdir Qt5Core`
 992             QT_CFLAGS="$QT_CFLAGS $QT_MAC_CFLAGS -F$QT_LIBDIR -framework QtCore -framework QtGui -framework QtQuick -framework QtQml -framework QtMacExtras"
 993             QT_LIBS="$QT_LIBS $QT_MAC_LIBS"
 994             HAVE_QT_WINDOWING="yes"
 995           ], [AC_MSG_NOTICE([Could not find Qt Mac integration])])
 996         fi
 997         if test "x$GST_GL_HAVE_WINDOW_EAGL" = "x1" -a "x$GST_GL_HAVE_PLATFORM_EAGL" = "x1"; then
 998           if test "x$HAVE_IOS" = "xyes"; then
 999             # iOS doesn't have its own extras package so if we have the core
1000             # modules we are good to go
1001             AC_DEFINE([HAVE_QT_IOS], [],
1002                 [Define if Qt iOS integration is installed])
1003             HAVE_QT_WINDOWING="yes"
1004           fi
1005         fi
1006         if test "x$HAVE_QT_WINDOWING" = "xno"; then
1007           AC_MSG_WARN([Could not find any Qt Windowing integration])
1008           HAVE_QT="no"
1009         fi
1010         AC_SUBST([QT_CFLAGS])
1011         AC_SUBST([QT_LIBS])
1012       fi
1013   ], [
1014       HAVE_QT="no"
1015   ])
1016 ])
1017
1018 dnl *** shout2 ***
1019 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
1020 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
1021   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
1022 ])
1023
1024 dnl *** soup ***
1025 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
1026 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
1027   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.48, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
1028   AC_SUBST(SOUP_CFLAGS)
1029   AC_SUBST(SOUP_LIBS)
1030 ])
1031
1032 dnl *** speex ***
1033 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
1034 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
1035   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
1036 ])
1037
1038 dnl *** taglib ***
1039 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
1040 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
1041   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
1042   if test "x$HAVE_CXX" != "xyes"; then
1043     USE_TAGLIB=false
1044     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
1045   else
1046     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
1047     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
1048         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
1049       ], [
1050         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
1051     ])
1052     AC_SUBST(TAGLIB_CXXFLAGS)
1053   fi
1054 ])
1055
1056 dnl *** twolame ***
1057 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
1058 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
1059   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
1060       HAVE_TWOLAME="yes"], [
1061       HAVE_TWOLAME="no"
1062   ])
1063   AC_SUBST(TWOLAME_CFLAGS)
1064   AC_SUBST(TWOLAME_LIBS)
1065 ])
1066
1067 PKG_CHECK_MODULES(TBM, libtbm)
1068 AC_SUBST(TBM_CFLAGS)
1069 AC_SUBST(TBM_LIBS)
1070
1071 dnl *** vpx ***
1072 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
1073 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
1074   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
1075   HAVE_VP8=no
1076   HAVE_VP9=no
1077
1078   if test $HAVE_VPX = "yes"; then
1079     OLD_LIBS="$LIBS"
1080     OLD_CFLAGS="$CFLAGS"
1081     CFLAGS="$CFLAGS $VPX_CFLAGS"
1082     LIBS="$LIBS $VPX_LIBS"
1083     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
1084       HAVE_VP8=yes
1085       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
1086     ])
1087     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
1088       HAVE_VP8=yes
1089       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
1090     ])
1091
1092     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
1093       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
1094         HAVE_VP9=yes
1095         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
1096       ])
1097       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
1098         HAVE_VP9=yes
1099         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
1100       ])
1101     ], [true])
1102
1103     PKG_CHECK_MODULES(VPX_140, vpx >= 1.4.0, [
1104       AC_DEFINE(HAVE_VPX_1_4, 1, [Defined if the VPX library version is 1.4 or bigger])
1105     ], [true])
1106
1107     PKG_CHECK_MODULES(VPX_180, vpx >= 1.8.0, [
1108       AC_DEFINE(HAVE_VPX_1_8, 1, [Defined if the VPX library version is 1.8 or bigger])
1109     ], [true])
1110
1111     LIBS="$OLD_LIBS"
1112     CFLAGS="$OLD_CFLAGS"
1113   fi
1114   AC_SUBST(VPX_LIBS)
1115   AC_SUBST(VPX_CFLAGS)
1116 ])
1117
1118 dnl *** wavpack ***
1119 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
1120 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
1121   AG_GST_PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.60.0)
1122 ])
1123
1124 dnl *** qtdemux & matroska prefer to have zlib ***
1125 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
1126 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
1127   AG_GST_CHECK_LIBHEADER(ZLIB,
1128     z, uncompress,, zlib.h, [
1129     HAVE_ZLIB="yes"
1130     ZLIB_LIBS="-lz"
1131     AC_SUBST(ZLIB_LIBS)
1132   ])
1133 ])
1134
1135 dnl *** matroska prefers to have bz2 ***
1136 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1137 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1138   save_LIBS=$LIBS
1139   LIBS="$LIBS -lbz2"
1140   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
1141   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
1142   AC_MSG_RESULT($HAVE_BZ2)
1143   LIBS=$save_LIBS
1144   if test "x$HAVE_BZ2" = "xyes"; then
1145     BZ2_LIBS="-lbz2"
1146   fi
1147   AC_SUBST(BZ2_LIBS)
1148 ])
1149
1150 else
1151
1152 dnl not building plugins with external dependencies,
1153 dnl but we still need to set the conditionals
1154 AM_CONDITIONAL(USE_AALIB, false)
1155 AM_CONDITIONAL(USE_BZ2, false)
1156 AM_CONDITIONAL(USE_CAIRO, false)
1157 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1158 AM_CONDITIONAL(USE_DV1394, false)
1159 AM_CONDITIONAL(USE_FLAC, false)
1160 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1161 AM_CONDITIONAL(USE_GTK3, false)
1162 AM_CONDITIONAL(USE_GTK3_GL, false)
1163 AM_CONDITIONAL(USE_JACK, false)
1164 AM_CONDITIONAL(USE_JPEG, false)
1165 AM_CONDITIONAL(USE_LAME, false)
1166 AM_CONDITIONAL(USE_LIBCACA, false)
1167 AM_CONDITIONAL(USE_LIBDV, false)
1168 AM_CONDITIONAL(USE_LIBIEC61883, false)
1169 AM_CONDITIONAL(USE_LIBPNG, false)
1170 AM_CONDITIONAL(USE_MPG123, false)
1171 AM_CONDITIONAL(USE_OSS, false)
1172 AM_CONDITIONAL(USE_OSS4, false)
1173 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1174 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1175 AM_CONDITIONAL(USE_PULSE, false)
1176 AM_CONDITIONAL(USE_QT, false)
1177 AM_CONDITIONAL(USE_SHOUT2, false)
1178 AM_CONDITIONAL(USE_SOUP, false)
1179 AM_CONDITIONAL(USE_SPEEX, false)
1180 AM_CONDITIONAL(USE_TAGLIB, false)
1181 AM_CONDITIONAL(USE_TWOLAME, false)
1182 AM_CONDITIONAL(USE_VPX, false)
1183 AM_CONDITIONAL(USE_WAVEFORM, false)
1184 AM_CONDITIONAL(USE_WAVPACK, false)
1185 AM_CONDITIONAL(USE_X, false)
1186 AM_CONDITIONAL(USE_XSHM, false)
1187 AM_CONDITIONAL(USE_ZLIB, false)
1188
1189 fi dnl of EXT plugins
1190
1191 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1192
1193 dnl Overview:
1194 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1195 dnl GST_*:              flags shared by all built objects
1196 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1197 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1198 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1199 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1200
1201 dnl GST_OPTION_CFLAGS
1202 if test "x$USE_DEBUG" = xyes; then
1203    PROFILE_CFLAGS="-g"
1204 fi
1205 AC_SUBST(PROFILE_CFLAGS)
1206
1207 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1208   dnl Define _only_ for git (not pre-releases or releases)
1209   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1210 else
1211   DEPRECATED_CFLAGS=""
1212 fi
1213 AC_SUBST(DEPRECATED_CFLAGS)
1214
1215 VISIBILITY_CFLAGS=""
1216 AS_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CFLAGS="-fvisibility=hidden"])
1217 AC_SUBST(VISIBILITY_CFLAGS)
1218
1219 VISIBILITY_CXXFLAGS=""
1220 if test "x$HAVE_CXX" = "xyes"; then
1221   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
1222 fi
1223 AC_SUBST(VISIBILITY_CXXFLAGS)
1224
1225 dnl disable strict aliasing
1226 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
1227 AC_SUBST(EXTRA_CFLAGS)
1228
1229 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1230 dnl at make time with e.g. make ERROR_CFLAGS=""
1231 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1232 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1233 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1234 AC_SUBST(GST_OPTION_CFLAGS)
1235 AC_SUBST(GST_OPTION_CXXFLAGS)
1236 AC_SUBST(GST_OPTION_OBJCFLAGS)
1237
1238 dnl our libraries need to be versioned correctly
1239 AC_SUBST(GST_LT_LDFLAGS)
1240
1241 dnl FIXME: do we want to rename to GST_ALL_* ?
1242 dnl prefer internal headers to already installed ones
1243 dnl also add builddir include for enumtypes and marshal
1244 dnl add ERROR_CFLAGS, but overridable
1245 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1246 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
1247 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1248 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $EXTRA_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
1249 AC_SUBST(GST_CFLAGS)
1250 AC_SUBST(GST_CXXFLAGS)
1251 AC_SUBST(GST_OBJCFLAGS)
1252 AC_SUBST(GST_LIBS)
1253
1254 dnl LDFLAGS really should only contain flags, not libs - they get added before
1255 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1256 GST_ALL_LDFLAGS="-no-undefined"
1257 if test "x${enable_Bsymbolic}" = "xyes"; then
1258   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
1259 fi
1260 AC_SUBST(GST_ALL_LDFLAGS)
1261
1262 dnl this really should only contain flags, not libs - they get added before
1263 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1264 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
1265 AC_SUBST(GST_PLUGIN_LDFLAGS)
1266
1267 dnl *** output files ***
1268
1269 $MKDIR_P tests/check/orc
1270
1271 dnl keep this alphabetic per directory, please
1272 AC_CONFIG_FILES(
1273 Makefile
1274 gst/Makefile
1275 gst/alpha/Makefile
1276 gst/apetag/Makefile
1277 gst/audiofx/Makefile
1278 gst/audioparsers/Makefile
1279 gst/auparse/Makefile
1280 gst/autodetect/Makefile
1281 gst/avi/Makefile
1282 gst/cutter/Makefile
1283 gst/deinterlace/Makefile
1284 gst/dtmf/Makefile
1285 gst/debugutils/Makefile
1286 gst/effectv/Makefile
1287 gst/equalizer/Makefile
1288 gst/flv/Makefile
1289 gst/goom/Makefile
1290 gst/goom2k1/Makefile
1291 gst/id3demux/Makefile
1292 gst/icydemux/Makefile
1293 gst/imagefreeze/Makefile
1294 gst/interleave/Makefile
1295 gst/isomp4/Makefile
1296 gst/law/Makefile
1297 gst/level/Makefile
1298 gst/matroska/Makefile
1299 gst/monoscope/Makefile
1300 gst/multifile/Makefile
1301 gst/multipart/Makefile
1302 gst/replaygain/Makefile
1303 gst/rtp/Makefile
1304 gst/rtpmanager/Makefile
1305 gst/rtsp/Makefile
1306 gst/shapewipe/Makefile
1307 gst/smpte/Makefile
1308 gst/spectrum/Makefile
1309 gst/udp/Makefile
1310 gst/videobox/Makefile
1311 gst/videocrop/Makefile
1312 gst/videofilter/Makefile
1313 gst/videomixer/Makefile
1314 gst/wavenc/Makefile
1315 gst/wavparse/Makefile
1316 gst/flx/Makefile
1317 gst/y4m/Makefile
1318 ext/Makefile
1319 ext/aalib/Makefile
1320 ext/cairo/Makefile
1321 ext/dv/Makefile
1322 ext/flac/Makefile
1323 ext/gdk_pixbuf/Makefile
1324 ext/gtk/Makefile
1325 ext/jack/Makefile
1326 ext/jpeg/Makefile
1327 ext/lame/Makefile
1328 ext/libcaca/Makefile
1329 ext/libpng/Makefile
1330 ext/mpg123/Makefile
1331 ext/pulse/Makefile
1332 ext/qt/Makefile
1333 ext/raw1394/Makefile
1334 ext/shout2/Makefile
1335 ext/soup/Makefile
1336 ext/speex/Makefile
1337 ext/taglib/Makefile
1338 ext/twolame/Makefile
1339 ext/vpx/Makefile
1340 ext/wavpack/Makefile
1341 sys/Makefile
1342 sys/directsound/Makefile
1343 sys/oss/Makefile
1344 sys/oss4/Makefile
1345 sys/osxaudio/Makefile
1346 sys/osxvideo/Makefile
1347 sys/v4l2/Makefile
1348 sys/waveform/Makefile
1349 sys/ximage/Makefile
1350 po/Makefile.in
1351 tests/Makefile
1352 tests/check/Makefile
1353 tests/examples/Makefile
1354 tests/examples/audiofx/Makefile
1355 tests/examples/cairo/Makefile
1356 tests/examples/equalizer/Makefile
1357 tests/examples/gtk/Makefile
1358 tests/examples/jack/Makefile
1359 tests/examples/level/Makefile
1360 tests/examples/rtp/Makefile
1361 tests/examples/rtsp/Makefile
1362 tests/examples/shapewipe/Makefile
1363 tests/examples/spectrum/Makefile
1364 tests/examples/v4l2/Makefile
1365 tests/files/Makefile
1366 tests/icles/Makefile
1367 common/Makefile
1368 common/m4/Makefile
1369 m4/Makefile
1370 docs/Makefile
1371 docs/plugins/Makefile
1372 docs/version.entities
1373 pkgconfig/Makefile
1374 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1375 )
1376 AC_OUTPUT
1377
1378 AG_GST_OUTPUT_PLUGINS
1379 ORC_OUTPUT
1380