configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.16.2],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 1602, 0, 1602)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.16.2
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  82
  83 AG_GST_ARG_DEBUG
  84 AG_GST_ARG_PROFILING
  85 AG_GST_ARG_VALGRIND
  86 AG_GST_ARG_GCOV
  87
  88 AG_GST_ARG_EXAMPLES
  89
  90 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  91 AG_GST_ARG_WITH_PACKAGE_NAME
  92 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  93
  94 AG_GST_PKG_CONFIG_PATH
  95
  96 dnl let distro override plugin install helper path
  97 AC_ARG_WITH(install-plugins-helper,
  98   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  99   [
 100     case "${withval}" in
 101       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 103       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 104     esac
 105   ],
 106   [
 107     dnl Default value
 108     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 109   ]
 110 )
 111 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 112 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 113     [plugin install helper script])
 114 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 115
 116 AG_GST_ARG_WITH_PLUGINS
 117
 118 AG_GST_ARG_ENABLE_EXTERNAL
 119
 120 AG_GST_ARG_ENABLE_EXPERIMENTAL
 121
 122 dnl *** checks for platform ***
 123 AG_GST_PLATFORM
 124
 125 dnl * hardware/architecture *
 126
 127 dnl common/m4/gst-arch.m4
 128 dnl check CPU type
 129 AG_GST_ARCH
 130
 131 dnl check for large file support
 132 dnl affected plugins must include config.h
 133 AC_SYS_LARGEFILE
 134
 135 dnl *** checks for programs ***
 136
 137 dnl find a compiler
 138 AC_PROG_CC
 139 AC_PROG_CC_STDC
 140
 141 dnl check if the compiler supports '-c' and '-o' options
 142 AM_PROG_CC_C_O
 143
 144 dnl determine if c++ is available on this system
 145 AC_PROG_CXX
 146 dnl CXX may be set to some default even if no c++ compiler is available
 147 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 148 AC_LANG_PUSH([C++])
 149 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 150 AC_LANG_POP([C++])
 151 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 152 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 153
 154 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 155 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 156
 157 dnl check for supporting tbm
 158 AC_MSG_CHECKING([for supporting tbm])
 159 AC_ARG_ENABLE(tbm, AC_HELP_STRING([--enable-tbm], [tbm support]),
 160   [
 161     case "${enableval}" in
 162       yes) USE_TBM=yes ;;
 163       no)  USE_TBM=no ;;
 164       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-tbm) ;;
 165     esac
 166   ],
 167   [USE_TBM=no])
 168 AM_CONDITIONAL(USE_TBM, test "x$USE_TBM" = "xyes")
 169 AC_MSG_RESULT([$USE_TBM])
 170 if test "x$USE_TBM" = "xyes"; then
 171   AC_DEFINE(USE_TBM, 1, [tbm support])
 172 fi
 173
 174 dnl Check for tv-product
 175 AC_ARG_ENABLE(tv, AC_HELP_STRING([--enable-tv], [use tv]),
 176         [
 177           case "${enableval}" in
 178            yes) HAVE_TV_PRODUCT=yes ;;
 179            no)  HAVE_TV_PRODUCT=no ;;
 180            *)   AC_MSG_ERROR(bad value ${enableval} for --enable-tv) ;;
 181           esac
 182         ],)
 183 AM_CONDITIONAL([HAVE_TV_PRODUCT], [test "x$HAVE_TV_PRODUCT" = "xyes"])
 184
 185 dnl check for gobject-introspection
 186 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 187
 188 dnl check for documentation tools
 189 GTK_DOC_CHECK([1.12])
 190 AG_GST_PLUGIN_DOCS([1.12])
 191
 192 dnl *** checks for libraries ***
 193
 194 dnl libm, for sin() etc.
 195 LT_LIB_M
 196 AC_SUBST(LIBM)
 197
 198 dnl check for pthreads
 199 AX_PTHREAD
 200
 201 dnl *** checks for header files ***
 202
 203 dnl check if we have ANSI C header files
 204 AC_HEADER_STDC
 205
 206 dnl check for GCC specific SSE headers
 207 dnl these are used by the speex resampler code
 208 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h smmintrin.h])
 209
 210 dnl also check which architecture we're on for building files with intrinsics
 211 dnl separately
 212 AC_CHECK_DECLS([__i386__], [HAVE_X86=1])
 213 AC_CHECK_DECLS([__x86_64__], [HAVE_X86=1])
 214
 215 dnl check for -m* compiler flags too
 216 SSE_CFLAGS="-msse"
 217 SSE2_CFLAGS="-msse2"
 218 SSE41_CFLAGS="-msse4.1"
 219
 220 AS_COMPILER_FLAG([$SSE_CFLAGS], [HAVE_SSE=1], [HAVE_SSE=0])
 221 AS_COMPILER_FLAG([$SSE2_CFLAGS], [HAVE_SSE2=1], [HAVE_SSE2=0])
 222 AS_COMPILER_FLAG([$SSE41_CFLAGS], [HAVE_SSE41=1], [HAVE_SSE41=0])
 223
 224 AM_CONDITIONAL(HAVE_X86, [test "x${HAVE_X86}" = "x1"])
 225
 226 AC_DEFINE_UNQUOTED(HAVE_SSE, [$HAVE_SSE], [SSE support is enabled])
 227 AC_DEFINE_UNQUOTED(HAVE_SSE2, [$HAVE_SSE2], [SSE2 support is enabled])
 228 AC_DEFINE_UNQUOTED(HAVE_SSE41, [$HAVE_SSE41], [SSE4.1 support is enabled])
 229
 230 AC_SUBST(SSE_CFLAGS)
 231 AC_SUBST(SSE2_CFLAGS)
 232 AC_SUBST(SSE41_CFLAGS)
 233
 234 dnl used in gst/tcp
 235 AC_CHECK_HEADERS([sys/socket.h],
 236   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 237 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 238
 239 dnl used in gst-libs/gst/rtsp
 240 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 241 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 242 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 243   WIN32_LIBS="-lws2_32"
 244   AC_SUBST(WIN32_LIBS)
 245 fi
 246
 247 dnl used in gst-libs/gst/pbutils and associated unit test
 248 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 249
 250 dnl checks for ARM NEON support
 251 dnl this instruction set is used by the speex resampler code
 252 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 253 AC_LINK_IFELSE([
 254 AC_LANG_PROGRAM([[
 255   #include <arm_neon.h>
 256   int32x4_t __attribute__((used)) testfunc(int16_t *a, int16_t *b) {
 257       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 258       return vmull_s16(vld1_s16(a), vld1_s16(b));
 259   }
 260 ]])],
 261 [
 262   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 263   AC_MSG_RESULT(yes)
 264 ],
 265 [
 266   AC_MSG_RESULT(no)
 267 ])
 268
 269 dnl also, Windows does not have long long
 270 AX_CREATE_STDINT_H
 271
 272 dnl *** checks for functions ***
 273 AC_CHECK_FUNCS([localtime_r gmtime_r])
 274
 275 dnl *** checks for math functions ***
 276 LIBS_SAVE=$LIBS
 277 LIBS="$LIBS $LIBM"
 278 AC_CHECK_FUNCS(log2)
 279 LIBS=$LIBS_SAVE
 280
 281 dnl *** checks for types/defines ***
 282
 283 dnl *** checks for structures ***
 284
 285 dnl *** checks for compiler characteristics ***
 286
 287 dnl *** checks for library functions ***
 288
 289 dnl check for fseeko()
 290 AC_FUNC_FSEEKO
 291
 292 dnl Check for fast float to int casting as defined in C99
 293 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 294 save_libs=$LIBS
 295 LIBS="$LIBS $LIBM"
 296 #AC_C99_FUNC_LRINT
 297 #AC_C99_FUNC_LRINTF
 298 LIBS=$save_libs
 299
 300 dnl Check for a way to display the function name in debug output
 301 AG_GST_CHECK_FUNCTION
 302
 303 dnl *** checks for dependency libraries ***
 304
 305 dnl GLib
 306 GLIB_REQ=2.40.0
 307 AG_GST_GLIB_CHECK([$GLIB_REQ])
 308
 309 ORC_CHECK([0.4.24])
 310
 311 dnl For Requires.private in pkg-config files
 312 ORC_PC=
 313 if test x"$HAVE_ORC" = "xyes"; then
 314     ORC_PC="orc-0.4"
 315 fi
 316 AC_SUBST(ORC_PC)
 317
 318 dnl checks for gstreamer
 319 dnl uninstalled is selected preferentially -- see pkg-config(1)
 320 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 321 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 322 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 323 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 324 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 325 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 326
 327 dnl Check for documentation xrefs
 328 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 329 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 330 AC_SUBST(GLIB_PREFIX)
 331 AC_SUBST(GST_PREFIX)
 332
 333 dnl check for gudev
 334 PKG_CHECK_MODULES(G_UDEV, gudev-1.0 , [
 335         AC_DEFINE([HAVE_GUDEV], 1, [Define if gudev is installed])
 336         HAVE_GUDEV="yes" ],
 337         [HAVE_GUDEV="no"])
 338
 339 AG_GST_GL_CHECKS
 340
 341 dnl GTK is optional and only used in examples
 342 HAVE_GTK=no
 343 HAVE_GTK_X11=no
 344 HAVE_GDK_PIXBUF=no
 345 GTK_REQ=3.10
 346 if test "x$BUILD_EXAMPLES" = "xyes"; then
 347   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 348   dnl some examples need gtk+-x11
 349   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 350   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 351   AC_SUBST(GTK_LIBS)
 352   AC_SUBST(GTK_CFLAGS)
 353
 354   PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0, HAVE_GDK_PIXBUF=yes, HAVE_GDK_PIXBUF=no)
 355   AC_SUBST(GDK_PIXBUF_LIBS)
 356   AC_SUBST(GDK_PIXBUF_CFLAGS)
 357 fi
 358 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 359 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 360 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 361 AM_CONDITIONAL(HAVE_GDK_PIXBUF, test "x$HAVE_GDK_PIXBUF" = "xyes")
 362
 363 HAVE_QT=no
 364 HAVE_QT_MOC=no
 365 dnl QT is optional and only used in examples
 366 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 367   HAVE_QT=yes
 368 ], [
 369   HAVE_QT=no
 370 ])
 371 if test "x$HAVE_QT" = "xyes"; then
 372   AC_CHECK_TOOL(QT_MOC, moc)
 373   AC_MSG_CHECKING([for Qt5 moc])
 374   mocversion=`$QT_MOC -v 2>&1`
 375   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 376   if test x"$mocversiongrep" != x"$mocversion"; then
 377     AC_MSG_RESULT([no])
 378     # moc was not the qt5 one, try with moc-qt5
 379     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 380     AC_MSG_CHECKING([for Qt5 moc-qt5])
 381     mocversion=`$QT_MOC -v 2>&1`
 382     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 383     if test x"$mocversiongrep" != x"$mocversion"; then
 384       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 385       AC_MSG_CHECKING([for qtchooser])
 386       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 387       mocversion=`$qt5tooldir/moc -v 2>&1`
 388       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 389       if test x"$mocversiongrep" != x"$mocversion"; then
 390         # no valid moc found
 391         QT_MOC="no"
 392       else
 393         QT_MOC=$qt5tooldir/moc
 394       fi
 395     else
 396       QT_MOC=$QT_MOC
 397     fi
 398   fi
 399   AC_SUBST(QT_MOC)
 400   AC_MSG_RESULT([$QT_MOC])
 401 fi
 402 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 403 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 404
 405 dnl Check for OpenGL example dependencies (clutter, sdl, etc.)
 406 AG_GST_GL_EXAMPLES_CHECKS
 407
 408 dnl chck for linux headers needed by the joystick seek example
 409 AC_COMPILE_IFELSE(
 410 [
 411   AC_LANG_PROGRAM([
 412     #include <linux/input.h>
 413     #include <linux/joystick.h>
 414   ],[
 415     struct js_event js;
 416     js.type = JS_EVENT_AXIS;
 417   ])
 418 ], [
 419   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 420 ], [
 421   HAVE_LINUX_JOYSTICK_HEADERS="no"
 422 ])
 423 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 424
 425 dnl Check for -Bsymbolic-functions linker flag used to avoid
 426 dnl intra-library PLT jumps, if available.
 427 AC_ARG_ENABLE(Bsymbolic,
 428               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 429               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 430                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 431                LDFLAGS=-Wl,-Bsymbolic-functions
 432                LIBS=
 433                AC_TRY_LINK([], [return 0],
 434                            AC_MSG_RESULT(yes)
 435                            enable_Bsymbolic=yes,
 436                            AC_MSG_RESULT(no)
 437                            enable_Bsymbolic=no)
 438                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 439
 440
 441 dnl *** set variables based on configure arguments ***
 442
 443 dnl set license and copyright notice
 444 GST_LICENSE="LGPL"
 445 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 446 AC_SUBST(GST_LICENSE)
 447
 448 dnl set location of plugin directory
 449 AG_GST_SET_PLUGINDIR
 450
 451 dnl set release date/time
 452 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 453   ["${srcdir}/gst-plugins-base.doap"],
 454   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 455
 456 dnl If only building static libraries, define GST_STATIC_COMPILATION. This is
 457 dnl needed only on Windows, but it doesn't hurt to have it everywhere.
 458 if test x$enable_static = xyes -a x$enable_shared = xno; then
 459   GST_STATIC_CFLAGS="-DGST_STATIC_COMPILATION"
 460 fi
 461
 462 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 463 dnl make sure it doesn't complain about unused variables if debugging is disabled
 464 NO_WARNINGS=""
 465 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 466
 467 dnl define an ERROR_CFLAGS Makefile variable
 468 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 469 dnl -Waggregate-return - xcb_intern_atom() returns an aggregate value
 470 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 471     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 472     -Wwrite-strings  -Wformat-nonliteral -Wformat-security
 473     -Winit-self -Wmissing-include-dirs -Waddress
 474     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 475
 476 dnl define an ERROR_CXXFLAGS Makefile variable
 477 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 478     -Wmissing-declarations -Wredundant-decls -Wundef
 479     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 480     -Winit-self -Wmissing-include-dirs -Waddress
 481     -Wno-multichar $NO_WARNINGS])
 482
 483 dnl define correct level for debugging messages
 484 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 485
 486 dnl used in examples
 487 AG_GST_DEFAULT_ELEMENTS
 488
 489 dnl needed for encoding-target
 490 GST_DATADIR="$GST_PREFIX/share"
 491 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 492 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 493
 494 dnl behaviour of speex based audio resampler
 495 AC_MSG_CHECKING(which audio resample format to use for integer)
 496 AC_ARG_WITH([audioresample_format],
 497         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 498         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 499 AC_MSG_RESULT($ac_cv_audioresample_format)
 500 case $ac_cv_audioresample_format in
 501   int)
 502     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 503     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 504   ;;
 505   float)
 506     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 507     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 508   ;;
 509   auto)
 510     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 511     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 512 esac
 513
 514 dnl Check for mmap (needed by allocators library)
 515 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 516
 517 dnl Check for DMABuf synchronization ioctl (needed for DMABuf CPU access)
 518 AC_CHECK_HEADERS([linux/dma-buf.h], [])
 519
 520 dnl *** plug-ins to include ***
 521
 522 dnl these are all the gst plug-ins, compilable without additional libs
 523 AG_GST_CHECK_PLUGIN(adder)
 524 AG_GST_CHECK_PLUGIN(app)
 525 AG_GST_CHECK_PLUGIN(audioconvert)
 526 AG_GST_CHECK_PLUGIN(audiomixer)
 527 AG_GST_CHECK_PLUGIN(audiorate)
 528 AG_GST_CHECK_PLUGIN(audiotestsrc)
 529 AG_GST_CHECK_PLUGIN(compositor)
 530 AG_GST_CHECK_PLUGIN(encoding)
 531 AG_GST_CHECK_PLUGIN(videoconvert)
 532 AG_GST_CHECK_PLUGIN(gio)
 533 AG_GST_CHECK_PLUGIN(overlaycomposition)
 534 AG_GST_CHECK_PLUGIN(playback)
 535 AG_GST_CHECK_PLUGIN(audioresample)
 536 AG_GST_CHECK_PLUGIN(rawparse)
 537 AG_GST_CHECK_PLUGIN(subparse)
 538 AG_GST_CHECK_PLUGIN(tcp)
 539 AG_GST_CHECK_PLUGIN(typefind)
 540 AG_GST_CHECK_PLUGIN(videotestsrc)
 541 AG_GST_CHECK_PLUGIN(videorate)
 542 AG_GST_CHECK_PLUGIN(videoscale)
 543 AG_GST_CHECK_PLUGIN(volume)
 544
 545 dnl iso-codes is optional, used by libgsttag
 546 AC_ARG_ENABLE(iso-codes,
 547 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 548 [case "${enableval}" in
 549   yes) enable_iso_codes=yes ;;
 550   no)  enable_iso_codes=no ;;
 551   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 552 esac
 553 ],
 554 [enable_iso_codes=yes]) dnl Default value
 555
 556 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 557 if test "x$enable_iso_codes" = "xyes"; then
 558   AC_MSG_RESULT([yes])
 559   have_iso_codes=no
 560   AC_MSG_CHECKING([whether iso-codes are available on this system])
 561   if $PKG_CONFIG iso-codes; then
 562     AC_MSG_RESULT([yes])
 563     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 564     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 565       AC_MSG_RESULT([yes])
 566       AC_MSG_CHECKING([for iso-codes prefix])
 567       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 568       if test -d "$ISO_CODES_PREFIX"; then
 569         AC_MSG_RESULT([yes])
 570         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 571         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 572         ISO_639_DOMAIN="iso_639"
 573         AC_MSG_CHECKING([ISO_639_DOMAIN])
 574         AC_MSG_RESULT([$ISO_639_DOMAIN])
 575         have_iso_codes=yes
 576         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 577         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 578         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 579         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 580       else
 581         AC_MSG_RESULT([no])
 582       fi
 583     else
 584       AC_MSG_RESULT([no])
 585     fi
 586   else
 587     AC_MSG_RESULT([no])
 588   fi
 589   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 590 else
 591   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 592   AM_CONDITIONAL(USE_ISO_CODES, false)
 593 fi
 594
 595 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 596 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 597 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 598   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 599       HAVE_ZLIB="yes"
 600     ], [
 601       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 602         HAVE_ZLIB="yes"
 603         ZLIB_LIBS="-lz"
 604         AC_SUBST(ZLIB_LIBS)
 605       ])
 606     ])
 607 ])
 608
 609 dnl *** sys plug-ins ***
 610
 611 echo
 612 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 613 echo
 614
 615 dnl *** X11 ***
 616 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 617 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 618                   [ximagesink], [
 619   AG_GST_PKG_CHECK_MODULES(X, x11)
 620 ])
 621
 622 dnl Check for Xv extension
 623 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 624 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 625                   [xvimagesink], [
 626   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 627 ])
 628
 629 dnl check for X Shm
 630 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 631 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 632   if test x$HAVE_X = xyes; then
 633     PKG_CHECK_MODULES(XSHM, xext, [
 634       AC_CHECK_LIB(Xext, XShmAttach, [
 635         HAVE_XSHM="yes"
 636       ], [
 637         HAVE_XSHM="no"
 638         XSHM_LIBS=""
 639       ], [ $X_LIBS ])
 640     ], [
 641       HAVE_XSHM="no"
 642     ])
 643   fi
 644 ], , [
 645   AC_SUBST(HAVE_XSHM)
 646   AC_SUBST(XSHM_LIBS)
 647 ])
 648
 649 dnl *** ext plug-ins ***
 650 dnl keep this list sorted alphabetically !
 651
 652 if test "x$BUILD_EXTERNAL" = "xyes"; then
 653
 654 echo
 655 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 656 echo
 657
 658 dnl *** alsa ***
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 660 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 661   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 662     HAVE_ALSA="yes"
 663     AC_SUBST(ALSA_CFLAGS)
 664     AC_SUBST(ALSA_LIBS)
 665   ], [
 666     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 667   ])
 668 ])
 669
 670 dnl *** CDParanoia ***
 671 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 673 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 674   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 675     HAVE_CDPARANOIA="yes"
 676   ], [
 677     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 678                         cdda_open, -lm,
 679                         cdda_interface.h,
 680                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 681                         HEADER_DIR="no"
 682                         FOUND_CDPARANOIA="yes")
 683     if test "x$FOUND_CDPARANOIA" != "xyes";
 684     then
 685       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 686                           cdda_open, -lm,
 687                           cdda/cdda_interface.h,
 688                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 689                           HEADER_DIR="yes"
 690                           FOUND_CDPARANOIA="yes")
 691     fi
 692     if test "x$HEADER_DIR" = "xyes";
 693     then
 694       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 695                          defined if cdda headers are in a cdda/ directory)
 696     fi
 697     if test "x$FOUND_CDPARANOIA" = "xyes";
 698     then
 699       AC_CHECK_LIB(cdda_paranoia,
 700                    paranoia_cachemodel_size,
 701                    : ,
 702                    HAVE_CDPARANOIA=no,
 703                  [-lcdda_interface])
 704     fi
 705
 706     AC_SUBST(CDPARANOIA_LIBS)
 707   ])
 708 ])
 709 dnl FIXME : add second check somehow if that is necessary
 710 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 711 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 712
 713 dnl *** gl ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_GL, true)
 715 AG_GST_CHECK_FEATURE(GL, [gl elements], gl, [
 716   HAVE_GL="no"
 717
 718   if test x"$USE_OPENGL" = x"yes" -o x"$USE_GLES2" = x"yes"; then
 719     HAVE_GL="yes"
 720     AG_GST_GL_PLUGIN_CHECKS
 721   fi
 722 ])
 723
 724 dnl *** ivorbis ***
 725 dnl AM_PATH_IVORBIS only takes two options
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 727 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 728   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 729   if test $HAVE_IVORBIS = no
 730   then
 731     IVORBIS_LIBS=
 732     IVORBIS_CFLAGS=
 733     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 734       [IVORBIS_LIBS=-lvorbisidec
 735       HAVE_IVORBIS=yes
 736       case $host in
 737       arm-*-*)
 738         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 739       esac
 740       ],
 741       HAVE_IVORBIS=no)
 742     AC_SUBST(IVORBIS_LIBS)
 743     AC_SUBST(IVORBIS_CFLAGS)
 744   else
 745     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 746       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 747       USE_TREMOLO=no)
 748   fi
 749 ])
 750
 751 dnl *** libvisual ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 753 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 754   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 755   if test x$HAVE_LIBVISUAL = xyes; then
 756     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 757   fi
 758   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 759   if test x$LIBVIS_PLUGINSDIR != x; then
 760     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 761         "$LIBVIS_PLUGINSDIR",
 762         [directory in which the detected libvisual's plugins are located])
 763   fi
 764 ])
 765
 766 dnl *** ogg ***
 767 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 768 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 769   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 770 ])
 771
 772 dnl *** Opus ***
 773 translit(dnm, m, l) AM_CONDITIONAL(USE_OPUS, true)
 774 AG_GST_CHECK_FEATURE(OPUS, [opus], opus, [
 775   PKG_CHECK_MODULES(OPUS, opus >= 0.9.4, [
 776           AC_DEFINE([HAVE_OPUS], 1, [Define if Opus >= 0.9.4 is installed])
 777           HAVE_OPUS="yes"
 778   ], [
 779           HAVE_OPUS="no"
 780   ])
 781   AC_SUBST(OPUS_CFLAGS)
 782   AC_SUBST(OPUS_LIBS)
 783 ])
 784
 785 dnl *** pango ***
 786 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 787 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 788   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 789 ])
 790
 791 dnl *** theora ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 793 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 794   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 795 ])
 796
 797 dnl *** vorbis ***
 798 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 799 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 800   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 801 ])
 802
 803 if test "x$HAVE_VORBIS" = "xyes"; then
 804   ac_cflags_save="$CFLAGS"
 805   AC_COMPILE_IFELSE([
 806     AC_LANG_PROGRAM([[
 807 #include <vorbis/codec.h>
 808                      ]],[[
 809 vorbis_dsp_state *v;
 810
 811 vorbis_synthesis_restart (v);
 812                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 813   if test "x$HAVE_VSR" = "xyes"; then
 814     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 815                        [defined if vorbis_synthesis_restart is present])
 816   fi
 817   CFLAGS="$ac_cflags_save"
 818 fi
 819
 820 else
 821
 822 dnl not building plugins with external dependencies,
 823 dnl but we still need to set the conditionals
 824 AM_CONDITIONAL(USE_ALSA, false)
 825 AM_CONDITIONAL(USE_CDPARANOIA, false)
 826 AM_CONDITIONAL(USE_GL, false)
 827 AM_CONDITIONAL(USE_IVORBIS, false)
 828 AM_CONDITIONAL(USE_LIBVISUAL, false)
 829 AM_CONDITIONAL(USE_OGG, false)
 830 AM_CONDITIONAL(USE_OPUS, false)
 831 AM_CONDITIONAL(USE_PANGO, false)
 832 AM_CONDITIONAL(USE_THEORA, false)
 833 AM_CONDITIONAL(USE_VORBIS, false)
 834
 835 fi dnl of EXT plugins
 836
 837 AM_CONDITIONAL(HAVE_GRAPHENE, test "x$HAVE_GRAPHENE" = "xyes")
 838 AM_CONDITIONAL(HAVE_PNG, test "x$HAVE_PNG" = "xyes")
 839 AM_CONDITIONAL(HAVE_JPEG, test "x$HAVE_JPEG" = "xyes")
 840
 841 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 842 PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24,
 843     HAVE_GIO_UNIX_2_0="yes",
 844     HAVE_GIO_UNIX_2_0="no")
 845 AM_CONDITIONAL(USE_GIO_UNIX_2_0, test "x$HAVE_GIO_UNIX_2_0" = "xyes")
 846
 847 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 848
 849 dnl Overview:
 850 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 851 dnl GST_*:              flags shared by built objects to link against GStreamer
 852 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 853 dnl                          (compare to other modules) or for i18n
 854 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 855 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 856 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 857 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 858
 859 dnl GST_OPTION_CFLAGS
 860 if test "x$USE_DEBUG" = xyes; then
 861    PROFILE_CFLAGS="-g"
 862 fi
 863 AC_SUBST(PROFILE_CFLAGS)
 864
 865 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 866   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 867   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 868 else
 869   DEPRECATED_CFLAGS=""
 870 fi
 871 AC_SUBST(DEPRECATED_CFLAGS)
 872
 873 VISIBILITY_CFLAGS=""
 874 AS_COMPILER_FLAG([-fvisibility=hidden], [
 875   VISIBILITY_CFLAGS="-fvisibility=hidden"
 876   AC_DEFINE(GST_API_EXPORT, [extern __attribute__ ((visibility ("default")))], [public symbol export define])
 877 ], [
 878   VISIBILITY_CFLAGS=""
 879   AC_DEFINE(GST_API_EXPORT, [extern], [public symbol export define])
 880 ])
 881 AC_SUBST(VISIBILITY_CFLAGS)
 882
 883 VISIBILITY_CXXFLAGS=""
 884 if test "x$HAVE_CXX" = "xyes"; then
 885   AS_CXX_COMPILER_FLAG([-fvisibility=hidden], [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 886 fi
 887 AC_SUBST(VISIBILITY_CXXFLAGS)
 888
 889 dnl disable strict aliasing
 890 AS_COMPILER_FLAG([-fno-strict-aliasing], [EXTRA_CFLAGS="-fno-strict-aliasing"])
 891 AC_SUBST(EXTRA_CFLAGS)
 892
 893 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 894 dnl at make time with e.g. make ERROR_CFLAGS=""
 895 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 896 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 897 AC_SUBST(GST_OPTION_CFLAGS)
 898 AC_SUBST(GST_OPTION_CXXFLAGS)
 899
 900 dnl our libraries need to be versioned correctly
 901 AC_SUBST(GST_LT_LDFLAGS)
 902
 903 dnl GST_PLUGINS_BASE_CFLAGS
 904 dnl prefer internal headers to already installed ones
 905 dnl also add builddir include for enumtypes and marshal
 906 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 907 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 908
 909 dnl FIXME: do we want to rename to GST_ALL_* ?
 910 dnl add GST_OPTION_CFLAGS, but overridable
 911 GST_CFLAGS="$GST_CFLAGS $GST_STATIC_CFLAGS"
 912 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS) \$(VISIBILITY_CXXFLAGS)"
 913 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $EXTRA_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS) \$(VISIBILITY_CFLAGS)"
 914 AC_SUBST(GST_CFLAGS)
 915 AC_SUBST(GST_CXXFLAGS)
 916 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 917 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 918 AC_SUBST(GST_LIBS)
 919
 920 dnl LDFLAGS really should only contain flags, not libs - they get added before
 921 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 922 GST_ALL_LDFLAGS="-no-undefined"
 923 if test "x${enable_Bsymbolic}" = "xyes"; then
 924   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 925 fi
 926 AC_SUBST(GST_ALL_LDFLAGS)
 927
 928 dnl GST_LIB_LDFLAGS
 929 dnl linker flags shared by all libraries
 930 dnl LDFLAGS modifier defining exported symbols from built libraries
 931 dnl (export _gst_foo but not __gst_foo)
 932 GST_LIB_LDFLAGS=""
 933 AC_SUBST(GST_LIB_LDFLAGS)
 934
 935 dnl this really should only contain flags, not libs - they get added before
 936 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 937 GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"
 938 AC_SUBST(GST_PLUGIN_LDFLAGS)
 939
 940 dnl use tbm
 941 PKG_CHECK_MODULES(TBM, libdrm libtbm)
 942 AC_SUBST(TBM_CFLAGS)
 943 AC_SUBST(TBM_LIBS)
 944
 945 dnl *** output files ***
 946
 947 $MKDIR_P tests/check/orc
 948
 949 AC_CONFIG_FILES(
 950 Makefile
 951 gst/Makefile
 952 gst/adder/Makefile
 953 gst/app/Makefile
 954 gst/audioconvert/Makefile
 955 gst/audiomixer/Makefile
 956 gst/audiorate/Makefile
 957 gst/audioresample/Makefile
 958 gst/audiotestsrc/Makefile
 959 gst/compositor/Makefile
 960 gst/encoding/Makefile
 961 gst/videoconvert/Makefile
 962 gst/gio/Makefile
 963 gst/overlaycomposition/Makefile
 964 gst/pbtypes/Makefile
 965 gst/playback/Makefile
 966 gst/rawparse/Makefile
 967 gst/subparse/Makefile
 968 gst/tcp/Makefile
 969 gst/typefind/Makefile
 970 gst/videotestsrc/Makefile
 971 gst/videorate/Makefile
 972 gst/videoscale/Makefile
 973 gst/volume/Makefile
 974 sys/Makefile
 975 sys/ximage/Makefile
 976 sys/xvimage/Makefile
 977 ext/Makefile
 978 ext/alsa/Makefile
 979 ext/cdparanoia/Makefile
 980 ext/gl/Makefile
 981 ext/libvisual/Makefile
 982 ext/ogg/Makefile
 983 ext/opus/Makefile
 984 ext/pango/Makefile
 985 ext/theora/Makefile
 986 ext/vorbis/Makefile
 987 gst-libs/Makefile
 988 gst-libs/gst/Makefile
 989 gst-libs/gst/allocators/Makefile
 990 gst-libs/gst/audio/Makefile
 991 gst-libs/gst/app/Makefile
 992 gst-libs/gst/fft/Makefile
 993 gst-libs/gst/gl/Makefile
 994 gst-libs/gst/gl/android/Makefile
 995 gst-libs/gst/gl/cocoa/Makefile
 996 gst-libs/gst/gl/dispmanx/Makefile
 997 gst-libs/gst/gl/glprototypes/Makefile
 998 gst-libs/gst/gl/eagl/Makefile
 999 gst-libs/gst/gl/egl/Makefile
1000 gst-libs/gst/gl/wayland/Makefile
1001 gst-libs/gst/gl/win32/Makefile
1002 gst-libs/gst/gl/x11/Makefile
1003 gst-libs/gst/gl/viv-fb/Makefile
1004 gst-libs/gst/gl/gbm/Makefile
1005 gst-libs/gst/riff/Makefile
1006 gst-libs/gst/rtp/Makefile
1007 gst-libs/gst/rtsp/Makefile
1008 gst-libs/gst/sdp/Makefile
1009 gst-libs/gst/tag/Makefile
1010 gst-libs/gst/pbutils/Makefile
1011 gst-libs/gst/pbutils/gstpluginsbaseversion.h
1012 gst-libs/gst/video/Makefile
1013 tools/Makefile
1014 pkgconfig/Makefile
1015 pkgconfig/gstreamer-allocators.pc
1016 pkgconfig/gstreamer-allocators-uninstalled.pc
1017 pkgconfig/gstreamer-audio.pc
1018 pkgconfig/gstreamer-audio-uninstalled.pc
1019 pkgconfig/gstreamer-app.pc
1020 pkgconfig/gstreamer-app-uninstalled.pc
1021 pkgconfig/gstreamer-fft.pc
1022 pkgconfig/gstreamer-fft-uninstalled.pc
1023 pkgconfig/gstreamer-pbutils.pc
1024 pkgconfig/gstreamer-pbutils-uninstalled.pc
1025 pkgconfig/gstreamer-riff.pc
1026 pkgconfig/gstreamer-riff-uninstalled.pc
1027 pkgconfig/gstreamer-rtp.pc
1028 pkgconfig/gstreamer-rtp-uninstalled.pc
1029 pkgconfig/gstreamer-rtsp.pc
1030 pkgconfig/gstreamer-rtsp-uninstalled.pc
1031 pkgconfig/gstreamer-sdp.pc
1032 pkgconfig/gstreamer-sdp-uninstalled.pc
1033 pkgconfig/gstreamer-tag.pc
1034 pkgconfig/gstreamer-tag-uninstalled.pc
1035 pkgconfig/gstreamer-video.pc
1036 pkgconfig/gstreamer-video-uninstalled.pc
1037 pkgconfig/gstreamer-gl.pc
1038 pkgconfig/gstreamer-gl-uninstalled.pc
1039 pkgconfig/gstreamer-plugins-base.pc
1040 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1041 tests/Makefile
1042 tests/check/Makefile
1043 tests/examples/Makefile
1044 tests/examples/app/Makefile
1045 tests/examples/audio/Makefile
1046 tests/examples/compositor/Makefile
1047 tests/examples/decodebin_next/Makefile
1048 tests/examples/dynamic/Makefile
1049 tests/examples/encoding/Makefile
1050 tests/examples/fft/Makefile
1051 tests/examples/gio/Makefile
1052 tests/examples/gl/Makefile
1053 tests/examples/gl/generic/Makefile
1054 tests/examples/gl/generic/cube/Makefile
1055 tests/examples/gl/generic/doublecube/Makefile
1056 tests/examples/gl/generic/recordgraphic/Makefile
1057 tests/examples/gl/generic/cubeyuv/Makefile
1058 tests/examples/gl/qt/Makefile
1059 tests/examples/gl/gtk/Makefile
1060 tests/examples/gl/gtk/fxtest/Makefile
1061 tests/examples/gl/gtk/3dvideo/Makefile
1062 tests/examples/gl/gtk/switchvideooverlay/Makefile
1063 tests/examples/gl/gtk/filternovideooverlay/Makefile
1064 tests/examples/gl/gtk/filtervideooverlay/Makefile
1065 tests/examples/gl/cocoa/Makefile
1066 tests/examples/gl/sdl/Makefile
1067 tests/examples/overlay/Makefile
1068 tests/examples/overlaycomposition/Makefile
1069 tests/examples/seek/Makefile
1070 tests/examples/snapshot/Makefile
1071 tests/examples/playback/Makefile
1072 tests/examples/playrec/Makefile
1073 tests/files/Makefile
1074 tests/icles/Makefile
1075 tests/icles/playback/Makefile
1076 docs/Makefile
1077 docs/libs/Makefile
1078 docs/plugins/Makefile
1079 docs/version.entities
1080 po/Makefile.in
1081 common/Makefile
1082 common/m4/Makefile
1083 m4/Makefile
1084 )
1085 AC_OUTPUT
1086
1087 AG_GST_OUTPUT_PLUGINS
1088 ORC_OUTPUT
1089