configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 100, 0, 100)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.1.0
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for gobject-introspection
 157 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 158
 159 dnl check for documentation tools
 160 GTK_DOC_CHECK([1.12])
 161 AG_GST_PLUGIN_DOCS([1.12])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 LT_LIB_M
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl check for GCC specific SSE headers
 175 dnl these are used by the speex resampler code
 176 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 177
 178 ac_cppflags_save="$CPPFLAGS"
 179 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 180 AC_COMPILE_IFELSE([
 181   AC_LANG_PROGRAM([[
 182 #include <libxml/HTMLparser.h>
 183 ]],[[
 184 #ifndef LIBXML_HTML_ENABLED
 185 #error libxml2 has no HTML support
 186 #endif /* LIBXML_HTML_ENABLED */
 187 ]])], [
 188   HAVE_LIBXML_HTML="yes"
 189 ], [
 190   HAVE_LIBXML_HTML="no"
 191 ])
 192 CPPFLAGS="$ac_cppflags_save"
 193 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 194
 195 dnl used in gst/tcp
 196 AC_CHECK_HEADERS([sys/socket.h],
 197   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 198 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 202
 203 dnl checks for ARM NEON support
 204 dnl this instruction set is used by the speex resampler code
 205 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 206 AC_LINK_IFELSE([
 207 AC_LANG_PROGRAM([[
 208   #include <arm_neon.h>
 209   int32x4_t testfunc(int16_t *a, int16_t *b) {
 210       return vmull_s16(vld1_s16(a), vld1_s16(b));
 211   }
 212 ]])],
 213 [
 214   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 215   AC_MSG_RESULT(yes)
 216 ],
 217 [
 218   AC_MSG_RESULT(no)
 219 ])
 220
 221 dnl also, Windows does not have long long
 222 AX_CREATE_STDINT_H
 223
 224 dnl *** checks for functions ***
 225 AC_CHECK_FUNCS([localtime_r gmtime_r])
 226
 227 dnl *** checks for math functions ***
 228 LIBS_SAVE=$LIBS
 229 LIBS="$LIBS $LIBM"
 230 AC_CHECK_FUNCS(log2)
 231 LIBS=$LIBS_SAVE
 232
 233 dnl *** checks for types/defines ***
 234
 235 dnl *** checks for structures ***
 236
 237 dnl *** checks for compiler characteristics ***
 238
 239 dnl *** checks for library functions ***
 240
 241 dnl check for fseeko()
 242 AC_FUNC_FSEEKO
 243
 244 dnl Check for fast float to int casting as defined in C99
 245 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 246 save_libs=$LIBS
 247 LIBS="$LIBS $LIBM"
 248 AC_C99_FUNC_LRINT
 249 AC_C99_FUNC_LRINTF
 250 LIBS=$save_libs
 251
 252 dnl Check for a way to display the function name in debug output
 253 AG_GST_CHECK_FUNCTION
 254
 255 dnl *** checks for dependency libraries ***
 256
 257 dnl GLib
 258 GLIB_REQ=2.32
 259 AG_GST_GLIB_CHECK([$GLIB_REQ])
 260
 261 ORC_CHECK([0.4.17])
 262
 263 dnl checks for gstreamer
 264 dnl uninstalled is selected preferentially -- see pkg-config(1)
 265 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 268 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 269 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 270
 271 dnl Check for documentation xrefs
 272 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 273 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 274 AC_SUBST(GLIB_PREFIX)
 275 AC_SUBST(GST_PREFIX)
 276
 277 dnl GTK is optional and only used in examples
 278 HAVE_GTK=no
 279 HAVE_GTK_X11=no
 280 GTK_REQ=3.0.0
 281 if test "x$BUILD_EXAMPLES" = "xyes"; then
 282   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 283   dnl some examples need gtk+-x11
 284   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 285   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 286   AC_SUBST(GTK_LIBS)
 287   AC_SUBST(GTK_CFLAGS)
 288 fi
 289 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 290 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 291 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 292
 293 dnl QT is optional and only used in examples
 294 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 295   HAVE_QT_GV=yes
 296   HAVE_QT=yes
 297 ], [
 298   HAVE_QT_GV=no
 299   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 300 ])
 301 if test "x$HAVE_QT" = "xyes"; then
 302   AC_MSG_CHECKING([Qt moc])
 303   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 304   AC_MSG_RESULT($QT4_MOC)
 305   AC_SUBST(QT4_MOC)
 306 fi
 307 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 308 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 309
 310 dnl chck for linux headers needed by the joystick seek example
 311 AC_COMPILE_IFELSE(
 312 [
 313   AC_LANG_PROGRAM([
 314     #include <linux/input.h>
 315     #include <linux/joystick.h>
 316   ],[
 317     struct js_event js;
 318     js.type = JS_EVENT_AXIS;
 319   ])
 320 ], [
 321   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 322 ], [
 323   HAVE_LINUX_JOYSTICK_HEADERS="no"
 324 ])
 325 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 326
 327 dnl Check for -Bsymbolic-functions linker flag used to avoid
 328 dnl intra-library PLT jumps, if available.
 329 AC_ARG_ENABLE(Bsymbolic,
 330               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 331               [SAVED_LDFLAGS="${LDFLAGS}"
 332                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 333                LDFLAGS=-Wl,-Bsymbolic-functions
 334                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 335                            AC_MSG_RESULT(yes)
 336                            enable_Bsymbolic=yes],[
 337                            AC_MSG_RESULT(no)
 338                            enable_Bsymbolic=no])
 339                LDFLAGS="${SAVED_LDFLAGS}"])
 340
 341
 342 dnl *** set variables based on configure arguments ***
 343
 344 dnl set license and copyright notice
 345 GST_LICENSE="LGPL"
 346 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 347 AC_SUBST(GST_LICENSE)
 348
 349 dnl set location of plugin directory
 350 AG_GST_SET_PLUGINDIR
 351
 352 dnl set release date/time
 353 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 354   ["${srcdir}/gst-plugins-base.doap"],
 355   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 356
 357 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 358 dnl make sure it doesn't complain about unused variables if debugging is disabled
 359 NO_WARNINGS=""
 360 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 361
 362 dnl define an ERROR_CFLAGS Makefile variable
 363 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 364 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 365     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 366     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 367     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 368     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 369
 370 dnl define an ERROR_CXXFLAGS Makefile variable
 371 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 372     -Wmissing-declarations -Wredundant-decls -Wundef
 373     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 374     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 375     -Wno-multichar $NO_WARNINGS])
 376
 377 dnl define correct level for debugging messages
 378 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 379
 380 dnl used in examples
 381 AG_GST_DEFAULT_ELEMENTS
 382
 383 dnl needed for encoding-target
 384 GST_DATADIR="$GST_PREFIX/share"
 385 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 386 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 387
 388 dnl behaviour of speex based audio resampler
 389 AC_MSG_CHECKING(which audio resample format to use for integer)
 390 AC_ARG_WITH([audioresample_format],
 391         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 392         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 393 AC_MSG_RESULT($ac_cv_audioresample_format)
 394 case $ac_cv_audioresample_format in
 395   int)
 396     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 397     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 398   ;;
 399   float)
 400     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 401     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 402   ;;
 403   auto)
 404     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 405     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 406 esac
 407
 408 dnl Check for mmap (needed by allocators library)
 409 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 410
 411 dnl *** plug-ins to include ***
 412
 413 dnl these are all the gst plug-ins, compilable without additional libs
 414 AG_GST_CHECK_PLUGIN(adder)
 415 AG_GST_CHECK_PLUGIN(app)
 416 AG_GST_CHECK_PLUGIN(audioconvert)
 417 AG_GST_CHECK_PLUGIN(audiorate)
 418 AG_GST_CHECK_PLUGIN(audiotestsrc)
 419 AG_GST_CHECK_PLUGIN(encoding)
 420 AG_GST_CHECK_PLUGIN(videoconvert)
 421 AG_GST_CHECK_PLUGIN(gio)
 422 AG_GST_CHECK_PLUGIN(playback)
 423 AG_GST_CHECK_PLUGIN(audioresample)
 424 AG_GST_CHECK_PLUGIN(subparse)
 425 AG_GST_CHECK_PLUGIN(tcp)
 426 AG_GST_CHECK_PLUGIN(typefind)
 427 AG_GST_CHECK_PLUGIN(videotestsrc)
 428 AG_GST_CHECK_PLUGIN(videorate)
 429 AG_GST_CHECK_PLUGIN(videoscale)
 430 AG_GST_CHECK_PLUGIN(volume)
 431
 432 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 433 AM_CONDITIONAL(USE_XML, false)
 434 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 435
 436 dnl disable plug-ins that require libxml2's HTML support if it is not available
 437 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 438   AG_GST_DISABLE_PLUGIN(subparse)
 439 fi
 440
 441 dnl iso-codes is optional, used by libgsttag
 442 AC_ARG_ENABLE(iso-codes,
 443 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 444 [case "${enableval}" in
 445   yes) enable_iso_codes=yes ;;
 446   no)  enable_iso_codes=no ;;
 447   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 448 esac
 449 ],
 450 [enable_iso_codes=yes]) dnl Default value
 451
 452 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 453 if test "x$enable_iso_codes" = "xyes"; then
 454   AC_MSG_RESULT([yes])
 455   have_iso_codes=no
 456   AC_MSG_CHECKING([whether iso-codes are available on this system])
 457   if $PKG_CONFIG iso-codes; then
 458     AC_MSG_RESULT([yes])
 459     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 460     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 461       AC_MSG_RESULT([yes])
 462       AC_MSG_CHECKING([for iso-codes prefix])
 463       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 464       if test -d "$ISO_CODES_PREFIX"; then
 465         AC_MSG_RESULT([yes])
 466         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 467         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 468         ISO_639_DOMAIN="iso_639"
 469         AC_MSG_CHECKING([ISO_639_DOMAIN])
 470         AC_MSG_RESULT([$ISO_639_DOMAIN])
 471         have_iso_codes=yes
 472         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 473         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 474         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 475         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 476       else
 477         AC_MSG_RESULT([no])
 478       fi
 479     else
 480       AC_MSG_RESULT([no])
 481     fi
 482   else
 483     AC_MSG_RESULT([no])
 484   fi
 485   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 486 else
 487   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 488   AM_CONDITIONAL(USE_ISO_CODES, false)
 489 fi
 490
 491 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 493 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 494   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 495       HAVE_ZLIB="yes"
 496     ], [
 497       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 498         HAVE_ZLIB="yes"
 499         ZLIB_LIBS="-lz"
 500         AC_SUBST(ZLIB_LIBS)
 501       ])
 502     ])
 503 ])
 504
 505 dnl *** sys plug-ins ***
 506
 507 echo
 508 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 509 echo
 510
 511 dnl *** X11 ***
 512 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 513 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 514                   [ximagesink], [
 515   AC_PATH_XTRA
 516   ac_cflags_save="$CFLAGS"
 517   ac_cppflags_save="$CPPFLAGS"
 518   CFLAGS="$CFLAGS $X_CFLAGS"
 519   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 520
 521   dnl now try to find the HEADER
 522   AC_CHECK_HEADER([X11/Xlib.h], [HAVE_X="yes"], [HAVE_X="no"], [AC_INCLUDES_DEFAULT])
 523
 524   if test "x$HAVE_X" = "xno"
 525   then
 526     AC_MSG_NOTICE([cannot find X11 development files])
 527   else
 528     dnl this is much more than we want
 529     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 530     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 531     dnl it does not add the libs; therefore we add them here
 532     X_LIBS="$X_LIBS -lX11"
 533     AC_SUBST(X_CFLAGS)
 534     AC_SUBST(X_LIBS)
 535   fi
 536   AC_SUBST(HAVE_X)
 537   CFLAGS="$ac_cflags_save"
 538   CPPFLAGS="$ac_cppflags_save"
 539 ])
 540
 541 dnl Check for Xv extension
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 543 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 544                   [xvimagesink], [
 545   AG_GST_CHECK_XV
 546 ])
 547
 548 dnl check for X Shm
 549 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 550 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 551   if test x$HAVE_X = xyes; then
 552     AC_CHECK_LIB(Xext, XShmAttach,
 553                  HAVE_XSHM="yes", HAVE_XSHM="no",
 554                  $X_LIBS)
 555     if test "x$HAVE_XSHM" = "xyes"; then
 556       XSHM_LIBS="-lXext"
 557     else
 558       dnl On AIX, it is in XextSam instead, but we still need -lXext
 559       AC_CHECK_LIB(XextSam, XShmAttach,
 560                    HAVE_XSHM="yes", HAVE_XSHM="no",
 561                    $X_LIBS)
 562       if test "x$HAVE_XSHM" = "xyes"; then
 563         XSHM_LIBS="-lXext -lXextSam"
 564       fi
 565     fi
 566   fi
 567 ], , [
 568   AC_SUBST(HAVE_XSHM)
 569   AC_SUBST(XSHM_LIBS)
 570 ])
 571
 572 dnl *** ext plug-ins ***
 573 dnl keep this list sorted alphabetically !
 574
 575 if test "x$BUILD_EXTERNAL" = "xyes"; then
 576
 577 echo
 578 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 579 echo
 580
 581 dnl *** alsa ***
 582 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 583 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 584   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 585     HAVE_ALSA="yes"
 586     AC_SUBST(ALSA_CFLAGS)
 587     AC_SUBST(ALSA_LIBS)
 588   ], [
 589     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 590   ])
 591 ])
 592
 593 dnl *** CDParanoia ***
 594 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 595 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 596 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 597   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 598     HAVE_CDPARANOIA="yes"
 599   ], [
 600     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 601                         cdda_open, -lm,
 602                         cdda_interface.h,
 603                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 604                         HEADER_DIR="no"
 605                         FOUND_CDPARANOIA="yes")
 606     if test "x$FOUND_CDPARANOIA" != "xyes";
 607     then
 608       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 609                           cdda_open, -lm,
 610                           cdda/cdda_interface.h,
 611                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 612                           HEADER_DIR="yes"
 613                           FOUND_CDPARANOIA="yes")
 614     fi
 615     if test "x$HEADER_DIR" = "xyes";
 616     then
 617       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 618                          defined if cdda headers are in a cdda/ directory)
 619     fi
 620     if test "x$FOUND_CDPARANOIA" = "xyes";
 621     then
 622       AC_CHECK_LIB(cdda_paranoia,
 623                    paranoia_cachemodel_size,
 624                    : ,
 625                    HAVE_CDPARANOIA=no,
 626                  [-lcdda_interface])
 627     fi
 628
 629     AC_SUBST(CDPARANOIA_LIBS)
 630   ])
 631 ])
 632 dnl FIXME : add second check somehow if that is necessary
 633 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 634 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 635
 636 dnl *** ivorbis ***
 637 dnl AM_PATH_IVORBIS only takes two options
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 639 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 640   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 641   if test $HAVE_IVORBIS = no
 642   then
 643     IVORBIS_LIBS=
 644     IVORBIS_CFLAGS=
 645     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 646       [IVORBIS_LIBS=-lvorbisidec
 647       HAVE_IVORBIS=yes
 648       case $host in
 649       arm-*-*)
 650         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 651       esac
 652       ],
 653       HAVE_IVORBIS=no)
 654     AC_SUBST(IVORBIS_LIBS)
 655     AC_SUBST(IVORBIS_CFLAGS)
 656   else
 657     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 658       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 659       USE_TREMOLO=no)
 660   fi
 661 ])
 662
 663 dnl *** libvisual ***
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 665 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 666   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 667   if test $HAVE_LIBVISUAL = no
 668   then
 669     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 670     if test x$HAVE_LIBVISUAL = xyes; then
 671       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 672     fi
 673   else
 674     if test x$HAVE_LIBVISUAL = xyes; then
 675       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 676     fi
 677   fi
 678   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 679   if test x$LIBVIS_PLUGINSDIR != x; then
 680     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 681         "$LIBVIS_PLUGINSDIR",
 682         [directory in which the detected libvisual's plugins are located])
 683   fi
 684 ])
 685
 686 dnl *** ogg ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 688 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 689   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 690   if test $HAVE_OGG = no
 691   then
 692     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 693     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 694   fi
 695 ])
 696
 697 dnl *** pango ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 699 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 700   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 701 ])
 702
 703 dnl *** theora ***
 704 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 705 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 706   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 707 ])
 708
 709 dnl *** vorbis ***
 710 dnl AM_PATH_VORBIS only takes two options
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 712 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 713   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 714   if test $HAVE_VORBIS = no
 715   then
 716     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 717     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 718   fi
 719 ])
 720
 721 if test "x$HAVE_VORBIS" = "xyes"; then
 722   ac_cflags_save="$CFLAGS"
 723   AC_COMPILE_IFELSE([
 724     AC_LANG_PROGRAM([[
 725 #include <vorbis/codec.h>
 726                      ]],[[
 727 vorbis_dsp_state *v;
 728
 729 vorbis_synthesis_restart (v);
 730                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 731   if test "x$HAVE_VSR" = "xyes"; then
 732     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 733                        [defined if vorbis_synthesis_restart is present])
 734   fi
 735   CFLAGS="$ac_cflags_save"
 736 fi
 737
 738 else
 739
 740 dnl not building plugins with external dependencies,
 741 dnl but we still need to set the conditionals
 742 AM_CONDITIONAL(USE_ALSA, false)
 743 AM_CONDITIONAL(USE_CDPARANOIA, false)
 744 AM_CONDITIONAL(USE_IVORBIS, false)
 745 AM_CONDITIONAL(USE_LIBVISUAL, false)
 746 AM_CONDITIONAL(USE_OGG, false)
 747 AM_CONDITIONAL(USE_PANGO, false)
 748 AM_CONDITIONAL(USE_THEORA, false)
 749 AM_CONDITIONAL(USE_VORBIS, false)
 750
 751 fi dnl of EXT plugins
 752
 753 dnl seeking needs freetype, so check for it here
 754 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 755   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 756 ])
 757 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 758 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 759 AC_SUBST(FT2_CFLAGS)
 760 AC_SUBST(FT2_LIBS)
 761
 762 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 763
 764 dnl Overview:
 765 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 766 dnl GST_*:              flags shared by built objects to link against GStreamer
 767 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 768 dnl                          (compare to other modules) or for i18n
 769 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 770 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 771 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 772 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 773
 774 dnl GST_OPTION_CFLAGS
 775 if test "x$USE_DEBUG" = xyes; then
 776    PROFILE_CFLAGS="-g"
 777 fi
 778 AC_SUBST(PROFILE_CFLAGS)
 779
 780 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 781   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 782   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 783 else
 784   DEPRECATED_CFLAGS=""
 785 fi
 786 AC_SUBST(DEPRECATED_CFLAGS)
 787
 788 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 789 dnl at make time with e.g. make ERROR_CFLAGS=""
 790 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 791 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 792 AC_SUBST(GST_OPTION_CFLAGS)
 793 AC_SUBST(GST_OPTION_CXXFLAGS)
 794
 795 dnl our libraries need to be versioned correctly
 796 AC_SUBST(GST_LT_LDFLAGS)
 797
 798 dnl GST_PLUGINS_BASE_CFLAGS
 799 dnl prefer internal headers to already installed ones
 800 dnl also add builddir include for enumtypes and marshal
 801 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 802 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 803
 804 dnl FIXME: do we want to rename to GST_ALL_* ?
 805 dnl add GST_OPTION_CFLAGS, but overridable
 806 GST_CFLAGS="$GST_CFLAGS"
 807 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 808 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 809 AC_SUBST(GST_CFLAGS)
 810 AC_SUBST(GST_CXXFLAGS)
 811 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 812 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 813 AC_SUBST(GST_LIBS)
 814
 815 dnl LDFLAGS really should only contain flags, not libs - they get added before
 816 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 817 GST_ALL_LDFLAGS="-no-undefined"
 818 if test "x${enable_Bsymbolic}" = "xyes"; then
 819   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 820 fi
 821 AC_SUBST(GST_ALL_LDFLAGS)
 822
 823 dnl GST_LIB_LDFLAGS
 824 dnl linker flags shared by all libraries
 825 dnl LDFLAGS modifier defining exported symbols from built libraries
 826 dnl (export _gst_foo but not __gst_foo)
 827 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 828 AC_SUBST(GST_LIB_LDFLAGS)
 829
 830 dnl this really should only contain flags, not libs - they get added before
 831 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 832 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 833 AC_SUBST(GST_PLUGIN_LDFLAGS)
 834
 835 dnl *** output files ***
 836
 837 AC_CONFIG_FILES(
 838 Makefile
 839 gst-plugins-base.spec
 840 gst/Makefile
 841 gst/adder/Makefile
 842 gst/app/Makefile
 843 gst/audioconvert/Makefile
 844 gst/audiorate/Makefile
 845 gst/audiotestsrc/Makefile
 846 gst/encoding/Makefile
 847 gst/videoconvert/Makefile
 848 gst/gio/Makefile
 849 gst/playback/Makefile
 850 gst/audioresample/Makefile
 851 gst/subparse/Makefile
 852 gst/tcp/Makefile
 853 gst/typefind/Makefile
 854 gst/videotestsrc/Makefile
 855 gst/videorate/Makefile
 856 gst/videoscale/Makefile
 857 gst/volume/Makefile
 858 sys/Makefile
 859 sys/ximage/Makefile
 860 sys/xvimage/Makefile
 861 ext/Makefile
 862 ext/alsa/Makefile
 863 ext/cdparanoia/Makefile
 864 ext/libvisual/Makefile
 865 ext/ogg/Makefile
 866 ext/pango/Makefile
 867 ext/theora/Makefile
 868 ext/vorbis/Makefile
 869 gst-libs/Makefile
 870 gst-libs/gst/Makefile
 871 gst-libs/gst/allocators/Makefile
 872 gst-libs/gst/audio/Makefile
 873 gst-libs/gst/app/Makefile
 874 gst-libs/gst/fft/Makefile
 875 gst-libs/gst/riff/Makefile
 876 gst-libs/gst/rtp/Makefile
 877 gst-libs/gst/rtsp/Makefile
 878 gst-libs/gst/sdp/Makefile
 879 gst-libs/gst/tag/Makefile
 880 gst-libs/gst/pbutils/Makefile
 881 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 882 gst-libs/gst/video/Makefile
 883 tools/Makefile
 884 pkgconfig/Makefile
 885 pkgconfig/gstreamer-allocators.pc
 886 pkgconfig/gstreamer-allocators-uninstalled.pc
 887 pkgconfig/gstreamer-audio.pc
 888 pkgconfig/gstreamer-audio-uninstalled.pc
 889 pkgconfig/gstreamer-app.pc
 890 pkgconfig/gstreamer-app-uninstalled.pc
 891 pkgconfig/gstreamer-fft.pc
 892 pkgconfig/gstreamer-fft-uninstalled.pc
 893 pkgconfig/gstreamer-pbutils.pc
 894 pkgconfig/gstreamer-pbutils-uninstalled.pc
 895 pkgconfig/gstreamer-riff.pc
 896 pkgconfig/gstreamer-riff-uninstalled.pc
 897 pkgconfig/gstreamer-rtp.pc
 898 pkgconfig/gstreamer-rtp-uninstalled.pc
 899 pkgconfig/gstreamer-rtsp.pc
 900 pkgconfig/gstreamer-rtsp-uninstalled.pc
 901 pkgconfig/gstreamer-sdp.pc
 902 pkgconfig/gstreamer-sdp-uninstalled.pc
 903 pkgconfig/gstreamer-tag.pc
 904 pkgconfig/gstreamer-tag-uninstalled.pc
 905 pkgconfig/gstreamer-video.pc
 906 pkgconfig/gstreamer-video-uninstalled.pc
 907 pkgconfig/gstreamer-plugins-base.pc
 908 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 909 tests/Makefile
 910 tests/check/Makefile
 911 tests/examples/Makefile
 912 tests/examples/app/Makefile
 913 tests/examples/audio/Makefile
 914 tests/examples/dynamic/Makefile
 915 tests/examples/encoding/Makefile
 916 tests/examples/fft/Makefile
 917 tests/examples/gio/Makefile
 918 tests/examples/overlay/Makefile
 919 tests/examples/seek/Makefile
 920 tests/examples/snapshot/Makefile
 921 tests/examples/playback/Makefile
 922 tests/examples/playrec/Makefile
 923 tests/files/Makefile
 924 tests/icles/Makefile
 925 tests/icles/playback/Makefile
 926 docs/Makefile
 927 docs/design/Makefile
 928 docs/libs/Makefile
 929 docs/plugins/Makefile
 930 docs/version.entities
 931 po/Makefile.in
 932 common/Makefile
 933 common/m4/Makefile
 934 m4/Makefile
 935 )
 936
 937 dnl Create the config.h file for Visual Studio builds
 938 dnl Beware of spaces and /'s in some of the shell variable contents.
 939 sed \
 940     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 941     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 942     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 943     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 944     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 945     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 946     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 947     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 948     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 949     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 950     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 951     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 952     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 953     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 954     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 955     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 956     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 957     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 958     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 959     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 960     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 961     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 962     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 963     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 964     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 965     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 966     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 967     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 968     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 969     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 970     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 971     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 972     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 973     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 974     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 975     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 976     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 977     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 978     config.h.in >win32/common/config.h-new
 979
 980
 981
 982 AC_OUTPUT
 983
 984 AG_GST_OUTPUT_PLUGINS
 985 ORC_OUTPUT
 986