gnulib/m4/unlinkdir.m4

   1 # serial 6
   2
   3 # Copyright (C) 2005-2007, 2009-2011 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Paul Eggert.
  10
  11 AC_DEFUN([gl_UNLINKDIR],
  12 [
  13   AC_REQUIRE([AC_CANONICAL_HOST])
  14   AC_CHECK_HEADERS_ONCE([priv.h])
  15
  16   AC_LIBOBJ([unlinkdir])
  17
  18   # The Hurd, the Linux kernel, the FreeBSD kernel version 2.2 and later,
  19   # Cygwin, and mingw never let anyone (even root) unlink directories.
  20   # If anyone knows of another system for which unlink can never
  21   # remove a directory, please report it to <bug-coreutils@gnu.org>.
  22   # Unfortunately this is difficult to test for, since it requires root access
  23   # and might create garbage in the file system,
  24   # so the code below simply relies on the kernel name and version number.
  25   case $host_os in
  26   gnu[[0-9]]* | \
  27   linux-* | linux | \
  28   freebsd2.2* | freebsd[[3-9]]* | freebsd[[1-9]][[0-9]]* | \
  29   cygwin | \
  30   mingw*)
  31     AC_DEFINE([UNLINK_CANNOT_UNLINK_DIR], [1],
  32       [Define to 1 if unlink (dir) cannot possibly succeed.]);;
  33   esac
  34 ])