build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2
   3 SET(CMAKE_C_STANDARD 99)
   4 SET(CMAKE_CXX_STANDARD 17)
   5 PROJECT(dali-demo C CXX)
   6
   7 SET(dali-demo_VERSION_MAJOR 1)
   8 SET(dali-demo_VERSION_MINOR 0)
   9
  10 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  11 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  13     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  14   endif()
  15 endif()
  16
  17 # Define options to CMake
  18 OPTION(ENABLE_EXPORTALL          "Enable Export all symbols" OFF)
  19 OPTION(ENABLE_DEBUG              "Enable Debug" OFF)
  20 OPTION(ENABLE_TRACE              "Enable Trace" OFF)
  21 OPTION(ENABLE_PKG_CONFIGURE      "Use pkgconfig" ON)
  22 OPTION(INTERNATIONALIZATION      "Internationalization demo string names" ON)
  23
  24 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  25 SET(DEMO_SHARED ${CMAKE_SOURCE_DIR}/../../shared)
  26
  27 SET(PREFIX ${CMAKE_INSTALL_PREFIX})
  28
  29 IF (APPLE)
  30   SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  31 ENDIF()
  32
  33 IF(DEFINED DALI_APP_DIR)
  34   SET(BINDIR ${DALI_APP_DIR})
  35 ELSE()
  36   SET(BINDIR ${PREFIX}/bin)
  37 ENDIF()
  38
  39 IF(DEFINED DALI_APP_RES_DIR)
  40   SET(APP_DATA_RES_DIR ${DALI_APP_RES_DIR})
  41 ELSE()
  42   SET(APP_DATA_RES_DIR ${PREFIX}/share/com.samsung.dali-demo/res)
  43 ENDIF()
  44
  45 MESSAGE( STATUS "CMAKE_BUILD_TYPE: " ${CMAKE_BUILD_TYPE} )
  46
  47 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  48   SET( ENABLE_DEBUG ON )
  49 ENDIF()
  50
  51 IF( ENABLE_DEBUG )
  52   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  53   SET( ENABLE_EXPORTALL ON )
  54 ELSE()
  55   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  56 ENDIF()
  57
  58 SET(RESOURCE_DIR ${ROOT_SRC_DIR}/resources)
  59 SET(LOCAL_IMAGES_DIR ${RESOURCE_DIR}/images)
  60 SET(LOCAL_GAME_DIR ${RESOURCE_DIR}/game)
  61 SET(LOCAL_VIDEOS_DIR ${RESOURCE_DIR}/videos)
  62 SET(LOCAL_MODELS_DIR ${RESOURCE_DIR}/models)
  63 SET(LOCAL_SCRIPTS_DIR ${RESOURCE_DIR}/scripts)
  64 SET(LOCAL_SHADERS_DIR ${RESOURCE_DIR}/shaders)
  65 IF(NOT DEFINED LOCAL_STYLE_DIR)
  66   SET(LOCAL_STYLE_DIR ${RESOURCE_DIR}/style)
  67 ENDIF()
  68
  69 IF(ANDROID)
  70   SET(LOCAL_STYLE_ANDROID_DIR ${RESOURCE_DIR}/style/android)
  71 ENDIF()
  72
  73 SET(IMAGES_DIR ${APP_DATA_RES_DIR}/images/)
  74 SET(GAME_DIR ${APP_DATA_RES_DIR}/game/)
  75 SET(VIDEOS_DIR ${APP_DATA_RES_DIR}/videos/)
  76 SET(MODELS_DIR ${APP_DATA_RES_DIR}/models/)
  77 SET(SCRIPTS_DIR ${APP_DATA_RES_DIR}/scripts/)
  78 SET(SHADERS_DIR ${APP_DATA_RES_DIR}/shaders/)
  79 SET(STYLE_DIR ${APP_DATA_RES_DIR}/style/)
  80
  81 IF(NOT DEFINED LOCALE_DIR)
  82    SET(LOCALE_DIR ${PREFIX}/share/locale)
  83 ENDIF()
  84
  85 IF(DEFINED DALI_DEMO_RES_DIR)
  86   SET(DEMO_IMAGE_DIR \\"${DALI_DEMO_RES_DIR}/images/\\")
  87   SET(DEMO_GAME_DIR \\"${DALI_DEMO_RES_DIR}/game/\\")
  88   SET(DEMO_VIDEO_DIR \\"${DALI_DEMO_RES_DIR}/videos/\\")
  89   SET(DEMO_MODEL_DIR \\"${DALI_DEMO_RES_DIR}/models/\\")
  90   SET(DEMO_SCRIPT_DIR \\"${DALI_DEMO_RES_DIR}/scripts/\\")
  91   SET(DEMO_SHADER_DIR \\"${DALI_DEMO_RES_DIR}/shaders/\\")
  92   SET(DEMO_STYLE_DIR \\"${DALI_DEMO_RES_DIR}/style/\\")
  93   SET(DEMO_THEME_PATH \\"${DALI_DEMO_RES_DIR}/style/demo-theme.json\\")
  94   SET(DEMO_LOCALE_DIR \\"${DALI_DEMO_RES_DIR}/locale/\\")
  95   SET(DEMO_STYLE_IMAGE_DIR \\"${DALI_DEMO_RES_DIR}/style/images\\")
  96 ELSE()
  97   SET(DEMO_GAME_DIR \\"${GAME_DIR}\\")
  98   SET(DEMO_IMAGE_DIR \\"${IMAGES_DIR}\\")
  99   SET(DEMO_VIDEO_DIR \\"${VIDEOS_DIR}\\")
 100   SET(DEMO_MODEL_DIR \\"${MODELS_DIR}\\")
 101   SET(DEMO_SCRIPT_DIR \\"${SCRIPTS_DIR}\\")
 102   SET(DEMO_SHADER_DIR \\"${SHADERS_DIR}\\")
 103   SET(DEMO_STYLE_DIR \\"${STYLE_DIR}\\")
 104   SET(DEMO_THEME_PATH \\"${STYLE_DIR}demo-theme.json\\")
 105   SET(DEMO_LOCALE_DIR \\"${LOCALE_DIR}\\")
 106   SET(DEMO_STYLE_IMAGE_DIR ${STYLE_DIR}/images)
 107 ENDIF()
 108
 109 SET(DEMO_EXAMPLE_BIN \\"${BINDIR}/\\")
 110 SET(DEMO_LANG \\"${LANG}\\")
 111
 112 #For run-time read/write directory
 113 IF(ANDROID)
 114   SET(DEMO_DATA_RW_DIR \\"/data/data/${DALI_DEMO_APP_ID}/\\")
 115   SET(DEMO_DATA_PUBLIC_RW_DIR \\"/sdcard/\\")
 116 ELSE()
 117   SET(DEMO_DATA_RW_DIR \\"/tmp/\\")
 118   SET(DEMO_DATA_PUBLIC_RW_DIR \\"/tmp/\\")
 119 ENDIF()
 120
 121 # Gets all sub-directories of SRC_DIR into the list RESULT, which will first be reset to empty.
 122 MACRO(GET_TREE RESULT SRC_DIR)
 123         FILE(GLOB_RECURSE LOCAL_LIST RELATIVE ${SRC_DIR} "${SRC_DIR}/*")
 124         SET(${RESULT} "/") # N.B. we need the contents of the root directory as well, and we can't have an empty string in a list in CMake.
 125         FOREACH(LOCAL_ENTRY ${LOCAL_LIST})
 126                 GET_FILENAME_COMPONENT(DIR ${LOCAL_ENTRY} DIRECTORY)
 127                 LIST(APPEND ${RESULT} ${DIR})
 128         ENDFOREACH()
 129         LIST(REMOVE_DUPLICATES ${RESULT})
 130 ENDMACRO()
 131
 132 # Installs files from each subdirectory of ROOT specified in TREE, matching FILTER, to DESTINATION,
 133 # while keeping the structure, up to (excluding) ROOT.
 134 MACRO(INSTALL_TREE_FILES ROOT TREE FILTER DESTINATION)
 135         FOREACH(LOCAL_DIR ${TREE})
 136                 SET(SRC_DIR "${ROOT}/${LOCAL_DIR}")
 137                 FILE(GLOB FILES
 138                         LIST_DIRECTORIES false
 139                         RELATIVE ${SRC_DIR} "${SRC_DIR}/${FILTER}")
 140                 FOREACH(LOCAL_FILE ${FILES})
 141                         INSTALL(FILES "${SRC_DIR}/${LOCAL_FILE}" DESTINATION "${DESTINATION}/${LOCAL_DIR}")
 142                 ENDFOREACH()
 143         ENDFOREACH()
 144 ENDMACRO()
 145
 146 GET_TREE(LOCAL_IMAGES_TREE "${LOCAL_IMAGES_DIR}")
 147 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.png" ${IMAGES_DIR})
 148 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.jpg" ${IMAGES_DIR})
 149 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.gif" ${IMAGES_DIR})
 150 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.webp" ${IMAGES_DIR})
 151 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.bmp" ${IMAGES_DIR})
 152 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.ico" ${IMAGES_DIR})
 153 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.wbmp" ${IMAGES_DIR})
 154 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.ktx" ${IMAGES_DIR})
 155 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.astc" ${IMAGES_DIR})
 156 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.svg" ${IMAGES_DIR})
 157 INSTALL_TREE_FILES(${LOCAL_IMAGES_DIR} "${LOCAL_IMAGES_TREE}" "*.json" ${IMAGES_DIR})
 158
 159 FILE(GLOB LOCAL_VIDEOS_LIST RELATIVE "${LOCAL_VIDEOS_DIR}" "${LOCAL_VIDEOS_DIR}/*")
 160 FOREACH(flag ${LOCAL_VIDEOS_LIST})
 161         INSTALL(FILES ${LOCAL_VIDEOS_DIR}/${flag} DESTINATION ${VIDEOS_DIR})
 162 ENDFOREACH(flag)
 163
 164 GET_TREE(LOCAL_MODELS_TREE "${LOCAL_MODELS_DIR}")
 165 INSTALL_TREE_FILES(${LOCAL_MODELS_DIR} "${LOCAL_MODELS_TREE}" "*" ${MODELS_DIR})
 166
 167 FILE(GLOB LOCAL_SCRIPTS_LIST RELATIVE "${LOCAL_SCRIPTS_DIR}" "${LOCAL_SCRIPTS_DIR}/*.json")
 168 FOREACH(flag ${LOCAL_SCRIPTS_LIST})
 169         INSTALL(FILES ${LOCAL_SCRIPTS_DIR}/${flag} DESTINATION ${SCRIPTS_DIR})
 170 ENDFOREACH(flag)
 171
 172 FILE(GLOB LOCAL_SHADERS_LIST RELATIVE "${LOCAL_SHADERS_DIR}" "${LOCAL_SHADERS_DIR}/*")
 173 FOREACH(flag ${LOCAL_SHADERS_LIST})
 174         INSTALL(FILES ${LOCAL_SHADERS_DIR}/${flag} DESTINATION ${SHADERS_DIR})
 175 ENDFOREACH(flag)
 176
 177 FILE(GLOB LOCAL_GAME_LIST RELATIVE "${LOCAL_GAME_DIR}" "${LOCAL_GAME_DIR}/*.*")
 178 FOREACH(flag ${LOCAL_GAME_LIST})
 179         INSTALL(FILES ${LOCAL_GAME_DIR}/${flag} DESTINATION ${GAME_DIR})
 180 ENDFOREACH(flag)
 181
 182 #Create resources location file
 183 CONFIGURE_FILE( resources-location.in ${DEMO_SHARED}/resources-location.cpp )
 184
 185 MESSAGE("Installing from: ${LOCAL_STYLE_DIR}")
 186 FILE(GLOB LOCAL_STYLES_LIST "${LOCAL_STYLE_DIR}/*.json")
 187 FOREACH(flag ${LOCAL_STYLES_LIST})
 188   INSTALL(FILES ${flag} DESTINATION ${STYLE_DIR})
 189 ENDFOREACH(flag)
 190 MESSAGE("Installed ${LOCAL_STYLES_LIST} to ${STYLE_DIR}")
 191
 192 IF(ANDROID)
 193 FILE(GLOB LOCAL_STYLES_ANDROID_LIST "${LOCAL_STYLE_ANDROID_DIR}/*.json")
 194 FOREACH(flag ${LOCAL_STYLES_ANDROID_LIST})
 195   INSTALL(FILES ${flag} DESTINATION ${STYLE_DIR})
 196 ENDFOREACH(flag)
 197 MESSAGE("Installed ${LOCAL_STYLES_ANDROID_LIST} to ${STYLE_DIR}")
 198 ENDIF()
 199
 200 FILE(GLOB LOCAL_STYLE_IMAGES_LIST "${LOCAL_STYLE_DIR}/images/*.png")
 201 FOREACH(flag ${LOCAL_STYLE_IMAGES_LIST})
 202   INSTALL(FILES ${flag} DESTINATION ${STYLE_DIR}/images)
 203 ENDFOREACH(flag)
 204 MESSAGE("Installed style resources ${LOCAL_STYLE_IMAGES_LIST} to ${STYLE_DIR}/images")
 205
 206 IF( ENABLE_PKG_CONFIGURE )
 207   SET(PKG_LIST dali2-core
 208                dali2-adaptor
 209                dali2-toolkit)
 210
 211   INCLUDE(FindPkgConfig)
 212   pkg_check_modules(REQUIRED_PKGS REQUIRED ${PKG_LIST})
 213
 214   FOREACH(flag ${REQUIRED_PKGS_CFLAGS})
 215         SET(REQUIRED_CFLAGS "${REQUIRED_CFLAGS} ${flag}")
 216   ENDFOREACH(flag)
 217
 218   pkg_check_modules(DALI_SCENE_LOADER dali2-scene-loader)
 219   IF( DALI_SCENE_LOADER_FOUND )
 220     FOREACH(flag ${DALI_SCENE_LOADER_CFLAGS})
 221       SET(REQUIRED_CFLAGS "${REQUIRED_CFLAGS} ${flag}")
 222     ENDFOREACH(flag)
 223
 224     SET( REQUIRED_CFLAGS "${REQUIRED_CFLAGS} -DDALI_SCENE_LOADER_AVAILABLE" )
 225
 226     FOREACH(flag ${DALI_SCENE_LOADER_LDFLAGS})
 227       SET(REQUIRED_PKGS_LDFLAGS "${REQUIRED_PKGS_LDFLAGS} ${flag}")
 228     ENDFOREACH(flag)
 229
 230     SET( ENABLE_SCENE_LOADER "ON" )
 231   ENDIF()
 232
 233   # if build as tizen platform, use capi-appfw-app-control
 234   IF( TIZEN )
 235     pkg_check_modules(CAPI_APPFW_APP_CONTROL capi-appfw-app-control)
 236     IF( CAPI_APPFW_APP_CONTROL_FOUND)
 237       FOREACH(flag ${CAPI_APPFW_APP_CONTROL_CFLAGS})
 238         SET(REQUIRED_CFLAGS "${REQUIRED_CFLAGS} ${flag}")
 239       ENDFOREACH(flag)
 240       FOREACH(flag ${CAPI_APPFW_APP_CONTROL_LDFLAGS})
 241         SET(REQUIRED_PKGS_LDFLAGS "${REQUIRED_PKGS_LDFLAGS} ${flag}")
 242       ENDFOREACH(flag)
 243     ENDIF()
 244   ENDIF()
 245 ENDIF()
 246
 247 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
 248
 249 IF( WIN32 OR APPLE ) # WIN32 includes x64 as well according to the cmake doc.
 250   IF ( WIN32 )
 251     FIND_PACKAGE( pthreads REQUIRED )
 252   ENDIF()
 253   FIND_PACKAGE( curl REQUIRED )
 254   FIND_LIBRARY( EXIF_LIBRARY NAMES libexif )
 255
 256   FIND_PACKAGE( png REQUIRED )
 257   FIND_PACKAGE( gif REQUIRED )
 258   FIND_PACKAGE( jpeg REQUIRED )
 259   FIND_LIBRARY( TURBO_JPEG_LIBRARY NAMES turbojpeg )
 260
 261   FIND_PACKAGE( freetype REQUIRED )
 262   FIND_PACKAGE( harfbuzz REQUIRED )
 263   FIND_LIBRARY( FRIBIDI_LIBRARY NAMES fribidi )
 264
 265   FIND_PACKAGE( unofficial-angle REQUIRED )
 266   FIND_PACKAGE( unofficial-cairo REQUIRED )
 267
 268   FIND_PACKAGE( WebP REQUIRED )
 269
 270   IF ( WIN32 )
 271     FIND_LIBRARY( GETOPT_LIBRARY NAMES getopt )
 272     FIND_PACKAGE( dali-windows-dependencies REQUIRED )
 273     FIND_PACKAGE( unofficial-fontconfig REQUIRED )
 274   ENDIF()
 275
 276   FIND_PACKAGE( dali2-core REQUIRED )
 277   FIND_PACKAGE( dali2-adaptor REQUIRED )
 278   FIND_PACKAGE( dali2-toolkit REQUIRED )
 279
 280   FIND_PACKAGE( dali2-scene-loader )
 281
 282   # Set up the include dir
 283   SET( INCLUDE_DIR $ENV{includedir} )
 284   IF( NOT INCLUDE_DIR )
 285     SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 286   ENDIF()
 287   IF( NOT INCLUDE_DIR )
 288     SET( INCLUDE_DIR ${PREFIX}/include )
 289   ENDIF()
 290
 291   SET( LIB_DIR $ENV{libdir} )
 292   IF( NOT LIB_DIR )
 293     SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 294   ENDIF()
 295   IF( NOT LIB_DIR )
 296     SET( LIB_DIR ${PREFIX}/lib )
 297   ENDIF()
 298
 299   SET( REQUIRED_LIBS
 300     CURL::libcurl
 301     ${EXIF_LIBRARY}
 302     ${PNG_LIBRARIES}
 303     ${GIF_LIBRARIES}
 304     JPEG::JPEG
 305     ${TURBO_JPEG_LIBRARY}
 306     Freetype::Freetype
 307     harfbuzz::harfbuzz
 308     ${FRIBIDI_LIBRARY}
 309     unofficial::angle::libEGL
 310     unofficial::angle::libGLESv2
 311     WebP::webp
 312     WebP::webpdemux
 313     dali2-core::dali2-core
 314     dali2-adaptor::dali2-adaptor
 315     dali2-toolkit::dali2-toolkit
 316   )
 317
 318   IF ( WIN32 )
 319     SET( REQUIRED_LIBS
 320       ${REQUIRED_LIBS}
 321       ${GETOPT_LIBRARY}
 322       unofficial::fontconfig::fontconfig
 323       unofficial::cairo::cairo
 324       PThreads4W::PThreads4W
 325       dali-windows-dependencies::dali-windows-dependencies
 326     )
 327   ENDIF()
 328
 329   IF (dali2-scene-loader_FOUND)
 330     SET(REQUIRED_LIBS
 331       ${REQUIRED_LIBS}
 332       dali2-scene-loader::dali2-scene-loader
 333     )
 334     SET( ENABLE_SCENE_LOADER "ON" )
 335   ENDIF()
 336 ELSEIF( UNIX )
 337   SET( REQUIRED_LIBS
 338     ${REQUIRED_PKGS_LDFLAGS}
 339     -pie
 340   )
 341
 342   IF( ANDROID )
 343     SET( REQUIRED_LIBS ${REQUIRED_LIBS} -lGLESv3 )
 344   ELSE()
 345     PKG_CHECK_MODULES( GLESV2 REQUIRED glesv2 )
 346     SET( REQUIRED_LIBS ${REQUIRED_LIBS} ${GLESV2_LIBRARIES} )
 347   ENDIF()
 348 ENDIF()
 349
 350 SET(DALI_DEMO_CFLAGS "-DDEMO_GAME_DIR=${DEMO_GAME_DIR} -DDEMO_IMAGE_DIR=${DEMO_IMAGE_DIR} -DDEMO_VIDEO_DIR=${DEMO_VIDEO_DIR} -DDEMO_MODEL_DIR=${DEMO_MODEL_DIR} -DDEMO_SCRIPT_DIR=${DEMO_SCRIPT_DIR} -DDEMO_SHADER_DIR=${DEMO_SHADER_DIR}  -DDEMO_STYLE_DIR=${DEMO_STYLE_DIR} -DDEMO_THEME_PATH=${DEMO_THEME_PATH} -DDEMO_EXAMPLE_BIN=${DEMO_EXAMPLE_BIN} -DDEMO_LOCALE_DIR=${DEMO_LOCALE_DIR} -DDEMO_LANG=${DEMO_LANG} -DDEMO_DATA_RW_DIR=${DEMO_DATA_RW_DIR} -DDEMO_DATA_PUBLIC_RW_DIR=${DEMO_DATA_PUBLIC_RW_DIR} ")
 351
 352 IF( ENABLE_DEBUG )
 353   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -DDEBUG_ENABLED")
 354 ENDIF()
 355
 356 IF( ENABLE_TRACE )
 357   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -DTRACE_ENABLED")
 358 ENDIF()
 359
 360 IF( ENABLE_SCENE_LOADER )
 361   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -DDALI_SCENE_LOADER_AVAILABLE")
 362 ENDIF()
 363
 364 IF( UNIX )
 365   IF( NOT ${ENABLE_EXPORTALL} )
 366     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
 367   ENDIF()
 368 ENDIF()
 369
 370 ###########################################################################
 371 # Internationalization
 372
 373 IF (UNIX)
 374   SET(PO_DIR ${RESOURCE_DIR}/po)
 375
 376   FILE(GLOB PO_FILES RELATIVE "${PO_DIR}" "${PO_DIR}/*.po")
 377
 378   SET(MSGFMT "msgfmt")
 379   SET(MO_FILES_DIR ${CMAKE_BINARY_DIR}/mo)
 380   FILE(MAKE_DIRECTORY ${MO_FILES_DIR})
 381
 382   FOREACH(PO_FILE ${PO_FILES})
 383         SET(PO_FILE ${PO_DIR}/${PO_FILE})
 384         MESSAGE("PO: ${PO_FILE}")
 385         GET_FILENAME_COMPONENT(ABS_PO_FILE ${PO_FILE} ABSOLUTE)
 386         GET_FILENAME_COMPONENT(lang ${ABS_PO_FILE} NAME_WE)
 387         SET(MO_FILE ${MO_FILES_DIR}/${lang}.mo)
 388         ADD_CUSTOM_COMMAND(OUTPUT ${MO_FILE}
 389                            COMMAND ${MSGFMT} -o ${MO_FILE} ${ABS_PO_FILE}
 390                            DEPENDS ${ABS_PO_FILE})
 391         INSTALL(FILES ${MO_FILE} DESTINATION ${LOCALE_DIR}/${lang}/LC_MESSAGES RENAME ${PROJECT_NAME}.mo)
 392         SET(MO_FILES ${MO_FILES} ${MO_FILE})
 393   ENDFOREACH(PO_FILE)
 394
 395   MESSAGE(".mo files: ${MO_FILES}")
 396   ADD_CUSTOM_TARGET(po ALL DEPENDS ${MO_FILES})
 397 ENDIF()
 398
 399 IF (INTERNATIONALIZATION)
 400   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -DINTERNATIONALIZATION_ENABLED")
 401 ENDIF(INTERNATIONALIZATION)
 402
 403 ###########################################################################
 404
 405 IF( WIN32 )
 406   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 407   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 408   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 409 ELSE()
 410   SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -Wall -fPIE")
 411   # -Werror is disable for clang in dali-adaptor
 412   IF ( NOT ${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" )
 413     SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -Werror")
 414   ENDIF()
 415
 416   IF( NOT ${ENABLE_EXPORTALL} )
 417     SET(DALI_DEMO_CFLAGS "${DALI_DEMO_CFLAGS} -fvisibility=hidden")
 418   ENDIF()
 419 ENDIF()
 420
 421 SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${REQUIRED_CFLAGS} ${DALI_DEMO_CFLAGS}")
 422 SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_C_FLAGS}")
 423
 424 INCLUDE_DIRECTORIES(
 425   ${SYSTEM_INCLUDE_DIR}
 426   ${ROOT_SRC_DIR}
 427   ${VCPKG_INCLUDE_DIR}
 428   ${INCLUDE_DIR}
 429 )
 430
 431 IF(ANDROID)
 432   INCLUDE_DIRECTORIES( ${ANDROID_NDK}/sources/android/native_app_glue )
 433   INCLUDE_DIRECTORIES( ${ANDROID_NDK}/sysroot/usr )
 434   INCLUDE_DIRECTORIES( ${ANDROID_NDK}/sysroot/usr/include/android )
 435   INCLUDE_DIRECTORIES( ${ROOT_SRC_DIR}/build/android/app/src/main/cpp )
 436 ENDIF()
 437
 438 LINK_DIRECTORIES(${LIB_DIR})
 439
 440 ADD_SUBDIRECTORY(demo)
 441 ADD_SUBDIRECTORY(examples)
 442 ADD_SUBDIRECTORY(examples-reel)
 443 ADD_SUBDIRECTORY(tests-reel)
 444 ADD_SUBDIRECTORY(builder)
 445
 446 # Setup CURRENT_BUILD_PLATFORM to use at message
 447 IF(ANDROID)
 448   SET(CURRENT_BUILD_PLATFORM "Android")
 449 ELSEIF(WIN32)
 450   SET(CURRENT_BUILD_PLATFORM "Windows")
 451 ELSEIF(APPLE)
 452   SET(CURRENT_BUILD_PLATFORM "MacOS")
 453 ELSEIF(TIZEN)
 454   SET(CURRENT_BUILD_PLATFORM "Tizen")
 455 ELSE()
 456   SET(CURRENT_BUILD_PLATFORM "Ubuntu")
 457 ENDIF()
 458
 459 MESSAGE( " Folder   DEMO_IMAGE_DIR : [" ${DEMO_IMAGE_DIR} "]" )
 460 MESSAGE( " Folder   DEMO_STYLE_DIR : [" ${DEMO_STYLE_DIR} "]" )
 461 MESSAGE( " Folder  DEMO_SHADER_DIR : [" ${DEMO_SHADER_DIR} "]" )
 462 MESSAGE( " Folder  DEMO_THEME_PATH : [" ${DEMO_THEME_PATH} "]" )
 463 MESSAGE( " Folder    DEMO_GAME_DIR : [" ${DEMO_GAME_DIR} "]" )
 464 MESSAGE( " Folder   DEMO_VIDEO_DIR : [" ${DEMO_VIDEO_DIR} "]" )
 465 MESSAGE( " Folder   DEMO_MODEL_DIR : [" ${DEMO_MODEL_DIR} "]" )
 466 MESSAGE( " Folder  DEMO_SCRIPT_DIR : [" ${DEMO_SCRIPT_DIR} "]" )
 467 MESSAGE( " Folder  DEMO_LOCALE_DIR : [" ${DEMO_LOCALE_DIR} "]" )
 468 MESSAGE( " Folder DEMO_EXAMPLE_BIN : [" ${DEMO_EXAMPLE_BIN} "]" )
 469 MESSAGE( " Folder        DEMO_LANG : [" ${DEMO_LANG} "]" )
 470 MESSAGE( " Current Build Platform  : [" ${CURRENT_BUILD_PLATFORM} "]" )
 471 MESSAGE( " Scene Loader Enabled    : [" ${ENABLE_SCENE_LOADER} "]" )