build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 0)
  12 SET(${name}_VERSION_PATCH 0)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  25
  26 # Set up compiler definitions
  27
  28 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  29   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  30   SET( ENABLE_DEBUG ON )
  31 ELSE()
  32   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  33 ENDIF()
  34
  35 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  36
  37 IF("${ARCH}" STREQUAL "arm")
  38   ADD_DEFINITIONS("-DTARGET")
  39 ENDIF("${ARCH}" STREQUAL "arm")
  40
  41 IF( ENABLE_DEBUG )
  42   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  43   SET( ENABLE_EXPORTALL ON )
  44 ENDIF( ENABLE_DEBUG )
  45
  46 IF( NOT ${ENABLE_EXPORTALL} )
  47   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  48 ENDIF( NOT ${ENABLE_EXPORTALL} )
  49
  50 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  51   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  52 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  53
  54 IF( ENABLE_LOCK_BACKTRACE )
  55   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  56 ENDIF( ENABLE_LOCK_BACKTRACE )
  57
  58 # Deployment folder should come from spec file or command line:
  59 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  60 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  61
  62 # from root/build/tizen, get back to root
  63 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
  64
  65 # Make sure the path is absolute
  66 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  67
  68 # Set up the include dir
  69 SET( INCLUDE_DIR $ENV{includedir} )
  70 IF( NOT INCLUDE_DIR )
  71   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  72 ENDIF()
  73 IF( NOT INCLUDE_DIR )
  74   SET( INCLUDE_DIR ${PREFIX}/include )
  75 ENDIF()
  76
  77 # Set up the lib dir
  78 SET( LIB_DIR $ENV{libdir} )
  79 IF( NOT LIB_DIR )
  80   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  81 ENDIF()
  82 IF( NOT LIB_DIR )
  83   SET( LIB_DIR ${PREFIX}/lib )
  84 ENDIF()
  85
  86 # Configure the pkg-config file
  87 # Requires the following variables to be setup:
  88 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  89 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
  90 SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali-core.pc )
  91 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
  92
  93 # Set up compiler flags and warnings
  94 ADD_COMPILE_OPTIONS( -std=c++11 )
  95 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  96
  97 # TODO: Clang is a lot more strict with warnings, we should address
  98 # those issues at some point.
  99 IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 100   ADD_COMPILE_OPTIONS( -Werror )
 101 ENDIF()
 102
 103 ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
 104
 105 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 106   ADD_COMPILE_OPTIONS( --coverage )
 107   SET(ENABLE_COVERAGE ON)
 108   SET(COVERAGE --coverage)
 109 ENDIF()
 110
 111 IF( ENABLE_TRACE )
 112   ADD_DEFINITIONS("-DTRACE_ENABLED")
 113 ENDIF()
 114
 115
 116 INCLUDE_DIRECTORIES(
 117   ${ROOT_SRC_DIR}
 118 )
 119
 120 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 121 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 122
 123 SET(SOURCES "")
 124
 125 # could use INCLUDE to get the source lists a different way;
 126 # would then need to specify a build folder somehow...
 127 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 128 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 129 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 130 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 131 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 132
 133 SET(LIBTYPE SHARED)
 134 IF(DEFINED STATIC)
 135   SET(LIBTYPE STATIC)
 136 ENDIF()
 137
 138 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 139
 140 # pthread required due to gcc issue
 141 FIND_LIBRARY(PTHREAD pthread)
 142 IF(PTHREAD)
 143   SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 144 ENDIF()
 145
 146 TARGET_LINK_LIBRARIES( ${name}
 147   ${OPTIONAL_LIBS}
 148   ${COVERAGE}
 149 )
 150
 151 SET_TARGET_PROPERTIES( ${name}
 152   PROPERTIES
 153   VERSION ${DALI_VERSION}
 154   SOVERSION ${${name}_VERSION_MAJOR}
 155   CLEAN_DIRECT_OUPUT 1
 156 )
 157
 158 # Install the library so file and symlinks
 159 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 160
 161 # Install the pkg-config file
 162 INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 163
 164 # macro for installing headers by replacing prefix. (TODO, investigate
 165 # if there is a CMAKE way of doing this automatically)
 166 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 167   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 168   FOREACH(HEADER ${${HEADER_LIST}})
 169     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 170     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 171     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 172   ENDFOREACH(HEADER)
 173 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 174
 175 # Install headers using lists defined by ADD_SUBDIRECTORY
 176 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 177 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 178 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 179 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 180
 181 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 182 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 183 # target names duplication with other DALi modules.
 184 IF( UNIX )
 185   FIND_PROGRAM( LCOV_BIN "lcov" )
 186   IF( LCOV_BIN )
 187
 188     # Define custom rules for coverage
 189     SET(COVERAGE_DIR .cov)
 190     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 191
 192     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 193     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 194     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 195     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 196     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 197       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 198     ENDIF()
 199
 200     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 201
 202     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 203       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 204
 205     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 206       DEPENDS cov_data )
 207
 208     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 209
 210     # Define custom rule for distclean
 211     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 212     ADD_CUSTOM_COMMAND(
 213           DEPENDS ${DALI_CORE_PREFIX}clean
 214           COMMENT "distribution clean"
 215           COMMAND find
 216           ARGS    .
 217           -not -name config.cmake -and \(
 218           -name tester.c -or
 219           -name Testing -or
 220           -name CMakeFiles -or
 221           -name doc -or
 222           -name cmake.depends -or
 223           -name cmake.check_depends -or
 224           -name CMakeCache.txt -or
 225           -name cmake.check_cache -or
 226           -name *.cmake -or
 227           -name Makefile -or
 228           -name core -or
 229           -name core.* -or
 230           -name gmon.out -or
 231           -name install_manifest.txt -or
 232           -name *.pc -or
 233           -name *.gcov -or
 234           -name *.gcno -or
 235           -name *.gcda -or
 236           -name *~ -or
 237           -name libdali*.so* \)
 238           | grep -v TC | xargs rm -rf
 239           TARGET  ${DALI_CORE_PREFIX}distclean
 240           VERBATIM
 241           )
 242
 243   ENDIF( LCOV_BIN )
 244 ENDIF( UNIX )
 245
 246 # Linker Test
 247 SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 248 SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 249 SET( LINKER_TEST_SOURCES
 250   linker-test.cpp
 251   ${DALI_TEST_SUITE_DIR}/test-application.cpp
 252   ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 253   ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 254   ${DALI_TEST_SUITE_DIR}/test-render-surface.cpp
 255   ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 256   ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 257   ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 258 )
 259 ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 260 TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 261 TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 262
 263 # Configuration Messages
 264 MESSAGE( STATUS "Configuration:\n" )
 265 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 266 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 267 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 268 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 269 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 270 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 271 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 272 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 273 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 274 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 275 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )