build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-core")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 17)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  23
  24 SET(DALI_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27
  28 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  29 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  30 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  31 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  32 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  33 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  34 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  35 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  36
  37 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  38   SET(dali-windows-dependencies_DIR "${CMAKE_INSTALL_PREFIX}/share/dali-windows-dependencies")
  39   FIND_PACKAGE( dali-windows-dependencies REQUIRED )
  40 ENDIF()
  41
  42 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  43
  44 # Set up compiler definitions
  45
  46 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  47   SET( ENABLE_DEBUG ON )
  48 ENDIF()
  49
  50 IF( ENABLE_DEBUG )
  51   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  52   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  53   SET( ENABLE_EXPORTALL ON )
  54 ELSE()
  55   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  56 ENDIF()
  57
  58 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  59
  60   IF(NOT DEFINED STATIC)
  61     ADD_DEFINITIONS( "-DBUILDING_DALI_CORE" )
  62   ENDIF()
  63
  64 ELSEIF( UNIX )
  65
  66   IF( NOT ${ENABLE_EXPORTALL} )
  67     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
  68   ENDIF()
  69
  70   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  71
  72   IF("${ARCH}" STREQUAL "arm")
  73     ADD_DEFINITIONS("-DTARGET")
  74   ENDIF()
  75
  76 ENDIF()
  77
  78 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  79   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  80 ENDIF()
  81
  82 IF( ENABLE_LOCK_BACKTRACE )
  83   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  84 ENDIF()
  85
  86 IF( ENABLE_TRACE )
  87   ADD_DEFINITIONS("-DTRACE_ENABLED")
  88 ENDIF()
  89
  90 # Deployment folder should come from spec file or command line:
  91 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  92 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  93
  94 # from root/build/tizen, get back to root
  95 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
  96
  97 # Make sure the path is absolute
  98 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  99
 100 # Set up the include dir
 101 SET( INCLUDE_DIR $ENV{includedir} )
 102 IF( NOT INCLUDE_DIR )
 103   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 104 ENDIF()
 105 IF( NOT INCLUDE_DIR )
 106   SET( INCLUDE_DIR ${PREFIX}/include )
 107 ENDIF()
 108
 109 # Set up the lib dir
 110 SET( LIB_DIR $ENV{libdir} )
 111 IF( NOT LIB_DIR )
 112   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 113 ENDIF()
 114 IF( NOT LIB_DIR )
 115   SET( LIB_DIR ${PREFIX}/lib )
 116 ENDIF()
 117
 118 # Set up the bin dir
 119 SET( BIN_DIR $ENV{bindir} )
 120 IF( NOT BIN_DIR )
 121   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 122 ENDIF()
 123 IF( NOT BIN_DIR )
 124   SET( BIN_DIR ${PREFIX}/bin )
 125 ENDIF()
 126
 127 IF( ENABLE_PKG_CONFIGURE )
 128   # Configure the pkg-config file
 129   # Requires the following variables to be setup:
 130   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 131   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 132   SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-core.pc )
 133   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 134 ENDIF()
 135
 136 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 137
 138   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 139   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 140   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 141
 142 ELSEIF( UNIX )
 143
 144   INCLUDE(CheckCXXCompilerFlag)
 145
 146   # Set up compiler flags and warnings
 147   ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
 148
 149   # TODO: Clang is a lot more strict with warnings, we should address
 150   # those issues at some point.
 151   IF( NOT ${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" )
 152     ADD_COMPILE_OPTIONS( -Werror )
 153   ENDIF()
 154
 155   ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
 156   CHECK_CXX_COMPILER_FLAG(-Wno-class-memaccess HAVE_NO_CLASS_MEMACCESS)
 157   IF (HAVE_NO_CLASS_MEMACCESS)
 158     ADD_COMPILE_OPTIONS( -Wno-class-memaccess )
 159   ENDIF()
 160
 161   CHECK_CXX_COMPILER_FLAG(-Wno-cast-function-type HAVE_NO_CAST_FUNCTION_TYPE)
 162   IF (HAVE_NO_CAST_FUNCTION_TYPE)
 163     ADD_COMPILE_OPTIONS( -Wno-cast-function-type )
 164   ENDIF()
 165
 166   CHECK_CXX_COMPILER_FLAG(-Wno-string-plus-int HAVE_NO_STRING_PLUS_INT)
 167   IF (HAVE_NO_STRING_PLUS_INT)
 168     ADD_COMPILE_OPTIONS( -Wno-string-plus-int )
 169   ENDIF()
 170   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 171     ADD_COMPILE_OPTIONS( --coverage )
 172     SET(ENABLE_COVERAGE ON)
 173     SET(COVERAGE --coverage)
 174   ENDIF()
 175
 176   IF( NOT ${ENABLE_EXPORTALL} )
 177     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 178   ENDIF()
 179
 180 ENDIF()
 181
 182 INCLUDE_DIRECTORIES(
 183   ${ROOT_SRC_DIR}
 184   ${VCPKG_INCLUDE_DIR}
 185   ${INCLUDE_DIR}
 186 )
 187
 188 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 189 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 190
 191 SET(SOURCES "")
 192
 193 # could use INCLUDE to get the source lists a different way;
 194 # would then need to specify a build folder somehow...
 195 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 196 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 197 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 198 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 199 INCLUDE( ${ROOT_SRC_DIR}/dali/graphics-api/file.list )
 200 IF( WIN32 )
 201   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-windows.list )
 202 ELSEIF( UNIX )
 203   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-unix.list )
 204 ENDIF()
 205 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 206
 207 SET(LIBTYPE SHARED)
 208 IF(DEFINED STATIC)
 209   SET(LIBTYPE STATIC)
 210 ENDIF()
 211
 212 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 213
 214 # pthread required due to gcc issue
 215 IF( WIN32 )
 216     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} dali-windows-dependencies::dali-windows-dependencies )
 217 ELSEIF( UNIX )
 218   FIND_LIBRARY(PTHREAD pthread)
 219   IF(PTHREAD)
 220     SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 221   ENDIF()
 222 ENDIF()
 223
 224 TARGET_LINK_LIBRARIES( ${name}
 225   ${OPTIONAL_LIBS}
 226   ${COVERAGE}
 227 )
 228
 229 SET_TARGET_PROPERTIES( ${name}
 230   PROPERTIES
 231   VERSION ${DALI_VERSION}
 232   SOVERSION ${${name}_VERSION_MAJOR}
 233   CLEAN_DIRECT_OUPUT 1
 234 )
 235
 236 IF( INSTALL_CMAKE_MODULES )
 237   IF( ENABLE_DEBUG )
 238     SET( BIN_DIR "${BIN_DIR}/debug" )
 239     SET( LIB_DIR "${LIB_DIR}/debug" )
 240   ENDIF()
 241
 242   # Install the library files.
 243   INSTALL( TARGETS ${name}
 244     EXPORT ${name}-targets
 245     LIBRARY DESTINATION ${LIB_DIR}
 246     ARCHIVE DESTINATION ${LIB_DIR}
 247     RUNTIME DESTINATION ${BIN_DIR}
 248   )
 249
 250   # Install the cmake modules.
 251   INSTALL(
 252     EXPORT ${name}-targets
 253     NAMESPACE ${name}::
 254     FILE ${name}-targets.cmake
 255     DESTINATION share/${name}
 256   )
 257
 258   FILE( WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 259     include(CMakeFindDependencyMacro)
 260     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 261   ")
 262   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name} )
 263
 264   # Install the pdb file.
 265   IF( ENABLE_DEBUG AND WIN32 )
 266     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 267   ENDIF()
 268 ELSE()
 269   # Install the library so file and symlinks.
 270   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 271 ENDIF()
 272
 273
 274 # Install the pkg-config file
 275 IF( ENABLE_PKG_CONFIGURE )
 276   INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 277 ENDIF()
 278
 279 # macro for installing headers by replacing prefix. (TODO, investigate
 280 # if there is a CMAKE way of doing this automatically)
 281 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 282   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 283   FOREACH(HEADER ${${HEADER_LIST}})
 284     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 285     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 286     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 287   ENDFOREACH(HEADER)
 288 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 289
 290 # Install headers using lists defined by ADD_SUBDIRECTORY
 291 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 292 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 293 INSTALL_HEADERS_WITH_DIRECTORY(GRAPHICS_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 294 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 295 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 296
 297 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 298 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 299 # target names duplication with other DALi modules.
 300 IF( ENABLE_COVERAGE )
 301   FIND_PROGRAM( LCOV_BIN "lcov" )
 302   IF( LCOV_BIN )
 303
 304     # Define custom rules for coverage
 305     SET(COVERAGE_DIR .cov)
 306     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 307
 308     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 309     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 310     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 311     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 312     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 313       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 314     ENDIF()
 315
 316     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 317
 318     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 319       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 320
 321     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 322       DEPENDS cov_data )
 323
 324     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 325
 326     # Define custom rule for distclean
 327     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 328     ADD_CUSTOM_COMMAND(
 329           DEPENDS ${DALI_CORE_PREFIX}clean
 330           COMMENT "distribution clean"
 331           COMMAND find
 332           ARGS    .
 333           -not -name config.cmake -and \(
 334           -name tester.c -or
 335           -name Testing -or
 336           -name CMakeFiles -or
 337           -name doc -or
 338           -name cmake.depends -or
 339           -name cmake.check_depends -or
 340           -name CMakeCache.txt -or
 341           -name cmake.check_cache -or
 342           -name *.cmake -or
 343           -name Makefile -or
 344           -name core -or
 345           -name core.* -or
 346           -name gmon.out -or
 347           -name install_manifest.txt -or
 348           -name *.pc -or
 349           -name *.gcov -or
 350           -name *.gcno -or
 351           -name *.gcda -or
 352           -name *~ -or
 353           -name libdali*.so* \)
 354           | grep -v TC | xargs rm -rf
 355           TARGET  ${DALI_CORE_PREFIX}distclean
 356 VERBATIM
 357           )
 358
 359   ENDIF( LCOV_BIN )
 360 ENDIF()
 361
 362 IF( ENABLE_LINK_TEST )
 363   # Linker Test
 364   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 365   SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 366   SET( LINKER_TEST_SOURCES
 367     linker-test.cpp
 368     ${DALI_TEST_SUITE_DIR}/test-application.cpp
 369     ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 370     ${DALI_TEST_SUITE_DIR}/test-graphics-sync-impl.cpp
 371     ${DALI_TEST_SUITE_DIR}/test-graphics-sync-object.cpp
 372     ${DALI_TEST_SUITE_DIR}/test-graphics-buffer.cpp
 373     ${DALI_TEST_SUITE_DIR}/test-graphics-command-buffer.cpp
 374     ${DALI_TEST_SUITE_DIR}/test-graphics-controller.cpp
 375     ${DALI_TEST_SUITE_DIR}/test-graphics-framebuffer.cpp
 376     ${DALI_TEST_SUITE_DIR}/test-graphics-pipeline.cpp
 377     ${DALI_TEST_SUITE_DIR}/test-graphics-program.cpp
 378     ${DALI_TEST_SUITE_DIR}/test-graphics-reflection.cpp
 379     ${DALI_TEST_SUITE_DIR}/test-graphics-sampler.cpp
 380     ${DALI_TEST_SUITE_DIR}/test-graphics-shader.cpp
 381     ${DALI_TEST_SUITE_DIR}/test-graphics-texture.cpp
 382     ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 383     ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 384     ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 385   )
 386   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 387   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 388   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 389 ENDIF()
 390
 391 # Configuration Messages
 392 MESSAGE( STATUS "Configuration:\n" )
 393 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 394 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 395 MESSAGE( STATUS "Bin Dir:               " ${BIN_DIR} )
 396 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 397 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 398 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 399 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 400 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 401 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 402 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 403 MESSAGE( STATUS "Use pkg configure:     " ${ENABLE_PKG_CONFIGURE} )
 404 MESSAGE( STATUS "Enable link test:      " ${ENABLE_LINK_TEST} )
 405 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 406 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )