build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 0)
  12 SET(${name}_VERSION_PATCH 0)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  25
  26 # Set up compiler definitions
  27
  28 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  29   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  30   SET( ENABLE_DEBUG ON )
  31 ELSE()
  32   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  33 ENDIF()
  34
  35 ADD_DEFINITIONS(-DPLATFORM_TIZEN -DDALI_COMPILATION)
  36 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  37
  38 IF("${ARCH}" STREQUAL "arm")
  39   ADD_DEFINITIONS("-DTARGET")
  40 ENDIF("${ARCH}" STREQUAL "arm")
  41
  42 IF( ENABLE_DEBUG )
  43   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  44   SET( ENABLE_EXPORTALL ON )
  45 ENDIF( ENABLE_DEBUG )
  46
  47 IF( NOT ${ENABLE_EXPORTALL} )
  48   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  49 ENDIF( NOT ${ENABLE_EXPORTALL} )
  50
  51 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  52   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  53 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  54
  55 IF( ENABLE_LOCK_BACKTRACE )
  56   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  57 ENDIF( ENABLE_LOCK_BACKTRACE )
  58
  59 # Deployment folder should come from spec file or command line:
  60 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  61 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  62
  63 # from root/build/tizen, get back to root
  64 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  65
  66 # Make sure the path is absolute
  67 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  68
  69 # Set up the include dir
  70 SET( INCLUDE_DIR $ENV{includedir} )
  71 IF( NOT INCLUDE_DIR )
  72   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  73 ENDIF()
  74 IF( NOT INCLUDE_DIR )
  75   SET( INCLUDE_DIR ${PREFIX}/include )
  76 ENDIF()
  77
  78 # Set up the lib dir
  79 SET( LIB_DIR $ENV{libdir} )
  80 IF( NOT LIB_DIR )
  81   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  82 ENDIF()
  83 IF( NOT LIB_DIR )
  84   SET( LIB_DIR ${PREFIX}/lib )
  85 ENDIF()
  86
  87 # Configure the pkg-config file
  88 # Requires the following variables to be setup:
  89 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  90 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
  91 SET( CORE_PKG_CFG_FILE dali-core.pc )
  92 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
  93
  94 # Set up compiler flags and warnings
  95 #ADD_COMPILE_OPTIONS( -std=c++11 -ggdb )
  96 ADD_COMPILE_OPTIONS( -std=c++11 -gdwarf-4 )
  97 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  98
  99 # TODO: Clang is a lot more strict with warnings, we should address
 100 # those issues at some point.
 101 IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 102   ADD_COMPILE_OPTIONS( -Werror )
 103 ENDIF()
 104
 105 ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
 106
 107 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 108   ADD_COMPILE_OPTIONS( --coverage )
 109   SET(ENABLE_COVERAGE ON)
 110   SET(COVERAGE --coverage)
 111 ENDIF()
 112
 113 IF( ENABLE_TRACE )
 114   ADD_DEFINITIONS("-DTRACE_ENABLED")
 115 ENDIF()
 116
 117
 118 INCLUDE_DIRECTORIES(
 119   ${ROOT_SRC_DIR}
 120 )
 121
 122 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 123 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 124
 125 SET(SOURCES "")
 126
 127 # could use INCLUDE to get the source lists a different way;
 128 # would then need to specify a build folder somehow...
 129 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 130 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 131 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 132 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 133 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 134
 135 SET(LIBTYPE SHARED)
 136 IF(DEFINED STATIC)
 137   SET(LIBTYPE STATIC)
 138 ENDIF()
 139
 140 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 141
 142 TARGET_LINK_LIBRARIES( ${name}
 143   -lpthread
 144   ${COVERAGE}
 145 )
 146
 147 SET_TARGET_PROPERTIES( ${name}
 148   PROPERTIES
 149   VERSION ${DALI_VERSION}
 150   SOVERSION ${${name}_VERSION_MAJOR}
 151   CLEAN_DIRECT_OUPUT 1
 152 )
 153
 154 # Install the library so file and symlinks
 155 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 156
 157 # Install the pkg-config file
 158 INSTALL( FILES ${CMAKE_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 159
 160 # macro for installing headers by replacing prefix. (TODO, investigate
 161 # if there is a CMAKE way of doing this automatically)
 162 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 163   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 164   FOREACH(HEADER ${${HEADER_LIST}})
 165     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 166     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 167     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 168   ENDFOREACH(HEADER)
 169 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 170
 171 # Install headers using lists defined by ADD_SUBDIRECTORY
 172 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 173 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 174 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 175 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 176
 177 IF( UNIX )
 178   FIND_PROGRAM( LCOV_BIN "lcov" )
 179   IF( LCOV_BIN )
 180
 181     # Define custom rules for coverage
 182     SET(COVERAGE_DIR .cov)
 183     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 184
 185     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 186     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 187     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 188     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 189     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 190       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 191     ENDIF()
 192
 193     ADD_CUSTOM_TARGET( rename_cov_data ./rename-cov-data )
 194
 195     ADD_CUSTOM_TARGET( cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 196       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 197
 198     ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 199       DEPENDS cov_data )
 200
 201     ADD_CUSTOM_TARGET( reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 202
 203     # Define custom rule for distclean
 204     ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 205     ADD_CUSTOM_COMMAND(
 206           DEPENDS clean
 207           COMMENT "distribution clean"
 208           COMMAND find
 209           ARGS    .
 210           -not -name config.cmake -and \(
 211           -name tester.c -or
 212           -name Testing -or
 213           -name CMakeFiles -or
 214           -name doc -or
 215           -name cmake.depends -or
 216           -name cmake.check_depends -or
 217           -name CMakeCache.txt -or
 218           -name cmake.check_cache -or
 219           -name *.cmake -or
 220           -name Makefile -or
 221           -name core -or
 222           -name core.* -or
 223           -name gmon.out -or
 224           -name install_manifest.txt -or
 225           -name *.pc -or
 226           -name *.gcov -or
 227           -name *.gcno -or
 228           -name *.gcda -or
 229           -name *~ -or
 230           -name libdali*.so* \)
 231           | grep -v TC | xargs rm -rf
 232           TARGET  distclean
 233           VERBATIM
 234           )
 235
 236   ENDIF( LCOV_BIN )
 237 ENDIF( UNIX )
 238
 239 # Linker Test
 240 SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 241 SET( LINKER_TEST_NAME linker-test )
 242 SET( LINKER_TEST_SOURCES
 243   linker-test.cpp
 244   ${DALI_TEST_SUITE_DIR}/test-application.cpp
 245   ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 246   ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 247   ${DALI_TEST_SUITE_DIR}/test-render-surface.cpp
 248   ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 249   ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 250   ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 251 )
 252 ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 253 TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 254 TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 255
 256 # Configuration Messages
 257 MESSAGE( STATUS "Configuration:\n" )
 258 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 259 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 260 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 261 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 262 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 263 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 264 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 265 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 266 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 267 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 268 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )