build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 # API VERSION (Not DALi release version)
  10 SET(${name}_VERSION_MAJOR 0)
  11 SET(${name}_VERSION_MINOR 0)
  12 SET(${name}_VERSION_PATCH 0)
  13 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  14
  15 SET(DALI_VERSION ${${name}_VERSION} )
  16
  17 # Define options to CMake
  18
  19 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  20 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  21 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  22 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  23 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  24 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  25
  26 # Set up compiler definitions
  27
  28 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  29   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  30   SET( ENABLE_DEBUG ON )
  31 ELSE()
  32   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  33 ENDIF()
  34
  35 ADD_DEFINITIONS(-DPLATFORM_TIZEN -DDALI_COMPILATION)
  36 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  37
  38 IF("${ARCH}" STREQUAL "arm")
  39   ADD_DEFINITIONS("-DTARGET")
  40 ENDIF("${ARCH}" STREQUAL "arm")
  41
  42 IF( ENABLE_DEBUG )
  43   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  44   SET( ENABLE_EXPORTALL ON )
  45 ENDIF( ENABLE_DEBUG )
  46
  47 IF( NOT ${ENABLE_EXPORTALL} )
  48   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  49 ENDIF( NOT ${ENABLE_EXPORTALL} )
  50
  51 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  52   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  53 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  54
  55 IF( ENABLE_LOCK_BACKTRACE )
  56   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  57 ENDIF( ENABLE_LOCK_BACKTRACE )
  58
  59 # Deployment folder should come from spec file or command line:
  60 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  61 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  62
  63 # from root/build/tizen, get back to root
  64 SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  65
  66 # Make sure the path is absolute
  67 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  68
  69 # Set up the include dir
  70 SET( INCLUDE_DIR $ENV{includedir} )
  71 IF( NOT INCLUDE_DIR )
  72   SET( INCLUDE_DIR ${PREFIX}/include )
  73 ENDIF()
  74
  75 # Set up the lib dir
  76 SET( LIB_DIR $ENV{libdir} )
  77 IF( NOT LIB_DIR )
  78   SET( LIB_DIR ${PREFIX}/lib )
  79 ENDIF()
  80
  81 # Configure the pkg-config file
  82 # Requires the following variables to be setup:
  83 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  84 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
  85 SET( CORE_PKG_CFG_FILE dali-core.pc )
  86 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
  87
  88 # Set up compiler flags and warnings
  89 #ADD_COMPILE_OPTIONS( -std=c++11 -ggdb )
  90 ADD_COMPILE_OPTIONS( -std=c++11 -gdwarf-4 )
  91 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  92
  93 # TODO: Clang is a lot more strict with warnings, we should address
  94 # those issues at some point.
  95 IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
  96   ADD_COMPILE_OPTIONS( -Werror )
  97 ENDIF()
  98
  99 ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
 100
 101 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 102   ADD_COMPILE_OPTIONS( --coverage )
 103   SET(ENABLE_COVERAGE ON)
 104   SET(COVERAGE --coverage)
 105 ENDIF()
 106
 107 IF( ENABLE_TRACE )
 108   ADD_DEFINITIONS("-DTRACE_ENABLED")
 109 ENDIF()
 110
 111
 112 INCLUDE_DIRECTORIES(
 113   ${ROOT_SRC_DIR}
 114 )
 115
 116 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 117 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 118
 119 SET(SOURCES "")
 120
 121 # could use INCLUDE to get the source lists a different way;
 122 # would then need to specify a build folder somehow...
 123 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 124 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 125 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 126 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 127 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 128
 129 SET(LIBTYPE SHARED)
 130 IF(DEFINED STATIC)
 131   SET(LIBTYPE STATIC)
 132 ENDIF()
 133
 134 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 135
 136 TARGET_LINK_LIBRARIES( ${name}
 137   -lpthread
 138   ${COVERAGE}
 139 )
 140
 141 SET_TARGET_PROPERTIES( ${name}
 142   PROPERTIES
 143   VERSION ${DALI_VERSION}
 144   SOVERSION ${${name}_VERSION_MAJOR}
 145   CLEAN_DIRECT_OUPUT 1
 146 )
 147
 148 # Install the library so file and symlinks
 149 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 150
 151 # Install the pkg-config file
 152 INSTALL( FILES ${CMAKE_BINARY_DIR}/${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 153
 154 # macro for installing headers by replacing prefix. (TODO, investigate
 155 # if there is a CMAKE way of doing this automatically)
 156 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 157   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 158   FOREACH(HEADER ${${HEADER_LIST}})
 159     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 160     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 161     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 162   ENDFOREACH(HEADER)
 163 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 164
 165 # Install headers using lists defined by ADD_SUBDIRECTORY
 166 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 167 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 168 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 169 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 170
 171 IF( UNIX )
 172   FIND_PROGRAM( LCOV_BIN "lcov" )
 173   IF( LCOV_BIN )
 174
 175     # Define custom rules for coverage
 176     SET(COVERAGE_DIR .cov)
 177     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 178
 179     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 180     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 181     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 182     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 183     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 184       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 185     ENDIF()
 186
 187     ADD_CUSTOM_TARGET( rename_cov_data ./rename-cov-data )
 188
 189     ADD_CUSTOM_TARGET( cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 190       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 191
 192     ADD_CUSTOM_TARGET( coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 193       DEPENDS cov_data )
 194
 195     ADD_CUSTOM_TARGET( reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 196
 197     # Define custom rule for distclean
 198     ADD_CUSTOM_TARGET( distclean @echo cleaning for source distribution )
 199     ADD_CUSTOM_COMMAND(
 200           DEPENDS clean
 201           COMMENT "distribution clean"
 202           COMMAND find
 203           ARGS    .
 204           -not -name config.cmake -and \(
 205           -name tester.c -or
 206           -name Testing -or
 207           -name CMakeFiles -or
 208           -name doc -or
 209           -name cmake.depends -or
 210           -name cmake.check_depends -or
 211           -name CMakeCache.txt -or
 212           -name cmake.check_cache -or
 213           -name *.cmake -or
 214           -name Makefile -or
 215           -name core -or
 216           -name core.* -or
 217           -name gmon.out -or
 218           -name install_manifest.txt -or
 219           -name *.pc -or
 220           -name *.gcov -or
 221           -name *.gcno -or
 222           -name *.gcda -or
 223           -name *~ -or
 224           -name libdali*.so* \)
 225           | grep -v TC | xargs rm -rf
 226           TARGET  distclean
 227           VERBATIM
 228           )
 229
 230   ENDIF( LCOV_BIN )
 231 ENDIF( UNIX )
 232
 233 # Linker Test
 234 SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 235 SET( LINKER_TEST_NAME linker-test )
 236 SET( LINKER_TEST_SOURCES
 237   linker-test.cpp
 238   ${DALI_TEST_SUITE_DIR}/test-application.cpp
 239   ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 240   ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 241   ${DALI_TEST_SUITE_DIR}/test-render-surface.cpp
 242   ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 243   ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 244   ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 245 )
 246 ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 247 TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 248 TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 249
 250 # Configuration Messages
 251 MESSAGE( STATUS "Configuration:\n" )
 252 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 253 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 254 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 255 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 256 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 257 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 258 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 259 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 260 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 261 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 262 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )