build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-core")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 17)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  23
  24 SET(DALI_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27
  28 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  29 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  30 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  31 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  32 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  33 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  34 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  35 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  36
  37 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  38   FIND_PACKAGE( dali-windows-dependencies REQUIRED )
  39 ENDIF()
  40
  41 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  42
  43 # Set up compiler definitions
  44
  45 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  46   SET( ENABLE_DEBUG ON )
  47 ENDIF()
  48
  49 IF( ENABLE_DEBUG )
  50   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  51   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  52   SET( ENABLE_EXPORTALL ON )
  53 ELSE()
  54   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  55 ENDIF()
  56
  57 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  58
  59   IF(NOT DEFINED STATIC)
  60     ADD_DEFINITIONS( "-DBUILDING_DALI_CORE" )
  61   ENDIF()
  62
  63 ELSEIF( UNIX )
  64
  65   IF( NOT ${ENABLE_EXPORTALL} )
  66     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
  67   ENDIF()
  68
  69   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  70
  71   IF("${ARCH}" STREQUAL "arm")
  72     ADD_DEFINITIONS("-DTARGET")
  73   ENDIF()
  74
  75 ENDIF()
  76
  77 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  78   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  79 ENDIF()
  80
  81 IF( ENABLE_LOCK_BACKTRACE )
  82   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  83 ENDIF()
  84
  85 IF( ENABLE_TRACE )
  86   ADD_DEFINITIONS("-DTRACE_ENABLED")
  87 ENDIF()
  88
  89 # Deployment folder should come from spec file or command line:
  90 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  91 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  92
  93 # from root/build/tizen, get back to root
  94 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
  95
  96 # Make sure the path is absolute
  97 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  98
  99 # Set up the include dir
 100 SET( INCLUDE_DIR $ENV{includedir} )
 101 IF( NOT INCLUDE_DIR )
 102   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 103 ENDIF()
 104 IF( NOT INCLUDE_DIR )
 105   SET( INCLUDE_DIR ${PREFIX}/include )
 106 ENDIF()
 107
 108 # Set up the lib dir
 109 SET( LIB_DIR $ENV{libdir} )
 110 IF( NOT LIB_DIR )
 111   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 112 ENDIF()
 113 IF( NOT LIB_DIR )
 114   SET( LIB_DIR ${PREFIX}/lib )
 115 ENDIF()
 116
 117 # Set up the bin dir
 118 SET( BIN_DIR $ENV{bindir} )
 119 IF( NOT BIN_DIR )
 120   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 121 ENDIF()
 122 IF( NOT BIN_DIR )
 123   SET( BIN_DIR ${PREFIX}/bin )
 124 ENDIF()
 125
 126 IF( ENABLE_PKG_CONFIGURE )
 127   # Configure the pkg-config file
 128   # Requires the following variables to be setup:
 129   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 130   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 131   SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-core.pc )
 132   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 133 ENDIF()
 134
 135 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 136
 137   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 138   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 139   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 140
 141 ELSEIF( UNIX )
 142
 143   # Set up compiler flags and warnings
 144   ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
 145
 146   # TODO: Clang is a lot more strict with warnings, we should address
 147   # those issues at some point.
 148   IF( NOT ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang" )
 149     ADD_COMPILE_OPTIONS( -Werror )
 150   ENDIF()
 151
 152   ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal -Wno-class-memaccess -Wno-cast-function-type )
 153
 154   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 155     ADD_COMPILE_OPTIONS( --coverage )
 156     SET(ENABLE_COVERAGE ON)
 157     SET(COVERAGE --coverage)
 158   ENDIF()
 159
 160   IF( NOT ${ENABLE_EXPORTALL} )
 161     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 162   ENDIF()
 163
 164 ENDIF()
 165
 166 INCLUDE_DIRECTORIES(
 167   ${ROOT_SRC_DIR}
 168   ${VCPKG_INCLUDE_DIR}
 169   ${INCLUDE_DIR}
 170 )
 171
 172 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 173 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 174
 175 SET(SOURCES "")
 176
 177 # could use INCLUDE to get the source lists a different way;
 178 # would then need to specify a build folder somehow...
 179 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 180 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 181 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 182 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 183 IF( WIN32 )
 184   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-windows.list )
 185 ELSEIF( UNIX )
 186   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-unix.list )
 187 ENDIF()
 188 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 189
 190 SET(LIBTYPE SHARED)
 191 IF(DEFINED STATIC)
 192   SET(LIBTYPE STATIC)
 193 ENDIF()
 194
 195 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 196
 197 # pthread required due to gcc issue
 198 IF( WIN32 )
 199     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} dali-windows-dependencies::dali-windows-dependencies )
 200 ELSEIF( UNIX )
 201   FIND_LIBRARY(PTHREAD pthread)
 202   IF(PTHREAD)
 203     SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 204   ENDIF()
 205 ENDIF()
 206
 207 TARGET_LINK_LIBRARIES( ${name}
 208   ${OPTIONAL_LIBS}
 209   ${COVERAGE}
 210 )
 211
 212 SET_TARGET_PROPERTIES( ${name}
 213   PROPERTIES
 214   VERSION ${DALI_VERSION}
 215   SOVERSION ${${name}_VERSION_MAJOR}
 216   CLEAN_DIRECT_OUPUT 1
 217 )
 218
 219 IF( INSTALL_CMAKE_MODULES )
 220   IF( ENABLE_DEBUG )
 221     SET( BIN_DIR "${BIN_DIR}/debug" )
 222     SET( LIB_DIR "${LIB_DIR}/debug" )
 223   ENDIF()
 224
 225   # Install the library files.
 226   INSTALL( TARGETS ${name}
 227     EXPORT ${name}-targets
 228     LIBRARY DESTINATION ${LIB_DIR}
 229     ARCHIVE DESTINATION ${LIB_DIR}
 230     RUNTIME DESTINATION ${BIN_DIR}
 231   )
 232
 233   # Install the cmake modules.
 234   INSTALL(
 235     EXPORT ${name}-targets
 236     NAMESPACE ${name}::
 237     FILE ${name}-targets.cmake
 238     DESTINATION share/${name}
 239   )
 240
 241   FILE( WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 242     include(CMakeFindDependencyMacro)
 243     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 244   ")
 245   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name} )
 246
 247   # Install the pdb file.
 248   IF( ENABLE_DEBUG )
 249     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 250   ENDIF()
 251 ELSE()
 252   # Install the library so file and symlinks.
 253   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 254 ENDIF()
 255
 256
 257 # Install the pkg-config file
 258 IF( ENABLE_PKG_CONFIGURE )
 259   INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 260 ENDIF()
 261
 262 # macro for installing headers by replacing prefix. (TODO, investigate
 263 # if there is a CMAKE way of doing this automatically)
 264 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 265   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 266   FOREACH(HEADER ${${HEADER_LIST}})
 267     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 268     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 269     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 270   ENDFOREACH(HEADER)
 271 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 272
 273 # Install headers using lists defined by ADD_SUBDIRECTORY
 274 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 275 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 276 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 277 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 278
 279 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 280 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 281 # target names duplication with other DALi modules.
 282 IF( ENABLE_COVERAGE )
 283   FIND_PROGRAM( LCOV_BIN "lcov" )
 284   IF( LCOV_BIN )
 285
 286     # Define custom rules for coverage
 287     SET(COVERAGE_DIR .cov)
 288     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 289
 290     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 291     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 292     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 293     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 294     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 295       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 296     ENDIF()
 297
 298     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 299
 300     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 301       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 302
 303     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 304       DEPENDS cov_data )
 305
 306     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 307
 308     # Define custom rule for distclean
 309     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 310     ADD_CUSTOM_COMMAND(
 311           DEPENDS ${DALI_CORE_PREFIX}clean
 312           COMMENT "distribution clean"
 313           COMMAND find
 314           ARGS    .
 315           -not -name config.cmake -and \(
 316           -name tester.c -or
 317           -name Testing -or
 318           -name CMakeFiles -or
 319           -name doc -or
 320           -name cmake.depends -or
 321           -name cmake.check_depends -or
 322           -name CMakeCache.txt -or
 323           -name cmake.check_cache -or
 324           -name *.cmake -or
 325           -name Makefile -or
 326           -name core -or
 327           -name core.* -or
 328           -name gmon.out -or
 329           -name install_manifest.txt -or
 330           -name *.pc -or
 331           -name *.gcov -or
 332           -name *.gcno -or
 333           -name *.gcda -or
 334           -name *~ -or
 335           -name libdali*.so* \)
 336           | grep -v TC | xargs rm -rf
 337           TARGET  ${DALI_CORE_PREFIX}distclean
 338           VERBATIM
 339           )
 340
 341   ENDIF( LCOV_BIN )
 342 ENDIF()
 343
 344 IF( ENABLE_LINK_TEST )
 345   # Linker Test
 346   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 347   SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 348   SET( LINKER_TEST_SOURCES
 349     linker-test.cpp
 350     ${DALI_TEST_SUITE_DIR}/test-application.cpp
 351     ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 352     ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 353     ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 354     ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 355     ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 356   )
 357   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 358   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 359   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 360 ENDIF()
 361
 362 # Configuration Messages
 363 MESSAGE( STATUS "Configuration:\n" )
 364 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 365 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 366 MESSAGE( STATUS "Bin Dir:               " ${BIN_DIR} )
 367 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 368 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 369 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 370 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 371 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 372 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 373 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 374 MESSAGE( STATUS "Use pkg configure:     " ${ENABLE_PKG_CONFIGURE} )
 375 MESSAGE( STATUS "Enable link test:      " ${ENABLE_LINK_TEST} )
 376 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 377 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )