build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.1)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  10 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  11   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  12     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  13   ENDIF()
  14 ENDIF()
  15
  16 # API VERSION (Not DALi release version)
  17 SET(${name}_VERSION_MAJOR 0)
  18 SET(${name}_VERSION_MINOR 0)
  19 SET(${name}_VERSION_PATCH 0)
  20 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  21
  22 SET(DALI_VERSION ${${name}_VERSION} )
  23
  24 # Define options to CMake
  25
  26 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  27 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  28 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  29 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  30 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  31 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  32 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  33 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  34
  35 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  36   FIND_PACKAGE( dali-windows-dependencies REQUIRED )
  37 ENDIF()
  38
  39 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  40
  41 # Set up compiler definitions
  42
  43 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  44   SET( ENABLE_DEBUG ON )
  45 ENDIF()
  46
  47 IF( ENABLE_DEBUG )
  48   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  49   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  50   SET( ENABLE_EXPORTALL ON )
  51 ELSE()
  52   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  53 ENDIF()
  54
  55 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  56
  57   IF(NOT DEFINED STATIC)
  58     ADD_DEFINITIONS( "-DBUILDING_DALI_CORE" )
  59   ENDIF()
  60
  61 ELSEIF( UNIX )
  62
  63   IF( NOT ${ENABLE_EXPORTALL} )
  64     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
  65   ENDIF()
  66
  67   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  68
  69   IF("${ARCH}" STREQUAL "arm")
  70     ADD_DEFINITIONS("-DTARGET")
  71   ENDIF()
  72
  73 ENDIF()
  74
  75 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  76   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  77 ENDIF()
  78
  79 IF( ENABLE_LOCK_BACKTRACE )
  80   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  81 ENDIF()
  82
  83 IF( ENABLE_TRACE )
  84   ADD_DEFINITIONS("-DTRACE_ENABLED")
  85 ENDIF()
  86
  87 # Deployment folder should come from spec file or command line:
  88 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  89 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  90
  91 # from root/build/tizen, get back to root
  92 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
  93
  94 # Make sure the path is absolute
  95 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  96
  97 # Set up the include dir
  98 SET( INCLUDE_DIR $ENV{includedir} )
  99 IF( NOT INCLUDE_DIR )
 100   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 101 ENDIF()
 102 IF( NOT INCLUDE_DIR )
 103   SET( INCLUDE_DIR ${PREFIX}/include )
 104 ENDIF()
 105
 106 # Set up the lib dir
 107 SET( LIB_DIR $ENV{libdir} )
 108 IF( NOT LIB_DIR )
 109   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 110 ENDIF()
 111 IF( NOT LIB_DIR )
 112   SET( LIB_DIR ${PREFIX}/lib )
 113 ENDIF()
 114
 115 # Set up the bin dir
 116 SET( BIN_DIR $ENV{bindir} )
 117 IF( NOT BIN_DIR )
 118   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 119 ENDIF()
 120 IF( NOT BIN_DIR )
 121   SET( BIN_DIR ${PREFIX}/bin )
 122 ENDIF()
 123
 124 IF( ENABLE_PKG_CONFIGURE )
 125   # Configure the pkg-config file
 126   # Requires the following variables to be setup:
 127   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 128   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 129   SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali-core.pc )
 130   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 131 ENDIF()
 132
 133 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 134
 135   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 136   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 137   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 138
 139 ELSEIF( UNIX )
 140
 141   # Set up compiler flags and warnings
 142   ADD_COMPILE_OPTIONS( -std=c++11 )
 143   ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
 144
 145   # TODO: Clang is a lot more strict with warnings, we should address
 146   # those issues at some point.
 147   IF( NOT ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang" )
 148     ADD_COMPILE_OPTIONS( -Werror )
 149   ENDIF()
 150
 151   ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal -Wno-class-memaccess -Wno-cast-function-type )
 152
 153   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 154     ADD_COMPILE_OPTIONS( --coverage )
 155     SET(ENABLE_COVERAGE ON)
 156     SET(COVERAGE --coverage)
 157   ENDIF()
 158
 159   IF( NOT ${ENABLE_EXPORTALL} )
 160     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 161   ENDIF()
 162
 163 ENDIF()
 164
 165 INCLUDE_DIRECTORIES(
 166   ${ROOT_SRC_DIR}
 167   ${VCPKG_INCLUDE_DIR}
 168   ${INCLUDE_DIR}
 169 )
 170
 171 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 172 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 173
 174 SET(SOURCES "")
 175
 176 # could use INCLUDE to get the source lists a different way;
 177 # would then need to specify a build folder somehow...
 178 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 179 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 180 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 181 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 182 IF( WIN32 )
 183   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-windows.list )
 184 ELSEIF( UNIX )
 185   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-unix.list )
 186 ENDIF()
 187 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 188
 189 SET(LIBTYPE SHARED)
 190 IF(DEFINED STATIC)
 191   SET(LIBTYPE STATIC)
 192 ENDIF()
 193
 194 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 195
 196 # pthread required due to gcc issue
 197 IF( WIN32 )
 198     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} dali-windows-dependencies::dali-windows-dependencies )
 199 ELSEIF( UNIX )
 200   FIND_LIBRARY(PTHREAD pthread)
 201   IF(PTHREAD)
 202     SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 203   ENDIF()
 204 ENDIF()
 205
 206 TARGET_LINK_LIBRARIES( ${name}
 207   ${OPTIONAL_LIBS}
 208   ${COVERAGE}
 209 )
 210
 211 SET_TARGET_PROPERTIES( ${name}
 212   PROPERTIES
 213   VERSION ${DALI_VERSION}
 214   SOVERSION ${${name}_VERSION_MAJOR}
 215   CLEAN_DIRECT_OUPUT 1
 216 )
 217
 218 IF( INSTALL_CMAKE_MODULES )
 219   IF( ENABLE_DEBUG )
 220     SET( BIN_DIR "${BIN_DIR}/debug" )
 221     SET( LIB_DIR "${LIB_DIR}/debug" )
 222   ENDIF()
 223
 224   # Install the library files.
 225   INSTALL( TARGETS ${name}
 226     EXPORT ${name}-targets
 227     LIBRARY DESTINATION ${LIB_DIR}
 228     ARCHIVE DESTINATION ${LIB_DIR}
 229     RUNTIME DESTINATION ${BIN_DIR}
 230   )
 231
 232   # Install the cmake modules.
 233   INSTALL(
 234     EXPORT ${name}-targets
 235     NAMESPACE ${name}::
 236     FILE ${name}-targets.cmake
 237     DESTINATION share/${name}
 238   )
 239
 240   FILE( WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 241     include(CMakeFindDependencyMacro)
 242     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 243   ")
 244   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name} )
 245
 246   # Install the pdb file.
 247   IF( ENABLE_DEBUG )
 248     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 249   ENDIF()
 250 ELSE()
 251   # Install the library so file and symlinks.
 252   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 253 ENDIF()
 254
 255
 256 # Install the pkg-config file
 257 IF( ENABLE_PKG_CONFIGURE )
 258   INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 259 ENDIF()
 260
 261 # macro for installing headers by replacing prefix. (TODO, investigate
 262 # if there is a CMAKE way of doing this automatically)
 263 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 264   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 265   FOREACH(HEADER ${${HEADER_LIST}})
 266     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 267     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 268     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 269   ENDFOREACH(HEADER)
 270 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 271
 272 # Install headers using lists defined by ADD_SUBDIRECTORY
 273 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 274 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 275 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 276 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 277
 278 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 279 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 280 # target names duplication with other DALi modules.
 281 IF( ENABLE_COVERAGE )
 282   FIND_PROGRAM( LCOV_BIN "lcov" )
 283   IF( LCOV_BIN )
 284
 285     # Define custom rules for coverage
 286     SET(COVERAGE_DIR .cov)
 287     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 288
 289     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 290     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 291     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 292     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 293     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 294       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 295     ENDIF()
 296
 297     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 298
 299     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 300       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 301
 302     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 303       DEPENDS cov_data )
 304
 305     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 306
 307     # Define custom rule for distclean
 308     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 309     ADD_CUSTOM_COMMAND(
 310           DEPENDS ${DALI_CORE_PREFIX}clean
 311           COMMENT "distribution clean"
 312           COMMAND find
 313           ARGS    .
 314           -not -name config.cmake -and \(
 315           -name tester.c -or
 316           -name Testing -or
 317           -name CMakeFiles -or
 318           -name doc -or
 319           -name cmake.depends -or
 320           -name cmake.check_depends -or
 321           -name CMakeCache.txt -or
 322           -name cmake.check_cache -or
 323           -name *.cmake -or
 324           -name Makefile -or
 325           -name core -or
 326           -name core.* -or
 327           -name gmon.out -or
 328           -name install_manifest.txt -or
 329           -name *.pc -or
 330           -name *.gcov -or
 331           -name *.gcno -or
 332           -name *.gcda -or
 333           -name *~ -or
 334           -name libdali*.so* \)
 335           | grep -v TC | xargs rm -rf
 336           TARGET  ${DALI_CORE_PREFIX}distclean
 337           VERBATIM
 338           )
 339
 340   ENDIF( LCOV_BIN )
 341 ENDIF()
 342
 343 IF( ENABLE_LINK_TEST )
 344   # Linker Test
 345   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 346   SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 347   SET( LINKER_TEST_SOURCES
 348     linker-test.cpp
 349     ${DALI_TEST_SUITE_DIR}/test-application.cpp
 350     ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 351     ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 352     ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 353     ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 354     ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 355   )
 356   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 357   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 358   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 359 ENDIF()
 360
 361 # Configuration Messages
 362 MESSAGE( STATUS "Configuration:\n" )
 363 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 364 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 365 MESSAGE( STATUS "Bin Dir:               " ${BIN_DIR} )
 366 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 367 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 368 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 369 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 370 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 371 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 372 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 373 MESSAGE( STATUS "Use pkg configure:     " ${ENABLE_PKG_CONFIGURE} )
 374 MESSAGE( STATUS "Enable link test:      " ${ENABLE_LINK_TEST} )
 375 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 376 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )