build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali2-core")
   5
   6 SET(CMAKE_C_STANDARD 99)
   7 SET(CMAKE_CXX_STANDARD 17)
   8 PROJECT(${name})
   9 SET(PKG_NAME ${name})
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 # API VERSION (Not DALi release version)
  19 SET(${name}_VERSION_MAJOR 2)
  20 SET(${name}_VERSION_MINOR 0)
  21 SET(${name}_VERSION_PATCH 0)
  22 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  23
  24 SET(DALI_VERSION ${${name}_VERSION} )
  25
  26 # Define options to CMake
  27
  28 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  29 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  30 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  31 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  32 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  33 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  34 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  35 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  36
  37 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  38   FIND_PACKAGE( dali-windows-dependencies REQUIRED )
  39 ENDIF()
  40
  41 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  42
  43 # Set up compiler definitions
  44
  45 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  46   SET( ENABLE_DEBUG ON )
  47 ENDIF()
  48
  49 IF( ENABLE_DEBUG )
  50   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  51   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  52   SET( ENABLE_EXPORTALL ON )
  53 ELSE()
  54   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  55 ENDIF()
  56
  57 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  58
  59   IF(NOT DEFINED STATIC)
  60     ADD_DEFINITIONS( "-DBUILDING_DALI_CORE" )
  61   ENDIF()
  62
  63 ELSEIF( UNIX )
  64
  65   IF( NOT ${ENABLE_EXPORTALL} )
  66     ADD_DEFINITIONS( "-DHIDE_DALI_INTERNALS" )
  67   ENDIF()
  68
  69   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  70
  71   IF("${ARCH}" STREQUAL "arm")
  72     ADD_DEFINITIONS("-DTARGET")
  73   ENDIF()
  74
  75 ENDIF()
  76
  77 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  78   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  79 ENDIF()
  80
  81 IF( ENABLE_LOCK_BACKTRACE )
  82   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  83 ENDIF()
  84
  85 IF( ENABLE_TRACE )
  86   ADD_DEFINITIONS("-DTRACE_ENABLED")
  87 ENDIF()
  88
  89 # Deployment folder should come from spec file or command line:
  90 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  91 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  92
  93 # from root/build/tizen, get back to root
  94 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
  95
  96 # Make sure the path is absolute
  97 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  98
  99 # Set up the include dir
 100 SET( INCLUDE_DIR $ENV{includedir} )
 101 IF( NOT INCLUDE_DIR )
 102   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
 103 ENDIF()
 104 IF( NOT INCLUDE_DIR )
 105   SET( INCLUDE_DIR ${PREFIX}/include )
 106 ENDIF()
 107
 108 # Set up the lib dir
 109 SET( LIB_DIR $ENV{libdir} )
 110 IF( NOT LIB_DIR )
 111   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
 112 ENDIF()
 113 IF( NOT LIB_DIR )
 114   SET( LIB_DIR ${PREFIX}/lib )
 115 ENDIF()
 116
 117 # Set up the bin dir
 118 SET( BIN_DIR $ENV{bindir} )
 119 IF( NOT BIN_DIR )
 120   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 121 ENDIF()
 122 IF( NOT BIN_DIR )
 123   SET( BIN_DIR ${PREFIX}/bin )
 124 ENDIF()
 125
 126 IF( ENABLE_PKG_CONFIGURE )
 127   # Configure the pkg-config file
 128   # Requires the following variables to be setup:
 129   # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 130   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 131   SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-core.pc )
 132   CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
 133 ENDIF()
 134
 135 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 136
 137   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) # Adds missing definitions.
 138   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 139   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 140
 141 ELSEIF( UNIX )
 142
 143   INCLUDE(CheckCXXCompilerFlag)
 144
 145   # Set up compiler flags and warnings
 146   ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
 147
 148   # TODO: Clang is a lot more strict with warnings, we should address
 149   # those issues at some point.
 150   IF( NOT ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang" )
 151     ADD_COMPILE_OPTIONS( -Werror )
 152   ENDIF()
 153
 154   ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal )
 155   CHECK_CXX_COMPILER_FLAG(-Wno-class-memaccess HAVE_NO_CLASS_MEMACCESS)
 156   IF (HAVE_NO_CLASS_MEMACCESS)
 157     ADD_COMPILE_OPTIONS( -Wno-class-memaccess )
 158   ENDIF()
 159
 160   CHECK_CXX_COMPILER_FLAG(-Wno-cast-function-type HAVE_NO_CAST_FUNCTION_TYPE)
 161   IF (HAVE_NO_CAST_FUNCTION_TYPE)
 162     ADD_COMPILE_OPTIONS( -Wno-cast-function-type )
 163   ENDIF()
 164
 165   CHECK_CXX_COMPILER_FLAG(-Wno-string-plus-int HAVE_NO_STRING_PLUS_INT)
 166   IF (HAVE_NO_STRING_PLUS_INT)
 167     ADD_COMPILE_OPTIONS( -Wno-string-plus-int )
 168   ENDIF()
 169   IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 170     ADD_COMPILE_OPTIONS( --coverage )
 171     SET(ENABLE_COVERAGE ON)
 172     SET(COVERAGE --coverage)
 173   ENDIF()
 174
 175   IF( NOT ${ENABLE_EXPORTALL} )
 176     ADD_COMPILE_OPTIONS( "-fvisibility=hidden" )
 177   ENDIF()
 178
 179 ENDIF()
 180
 181 INCLUDE_DIRECTORIES(
 182   ${ROOT_SRC_DIR}
 183   ${VCPKG_INCLUDE_DIR}
 184   ${INCLUDE_DIR}
 185 )
 186
 187 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 188 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 189
 190 SET(SOURCES "")
 191
 192 # could use INCLUDE to get the source lists a different way;
 193 # would then need to specify a build folder somehow...
 194 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 195 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 196 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 197 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 198 IF( WIN32 )
 199   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-windows.list )
 200 ELSEIF( UNIX )
 201   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-unix.list )
 202 ENDIF()
 203 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 204
 205 SET(LIBTYPE SHARED)
 206 IF(DEFINED STATIC)
 207   SET(LIBTYPE STATIC)
 208 ENDIF()
 209
 210 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 211
 212 # pthread required due to gcc issue
 213 IF( WIN32 )
 214     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} dali-windows-dependencies::dali-windows-dependencies )
 215 ELSEIF( UNIX )
 216   FIND_LIBRARY(PTHREAD pthread)
 217   IF(PTHREAD)
 218     SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 219   ENDIF()
 220 ENDIF()
 221
 222 TARGET_LINK_LIBRARIES( ${name}
 223   ${OPTIONAL_LIBS}
 224   ${COVERAGE}
 225 )
 226
 227 SET_TARGET_PROPERTIES( ${name}
 228   PROPERTIES
 229   VERSION ${DALI_VERSION}
 230   SOVERSION ${${name}_VERSION_MAJOR}
 231   CLEAN_DIRECT_OUPUT 1
 232 )
 233
 234 IF( INSTALL_CMAKE_MODULES )
 235   IF( ENABLE_DEBUG )
 236     SET( BIN_DIR "${BIN_DIR}/debug" )
 237     SET( LIB_DIR "${LIB_DIR}/debug" )
 238   ENDIF()
 239
 240   # Install the library files.
 241   INSTALL( TARGETS ${name}
 242     EXPORT ${name}-targets
 243     LIBRARY DESTINATION ${LIB_DIR}
 244     ARCHIVE DESTINATION ${LIB_DIR}
 245     RUNTIME DESTINATION ${BIN_DIR}
 246   )
 247
 248   # Install the cmake modules.
 249   INSTALL(
 250     EXPORT ${name}-targets
 251     NAMESPACE ${name}::
 252     FILE ${name}-targets.cmake
 253     DESTINATION share/${name}
 254   )
 255
 256   FILE( WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 257     include(CMakeFindDependencyMacro)
 258     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 259   ")
 260   INSTALL( FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name} )
 261
 262   # Install the pdb file.
 263   IF( ENABLE_DEBUG AND WIN32 )
 264     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 265   ENDIF()
 266 ELSE()
 267   # Install the library so file and symlinks.
 268   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 269 ENDIF()
 270
 271
 272 # Install the pkg-config file
 273 IF( ENABLE_PKG_CONFIGURE )
 274   INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 275 ENDIF()
 276
 277 # macro for installing headers by replacing prefix. (TODO, investigate
 278 # if there is a CMAKE way of doing this automatically)
 279 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 280   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 281   FOREACH(HEADER ${${HEADER_LIST}})
 282     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 283     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 284     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 285   ENDFOREACH(HEADER)
 286 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 287
 288 # Install headers using lists defined by ADD_SUBDIRECTORY
 289 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 290 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 291 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 292 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 293
 294 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 295 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 296 # target names duplication with other DALi modules.
 297 IF( ENABLE_COVERAGE )
 298   FIND_PROGRAM( LCOV_BIN "lcov" )
 299   IF( LCOV_BIN )
 300
 301     # Define custom rules for coverage
 302     SET(COVERAGE_DIR .cov)
 303     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 304
 305     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 306     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 307     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 308     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 309     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 310       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 311     ENDIF()
 312
 313     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 314
 315     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 316       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 317
 318     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 319       DEPENDS cov_data )
 320
 321     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 322
 323     # Define custom rule for distclean
 324     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 325     ADD_CUSTOM_COMMAND(
 326           DEPENDS ${DALI_CORE_PREFIX}clean
 327           COMMENT "distribution clean"
 328           COMMAND find
 329           ARGS    .
 330           -not -name config.cmake -and \(
 331           -name tester.c -or
 332           -name Testing -or
 333           -name CMakeFiles -or
 334           -name doc -or
 335           -name cmake.depends -or
 336           -name cmake.check_depends -or
 337           -name CMakeCache.txt -or
 338           -name cmake.check_cache -or
 339           -name *.cmake -or
 340           -name Makefile -or
 341           -name core -or
 342           -name core.* -or
 343           -name gmon.out -or
 344           -name install_manifest.txt -or
 345           -name *.pc -or
 346           -name *.gcov -or
 347           -name *.gcno -or
 348           -name *.gcda -or
 349           -name *~ -or
 350           -name libdali*.so* \)
 351           | grep -v TC | xargs rm -rf
 352           TARGET  ${DALI_CORE_PREFIX}distclean
 353           VERBATIM
 354           )
 355
 356   ENDIF( LCOV_BIN )
 357 ENDIF()
 358
 359 IF( ENABLE_LINK_TEST )
 360   # Linker Test
 361   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 362   SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 363   SET( LINKER_TEST_SOURCES
 364     linker-test.cpp
 365     ${DALI_TEST_SUITE_DIR}/test-application.cpp
 366     ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 367     ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 368     ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 369     ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 370     ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 371   )
 372   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 373   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 374   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 375 ENDIF()
 376
 377 # Configuration Messages
 378 MESSAGE( STATUS "Configuration:\n" )
 379 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 380 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 381 MESSAGE( STATUS "Bin Dir:               " ${BIN_DIR} )
 382 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 383 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 384 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 385 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 386 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 387 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 388 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 389 MESSAGE( STATUS "Use pkg configure:     " ${ENABLE_PKG_CONFIGURE} )
 390 MESSAGE( STATUS "Enable link test:      " ${ENABLE_LINK_TEST} )
 391 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 392 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )