build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(name "dali-core")
   5
   6 PROJECT(${name})
   7 SET(PKG_NAME ${name})
   8
   9 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  10 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  11   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  12     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  13   endif()
  14 endif()
  15
  16 # API VERSION (Not DALi release version)
  17 SET(${name}_VERSION_MAJOR 0)
  18 SET(${name}_VERSION_MINOR 0)
  19 SET(${name}_VERSION_PATCH 0)
  20 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  21
  22 SET(DALI_VERSION ${${name}_VERSION} )
  23
  24 # Define options to CMake
  25
  26 OPTION(ENABLE_EXPORTALL      "Enable Export all symbols" OFF)
  27 OPTION(ENABLE_DEBUG          "Enable Debug" OFF)
  28 OPTION(ENABLE_BACKTRACE      "Enable Backtrace" OFF)
  29 OPTION(ENABLE_LOCK_BACKTRACE "Enable" OFF)
  30 OPTION(ENABLE_COVERAGE       "Coverage" OFF)
  31 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  32
  33 # Set up compiler definitions
  34
  35 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  36   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  37   SET( ENABLE_DEBUG ON )
  38 ELSE()
  39   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  40 ENDIF()
  41
  42 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  43
  44 IF("${ARCH}" STREQUAL "arm")
  45   ADD_DEFINITIONS("-DTARGET")
  46 ENDIF("${ARCH}" STREQUAL "arm")
  47
  48 IF( ENABLE_DEBUG )
  49   ADD_DEFINITIONS( "-DDEBUG_ENABLED" )
  50   SET( ENABLE_EXPORTALL ON )
  51 ENDIF( ENABLE_DEBUG )
  52
  53 IF( NOT ${ENABLE_EXPORTALL} )
  54   ADD_DEFINITIONS( "-fvisibility=hidden -DHIDE_DALI_INTERNALS" )
  55 ENDIF( NOT ${ENABLE_EXPORTALL} )
  56
  57 IF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  58   ADD_DEFINITIONS( "-DBACKTRACE_ENABLED" )
  59 ENDIF( ENABLE_BACKTRACE OR ENABLE_LOCK_BACKTRACE )
  60
  61 IF( ENABLE_LOCK_BACKTRACE )
  62   ADD_DEFINITIONS( "-DLOCK_BACKTRACE_ENABLED" )
  63 ENDIF( ENABLE_LOCK_BACKTRACE )
  64
  65 # Deployment folder should come from spec file or command line:
  66 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  67 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  68
  69 # from root/build/tizen, get back to root
  70 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../..)
  71
  72 # Make sure the path is absolute
  73 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  74
  75 # Set up the include dir
  76 SET( INCLUDE_DIR $ENV{includedir} )
  77 IF( NOT INCLUDE_DIR )
  78   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  79 ENDIF()
  80 IF( NOT INCLUDE_DIR )
  81   SET( INCLUDE_DIR ${PREFIX}/include )
  82 ENDIF()
  83
  84 # Set up the lib dir
  85 SET( LIB_DIR $ENV{libdir} )
  86 IF( NOT LIB_DIR )
  87   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  88 ENDIF()
  89 IF( NOT LIB_DIR )
  90   SET( LIB_DIR ${PREFIX}/lib )
  91 ENDIF()
  92
  93 # Configure the pkg-config file
  94 # Requires the following variables to be setup:
  95 # @PREFIX@ @EXEC_PREFIX@ @DALI_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
  96 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
  97 SET( CORE_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali-core.pc )
  98 CONFIGURE_FILE( ${CORE_PKG_CFG_FILE}.in ${CORE_PKG_CFG_FILE} @ONLY )
  99
 100 # Set up compiler flags and warnings
 101 ADD_COMPILE_OPTIONS( -std=c++11 )
 102 ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
 103
 104 # TODO: Clang is a lot more strict with warnings, we should address
 105 # those issues at some point.
 106 IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
 107   ADD_COMPILE_OPTIONS( -Werror )
 108 ENDIF()
 109
 110 ADD_COMPILE_OPTIONS( -Wall -Wextra -Wno-unused-parameter -Wfloat-equal -Wno-class-memaccess -Wno-cast-function-type )
 111
 112 IF( ENABLE_COVERAGE OR "$ENV{CXXFLAGS}" MATCHES --coverage )
 113   ADD_COMPILE_OPTIONS( --coverage )
 114   SET(ENABLE_COVERAGE ON)
 115   SET(COVERAGE --coverage)
 116 ENDIF()
 117
 118 IF( ENABLE_TRACE )
 119   ADD_DEFINITIONS("-DTRACE_ENABLED")
 120 ENDIF()
 121
 122
 123 INCLUDE_DIRECTORIES(
 124   ${ROOT_SRC_DIR}
 125 )
 126
 127 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 128 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 129
 130 SET(SOURCES "")
 131
 132 # could use INCLUDE to get the source lists a different way;
 133 # would then need to specify a build folder somehow...
 134 INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file.list )
 135 INCLUDE( ${ROOT_SRC_DIR}/dali/integration-api/file.list )
 136 INCLUDE( ${ROOT_SRC_DIR}/dali/public-api/file.list )
 137 INCLUDE( ${ROOT_SRC_DIR}/dali/devel-api/file.list )
 138 IF( UNIX )
 139   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-unix.list )
 140 ELSEIF( WIN32 )
 141   INCLUDE( ${ROOT_SRC_DIR}/dali/internal/file-windows.list )
 142 ENDIF()
 143 INCLUDE( ${ROOT_SRC_DIR}/doc/file.list )
 144
 145 SET(LIBTYPE SHARED)
 146 IF(DEFINED STATIC)
 147   SET(LIBTYPE STATIC)
 148 ENDIF()
 149
 150 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 151
 152 # pthread required due to gcc issue
 153 FIND_LIBRARY(PTHREAD pthread)
 154 IF(PTHREAD)
 155   SET(OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread)
 156 ENDIF()
 157
 158 TARGET_LINK_LIBRARIES( ${name}
 159   ${OPTIONAL_LIBS}
 160   ${COVERAGE}
 161 )
 162
 163 SET_TARGET_PROPERTIES( ${name}
 164   PROPERTIES
 165   VERSION ${DALI_VERSION}
 166   SOVERSION ${${name}_VERSION_MAJOR}
 167   CLEAN_DIRECT_OUPUT 1
 168 )
 169
 170 # Install the library so file and symlinks
 171 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 172
 173 # Install the pkg-config file
 174 INSTALL( FILES ${CORE_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 175
 176 # macro for installing headers by replacing prefix. (TODO, investigate
 177 # if there is a CMAKE way of doing this automatically)
 178 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 179   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 180   FOREACH(HEADER ${${HEADER_LIST}})
 181     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 182     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 183     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 184   ENDFOREACH(HEADER)
 185 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 186
 187 # Install headers using lists defined by ADD_SUBDIRECTORY
 188 INSTALL_HEADERS_WITH_DIRECTORY(PUBLIC_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 189 INSTALL_HEADERS_WITH_DIRECTORY(DEVEL_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 190 INSTALL_HEADERS_WITH_DIRECTORY(INTEGRATION_API_HEADERS ${ROOT_SRC_DIR}/dali "dali")
 191 INSTALL_HEADERS_WITH_DIRECTORY(PACKAGE_DOXY_HEADERS ${PACKAGE_DOXY_SRC_DIR} "dali/doc" )
 192
 193 # The DALI_CORE_PREFIX must be set if this CMakeLists.txt is executed
 194 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 195 # target names duplication with other DALi modules.
 196 IF( UNIX )
 197   FIND_PROGRAM( LCOV_BIN "lcov" )
 198   IF( LCOV_BIN )
 199
 200     # Define custom rules for coverage
 201     SET(COVERAGE_DIR .cov)
 202     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 203
 204     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 205     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 206     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 207     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 208     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 209       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 210     ENDIF()
 211
 212     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}rename_cov_data ./rename-cov-data )
 213
 214     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 215       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"public-api/shader-effects/*\" \"*/image-actor*\" -o dali.info )
 216
 217     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 218       DEPENDS cov_data )
 219
 220     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 221
 222     # Define custom rule for distclean
 223     ADD_CUSTOM_TARGET( ${DALI_CORE_PREFIX}distclean @echo cleaning for source distribution )
 224     ADD_CUSTOM_COMMAND(
 225           DEPENDS ${DALI_CORE_PREFIX}clean
 226           COMMENT "distribution clean"
 227           COMMAND find
 228           ARGS    .
 229           -not -name config.cmake -and \(
 230           -name tester.c -or
 231           -name Testing -or
 232           -name CMakeFiles -or
 233           -name doc -or
 234           -name cmake.depends -or
 235           -name cmake.check_depends -or
 236           -name CMakeCache.txt -or
 237           -name cmake.check_cache -or
 238           -name *.cmake -or
 239           -name Makefile -or
 240           -name core -or
 241           -name core.* -or
 242           -name gmon.out -or
 243           -name install_manifest.txt -or
 244           -name *.pc -or
 245           -name *.gcov -or
 246           -name *.gcno -or
 247           -name *.gcda -or
 248           -name *~ -or
 249           -name libdali*.so* \)
 250           | grep -v TC | xargs rm -rf
 251           TARGET  ${DALI_CORE_PREFIX}distclean
 252           VERBATIM
 253           )
 254
 255   ENDIF( LCOV_BIN )
 256 ENDIF( UNIX )
 257
 258 # Linker Test
 259 SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 260 SET( LINKER_TEST_NAME ${DALI_CORE_PREFIX}linker-test )
 261 SET( LINKER_TEST_SOURCES
 262   linker-test.cpp
 263   ${DALI_TEST_SUITE_DIR}/test-application.cpp
 264   ${DALI_TEST_SUITE_DIR}/test-platform-abstraction.cpp
 265   ${DALI_TEST_SUITE_DIR}/test-render-controller.cpp
 266   ${DALI_TEST_SUITE_DIR}/test-render-surface.cpp
 267   ${DALI_TEST_SUITE_DIR}/test-gl-abstraction.cpp
 268   ${DALI_TEST_SUITE_DIR}/test-gl-sync-abstraction.cpp
 269   ${DALI_TEST_SUITE_DIR}/test-trace-call-stack.cpp
 270 )
 271 ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 272 TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} )
 273 TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 274
 275 # Configuration Messages
 276 MESSAGE( STATUS "Configuration:\n" )
 277 MESSAGE( STATUS "Prefix:                " ${PREFIX} )
 278 MESSAGE( STATUS "Lib Dir:               " ${LIB_DIR} )
 279 MESSAGE( STATUS "Include Dir:           " ${INCLUDE_DIR} )
 280 MESSAGE( STATUS "Debug build:           " ${ENABLE_DEBUG} )
 281 MESSAGE( STATUS "Export all symbols:    " ${ENABLE_EXPORTALL} )
 282 MESSAGE( STATUS "Backtrace:             " ${ENABLE_BACKTRACE} )
 283 MESSAGE( STATUS "Scoped Lock backtrace: " ${ENABLE_LOCK_BACKTRACE} )
 284 MESSAGE( STATUS "Coverage:              " ${ENABLE_COVERAGE} )
 285 MESSAGE( STATUS "Trace:                 " ${ENABLE_TRACE} )
 286 MESSAGE( STATUS "CXXFLAGS:              " ${CMAKE_CXX_FLAGS} )
 287 MESSAGE( STATUS "LDFLAGS:               " ${CMAKE_SHARED_LINKER_FLAGS_INIT}${CMAKE_SHARED_LINKER_FLAGS} )