build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.1)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_CXX_STANDARD 11)
   5 SET(CMAKE_C_STANDARD 99)
   6 PROJECT(${name} CXX)
   7 SET(PKG_NAME ${name})
   8
   9 SET(name "dali-adaptor")
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  19 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  20
  21 # Include additional macros
  22 INCLUDE( common.cmake )
  23
  24 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  25   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  26   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  27   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  28 ELSE()
  29   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  30 ENDIF()
  31
  32 # from root/build/tizen, get back to root.
  33 # set the variable only if it's not set yet. it allows to access build script
  34 # from top-level directory
  35 IF( NOT ROOT_SRC_DIR )
  36   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  37 ENDIF()
  38 # Make sure the path is absolute
  39 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  40
  41 # API VERSION (Not DALi release version)
  42 SET(${name}_VERSION_MAJOR 0)
  43 SET(${name}_VERSION_MINOR 0)
  44 SET(${name}_VERSION_PATCH 0)
  45 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  46
  47 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  48
  49 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  50   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  51   FIND_PACKAGE( dali-core REQUIRED)
  52   FIND_PATH( SYSTEM_INCLUDE_DIR "dali-windows-dependencies.h" )
  53 ENDIF()
  54
  55 IF( UNIX )
  56   ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  57   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  58
  59   IF("${ARCH}" STREQUAL "arm")
  60     ADD_DEFINITIONS("-DTARGET")
  61   ENDIF("${ARCH}" STREQUAL "arm")
  62 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  63   IF(NOT DEFINED STATIC)
  64     ADD_DEFINITIONS( "-DBUILDING_DALI_ADAPTOR" )
  65   ENDIF()
  66
  67   ADD_DEFINITIONS( "-DDALI_ADAPTOR_COMPILATION" )
  68   ADD_DEFINITIONS( "-D_NSIG=65" )
  69 ENDIF()
  70
  71 # Deployment folder should come from spec file or command line:
  72 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  73 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  74
  75 # Set up the include dir
  76 SET( INCLUDE_DIR $ENV{includedir} )
  77 IF( NOT INCLUDE_DIR )
  78   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  79 ENDIF()
  80 IF( NOT INCLUDE_DIR )
  81   SET( INCLUDE_DIR ${PREFIX}/include )
  82 ENDIF()
  83
  84 # Set up the lib dir
  85 IF( SET_VCPKG_INSTALL_PREFIX )
  86   SET( LIB_DIR ${PREFIX}/lib )
  87   SET( BIN_DIR ${PREFIX}/bin )
  88 ELSE()
  89   SET( LIB_DIR $ENV{libdir} )
  90   IF( NOT LIB_DIR )
  91     SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  92   ENDIF()
  93   IF( NOT LIB_DIR )
  94     SET( LIB_DIR ${PREFIX}/lib )
  95   ENDIF()
  96 ENDIF()
  97
  98 IF( UNIX )
  99   INCLUDE( deps-check.cmake )
 100 ENDIF()
 101
 102 # Set up compiler flags and warnings
 103 IF( UNIX )
 104   ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
 105 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 106   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) #
 107   ADD_COMPILE_OPTIONS( /FIextern-definitions.h )        # Adds missing definitions.
 108   ADD_COMPILE_OPTIONS( /FIpreprocessor-definitions.h )  #
 109   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 110   ADD_COMPILE_OPTIONS( /TP )                            # All files considered C++
 111 ENDIF()
 112
 113 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES
 114                  ${DEFINITIONS} )
 115
 116 # from root/build/tizen, get back to root
 117 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
 118
 119 # Make sure the path is absolute
 120 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 121
 122 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 123 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 124 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 125 SET(SOURCES "")
 126
 127 # Include list of modules
 128 INCLUDE( module-list.cmake )
 129
 130 # Include profile specific setup
 131 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 132
 133 IF( ENABLE_PKG_CONFIGURE )
 134   # Configure the pkg-config file
 135   # Requires the following variables to be setup:
 136   # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 137   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 138   SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali-adaptor.pc )
 139   SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali-adaptor-integration.pc )
 140   CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 141   CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 142 ENDIF()
 143
 144 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 145
 146 SET( THIRD_PARTY_WINDOWS_PLATFORM "" )
 147 IF( WIN32 )
 148   SET( THIRD_PARTY_WINDOWS_PLATFORM ${ROOT_SRC_DIR}/third-party/windows-platform )
 149 ENDIF()
 150
 151 INCLUDE_DIRECTORIES(
 152   ${ROOT_SRC_DIR}
 153   ${PROFILE_INCLUDE_DIRECTORIES}
 154   ${THIRD_PARTY_WINDOWS_PLATFORM}
 155   ${SYSTEM_INCLUDE_DIR}
 156 )
 157
 158 SET(LIBTYPE SHARED)
 159 IF(DEFINED STATIC)
 160   SET(LIBTYPE STATIC)
 161 ENDIF()
 162
 163 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 164
 165 IF( UNIX )
 166   # pthread required due to gcc issue
 167   FIND_LIBRARY( PTHREAD pthread )
 168   IF( PTHREAD AND NOT ANDROID_PROFILE )
 169     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 170   ENDIF()
 171 ENDIF()
 172
 173 TARGET_LINK_LIBRARIES( ${name}
 174                        ${DALI_LDFLAGS}
 175   ${REQUIRED_LIBS}
 176   ${OPTIONAL_LIBS}
 177   ${COVERAGE}
 178 )
 179
 180 SET_TARGET_PROPERTIES( ${name}
 181   PROPERTIES
 182   VERSION ${DALI_ADAPTOR_VERSION}
 183   SOVERSION ${${name}_VERSION_MAJOR}
 184   CLEAN_DIRECT_OUPUT 1
 185 )
 186
 187 # Install the library so file and symlinks
 188 IF( INSTALL_CMAKE_MODULES )
 189   INSTALL( TARGETS ${name}
 190     EXPORT ${name}-targets
 191     LIBRARY DESTINATION ${LIB_DIR}
 192     ARCHIVE DESTINATION ${LIB_DIR}
 193     RUNTIME DESTINATION ${BIN_DIR}
 194   )
 195
 196   INSTALL(
 197     EXPORT ${name}-targets
 198     NAMESPACE ${name}::
 199     FILE ${name}-targets.cmake
 200     DESTINATION share/${name}
 201   )
 202
 203   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 204     include(CMakeFindDependencyMacro)
 205     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 206   ")
 207   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 208 ELSE()
 209   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 210 ENDIF()
 211
 212 IF( ENABLE_PKG_CONFIGURE )
 213   # Install the pkg-config file
 214   INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 215   INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 216 ENDIF()
 217
 218 # macro for installing headers by replacing prefix. (TODO, investigate
 219 # if there is a CMAKE way of doing this automatically)
 220 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 221   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 222   FOREACH(HEADER ${${HEADER_LIST}})
 223     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 224     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 225     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 226   ENDFOREACH(HEADER)
 227 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 228
 229
 230 ########################################################################################
 231 # INSTALL:
 232 # Set deployment directories
 233 # Due to complicated adaptor deployment the install section is pretty much converted from
 234 # the automake counterpart.
 235 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 236 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 237 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 238 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 239 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 240 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 241 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 242 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 243 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 244
 245 # Android framework headers for Android build
 246 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 247
 248 # Install headers
 249 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 250 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 251 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 252 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 253 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 254
 255 # Install Android framework headers for Android build
 256 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 257
 258 # Install DOXY
 259 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 260 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 261 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 262 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 263
 264 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE AND NOT WINDOWS_PROFILE )
 265   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 266   IF( NOT WAYLAND )
 267     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 268   ENDIF()
 269 ENDIF()
 270
 271 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 272 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 273 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 274 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 275
 276 IF( ANDROID_PROFILE )
 277   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 278   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 279 ELSEIF( UNIX )
 280   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 281   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 282 ENDIF()
 283
 284 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 285
 286 ########################################################################################
 287
 288 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 289 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 290 # target names duplication with other DALi modules.
 291 IF( ENABLE_COVERAGE )
 292   FIND_PROGRAM( LCOV_BIN "lcov" )
 293   IF( LCOV_BIN )
 294
 295     # Define custom rules for coverage
 296     SET(COVERAGE_DIR .cov)
 297     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 298
 299     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 300     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 301     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 302     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 303     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 304       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 305     ENDIF()
 306
 307     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 308
 309     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 310       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" -o dali.info )
 311
 312     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 313       DEPENDS cov_data )
 314
 315     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 316
 317     # Define custom rule for distclean
 318     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 319     ADD_CUSTOM_COMMAND(
 320           DEPENDS clean
 321           COMMENT "distribution clean"
 322           COMMAND find
 323           ARGS    .
 324           -not -name config.cmake -and \(
 325           -name tester.c -or
 326           -name Testing -or
 327           -name CMakeFiles -or
 328           -name doc -or
 329           -name cmake.depends -or
 330           -name cmake.check_depends -or
 331           -name CMakeCache.txt -or
 332           -name cmake.check_cache -or
 333           -name *.cmake -or
 334           -name Makefile -or
 335           -name core -or
 336           -name core.* -or
 337           -name gmon.out -or
 338           -name install_manifest.txt -or
 339           -name *.pc -or
 340           -name *.gcov -or
 341           -name *.gcno -or
 342           -name *.gcda -or
 343           -name *~ -or
 344           -name libdali*.so* \)
 345           | grep -v TC | xargs rm -rf
 346           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 347           VERBATIM
 348           )
 349
 350   ENDIF( LCOV_BIN )
 351 ENDIF()
 352
 353 IF( ENABLE_LINK_TEST )
 354   # Linker Test
 355   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 356   SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 357   SET( LINKER_TEST_SOURCES
 358     linker-test.cpp
 359   )
 360   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 361   MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 362   TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 363   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} )
 364   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 365 ENDIF()
 366
 367 # Configuration Messages
 368 MESSAGE( STATUS "Configuration:\n" )
 369 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 370 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 371 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 372 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 373 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 374 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 375 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 376 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 377 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 378 MESSAGE( STATUS "EldBus:                           ${eldbus_available_ENABLED}")
 379 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 380 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORKLOGGING}")
 381 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 382 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 383 MESSAGE( STATUS "Use pkg configure:                ${ENABLE_PKG_CONFIGURE}" )
 384 MESSAGE( STATUS "Enable link test:                 ${ENABLE_LINK_TEST}" )
 385 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 386 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 387 IF( enable_feedback )
 388   ADD_SUBDIRECTORY( plugins )
 389 ENDIF()
 390
 391 CLEAN_ARG_CACHE()