build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_C_STANDARD 99)
   5 SET(CMAKE_CXX_STANDARD 17)
   6 PROJECT(${name} CXX)
   7 SET(PKG_NAME ${name})
   8
   9 SET(name "dali2-adaptor")
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 OPTION(ENABLE_PKG_CONFIGURE     "Use pkgconfig" ON)
  19 OPTION(ENABLE_LINK_TEST         "Enable the link test" ON)
  20 OPTION(ENABLE_ATSPI             "Enable AT-SPI accessibility" ON)
  21 OPTION(ENABLE_TRACE             "Enable Trace" OFF)
  22 OPTION(ENABLE_TRACE_STREAMLINE  "Enable Trace (Streamline)" OFF)
  23
  24 # Include additional macros
  25 INCLUDE( common.cmake )
  26
  27 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  28   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  29   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  30   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  31 ELSE()
  32   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  33 ENDIF()
  34
  35 # from root/build/tizen, get back to root.
  36 # set the variable only if it's not set yet. it allows to access build script
  37 # from top-level directory
  38 IF( NOT ROOT_SRC_DIR )
  39   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  40 ENDIF()
  41 # Make sure the path is absolute
  42 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  43
  44 # API VERSION (Not DALi release version)
  45 SET(${name}_VERSION_MAJOR 2)
  46 SET(${name}_VERSION_MINOR 0)
  47 SET(${name}_VERSION_PATCH 0)
  48 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  49
  50 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  51
  52 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  53   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  54   FIND_PACKAGE( dali2-core REQUIRED)
  55 ENDIF()
  56
  57 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  58
  59 IF( UNIX )
  60   ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  61   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  62
  63   IF("${ARCH}" STREQUAL "arm")
  64     ADD_DEFINITIONS("-DTARGET")
  65   ENDIF("${ARCH}" STREQUAL "arm")
  66 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  67   IF(NOT DEFINED STATIC)
  68     ADD_DEFINITIONS( "-DBUILDING_DALI_ADAPTOR" )
  69   ENDIF()
  70
  71   ADD_DEFINITIONS( "-DDALI_ADAPTOR_COMPILATION" )
  72   ADD_DEFINITIONS( "-D_NSIG=65" )
  73 ENDIF()
  74
  75 # Deployment folder should come from spec file or command line:
  76 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  77 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  78
  79 # Set up the include dir
  80 SET( INCLUDE_DIR $ENV{includedir} )
  81 IF( NOT INCLUDE_DIR )
  82   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  83 ENDIF()
  84 IF( NOT INCLUDE_DIR )
  85   SET( INCLUDE_DIR ${PREFIX}/include )
  86 ENDIF()
  87
  88 # Set up the lib dir
  89 SET( LIB_DIR $ENV{libdir} )
  90 IF( NOT LIB_DIR )
  91   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  92 ENDIF()
  93 IF( NOT LIB_DIR )
  94   SET( LIB_DIR ${PREFIX}/lib )
  95 ENDIF()
  96
  97 # Set up the bin dir
  98 SET( BIN_DIR $ENV{bindir} )
  99 IF( NOT BIN_DIR )
 100   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 101 ENDIF()
 102 IF( NOT BIN_DIR )
 103   SET( BIN_DIR ${PREFIX}/bin )
 104 ENDIF()
 105
 106 IF( UNIX )
 107   INCLUDE( deps-check.cmake )
 108 ENDIF()
 109
 110 IF( UBUNTU_PROFILE OR ANDROID_PROFILE OR WIN32 OR APPLE OR LIBUV_X11_PROFILE OR GLIB_X11_PROFILE)
 111   SET( ENABLE_VCONF OFF )
 112 ELSE()
 113   SET( ENABLE_VCONF ON )
 114 ENDIF()
 115
 116 IF( NOT DALI_ELDBUS_AVAILABLE OR LIBUV_X11_PROFILE OR GLIB_X11_PROFILE)
 117   SET( ENABLE_ATSPI OFF )
 118 ENDIF()
 119
 120 IF( ENABLE_VCONF )
 121   ADD_DEFINITIONS("-DVCONF_ENABLED")
 122 ENDIF()
 123
 124 IF( ENABLE_TRACE OR ENABLE_TRACE_STREAMLINE )
 125   ADD_DEFINITIONS("-DTRACE_ENABLED")
 126   SET(ENABLE_TRACE_STRING ON)
 127   IF( ENABLE_TRACE_STREAMLINE )
 128     SET(ENABLE_TRACE_STRING "ON (Streamline)")
 129   ENDIF()
 130 ELSE()
 131   SET(ENABLE_TRACE_STRING OFF)
 132 ENDIF()
 133
 134 # Set up compiler flags and warnings
 135 IF( UNIX )
 136   ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
 137 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 138   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) #
 139   ADD_COMPILE_OPTIONS( /FIextern-definitions.h )        # Adds missing definitions.
 140   ADD_COMPILE_OPTIONS( /FIpreprocessor-definitions.h )  #
 141   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 142   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 143 ENDIF()
 144
 145 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES ${DEFINITIONS} )
 146
 147
 148 # from root/build/tizen, get back to root
 149 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
 150
 151 # Make sure the path is absolute
 152 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 153
 154 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 155 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 156 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 157 SET(SOURCES "")
 158
 159 # Include list of modules
 160 INCLUDE( module-list.cmake )
 161
 162 # Include profile specific setup
 163 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 164
 165 IF ( ENABLE_ATSPI )
 166   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_bridge_src_files} )
 167 ELSE()
 168   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_dummy_src_files} )
 169 ENDIF()
 170
 171 IF( ENABLE_PKG_CONFIGURE )
 172   # Configure the pkg-config file
 173   # Requires the following variables to be setup:
 174   # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 175   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 176   SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor.pc )
 177   SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor-integration.pc )
 178   CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 179   CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 180 ENDIF()
 181
 182 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 183
 184 SET( THIRD_PARTY_WINDOWS_PLATFORM "" )
 185 IF( WIN32 )
 186   SET( THIRD_PARTY_WINDOWS_PLATFORM ${ROOT_SRC_DIR}/third-party/windows-platform )
 187 ENDIF()
 188
 189 SET( THIRD_PARTY_MACOS_PLATFORM "" )
 190 IF( APPLE )
 191   SET( THIRD_PARTY_MACOS_PLATFORM ${ROOT_SRC_DIR}/third-party/macos-platform )
 192 ENDIF()
 193
 194 INCLUDE_DIRECTORIES(
 195   ${ROOT_SRC_DIR}
 196   ${PROFILE_INCLUDE_DIRECTORIES}
 197   ${THIRD_PARTY_WINDOWS_PLATFORM}
 198   ${THIRD_PARTY_MACOS_PLATFORM}
 199   ${VCPKG_INCLUDE_DIR}
 200   ${INCLUDE_DIR}
 201 )
 202
 203 SET(LIBTYPE SHARED)
 204 IF(DEFINED STATIC)
 205   SET(LIBTYPE STATIC)
 206 ENDIF()
 207
 208 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 209
 210 IF( UNIX )
 211   # pthread required due to gcc issue
 212   FIND_LIBRARY( PTHREAD pthread )
 213   IF( PTHREAD AND NOT ANDROID_PROFILE )
 214     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 215   ENDIF()
 216 ENDIF()
 217
 218 TARGET_LINK_LIBRARIES( ${name}
 219                        ${DALI_LDFLAGS}
 220                        ${REQUIRED_LIBS}
 221                        ${OPTIONAL_LIBS}
 222                        ${COVERAGE}
 223 )
 224
 225 SET_TARGET_PROPERTIES( ${name}
 226   PROPERTIES
 227   VERSION ${DALI_ADAPTOR_VERSION}
 228   SOVERSION ${${name}_VERSION_MAJOR}
 229   CLEAN_DIRECT_OUPUT 1
 230 )
 231
 232 IF( INSTALL_CMAKE_MODULES )
 233   IF( ENABLE_DEBUG )
 234     SET( BIN_DIR "${BIN_DIR}/debug" )
 235     SET( LIB_DIR "${LIB_DIR}/debug" )
 236   ENDIF()
 237
 238   # Install the library files.
 239   INSTALL( TARGETS ${name}
 240     EXPORT ${name}-targets
 241     LIBRARY DESTINATION ${LIB_DIR}
 242     ARCHIVE DESTINATION ${LIB_DIR}
 243     RUNTIME DESTINATION ${BIN_DIR}
 244   )
 245
 246   # Install the cmake modules.
 247   INSTALL(
 248     EXPORT ${name}-targets
 249     NAMESPACE ${name}::
 250     FILE ${name}-targets.cmake
 251     DESTINATION share/${name}
 252   )
 253
 254   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 255     include(CMakeFindDependencyMacro)
 256     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 257   ")
 258   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 259
 260   # Install the pdb file.
 261   IF( ENABLE_DEBUG AND WIN32 )
 262     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 263   ENDIF()
 264 ELSE()
 265   # Install the library so file and symlinks
 266   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 267 ENDIF()
 268
 269 IF( ENABLE_PKG_CONFIGURE )
 270   # Install the pkg-config file
 271   INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 272   INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 273 ENDIF()
 274
 275 # macro for installing headers by replacing prefix. (TODO, investigate
 276 # if there is a CMAKE way of doing this automatically)
 277 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 278   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 279   FOREACH(HEADER ${${HEADER_LIST}})
 280     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 281     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 282     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 283   ENDFOREACH(HEADER)
 284 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 285
 286
 287 ########################################################################################
 288 # INSTALL:
 289 # Set deployment directories
 290 # Due to complicated adaptor deployment the install section is pretty much converted from
 291 # the automake counterpart.
 292 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 293 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 294 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 295 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 296 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 297 SET( tizencanvasrendererdevelapidir ${tizenadaptorframeworkdevelapidir}/canvas-renderer )
 298 SET( tizenwebenginedevelapidir ${tizenadaptorframeworkdevelapidir}/web-engine )
 299 SET( tizenatspiinterfacesdevelapidir ${tizenadaptordevelapidir}/atspi-interfaces )
 300 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 301 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 302 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 303 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 304
 305 # Android framework headers for Android build
 306 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 307
 308 # Install headers
 309 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 310 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 311 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 312 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 313 INSTALL( FILES ${devel_api_adaptor_framework_canvas_renderer_header_files} DESTINATION ${tizencanvasrendererdevelapidir} )
 314 INSTALL( FILES ${devel_api_adaptor_framework_web_engine_header_files} DESTINATION ${tizenwebenginedevelapidir} )
 315 INSTALL( FILES ${devel_api_atspi_interfaces_header_files} DESTINATION ${tizenatspiinterfacesdevelapidir} )
 316 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 317
 318 # Install Android framework headers for Android build
 319 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 320
 321 # Install DOXY
 322 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 323 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 324 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 325 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 326
 327 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE AND NOT WINDOWS_PROFILE AND NOT MACOS_PROFILE )
 328   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 329   IF( NOT WAYLAND )
 330     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 331   ENDIF()
 332 ENDIF()
 333
 334 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 335 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 336 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 337 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 338
 339 IF( ANDROID_PROFILE )
 340   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 341   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 342 ELSEIF( UNIX )
 343   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 344   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 345 ENDIF()
 346
 347 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 348
 349 ########################################################################################
 350
 351 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 352 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 353 # target names duplication with other DALi modules.
 354 IF( ENABLE_COVERAGE )
 355   FIND_PROGRAM( LCOV_BIN "lcov" )
 356   IF( LCOV_BIN )
 357
 358     # Define custom rules for coverage
 359     SET(COVERAGE_DIR .cov)
 360     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 361
 362     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 363     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 364     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 365     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 366     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 367       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 368     ENDIF()
 369
 370     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 371
 372     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 373       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"*/third-party/*\" \"/usr/local/include/*\" -o dali.info )
 374
 375     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 376       DEPENDS cov_data )
 377
 378     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 379
 380     # Define custom rule for distclean
 381     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 382     ADD_CUSTOM_COMMAND(
 383           DEPENDS clean
 384           COMMENT "distribution clean"
 385           COMMAND find
 386           ARGS    .
 387           -not -name config.cmake -and \(
 388           -name tester.c -or
 389           -name Testing -or
 390           -name CMakeFiles -or
 391           -name doc -or
 392           -name cmake.depends -or
 393           -name cmake.check_depends -or
 394           -name CMakeCache.txt -or
 395           -name cmake.check_cache -or
 396           -name *.cmake -or
 397           -name Makefile -or
 398           -name core -or
 399           -name core.* -or
 400           -name gmon.out -or
 401           -name install_manifest.txt -or
 402           -name *.pc -or
 403           -name *.gcov -or
 404           -name *.gcno -or
 405           -name *.gcda -or
 406           -name *~ -or
 407           -name libdali*.so* \)
 408           | grep -v TC | xargs rm -rf
 409           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 410           VERBATIM
 411           )
 412
 413   ENDIF( LCOV_BIN )
 414 ENDIF()
 415
 416 IF( ENABLE_LINK_TEST )
 417   # Linker Test
 418   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 419   SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 420   SET( LINKER_TEST_SOURCES
 421     linker-test.cpp
 422   )
 423   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 424   MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 425   TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 426   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} )
 427   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 428 ENDIF()
 429
 430 # Configuration Messages
 431 MESSAGE( STATUS "Configuration:\n" )
 432 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 433 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 434 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 435 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 436 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 437 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 438 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 439 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 440 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 441 MESSAGE( STATUS "WebP:                             ${webp_available_ENABLED}")
 442 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 443 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORK_LOGGING}")
 444 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 445 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 446 MESSAGE( STATUS "Use pkg configure:                ${ENABLE_PKG_CONFIGURE}" )
 447 MESSAGE( STATUS "Enable link test:                 ${ENABLE_LINK_TEST}" )
 448 MESSAGE( STATUS "Enable AT-SPI:                    ${ENABLE_ATSPI}" )
 449 MESSAGE( STATUS "Enable Trace:                     ${ENABLE_TRACE_STRING}" )
 450 MESSAGE( STATUS "Enable VConf:                     ${ENABLE_VCONF}" )
 451 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 452 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 453 MESSAGE( STATUS "Compile flags:                    ${CMAKE_C_FLAGS}")
 454 MESSAGE( STATUS "CMAKE_SYSROOT:                    ${CMAKE_SYSROOT}")
 455 MESSAGE( STATUS "CMAKE_SYSTEM_INCLUDE_PATH:        ${CMAKE_SYSTEM_INCLUDE_PATH}")
 456 MESSAGE( STATUS "CMAKE_SYSTEM_LIBRARY_PATH:        ${CMAKE_SYSTEM_LIBRARY_PATH}")
 457 IF( enable_feedback )
 458   ADD_SUBDIRECTORY( plugins )
 459 ENDIF()
 460
 461 CLEAN_ARG_CACHE()