build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_CXX_STANDARD 11)
   5 SET(CMAKE_C_STANDARD 99)
   6
   7 PROJECT(${name} CXX)
   8 SET(PKG_NAME ${name})
   9
  10 SET(name "dali-adaptor")
  11
  12 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  13 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  14   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  15     message(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  16   endif()
  17 endif()
  18
  19 # Include additional macros
  20 INCLUDE( common.cmake )
  21
  22 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  23   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  24   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  25   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  26 ELSE()
  27   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  28 ENDIF()
  29
  30 # from root/build/tizen, get back to root.
  31 # set the variable only if it's not set yet. it allows to access build script
  32 # from top-level directory
  33 IF( NOT ROOT_SRC_DIR )
  34   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  35 ENDIF()
  36 # Make sure the path is absolute
  37 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  38
  39 # API VERSION (Not DALi release version)
  40 SET(${name}_VERSION_MAJOR 0)
  41 SET(${name}_VERSION_MINOR 0)
  42 SET(${name}_VERSION_PATCH 0)
  43 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  44
  45 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  46
  47 ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  48 ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  49
  50 IF("${ARCH}" STREQUAL "arm")
  51   ADD_DEFINITIONS("-DTARGET")
  52 ENDIF("${ARCH}" STREQUAL "arm")
  53
  54 # Deployment folder should come from spec file or command line:
  55 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  56 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  57
  58 # Set up the include dir
  59 SET( INCLUDE_DIR $ENV{includedir} )
  60 IF( NOT INCLUDE_DIR )
  61   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  62 ENDIF()
  63 IF( NOT INCLUDE_DIR )
  64   SET( INCLUDE_DIR ${PREFIX}/include )
  65 ENDIF()
  66
  67 # Set up the lib dir
  68 SET( LIB_DIR $ENV{libdir} )
  69 IF( NOT LIB_DIR )
  70   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  71 ENDIF()
  72 IF( NOT LIB_DIR )
  73   SET( LIB_DIR ${PREFIX}/lib )
  74 ENDIF()
  75
  76 INCLUDE( deps-check.cmake )
  77
  78 # Set up compiler flags and warnings
  79 #SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11" )
  80 #ADD_COMPILE_OPTIONS( -Wnon-virtual-dtor -Woverloaded-virtual -Wold-style-cast )
  81
  82 # TODO: Clang is a lot more strict with warnings, we should address
  83 # those issues at some point.
  84 #IF( NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" )
  85   #ADD_COMPILE_OPTIONS( -Werror )
  86 #ENDIF()
  87
  88 ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
  89
  90 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES
  91                  ${DEFINITIONS} )
  92
  93 # from root/build/tizen, get back to root
  94 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
  95
  96 # Make sure the path is absolute
  97 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  98
  99 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 100 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 101 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 102 SET(SOURCES "")
 103
 104 # Include list of modules
 105 INCLUDE( module-list.cmake )
 106
 107 # Include profile specific setup
 108 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 109
 110 # Configure the pkg-config file
 111 # Requires the following variables to be setup:
 112 # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 113 SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 114 SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali-adaptor.pc )
 115 SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali-adaptor-integration.pc )
 116 CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 117 CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 118 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 119
 120 INCLUDE_DIRECTORIES(
 121   ${ROOT_SRC_DIR}
 122   ${PROFILE_INCLUDE_DIRECTORIES}
 123 )
 124
 125 SET(LIBTYPE SHARED)
 126 IF(DEFINED STATIC)
 127   SET(LIBTYPE STATIC)
 128 ENDIF()
 129
 130 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 131
 132 # pthread required due to gcc issue
 133 FIND_LIBRARY( PTHREAD pthread )
 134 IF( PTHREAD AND NOT ANDROID_PROFILE )
 135   SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 136 ENDIF()
 137
 138 TARGET_LINK_LIBRARIES( ${name}
 139                        ${DALI_LDFLAGS}
 140   ${REQUIRED_LIBS}
 141   ${OPTIONAL_LIBS}
 142   ${COVERAGE}
 143 )
 144
 145 SET_TARGET_PROPERTIES( ${name}
 146   PROPERTIES
 147   VERSION ${DALI_ADAPTOR_VERSION}
 148   SOVERSION ${${name}_VERSION_MAJOR}
 149   CLEAN_DIRECT_OUPUT 1
 150 )
 151
 152 # Install the library so file and symlinks
 153 INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 154
 155 # Install the pkg-config file
 156 INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 157 INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 158
 159 # macro for installing headers by replacing prefix. (TODO, investigate
 160 # if there is a CMAKE way of doing this automatically)
 161 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 162   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 163   FOREACH(HEADER ${${HEADER_LIST}})
 164     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 165     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 166     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 167   ENDFOREACH(HEADER)
 168 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 169
 170
 171 ########################################################################################
 172 # INSTALL:
 173 # Set deployment directories
 174 # Due to complicated adaptor deployment the install section is pretty much converted from
 175 # the automake counterpart.
 176 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 177 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 178 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 179 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 180 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 181 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 182 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 183 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 184 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 185
 186 # Android framework headers for Android build
 187 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 188
 189 # Install headers
 190 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 191 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 192 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 193 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 194 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 195
 196 # Install Android framework headers for Android build
 197 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 198
 199 # Install DOXY
 200 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 201 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 202 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 203 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 204
 205 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE )
 206   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 207   IF( NOT WAYLAND )
 208     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 209   ENDIF()
 210 ENDIF()
 211
 212 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 213 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 214 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 215 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 216
 217 IF( ANDROID_PROFILE )
 218   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 219   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 220 ELSE()
 221   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 222   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 223 ENDIF()
 224
 225 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 226
 227 ########################################################################################
 228
 229 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 230 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 231 # target names duplication with other DALi modules.
 232 IF( UNIX AND NOT ANDROID )
 233   FIND_PROGRAM( LCOV_BIN "lcov" )
 234   IF( LCOV_BIN )
 235
 236     # Define custom rules for coverage
 237     SET(COVERAGE_DIR .cov)
 238     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 239
 240     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 241     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 242     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 243     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 244     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 245       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 246     ENDIF()
 247
 248     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 249
 250     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 251       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" -o dali.info )
 252
 253     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 254       DEPENDS cov_data )
 255
 256     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 257
 258     # Define custom rule for distclean
 259     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 260     ADD_CUSTOM_COMMAND(
 261           DEPENDS clean
 262           COMMENT "distribution clean"
 263           COMMAND find
 264           ARGS    .
 265           -not -name config.cmake -and \(
 266           -name tester.c -or
 267           -name Testing -or
 268           -name CMakeFiles -or
 269           -name doc -or
 270           -name cmake.depends -or
 271           -name cmake.check_depends -or
 272           -name CMakeCache.txt -or
 273           -name cmake.check_cache -or
 274           -name *.cmake -or
 275           -name Makefile -or
 276           -name core -or
 277           -name core.* -or
 278           -name gmon.out -or
 279           -name install_manifest.txt -or
 280           -name *.pc -or
 281           -name *.gcov -or
 282           -name *.gcno -or
 283           -name *.gcda -or
 284           -name *~ -or
 285           -name libdali*.so* \)
 286           | grep -v TC | xargs rm -rf
 287           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 288           VERBATIM
 289           )
 290
 291   ENDIF( LCOV_BIN )
 292 ENDIF( UNIX AND NOT ANDROID )
 293
 294 # Linker Test
 295 SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 296 SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 297 SET( LINKER_TEST_SOURCES
 298   linker-test.cpp
 299 )
 300 ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 301 MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 302 TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 303 TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} ${AUTOFILL_LDFLAGS} )
 304 TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 305
 306 # Configuration Messages
 307 MESSAGE( STATUS "Configuration:\n" )
 308 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 309 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 310 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 311 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 312 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 313 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 314 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 315 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 316 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 317 MESSAGE( STATUS "EldBus:                           ${eldbus_available_ENABLED}")
 318 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 319 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORKLOGGING}")
 320 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 321 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 322 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 323 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 324 IF( enable_feedback )
 325   ADD_SUBDIRECTORY( plugins )
 326 ENDIF()
 327
 328 CLEAN_ARG_CACHE()