build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.1)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_C_STANDARD 99)
   5 PROJECT(${name} CXX)
   6 SET(PKG_NAME ${name})
   7
   8 SET(name "dali2-adaptor")
   9
  10 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  11 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  13     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  14   ENDIF()
  15 ENDIF()
  16
  17 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  18 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  19
  20 # Include additional macros
  21 INCLUDE( common.cmake )
  22
  23 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  24   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  25   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  26   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  27 ELSE()
  28   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  29 ENDIF()
  30
  31 # from root/build/tizen, get back to root.
  32 # set the variable only if it's not set yet. it allows to access build script
  33 # from top-level directory
  34 IF( NOT ROOT_SRC_DIR )
  35   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  36 ENDIF()
  37 # Make sure the path is absolute
  38 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  39
  40 # API VERSION (Not DALi release version)
  41 SET(${name}_VERSION_MAJOR 2)
  42 SET(${name}_VERSION_MINOR 0)
  43 SET(${name}_VERSION_PATCH 0)
  44 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  45
  46 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  47
  48 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  49   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  50   FIND_PACKAGE( dali2-core REQUIRED)
  51 ENDIF()
  52
  53 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  54
  55 IF( UNIX )
  56   ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  57   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  58
  59   IF("${ARCH}" STREQUAL "arm")
  60     ADD_DEFINITIONS("-DTARGET")
  61   ENDIF("${ARCH}" STREQUAL "arm")
  62 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  63   IF(NOT DEFINED STATIC)
  64     ADD_DEFINITIONS( "-DBUILDING_DALI_ADAPTOR" )
  65   ENDIF()
  66
  67   ADD_DEFINITIONS( "-DDALI_ADAPTOR_COMPILATION" )
  68   ADD_DEFINITIONS( "-D_NSIG=65" )
  69 ENDIF()
  70
  71 # Deployment folder should come from spec file or command line:
  72 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  73 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  74
  75 # Set up the include dir
  76 SET( INCLUDE_DIR $ENV{includedir} )
  77 IF( NOT INCLUDE_DIR )
  78   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  79 ENDIF()
  80 IF( NOT INCLUDE_DIR )
  81   SET( INCLUDE_DIR ${PREFIX}/include )
  82 ENDIF()
  83
  84 # Set up the lib dir
  85 SET( LIB_DIR $ENV{libdir} )
  86 IF( NOT LIB_DIR )
  87   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  88 ENDIF()
  89 IF( NOT LIB_DIR )
  90   SET( LIB_DIR ${PREFIX}/lib )
  91 ENDIF()
  92
  93 # Set up the bin dir
  94 SET( BIN_DIR $ENV{bindir} )
  95 IF( NOT BIN_DIR )
  96   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
  97 ENDIF()
  98 IF( NOT BIN_DIR )
  99   SET( BIN_DIR ${PREFIX}/bin )
 100 ENDIF()
 101
 102 IF( UNIX )
 103   INCLUDE( deps-check.cmake )
 104 ENDIF()
 105
 106 # Set up compiler flags and warnings
 107 IF( UNIX )
 108   ADD_COMPILE_OPTIONS( -std=c++17 )                     # c++17 support
 109   ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
 110 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 111   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) #
 112   ADD_COMPILE_OPTIONS( /FIextern-definitions.h )        # Adds missing definitions.
 113   ADD_COMPILE_OPTIONS( /FIpreprocessor-definitions.h )  #
 114   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 115   ADD_COMPILE_OPTIONS( /std:c++17 )                     # c++17 support
 116   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 117 ENDIF()
 118
 119 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES
 120                  ${DEFINITIONS} )
 121
 122 # from root/build/tizen, get back to root
 123 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
 124
 125 # Make sure the path is absolute
 126 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 127
 128 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 129 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 130 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 131 SET(SOURCES "")
 132
 133 # Include list of modules
 134 INCLUDE( module-list.cmake )
 135
 136 # Include profile specific setup
 137 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 138
 139 IF( ENABLE_PKG_CONFIGURE )
 140   # Configure the pkg-config file
 141   # Requires the following variables to be setup:
 142   # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 143   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 144   SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor.pc )
 145   SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor-integration.pc )
 146   CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 147   CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 148 ENDIF()
 149
 150 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 151
 152 SET( THIRD_PARTY_WINDOWS_PLATFORM "" )
 153 IF( WIN32 )
 154   SET( THIRD_PARTY_WINDOWS_PLATFORM ${ROOT_SRC_DIR}/third-party/windows-platform )
 155 ENDIF()
 156
 157 INCLUDE_DIRECTORIES(
 158   ${ROOT_SRC_DIR}
 159   ${PROFILE_INCLUDE_DIRECTORIES}
 160   ${THIRD_PARTY_WINDOWS_PLATFORM}
 161   ${VCPKG_INCLUDE_DIR}
 162   ${INCLUDE_DIR}
 163 )
 164
 165 SET(LIBTYPE SHARED)
 166 IF(DEFINED STATIC)
 167   SET(LIBTYPE STATIC)
 168 ENDIF()
 169
 170 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 171
 172 IF( UNIX )
 173   # pthread required due to gcc issue
 174   FIND_LIBRARY( PTHREAD pthread )
 175   IF( PTHREAD AND NOT ANDROID_PROFILE )
 176     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 177   ENDIF()
 178 ENDIF()
 179
 180 TARGET_LINK_LIBRARIES( ${name}
 181                        ${DALI_LDFLAGS}
 182                        ${REQUIRED_LIBS}
 183                        ${OPTIONAL_LIBS}
 184                        ${COVERAGE}
 185 )
 186
 187 SET_TARGET_PROPERTIES( ${name}
 188   PROPERTIES
 189   VERSION ${DALI_ADAPTOR_VERSION}
 190   SOVERSION ${${name}_VERSION_MAJOR}
 191   CLEAN_DIRECT_OUPUT 1
 192 )
 193
 194 IF( INSTALL_CMAKE_MODULES )
 195   IF( ENABLE_DEBUG )
 196     SET( BIN_DIR "${BIN_DIR}/debug" )
 197     SET( LIB_DIR "${LIB_DIR}/debug" )
 198   ENDIF()
 199
 200   # Install the library files.
 201   INSTALL( TARGETS ${name}
 202     EXPORT ${name}-targets
 203     LIBRARY DESTINATION ${LIB_DIR}
 204     ARCHIVE DESTINATION ${LIB_DIR}
 205     RUNTIME DESTINATION ${BIN_DIR}
 206   )
 207
 208   # Install the cmake modules.
 209   INSTALL(
 210     EXPORT ${name}-targets
 211     NAMESPACE ${name}::
 212     FILE ${name}-targets.cmake
 213     DESTINATION share/${name}
 214   )
 215
 216   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 217     include(CMakeFindDependencyMacro)
 218     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 219   ")
 220   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 221
 222   # Install the pdb file.
 223   IF( ENABLE_DEBUG )
 224     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 225   ENDIF()
 226 ELSE()
 227   # Install the library so file and symlinks
 228   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 229 ENDIF()
 230
 231 IF( ENABLE_PKG_CONFIGURE )
 232   # Install the pkg-config file
 233   INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 234   INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 235 ENDIF()
 236
 237 # macro for installing headers by replacing prefix. (TODO, investigate
 238 # if there is a CMAKE way of doing this automatically)
 239 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 240   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 241   FOREACH(HEADER ${${HEADER_LIST}})
 242     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 243     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 244     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 245   ENDFOREACH(HEADER)
 246 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 247
 248
 249 ########################################################################################
 250 # INSTALL:
 251 # Set deployment directories
 252 # Due to complicated adaptor deployment the install section is pretty much converted from
 253 # the automake counterpart.
 254 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 255 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 256 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 257 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 258 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 259 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 260 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 261 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 262 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 263
 264 # Android framework headers for Android build
 265 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 266
 267 # Install headers
 268 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 269 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 270 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 271 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 272 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 273
 274 # Install Android framework headers for Android build
 275 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 276
 277 # Install DOXY
 278 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 279 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 280 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 281 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 282
 283 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE AND NOT WINDOWS_PROFILE )
 284   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 285   IF( NOT WAYLAND )
 286     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 287   ENDIF()
 288 ENDIF()
 289
 290 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 291 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 292 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 293 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 294
 295 IF( ANDROID_PROFILE )
 296   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 297   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 298 ELSEIF( UNIX )
 299   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 300   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 301 ENDIF()
 302
 303 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 304
 305 ########################################################################################
 306
 307 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 308 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 309 # target names duplication with other DALi modules.
 310 IF( ENABLE_COVERAGE )
 311   FIND_PROGRAM( LCOV_BIN "lcov" )
 312   IF( LCOV_BIN )
 313
 314     # Define custom rules for coverage
 315     SET(COVERAGE_DIR .cov)
 316     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 317
 318     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 319     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 320     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 321     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 322     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 323       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 324     ENDIF()
 325
 326     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 327
 328     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 329       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" -o dali.info )
 330
 331     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 332       DEPENDS cov_data )
 333
 334     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 335
 336     # Define custom rule for distclean
 337     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 338     ADD_CUSTOM_COMMAND(
 339           DEPENDS clean
 340           COMMENT "distribution clean"
 341           COMMAND find
 342           ARGS    .
 343           -not -name config.cmake -and \(
 344           -name tester.c -or
 345           -name Testing -or
 346           -name CMakeFiles -or
 347           -name doc -or
 348           -name cmake.depends -or
 349           -name cmake.check_depends -or
 350           -name CMakeCache.txt -or
 351           -name cmake.check_cache -or
 352           -name *.cmake -or
 353           -name Makefile -or
 354           -name core -or
 355           -name core.* -or
 356           -name gmon.out -or
 357           -name install_manifest.txt -or
 358           -name *.pc -or
 359           -name *.gcov -or
 360           -name *.gcno -or
 361           -name *.gcda -or
 362           -name *~ -or
 363           -name libdali*.so* \)
 364           | grep -v TC | xargs rm -rf
 365           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 366           VERBATIM
 367           )
 368
 369   ENDIF( LCOV_BIN )
 370 ENDIF()
 371
 372 IF( ENABLE_LINK_TEST )
 373   # Linker Test
 374   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 375   SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 376   SET( LINKER_TEST_SOURCES
 377     linker-test.cpp
 378   )
 379   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 380   MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 381   TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 382   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} )
 383   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 384 ENDIF()
 385
 386 # Configuration Messages
 387 MESSAGE( STATUS "Configuration:\n" )
 388 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 389 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 390 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 391 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 392 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 393 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 394 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 395 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 396 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 397 MESSAGE( STATUS "EldBus:                           ${eldbus_available_ENABLED}")
 398 MESSAGE( STATUS "WebP:                             ${webp_available_ENABLED}")
 399 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 400 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORKLOGGING}")
 401 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 402 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 403 MESSAGE( STATUS "Use pkg configure:                ${ENABLE_PKG_CONFIGURE}" )
 404 MESSAGE( STATUS "Enable link test:                 ${ENABLE_LINK_TEST}" )
 405 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 406 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 407 MESSAGE( STATUS "Compile flags:                    ${CMAKE_C_FLAGS}")
 408 IF( enable_feedback )
 409   ADD_SUBDIRECTORY( plugins )
 410 ENDIF()
 411
 412 CLEAN_ARG_CACHE()