build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_C_STANDARD 99)
   5 SET(CMAKE_CXX_STANDARD 17)
   6 PROJECT(${name} CXX)
   7 SET(PKG_NAME ${name})
   8
   9 SET(name "dali2-adaptor")
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  19 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  20 OPTION(ENABLE_ATSPI          "Enable AT-SPI accessibility" ON)
  21 OPTION(ENABLE_TRACE          "Enable Trace" OFF)
  22
  23 # Include additional macros
  24 INCLUDE( common.cmake )
  25
  26 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  27   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  28   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  29   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  30 ELSE()
  31   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  32 ENDIF()
  33
  34 # from root/build/tizen, get back to root.
  35 # set the variable only if it's not set yet. it allows to access build script
  36 # from top-level directory
  37 IF( NOT ROOT_SRC_DIR )
  38   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  39 ENDIF()
  40 # Make sure the path is absolute
  41 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  42
  43 # API VERSION (Not DALi release version)
  44 SET(${name}_VERSION_MAJOR 2)
  45 SET(${name}_VERSION_MINOR 0)
  46 SET(${name}_VERSION_PATCH 0)
  47 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  48
  49 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  50
  51 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  52   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  53   FIND_PACKAGE( dali2-core REQUIRED)
  54 ENDIF()
  55
  56 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  57
  58 IF( UNIX )
  59   ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  60   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  61
  62   IF("${ARCH}" STREQUAL "arm")
  63     ADD_DEFINITIONS("-DTARGET")
  64   ENDIF("${ARCH}" STREQUAL "arm")
  65 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  66   IF(NOT DEFINED STATIC)
  67     ADD_DEFINITIONS( "-DBUILDING_DALI_ADAPTOR" )
  68   ENDIF()
  69
  70   ADD_DEFINITIONS( "-DDALI_ADAPTOR_COMPILATION" )
  71   ADD_DEFINITIONS( "-D_NSIG=65" )
  72 ENDIF()
  73
  74 # Deployment folder should come from spec file or command line:
  75 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  76 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  77
  78 # Set up the include dir
  79 SET( INCLUDE_DIR $ENV{includedir} )
  80 IF( NOT INCLUDE_DIR )
  81   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  82 ENDIF()
  83 IF( NOT INCLUDE_DIR )
  84   SET( INCLUDE_DIR ${PREFIX}/include )
  85 ENDIF()
  86
  87 # Set up the lib dir
  88 SET( LIB_DIR $ENV{libdir} )
  89 IF( NOT LIB_DIR )
  90   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  91 ENDIF()
  92 IF( NOT LIB_DIR )
  93   SET( LIB_DIR ${PREFIX}/lib )
  94 ENDIF()
  95
  96 # Set up the bin dir
  97 SET( BIN_DIR $ENV{bindir} )
  98 IF( NOT BIN_DIR )
  99   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
 100 ENDIF()
 101 IF( NOT BIN_DIR )
 102   SET( BIN_DIR ${PREFIX}/bin )
 103 ENDIF()
 104
 105 IF( UNIX )
 106   INCLUDE( deps-check.cmake )
 107 ENDIF()
 108
 109 IF( NOT DALI_ELDBUS_AVAILABLE )
 110   SET( ENABLE_ATSPI OFF )
 111 ENDIF()
 112
 113 IF( ENABLE_TRACE )
 114   ADD_DEFINITIONS("-DTRACE_ENABLED")
 115 ENDIF()
 116
 117 # Set up compiler flags and warnings
 118 IF( UNIX )
 119   ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
 120 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 121   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) #
 122   ADD_COMPILE_OPTIONS( /FIextern-definitions.h )        # Adds missing definitions.
 123   ADD_COMPILE_OPTIONS( /FIpreprocessor-definitions.h )  #
 124   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 125   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 126 ENDIF()
 127
 128 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES
 129                  ${DEFINITIONS} )
 130
 131 # from root/build/tizen, get back to root
 132 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
 133
 134 # Make sure the path is absolute
 135 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 136
 137 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 138 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 139 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 140 SET(SOURCES "")
 141
 142 # Include list of modules
 143 INCLUDE( module-list.cmake )
 144
 145 # Include profile specific setup
 146 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 147
 148 IF ( ENABLE_ATSPI )
 149   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_bridge_src_files} )
 150 ELSE()
 151   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_dummy_src_files} )
 152 ENDIF()
 153
 154 IF( ENABLE_PKG_CONFIGURE )
 155   # Configure the pkg-config file
 156   # Requires the following variables to be setup:
 157   # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 158   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 159   SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor.pc )
 160   SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor-integration.pc )
 161   CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 162   CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 163 ENDIF()
 164
 165 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 166
 167 SET( THIRD_PARTY_WINDOWS_PLATFORM "" )
 168 IF( WIN32 )
 169   SET( THIRD_PARTY_WINDOWS_PLATFORM ${ROOT_SRC_DIR}/third-party/windows-platform )
 170 ENDIF()
 171
 172 SET( THIRD_PARTY_MACOS_PLATFORM "" )
 173 IF( APPLE )
 174   SET( THIRD_PARTY_MACOS_PLATFORM ${ROOT_SRC_DIR}/third-party/macos-platform )
 175 ENDIF()
 176
 177 INCLUDE_DIRECTORIES(
 178   ${ROOT_SRC_DIR}
 179   ${PROFILE_INCLUDE_DIRECTORIES}
 180   ${THIRD_PARTY_WINDOWS_PLATFORM}
 181   ${THIRD_PARTY_MACOS_PLATFORM}
 182   ${VCPKG_INCLUDE_DIR}
 183   ${INCLUDE_DIR}
 184 )
 185
 186 SET(LIBTYPE SHARED)
 187 IF(DEFINED STATIC)
 188   SET(LIBTYPE STATIC)
 189 ENDIF()
 190
 191 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 192
 193 IF( UNIX )
 194   # pthread required due to gcc issue
 195   FIND_LIBRARY( PTHREAD pthread )
 196   IF( PTHREAD AND NOT ANDROID_PROFILE )
 197     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 198   ENDIF()
 199 ENDIF()
 200
 201 TARGET_LINK_LIBRARIES( ${name}
 202                        ${DALI_LDFLAGS}
 203                        ${REQUIRED_LIBS}
 204                        ${OPTIONAL_LIBS}
 205                        ${COVERAGE}
 206 )
 207
 208 SET_TARGET_PROPERTIES( ${name}
 209   PROPERTIES
 210   VERSION ${DALI_ADAPTOR_VERSION}
 211   SOVERSION ${${name}_VERSION_MAJOR}
 212   CLEAN_DIRECT_OUPUT 1
 213 )
 214
 215 IF( INSTALL_CMAKE_MODULES )
 216   IF( ENABLE_DEBUG )
 217     SET( BIN_DIR "${BIN_DIR}/debug" )
 218     SET( LIB_DIR "${LIB_DIR}/debug" )
 219   ENDIF()
 220
 221   # Install the library files.
 222   INSTALL( TARGETS ${name}
 223     EXPORT ${name}-targets
 224     LIBRARY DESTINATION ${LIB_DIR}
 225     ARCHIVE DESTINATION ${LIB_DIR}
 226     RUNTIME DESTINATION ${BIN_DIR}
 227   )
 228
 229   # Install the cmake modules.
 230   INSTALL(
 231     EXPORT ${name}-targets
 232     NAMESPACE ${name}::
 233     FILE ${name}-targets.cmake
 234     DESTINATION share/${name}
 235   )
 236
 237   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 238     include(CMakeFindDependencyMacro)
 239     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 240   ")
 241   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 242
 243   # Install the pdb file.
 244   IF( ENABLE_DEBUG AND WIN32 )
 245     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 246   ENDIF()
 247 ELSE()
 248   # Install the library so file and symlinks
 249   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 250 ENDIF()
 251
 252 IF( ENABLE_PKG_CONFIGURE )
 253   # Install the pkg-config file
 254   INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 255   INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 256 ENDIF()
 257
 258 # macro for installing headers by replacing prefix. (TODO, investigate
 259 # if there is a CMAKE way of doing this automatically)
 260 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 261   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 262   FOREACH(HEADER ${${HEADER_LIST}})
 263     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 264     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 265     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 266   ENDFOREACH(HEADER)
 267 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 268
 269
 270 ########################################################################################
 271 # INSTALL:
 272 # Set deployment directories
 273 # Due to complicated adaptor deployment the install section is pretty much converted from
 274 # the automake counterpart.
 275 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 276 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 277 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 278 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 279 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 280 SET( tizencanvasrendererdevelapidir ${tizenadaptorframeworkdevelapidir}/canvas-renderer )
 281 SET( tizenwebenginedevelapidir ${tizenadaptorframeworkdevelapidir}/web-engine )
 282 SET( tizenatspiinterfacesdevelapidir ${tizenadaptordevelapidir}/atspi-interfaces )
 283 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 284 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 285 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 286 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 287
 288 # Android framework headers for Android build
 289 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 290
 291 # Install headers
 292 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 293 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 294 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 295 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 296 INSTALL( FILES ${devel_api_adaptor_framework_canvas_renderer_header_files} DESTINATION ${tizencanvasrendererdevelapidir} )
 297 INSTALL( FILES ${devel_api_adaptor_framework_web_engine_header_files} DESTINATION ${tizenwebenginedevelapidir} )
 298 INSTALL( FILES ${devel_api_atspi_interfaces_header_files} DESTINATION ${tizenatspiinterfacesdevelapidir} )
 299 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 300
 301 # Install Android framework headers for Android build
 302 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 303
 304 # Install DOXY
 305 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 306 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 307 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 308 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 309
 310 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE AND NOT WINDOWS_PROFILE AND NOT MACOS_PROFILE )
 311   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 312   IF( NOT WAYLAND )
 313     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 314   ENDIF()
 315 ENDIF()
 316
 317 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 318 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 319 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 320 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 321
 322 IF( ANDROID_PROFILE )
 323   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 324   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 325 ELSEIF( UNIX )
 326   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 327   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 328 ENDIF()
 329
 330 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 331
 332 ########################################################################################
 333
 334 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 335 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 336 # target names duplication with other DALi modules.
 337 IF( ENABLE_COVERAGE )
 338   FIND_PROGRAM( LCOV_BIN "lcov" )
 339   IF( LCOV_BIN )
 340
 341     # Define custom rules for coverage
 342     SET(COVERAGE_DIR .cov)
 343     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 344
 345     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 346     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 347     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 348     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 349     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 350       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 351     ENDIF()
 352
 353     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 354
 355     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 356       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" \"*/third-party/*\" \"/usr/local/include/*\" -o dali.info )
 357
 358     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 359       DEPENDS cov_data )
 360
 361     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 362
 363     # Define custom rule for distclean
 364     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 365     ADD_CUSTOM_COMMAND(
 366           DEPENDS clean
 367           COMMENT "distribution clean"
 368           COMMAND find
 369           ARGS    .
 370           -not -name config.cmake -and \(
 371           -name tester.c -or
 372           -name Testing -or
 373           -name CMakeFiles -or
 374           -name doc -or
 375           -name cmake.depends -or
 376           -name cmake.check_depends -or
 377           -name CMakeCache.txt -or
 378           -name cmake.check_cache -or
 379           -name *.cmake -or
 380           -name Makefile -or
 381           -name core -or
 382           -name core.* -or
 383           -name gmon.out -or
 384           -name install_manifest.txt -or
 385           -name *.pc -or
 386           -name *.gcov -or
 387           -name *.gcno -or
 388           -name *.gcda -or
 389           -name *~ -or
 390           -name libdali*.so* \)
 391           | grep -v TC | xargs rm -rf
 392           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 393           VERBATIM
 394           )
 395
 396   ENDIF( LCOV_BIN )
 397 ENDIF()
 398
 399 IF( ENABLE_LINK_TEST )
 400   # Linker Test
 401   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 402   SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 403   SET( LINKER_TEST_SOURCES
 404     linker-test.cpp
 405   )
 406   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 407   MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 408   TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 409   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} )
 410   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 411 ENDIF()
 412
 413 # Configuration Messages
 414 MESSAGE( STATUS "Configuration:\n" )
 415 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 416 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 417 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 418 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 419 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 420 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 421 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 422 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 423 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 424 MESSAGE( STATUS "WebP:                             ${webp_available_ENABLED}")
 425 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 426 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORK_LOGGING}")
 427 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 428 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 429 MESSAGE( STATUS "Use pkg configure:                ${ENABLE_PKG_CONFIGURE}" )
 430 MESSAGE( STATUS "Enable link test:                 ${ENABLE_LINK_TEST}" )
 431 MESSAGE( STATUS "Enable AT-SPI:                    ${ENABLE_ATSPI}" )
 432 MESSAGE( STATUS "Enable Trace:                     ${ENABLE_TRACE}" )
 433 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 434 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 435 MESSAGE( STATUS "Compile flags:                    ${CMAKE_C_FLAGS}")
 436 MESSAGE( STATUS "CMAKE_SYSROOT:                    ${CMAKE_SYSROOT}")
 437 MESSAGE( STATUS "CMAKE_SYSTEM_INCLUDE_PATH:        ${CMAKE_SYSTEM_INCLUDE_PATH}")
 438 MESSAGE( STATUS "CMAKE_SYSTEM_LIBRARY_PATH:        ${CMAKE_SYSTEM_LIBRARY_PATH}")
 439 IF( enable_feedback )
 440   ADD_SUBDIRECTORY( plugins )
 441 ENDIF()
 442
 443 CLEAN_ARG_CACHE()