build/tizen/CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED(VERSION 3.8.2)
   2 CMAKE_POLICY(SET CMP0012 NEW) # Prevent dereferencing of OFF/ON as variables
   3
   4 SET(CMAKE_C_STANDARD 99)
   5 SET(CMAKE_CXX_STANDARD 17)
   6 PROJECT(${name} CXX)
   7 SET(PKG_NAME ${name})
   8
   9 SET(name "dali2-adaptor")
  10
  11 SET(GCC_COMPILER_VERSION_REQUIRED "6")
  12 IF(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  13   IF(CMAKE_CXX_COMPILER_VERSION VERSION_LESS GCC_COMPILER_VERSION_REQUIRED)
  14     MESSAGE(FATAL_ERROR "The GCC required compiler version is " ${GCC_COMPILER_VERSION_REQUIRED})
  15   ENDIF()
  16 ENDIF()
  17
  18 OPTION(ENABLE_PKG_CONFIGURE  "Use pkgconfig" ON)
  19 OPTION(ENABLE_LINK_TEST      "Enable the link test" ON)
  20 OPTION(ENABLE_ATSPI          "Enable AT-SPI accessibility" OFF)
  21
  22 # Include additional macros
  23 INCLUDE( common.cmake )
  24
  25 IF(CMAKE_BUILD_TYPE MATCHES Debug)
  26   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Debug )
  27   SET( ENABLE_DEBUG "ON" CACHE STRING "" )
  28   SET( ENABLE_EXPORTALL "ON" CACHE STRING "" )
  29 ELSE()
  30   MESSAGE( STATUS "CMAKE_BUILD_TYPE: " Release )
  31 ENDIF()
  32
  33 # from root/build/tizen, get back to root.
  34 # set the variable only if it's not set yet. it allows to access build script
  35 # from top-level directory
  36 IF( NOT ROOT_SRC_DIR )
  37   SET(ROOT_SRC_DIR ${CMAKE_SOURCE_DIR}/../..)
  38 ENDIF()
  39 # Make sure the path is absolute
  40 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
  41
  42 # API VERSION (Not DALi release version)
  43 SET(${name}_VERSION_MAJOR 2)
  44 SET(${name}_VERSION_MINOR 0)
  45 SET(${name}_VERSION_PATCH 0)
  46 SET(${name}_VERSION ${${name}_VERSION_MAJOR}.${${name}_VERSION_MINOR}.${${name}_VERSION_PATCH})
  47
  48 SET(DALI_ADAPTOR_VERSION ${${name}_VERSION} )
  49
  50 IF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  51   FIND_PACKAGE( dali-windows-dependencies REQUIRED)
  52   FIND_PACKAGE( dali2-core REQUIRED)
  53 ENDIF()
  54
  55 SET( VCPKG_INCLUDE_DIR "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/include")
  56
  57 IF( UNIX )
  58   ADD_DEFINITIONS(-DPLATFORM_TIZEN)
  59   ADD_DEFINITIONS(-DPIC -DSTDC_HEADERS)
  60
  61   IF("${ARCH}" STREQUAL "arm")
  62     ADD_DEFINITIONS("-DTARGET")
  63   ENDIF("${ARCH}" STREQUAL "arm")
  64 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
  65   IF(NOT DEFINED STATIC)
  66     ADD_DEFINITIONS( "-DBUILDING_DALI_ADAPTOR" )
  67   ENDIF()
  68
  69   ADD_DEFINITIONS( "-DDALI_ADAPTOR_COMPILATION" )
  70   ADD_DEFINITIONS( "-D_NSIG=65" )
  71 ENDIF()
  72
  73 # Deployment folder should come from spec file or command line:
  74 SET( PREFIX ${CMAKE_INSTALL_PREFIX})
  75 SET( EXEC_PREFIX ${CMAKE_INSTALL_PREFIX})
  76
  77 # Set up the include dir
  78 SET( INCLUDE_DIR $ENV{includedir} )
  79 IF( NOT INCLUDE_DIR )
  80   SET( INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR} )
  81 ENDIF()
  82 IF( NOT INCLUDE_DIR )
  83   SET( INCLUDE_DIR ${PREFIX}/include )
  84 ENDIF()
  85
  86 # Set up the lib dir
  87 SET( LIB_DIR $ENV{libdir} )
  88 IF( NOT LIB_DIR )
  89   SET( LIB_DIR ${CMAKE_INSTALL_LIBDIR} )
  90 ENDIF()
  91 IF( NOT LIB_DIR )
  92   SET( LIB_DIR ${PREFIX}/lib )
  93 ENDIF()
  94
  95 # Set up the bin dir
  96 SET( BIN_DIR $ENV{bindir} )
  97 IF( NOT BIN_DIR )
  98   SET( BIN_DIR ${CMAKE_INSTALL_BINDIR} )
  99 ENDIF()
 100 IF( NOT BIN_DIR )
 101   SET( BIN_DIR ${PREFIX}/bin )
 102 ENDIF()
 103
 104 IF( UNIX )
 105   INCLUDE( deps-check.cmake )
 106 ENDIF()
 107
 108 # Set up compiler flags and warnings
 109 IF( UNIX )
 110   ADD_COMPILE_OPTIONS( -Wall ${DALI_CFLAGS} )# -Wextra -Wno-unused-parameter )# -Wfloat-equal )
 111 ELSEIF( WIN32 ) # WIN32 includes x64 as well according to the cmake doc.
 112   ADD_COMPILE_OPTIONS( /FIdali-windows-dependencies.h ) #
 113   ADD_COMPILE_OPTIONS( /FIextern-definitions.h )        # Adds missing definitions.
 114   ADD_COMPILE_OPTIONS( /FIpreprocessor-definitions.h )  #
 115   ADD_COMPILE_OPTIONS( /vmg )                           # Avoids a 'reinterpret_cast' compile error while compiling signals and callbacks.
 116   ADD_COMPILE_OPTIONS( /wd4251 )                        # Ignores warning C4251: "'identifier' : class 'type' needs to have dll-interface to be used by clients of class 'type2'"
 117 ENDIF()
 118
 119 ADD_DEFINITIONS( -DNON_POWER_OF_TWO_TEXTURES
 120                  ${DEFINITIONS} )
 121
 122 # from root/build/tizen, get back to root
 123 SET(ROOT_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../../)
 124
 125 # Make sure the path is absolute
 126 GET_FILENAME_COMPONENT(ROOT_SRC_DIR ${ROOT_SRC_DIR} ABSOLUTE)
 127
 128 SET(SOURCE_DIR "${ROOT_SRC_DIR}/dali")
 129 SET(ADAPTOR_ROOT ${ROOT_SRC_DIR})
 130 SET(PACKAGE_DOXY_SRC_DIR "${ROOT_SRC_DIR}/doc")
 131 SET(SOURCES "")
 132
 133 # Include list of modules
 134 INCLUDE( module-list.cmake )
 135
 136 # Include profile specific setup
 137 INCLUDE( profiles/${PROFILE_LCASE}-profile.cmake )
 138
 139 IF ( ENABLE_ATSPI )
 140   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_bridge_src_files} )
 141 ELSE()
 142   SET( SOURCES ${SOURCES} ${adaptor_accessibility_atspi_dummy_src_files} )
 143 ENDIF()
 144
 145 IF( ENABLE_PKG_CONFIGURE )
 146   # Configure the pkg-config file
 147   # Requires the following variables to be setup:
 148   # @PREFIX@ @EXEC_PREFIX@ @DALI_ADAPTOR_VERSION@ @LIB_DIR@ @DEV_INCLUDE_PATH@
 149   SET( DEV_INCLUDE_PATH ${INCLUDE_DIR} )
 150   SET( ADAPTOR_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor.pc )
 151   SET( ADAPTOR_INTEGRATION_PKG_CFG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/dali2-adaptor-integration.pc )
 152   CONFIGURE_FILE( ${ADAPTOR_PKG_CFG_FILE}.in ${ADAPTOR_PKG_CFG_FILE} @ONLY )
 153   CONFIGURE_FILE( ${ADAPTOR_INTEGRATION_PKG_CFG_FILE}.in ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} @ONLY )
 154 ENDIF()
 155
 156 CONFIGURE_FILE( ${CMAKE_CURRENT_SOURCE_DIR}/system-cache-path.in ${ADAPTOR_ROOT}/dali/internal/adaptor/common/system-cache-path.cpp @ONLY)
 157
 158 SET( THIRD_PARTY_WINDOWS_PLATFORM "" )
 159 IF( WIN32 )
 160   SET( THIRD_PARTY_WINDOWS_PLATFORM ${ROOT_SRC_DIR}/third-party/windows-platform )
 161 ENDIF()
 162
 163 INCLUDE_DIRECTORIES(
 164   ${ROOT_SRC_DIR}
 165   ${PROFILE_INCLUDE_DIRECTORIES}
 166   ${THIRD_PARTY_WINDOWS_PLATFORM}
 167   ${VCPKG_INCLUDE_DIR}
 168   ${INCLUDE_DIR}
 169 )
 170
 171 SET(LIBTYPE SHARED)
 172 IF(DEFINED STATIC)
 173   SET(LIBTYPE STATIC)
 174 ENDIF()
 175
 176 ADD_LIBRARY( ${name} ${LIBTYPE} ${SOURCES} )
 177
 178 IF( UNIX )
 179   # pthread required due to gcc issue
 180   FIND_LIBRARY( PTHREAD pthread )
 181   IF( PTHREAD AND NOT ANDROID_PROFILE )
 182     SET( OPTIONAL_LIBS ${OPTIONAL_LIBS} -lpthread )
 183   ENDIF()
 184 ENDIF()
 185
 186 TARGET_LINK_LIBRARIES( ${name}
 187                        ${DALI_LDFLAGS}
 188                        ${REQUIRED_LIBS}
 189                        ${OPTIONAL_LIBS}
 190                        ${COVERAGE}
 191 )
 192
 193 SET_TARGET_PROPERTIES( ${name}
 194   PROPERTIES
 195   VERSION ${DALI_ADAPTOR_VERSION}
 196   SOVERSION ${${name}_VERSION_MAJOR}
 197   CLEAN_DIRECT_OUPUT 1
 198 )
 199
 200 IF( INSTALL_CMAKE_MODULES )
 201   IF( ENABLE_DEBUG )
 202     SET( BIN_DIR "${BIN_DIR}/debug" )
 203     SET( LIB_DIR "${LIB_DIR}/debug" )
 204   ENDIF()
 205
 206   # Install the library files.
 207   INSTALL( TARGETS ${name}
 208     EXPORT ${name}-targets
 209     LIBRARY DESTINATION ${LIB_DIR}
 210     ARCHIVE DESTINATION ${LIB_DIR}
 211     RUNTIME DESTINATION ${BIN_DIR}
 212   )
 213
 214   # Install the cmake modules.
 215   INSTALL(
 216     EXPORT ${name}-targets
 217     NAMESPACE ${name}::
 218     FILE ${name}-targets.cmake
 219     DESTINATION share/${name}
 220   )
 221
 222   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake "
 223     include(CMakeFindDependencyMacro)
 224     include(\${CMAKE_CURRENT_LIST_DIR}/${name}-targets.cmake)
 225   ")
 226   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${name}-config.cmake DESTINATION share/${name})
 227
 228   # Install the pdb file.
 229   IF( ENABLE_DEBUG )
 230     install( FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/${name}.pdb DESTINATION ${BIN_DIR} )
 231   ENDIF()
 232 ELSE()
 233   # Install the library so file and symlinks
 234   INSTALL( TARGETS ${name} DESTINATION ${LIB_DIR} )
 235 ENDIF()
 236
 237 IF( ENABLE_PKG_CONFIGURE )
 238   # Install the pkg-config file
 239   INSTALL( FILES ${ADAPTOR_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 240   INSTALL( FILES ${ADAPTOR_INTEGRATION_PKG_CFG_FILE} DESTINATION ${LIB_DIR}/pkgconfig )
 241 ENDIF()
 242
 243 # macro for installing headers by replacing prefix. (TODO, investigate
 244 # if there is a CMAKE way of doing this automatically)
 245 MACRO(INSTALL_HEADERS_WITH_DIRECTORY HEADER_LIST STRIP_PREFIX REPLACE_PREFIX)
 246   GET_FILENAME_COMPONENT( SPREFIX ${STRIP_PREFIX} ABSOLUTE )
 247   FOREACH(HEADER ${${HEADER_LIST}})
 248     STRING(REGEX MATCH "(.*)[/]" DIR ${HEADER})
 249     STRING(REPLACE ${SPREFIX} ${REPLACE_PREFIX} NEWDIR ${DIR})
 250     INSTALL(FILES ${HEADER} DESTINATION ${INCLUDE_DIR}/${NEWDIR})
 251   ENDFOREACH(HEADER)
 252 ENDMACRO(INSTALL_HEADERS_WITH_DIRECTORY)
 253
 254
 255 ########################################################################################
 256 # INSTALL:
 257 # Set deployment directories
 258 # Due to complicated adaptor deployment the install section is pretty much converted from
 259 # the automake counterpart.
 260 SET( tizenadaptorpublicapidir ${INCLUDE_DIR}/dali/public-api )
 261 SET( tizenadaptordevelapidir ${INCLUDE_DIR}/dali/devel-api )
 262 SET( tizenadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework )
 263 SET( tizenadaptorframeworkpublicapidir ${tizenadaptorpublicapidir}/adaptor-framework )
 264 SET( tizenadaptorframeworkdevelapidir ${tizenadaptordevelapidir}/adaptor-framework )
 265 SET( tizentextabstractiondevelapidir ${tizenadaptordevelapidir}/text-abstraction )
 266 SET( tizenadaptordaliheaderdir ${INCLUDE_DIR}/dali )
 267 SET( tizenwatchpublicapidir ${tizenadaptorpublicapidir}/watch )
 268 SET( tizencapturepublicapidir ${tizenadaptorpublicapidir}/capture )
 269
 270 # Android framework headers for Android build
 271 SET( androidadaptorintegrationapidir ${INCLUDE_DIR}/dali/integration-api/adaptor-framework/android )
 272
 273 # Install headers
 274 INSTALL( FILES ${public_api_header_files} DESTINATION ${tizenadaptorpublicapidir} )
 275 INSTALL( FILES ${adaptor_integration_api_header_files} DESTINATION ${tizenadaptorintegrationapidir} )
 276 INSTALL( FILES ${public_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 277 INSTALL( FILES ${devel_api_adaptor_framework_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 278 INSTALL( FILES ${text_abstraction_header_files} DESTINATION ${tizentextabstractiondevelapidir} )
 279
 280 # Install Android framework headers for Android build
 281 INSTALL( FILES ${adaptor_integration_api_android_header_files} DESTINATION ${androidadaptorintegrationapidir} )
 282
 283 # Install DOXY
 284 SET( packagedoxydir ${INCLUDE_DIR}/dali/doc )
 285 SET( package_doxy_dir ${ADAPTOR_ROOT}/doc )
 286 INCLUDE( ${ADAPTOR_ROOT}/doc/file.list )
 287 INSTALL( FILES ${package_doxy_files} DESTINATION ${packagedoxydir} )
 288
 289 IF( NOT UBUNTU_PROFILE AND NOT ANDROID_PROFILE AND NOT WINDOWS_PROFILE )
 290   INSTALL( FILES ${public_api_adaptor_tizen_header_files} DESTINATION ${tizenadaptorframeworkpublicapidir} )
 291   IF( NOT WAYLAND )
 292     INSTALL( FILES ${devel_api_adaptor_tizen_x11_header_files} DESTINATION ${tizenadaptorframeworkdevelapidir} )
 293   ENDIF()
 294 ENDIF()
 295
 296 INSTALL( FILES ${adaptor_dali_header_file} DESTINATION ${tizenadaptordaliheaderdir} )
 297 INSTALL( FILES ${adaptor_dali_wearable_header_file} DESTINATION ${tizenadaptorpublicapidir} )
 298 INSTALL( FILES ${public_dali_watch_header_files} DESTINATION ${tizenwatchpublicapidir} )
 299 INSTALL( FILES ${public_dali_capture_header_files} DESTINATION ${tizencapturepublicapidir} )
 300
 301 IF( ANDROID_PROFILE )
 302   SET( daliShaderbinCacheDir ${CMAKE_INSTALL_PREFIX}/core/shaderbin/)
 303   INSTALL( DIRECTORY DESTINATION ${daliShaderbinCacheDir} )
 304 ELSEIF( UNIX )
 305   SET( daliShaderbinCacheDir ${CMAKE_BINARY_DIR}/${dataReadOnlyDir}/core/shaderbin/)
 306   INSTALL( DIRECTORY DESTINATION ${dataReadOnlyDir}/core/shaderbin )
 307 ENDIF()
 308
 309 INSTALL( FILES ${ADAPTOR_ROOT}/adaptors/scripts/dalireslog.sh DESTINATION ${CMAKE_INSTALL_PREFIX}/bin )
 310
 311 ########################################################################################
 312
 313 # The DALI_ADAPTOR_PREFIX must be set if this CMakeLists.txt is executed
 314 # from the top-level CMake script using ADD_SUBDIRECTORY() to avoid
 315 # target names duplication with other DALi modules.
 316 IF( ENABLE_COVERAGE )
 317   FIND_PROGRAM( LCOV_BIN "lcov" )
 318   IF( LCOV_BIN )
 319
 320     # Define custom rules for coverage
 321     SET(COVERAGE_DIR .cov)
 322     SET(COVERAGE_OUTPUT_DIR doc/coverage)
 323
 324     # lcov prior to 1.10 doesn't have -rc option; this and subsequent version don't output
 325     # branch coverage. Determine the lcov version, and enable branch coverage accordingly.
 326     EXECUTE_PROCESS( COMMAND bash -c "${LCOV_BIN} --version | cut -d' ' -f4" OUTPUT_VARIABLE LCOV_VERSION )
 327     STRING( REPLACE "." ";" LCOV_VLIST ${LCOV_VERSION})
 328     IF( NOT $<VERSION_LESS:${LCOV_VERSION},"1.10"> )
 329       SET(LCOV_OPTS --rc lcov_branch_coverage=1)
 330     ENDIF()
 331
 332     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}rename_cov_data ./rename-cov-data )
 333
 334     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}cov_data ${LCOV_BIN} ${LCOV_OPTS} --base-directory . --directory . -c -o dali.info
 335       COMMAND ${LCOV_BIN} ${LCOV_OPTS} --remove dali.info \"*/dali-env/*\" \"/usr/include/*\" -o dali.info )
 336
 337     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}coverage genhtml ${LCOV_OPTS} -o ${COVERAGE_OUTPUT_DIR} dali.info
 338       DEPENDS cov_data )
 339
 340     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}reset_coverage @${LCOV_BIN} -z --directory `pwd` )
 341
 342     # Define custom rule for distclean
 343     ADD_CUSTOM_TARGET( ${DALI_ADAPTOR_PREFIX}distclean @echo cleaning for source distribution )
 344     ADD_CUSTOM_COMMAND(
 345           DEPENDS clean
 346           COMMENT "distribution clean"
 347           COMMAND find
 348           ARGS    .
 349           -not -name config.cmake -and \(
 350           -name tester.c -or
 351           -name Testing -or
 352           -name CMakeFiles -or
 353           -name doc -or
 354           -name cmake.depends -or
 355           -name cmake.check_depends -or
 356           -name CMakeCache.txt -or
 357           -name cmake.check_cache -or
 358           -name *.cmake -or
 359           -name Makefile -or
 360           -name core -or
 361           -name core.* -or
 362           -name gmon.out -or
 363           -name install_manifest.txt -or
 364           -name *.pc -or
 365           -name *.gcov -or
 366           -name *.gcno -or
 367           -name *.gcda -or
 368           -name *~ -or
 369           -name libdali*.so* \)
 370           | grep -v TC | xargs rm -rf
 371           TARGET  ${DALI_ADAPTOR_PREFIX}distclean
 372           VERBATIM
 373           )
 374
 375   ENDIF( LCOV_BIN )
 376 ENDIF()
 377
 378 IF( ENABLE_LINK_TEST )
 379   # Linker Test
 380   SET( DALI_TEST_SUITE_DIR ${ROOT_SRC_DIR}/automated-tests/src/dali/dali-test-suite-utils )
 381   SET( LINKER_TEST_NAME ${DALI_ADAPTOR_PREFIX}linker-test )
 382   SET( LINKER_TEST_SOURCES
 383     linker-test.cpp
 384   )
 385   ADD_EXECUTABLE( ${LINKER_TEST_NAME} ${LINKER_TEST_SOURCES} )
 386   MESSAGE(STATUS "libs: ${DALICORE_LDFLAGS}")
 387   TARGET_COMPILE_OPTIONS( ${LINKER_TEST_NAME} PRIVATE -I${ROOT_SRC_DIR} ${DALICORE_CFLAGS} )
 388   TARGET_LINK_LIBRARIES(${LINKER_TEST_NAME} ${name} ${DALICORE_LDFLAGS} ${VCONF_LDFLAGS} ${HARFBUZZ_LDFLAGS} )
 389   TARGET_INCLUDE_DIRECTORIES( ${LINKER_TEST_NAME} PRIVATE ${DALI_TEST_SUITE_DIR} )
 390 ENDIF()
 391
 392 # Configuration Messages
 393 MESSAGE( STATUS "Configuration:\n" )
 394 MESSAGE( STATUS "Prefix:                           ${PREFIX}")
 395 MESSAGE( STATUS "Lib Dir:                          ${LIB_DIR}" )
 396 MESSAGE( STATUS "Include Dir:                      ${INCLUDE_DIR}" )
 397 MESSAGE( STATUS "Coverage:                         ${ENABLE_COVERAGE}" )
 398 MESSAGE( STATUS "Debug Build:                      ${ENABLE_DEBUG}")
 399 MESSAGE( STATUS "Freetype bitmap support (Emoji):  ${freetype_bitmap_support_ENABLED}")
 400 MESSAGE( STATUS "Profile:                          ${ENABLE_PROFILE}")
 401 MESSAGE( STATUS "Data Dir (Read/Write):            ${dataReadWriteDir}")
 402 MESSAGE( STATUS "Data Dir (Read Only):             ${dataReadOnlyDir}")
 403 MESSAGE( STATUS "WebP:                             ${webp_available_ENABLED}")
 404 MESSAGE( STATUS "Shader Binary Cache:              ${ENABLE_SHADERBINCACHE}")
 405 MESSAGE( STATUS "Network logging enabled:          ${ENABLE_NETWORKLOGGING}")
 406 MESSAGE( STATUS "Font config file:                 ${fontConfigurationFile}")
 407 MESSAGE( STATUS "Using Tizen APP FW libraries:     ${ENABLE_APPFW}")
 408 MESSAGE( STATUS "Use pkg configure:                ${ENABLE_PKG_CONFIGURE}" )
 409 MESSAGE( STATUS "Enable link test:                 ${ENABLE_LINK_TEST}" )
 410 MESSAGE( STATUS "Tizen Platform Config supported   ${TIZEN_PLATFORM_CONFIG_SUPPORTED_LOGMSG}")
 411 MESSAGE( STATUS "Compile flags:                    ${CMAKE_CXX_FLAGS}")
 412 MESSAGE( STATUS "Compile flags:                    ${CMAKE_C_FLAGS}")
 413 IF( enable_feedback )
 414   ADD_SUBDIRECTORY( plugins )
 415 ENDIF()
 416
 417 CLEAN_ARG_CACHE()