subprojects/gst-plugins-good/gst/videobox/meson.build

   1 orcsrc = 'gstvideoboxorc'
   2 if have_orcc
   3   orc_h = custom_target(orcsrc + '.h',
   4     input : orcsrc + '.orc',
   5     output : orcsrc + '.h',
   6     command : orcc_args + ['--header', '-o', '@OUTPUT@', '@INPUT@'])
   7   orc_c = custom_target(orcsrc + '.c',
   8     input : orcsrc + '.orc',
   9     output : orcsrc + '.c',
  10     command : orcc_args + ['--implementation', '-o', '@OUTPUT@', '@INPUT@'])
  11   orc_targets += {'name': orcsrc, 'orc-source': files(orcsrc + '.orc'), 'header': orc_h, 'source': orc_c}
  12 else
  13   orc_h = configure_file(input : orcsrc + '-dist.h',
  14     output : orcsrc + '.h',
  15     copy : true)
  16   orc_c = configure_file(input : orcsrc + '-dist.c',
  17     output : orcsrc + '.c',
  18     copy : true)
  19 endif
  20
  21 gstvideobox = library('gstvideobox',
  22   'gstvideobox.c', orc_c, orc_h,
  23   c_args : gst_plugins_good_args,
  24   include_directories : [configinc],
  25   dependencies : [orc_dep, gstbase_dep, gstvideo_dep],
  26   install : true,
  27   install_dir : plugins_install_dir,
  28 )
  29 plugins += [gstvideobox]