configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl This file is free software; as a special exception the author gives
   4 dnl unlimited permission to copy and/or distribute it, with or without
   5 dnl modifications, as long as this notice is preserved.
   6 dnl
   7 dnl This program is distributed in the hope that it will be useful, but
   8 dnl WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
   9 dnl implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  10
  11 AC_INIT([GNU Hello], [2.8], [bug-hello@gnu.org])
  12
  13 dnl Must come before AM_INIT_AUTOMAKE.
  14 AC_CONFIG_AUX_DIR([build-aux])
  15 AM_INIT_AUTOMAKE([readme-alpha])
  16
  17 # Minimum Autoconf version required.
  18 AC_PREREQ(2.60)
  19
  20 # Where to generate output; srcdir location.
  21 AC_CONFIG_HEADERS([config.h:config.in])dnl Keep filename to 8.3 for MS-DOS.
  22 AC_CONFIG_SRCDIR([src/hello.c])
  23
  24 dnl Checks for programs.
  25 # We need a C compiler.
  26 AC_PROG_CC
  27
  28 # Since we use gnulib: gl_EARLY must be called as soon as possible after
  29 # the C compiler is checked.  The others could be later, but we just
  30 # keep everything together.
  31 gl_EARLY
  32 gl_INIT
  33
  34 # GNU help2man creates man pages from --help output; in many cases, this
  35 # is sufficient, and obviates the need to maintain man pages separately.
  36 # However, this means invoking executables, which we generally cannot do
  37 # when cross-compiling, so we test to avoid that (the variable
  38 # "cross_compiling" is set by AC_PROG_CC).
  39 if test $cross_compiling = no; then
  40   AM_MISSING_PROG(HELP2MAN, help2man)
  41 else
  42   HELP2MAN=:
  43 fi
  44
  45 # i18n support from GNU gettext.
  46 AM_GNU_GETTEXT_VERSION([0.18.1])
  47 AM_GNU_GETTEXT([external])
  48
  49 AC_CONFIG_FILES([Makefile
  50            contrib/Makefile
  51            doc/Makefile
  52            lib/Makefile
  53            man/Makefile
  54            po/Makefile.in
  55            src/Makefile
  56            tests/Makefile])
  57 AC_OUTPUT