configure.ac

   1 AC_PREREQ([2.66])
   2
   3 AC_INIT([renderer-service-upnp],
   4         [0.2.0],
   5         [https://github.com/01org/renderer-service-upnp/issues/new],
   6         ,
   7         [https://01.org/dleyna/])
   8
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11 AC_CONFIG_MACRO_DIR([m4])
  12 AC_CONFIG_SRCDIR([src/renderer-service-upnp.c])
  13
  14 AC_PREFIX_DEFAULT(/usr/local)
  15
  16 AM_INIT_AUTOMAKE([subdir-objects])
  17
  18 AM_MAINTAINER_MODE
  19 AM_SILENT_RULES([yes])
  20
  21 RSU_COMPILER_FLAGS
  22
  23 # Checks for languages.
  24 AC_LANG_C
  25
  26 # Checks for programs.
  27 AC_PROG_CC
  28 AM_PROG_CC_C_O
  29 AC_PROG_MKDIR_P
  30
  31 # Checks for libraries.
  32 PKG_PROG_PKG_CONFIG(0.16)
  33 PKG_CHECK_MODULES([DBUS], [dbus-1])
  34 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.26.1])
  35 PKG_CHECK_MODULES([GIO], [gio-2.0 >= 2.26.1])
  36 PKG_CHECK_MODULES([GSSDP], [gssdp-1.0 >= 0.13.0])
  37 PKG_CHECK_MODULES([GUPNP], [gupnp-1.0 >= 0.19.0])
  38 PKG_CHECK_MODULES([GUPNPAV], [gupnp-av-1.0 >= 0.11.0])
  39 PKG_CHECK_MODULES([SOUP], [libsoup-2.4 >= 2.28.2])
  40
  41 # Checks for header files.
  42 AC_CHECK_HEADERS([stdlib.h string.h syslog.h])
  43
  44 # Checks for typedefs, structures, and compiler characteristics.
  45 AC_TYPE_UINT8_T
  46 AC_HEADER_STDBOOL
  47 AC_TYPE_SIZE_T
  48
  49 # Checks for library functions.
  50 AC_FUNC_MALLOC
  51 AC_FUNC_REALLOC
  52 AC_CHECK_FUNCS([memset strchr strrchr strstr])
  53
  54 # Define Log Level values
  55 LOG_LEVEL_0=0x00
  56 LOG_LEVEL_1=0x01
  57 LOG_LEVEL_2=0x02
  58 LOG_LEVEL_3=0x04
  59 LOG_LEVEL_4=0x08
  60 LOG_LEVEL_5=0x10
  61 LOG_LEVEL_6=0x20
  62 LOG_LEVEL_7=0x13
  63 LOG_LEVEL_8=0x3F
  64
  65 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_DISABLED], [${LOG_LEVEL_0}], [Log level flag for disabled messages])
  66 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_ERROR],    [${LOG_LEVEL_1}], [Log level flag for errors])
  67 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_CRITICAL], [${LOG_LEVEL_2}], [Log level flag for critical messages])
  68 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_WARNING],  [${LOG_LEVEL_3}], [Log level flag for warnings])
  69 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_MESSAGE],  [${LOG_LEVEL_4}], [Log level flag for messages])
  70 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_INFO],     [${LOG_LEVEL_5}], [Log level flag for informational messages])
  71 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_DEBUG],    [${LOG_LEVEL_6}], [Log level flag for debug messages])
  72 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_DEFAULT],  [${LOG_LEVEL_7}], [Log level flag to display default level messages])
  73 AC_DEFINE_UNQUOTED([RSU_LOG_LEVEL_ALL],      [${LOG_LEVEL_8}], [Log level flag for all messages])
  74
  75
  76 AC_ARG_ENABLE(debug,
  77                 AS_HELP_STRING(
  78                         [--enable-debug],
  79                         [enable compiling with debugging information]),
  80                 [],
  81                 [enable_debug=no])
  82
  83 AS_CASE("${enable_debug}",
  84         [yes],  [       CFLAGS="$CFLAGS -g";
  85                         AC_DEFINE_UNQUOTED([RSU_DEBUG_ENABLED],[1], [Compiling with debugging information enabled])
  86                 ],
  87         [no],   [],
  88         [AC_MSG_ERROR([bad value ${enable_debug} for --enable-debug])])
  89
  90
  91 AC_ARG_ENABLE(werror,
  92                 AS_HELP_STRING(
  93                         [--enable-werror],
  94                         [warnings are treated as errors]),
  95                 [],
  96                 [enable_werror=no])
  97
  98 AS_CASE("${enable_werror}",
  99         [yes], [CFLAGS="$CFLAGS -Werror"],
 100         [no], [],
 101         [AC_MSG_ERROR([bad value ${enable_werror} for --enable-werror])])
 102
 103
 104 AC_ARG_ENABLE(optimization,
 105                 AS_HELP_STRING(
 106                         [--disable-optimization],
 107                         [disable code optimization through compiler]),
 108                 [],
 109                 [enable_optimization=yes])
 110
 111 AS_CASE("${enable_optimization}",
 112         [yes], [disable_optimization=no],
 113         [no], [CFLAGS="$CFLAGS -O0"; disable_optimization=yes],
 114         [AC_MSG_ERROR([bad value ${enable_optimization} for --enable-werror])])
 115
 116
 117 AC_ARG_ENABLE(never-quit,
 118                 AS_HELP_STRING(
 119                         [--enable-never-quit],
 120                         [Service doesn't quit when last client disconnects]),
 121                 [],
 122                 [enable_never_quit=no])
 123
 124 AS_CASE("${enable_never_quit}",
 125         [yes], [never_quit=true; NQ=TRUE],
 126         [no], [never_quit=false; NQ=FALSE],
 127         [AC_MSG_ERROR([bad value ${enable_never_quit} for --enable-never-quit])])
 128
 129 AC_DEFINE_UNQUOTED([RSU_NEVER_QUIT], [${NQ}], [Default service behavior when last client disconnects])
 130
 131
 132 AC_ARG_WITH(log-level,
 133                 AS_HELP_STRING(
 134                         [--with-log-level],
 135                         [enable logging information (0,1..6,7,8)\
 136                          0=disabled \
 137                          7=default (=1,2,5) \
 138                          8=all (=1,2,3,4,5,6) \
 139                          1,..,6=a comma separated list of log level\
 140                         ]),
 141                 [],
 142                 [with_log_level=7])
 143
 144 RSU_LOG_LEVEL_CHECK([${with_log_level}])
 145
 146
 147 AC_ARG_WITH(log-type,
 148                 AS_HELP_STRING(
 149                         [--with-log-type],
 150                         [Select log output technology \
 151                          0=syslog  1=GLib \
 152                         ]),
 153                 [],
 154                 [with_log_type=0])
 155
 156 RSU_LOG_TYPE_CHECK([${with_log_type}])
 157
 158
 159 DBUS_SESSION_DIR=`$PKG_CONFIG --variable=session_bus_services_dir dbus-1`
 160 AC_SUBST(DBUS_SESSION_DIR)
 161
 162 AC_DEFINE([RSU_SERVICE], "com.intel.RendererServiceUPnP", [Prefixed used for dbus names])
 163 AC_DEFINE([RSU_OBJECT], "/com/intel/RendererServiceUPnP", [Name of object exposed by renderer-service-upnp])
 164 AC_DEFINE([RSU_SERVER_PATH], "/com/intel/RendererServiceUPnP/server", [Path of server objects])
 165
 166 RSU_SERVER_NAME=com.intel.renderer-service-upnp
 167 AC_SUBST(RSU_SERVER_NAME)
 168 AC_DEFINE([RSU_SERVER_NAME], "com.intel.renderer-service-upnp",
 169                                  [d-Bus Name of renderer-service-upnp])
 170
 171 RSU_INTERFACE_MANAGER=com.intel.RendererServiceUPnP.Manager
 172 AC_SUBST(RSU_INTERFACE_MANAGER)
 173 AC_DEFINE([RSU_INTERFACE_MANAGER], "com.intel.RendererServiceUPnP.Manager",
 174                                [d-Bus Name of renderer-service-upnp main interface])
 175
 176 RSU_INTERFACE_RENDERER_DEVICE=com.intel.UPnP.RendererDevice
 177 AC_SUBST(RSU_INTERFACE_RENDERER_DEVICE)
 178 AC_DEFINE([RSU_INTERFACE_RENDERER_DEVICE], "com.intel.UPnP.RendererDevice",
 179                                [d-Bus Name of renderer-service-upnp device interface])
 180
 181 RSU_INTERFACE_PUSH_HOST=com.intel.RendererServiceUPnP.PushHost
 182 AC_SUBST(RSU_INTERFACE_PUSH_HOST)
 183 AC_DEFINE([RSU_INTERFACE_PUSH_HOST], "com.intel.RendererServiceUPnP.PushHost",
 184                                [d-Bus Name of renderer-service-upnp push host interface])
 185
 186 AC_SUBST([never_quit])
 187 AC_SUBST([with_log_level])
 188 AC_SUBST([with_log_type])
 189
 190 AC_CONFIG_FILES([Makefile \
 191                  src/com.intel.renderer-service-upnp.service \
 192                  renderer-service-upnp.pc \
 193                  renderer-service-upnp.conf])
 194
 195 AC_OUTPUT
 196
 197 AS_ECHO(["-------------------------------------------------
 198
 199 ${PACKAGE_NAME} Version ${PACKAGE_VERSION}
 200
 201 Prefix    : '${prefix}'.
 202 Compiler  : '${CC}'
 203 CFLAGS    : '${CFLAGS}'
 204
 205 -Package features:
 206         - enable-werror       : ${enable_werror}
 207         - enable-debug        : ${enable_debug}
 208         - disable-optimization: ${disable_optimization}
 209         - enable-never-quit   : ${enable_never_quit}
 210         - with-log-level      : ${with_log_level}
 211         - with-log-type       : ${with_log_type}
 212
 213 --------------------------------------------------"])