examples/quick/animation/pathinterpolator/pathinterpolator.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     id: window
  45     width: 320
  46     height: 480
  47
  48     Canvas {
  49         id: canvas
  50         anchors.fill: parent
  51         smooth: true
  52
  53         onPaint: {
  54             var context = canvas.getContext("2d")
  55             context.clearRect(0, 0, width, height)
  56             context.strokeStyle = "black"
  57             context.path = motionPath.path
  58             context.stroke()
  59         }
  60     }
  61
  62     //! [0]
  63     PathInterpolator {
  64         id: motionPath
  65
  66         path: Path {
  67             startX: 50; startY: 50
  68
  69             PathCubic {
  70                 x: window.width - 50
  71                 y: window.height - 50
  72
  73                 control1X: x; control1Y: 50
  74                 control2X: 50; control2Y: y
  75             }
  76
  77             onChanged: canvas.requestPaint()
  78         }
  79
  80         SequentialAnimation on progress {
  81             running: true
  82             loops: -1
  83             PauseAnimation { duration: 1000 }
  84             NumberAnimation {
  85                 id: progressAnim
  86                 running: false
  87                 from: 0; to: 1
  88                 duration: 2000
  89                 easing.type: Easing.InQuad
  90             }
  91         }
  92     }
  93     //! [0]
  94
  95     Rectangle {
  96         id: box
  97
  98         width: 50; height: 50
  99         border.width: 1
 100         smooth: true
 101
 102         //bind our attributes to follow the path as progress changes
 103         x: motionPath.x
 104         y: motionPath.y
 105         rotation: motionPath.angle
 106         transform: Translate { x: -box.width/2; y: -box.height/2 }
 107
 108         Text {
 109             anchors.centerIn: parent
 110             text: "Box"
 111         }
 112     }
 113
 114 }