CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 #
   4 # This file allows building PCRE with the CMake configuration and build
   5 # tool. Download CMake in source or binary form from http://www.cmake.org/
   6 #
   7 # Original listfile by Christian Ehrlicher <Ch.Ehrlicher@gmx.de>
   8 # Refined and expanded by Daniel Richard G. <skunk@iSKUNK.ORG>
   9 # 2007-09-14 mod by Sheri so 7.4 supported configuration options can be entered
  10 # 2007-09-19 Adjusted by PH to retain previous default settings
  11 # 2007-12-26 (a) On UNIX, use names libpcre instead of just pcre
  12 #            (b) Ensure pcretest and pcregrep link with the local library,
  13 #                not a previously-installed one.
  14 #            (c) Add PCRE_SUPPORT_LIBREADLINE, PCRE_SUPPORT_LIBZ, and
  15 #                PCRE_SUPPORT_LIBBZ2.
  16 # 2008-01-20 Brought up to date to include several new features by Christian
  17 #            Ehrlicher.
  18 # 2008-01-22 Sheri added options for backward compatibility of library names
  19 #            when building with minGW:
  20 #            if "ON", NON_STANDARD_LIB_PREFIX causes shared libraries to
  21 #            be built without "lib" as prefix. (The libraries will be named
  22 #            pcre.dll, pcreposix.dll and pcrecpp.dll).
  23 #            if "ON", NON_STANDARD_LIB_SUFFIX causes shared libraries to
  24 #            be built with suffix of "-0.dll". (The libraries will be named
  25 #            libpcre-0.dll, libpcreposix-0.dll and libpcrecpp-0.dll - same names
  26 #            built by default with Configure and Make.
  27 # 2008-01-23 PH removed the automatic build of pcredemo.
  28 # 2008-04-22 PH modified READLINE support so it finds NCURSES when needed.
  29 # 2008-07-03 PH updated for revised UCP property support (change of files)
  30 # 2009-03-23 PH applied Steven Van Ingelgem's patch to change the name
  31 #            CMAKE_BINARY_DIR to PROJECT_BINARY_DIR so that it works when PCRE
  32 #            is included within another project.
  33 # 2009-03-23 PH applied a modified version of Steven Van Ingelgem's patches to
  34 #            add options to stop the building of pcregrep and the tests, and
  35 #            to disable the final configuration report.
  36 # 2009-04-11 PH applied Christian Ehrlicher's patch to show compiler flags that
  37 #            are set by specifying a release type.
  38 # 2010-01-02 PH added test for stdint.h
  39 # 2010-03-02 PH addes test for inttypes.h
  40
  41 PROJECT(PCRE C CXX)
  42
  43 CMAKE_MINIMUM_REQUIRED(VERSION 2.4.6)
  44
  45 SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake) # for FindReadline.cmake
  46
  47 # external packages
  48 FIND_PACKAGE( BZip2 )
  49 FIND_PACKAGE( ZLIB )
  50 FIND_PACKAGE( Readline )
  51
  52 # Configuration checks
  53
  54 INCLUDE(CheckIncludeFile)
  55 INCLUDE(CheckIncludeFileCXX)
  56 INCLUDE(CheckFunctionExists)
  57 INCLUDE(CheckTypeSize)
  58
  59 CHECK_INCLUDE_FILE(dirent.h     HAVE_DIRENT_H)
  60 CHECK_INCLUDE_FILE(stdint.h     HAVE_STDINT_H)
  61 CHECK_INCLUDE_FILE(inttypes.h   HAVE_INTTYPES_H)
  62 CHECK_INCLUDE_FILE(sys/stat.h   HAVE_SYS_STAT_H)
  63 CHECK_INCLUDE_FILE(sys/types.h  HAVE_SYS_TYPES_H)
  64 CHECK_INCLUDE_FILE(unistd.h     HAVE_UNISTD_H)
  65 CHECK_INCLUDE_FILE(windows.h    HAVE_WINDOWS_H)
  66
  67 CHECK_INCLUDE_FILE_CXX(type_traits.h            HAVE_TYPE_TRAITS_H)
  68 CHECK_INCLUDE_FILE_CXX(bits/type_traits.h       HAVE_BITS_TYPE_TRAITS_H)
  69
  70 CHECK_FUNCTION_EXISTS(bcopy     HAVE_BCOPY)
  71 CHECK_FUNCTION_EXISTS(memmove   HAVE_MEMMOVE)
  72 CHECK_FUNCTION_EXISTS(strerror  HAVE_STRERROR)
  73 CHECK_FUNCTION_EXISTS(strtoll   HAVE_STRTOLL)
  74 CHECK_FUNCTION_EXISTS(strtoq    HAVE_STRTOQ)
  75 CHECK_FUNCTION_EXISTS(_strtoi64 HAVE__STRTOI64)
  76
  77 CHECK_TYPE_SIZE("long long"             LONG_LONG)
  78 CHECK_TYPE_SIZE("unsigned long long"    UNSIGNED_LONG_LONG)
  79
  80 # User-configurable options
  81 #
  82 # (Note: CMakeSetup displays these in alphabetical order, regardless of
  83 # the order we use here)
  84
  85 SET(BUILD_SHARED_LIBS OFF CACHE BOOL
  86     "Build shared libraries instead of static ones.")
  87
  88 OPTION(PCRE_BUILD_PCRECPP "Build the PCRE C++ library (pcrecpp)." ON)
  89
  90 SET(PCRE_EBCDIC OFF CACHE BOOL
  91     "Use EBCDIC coding instead of ASCII. (This is rarely used outside of mainframe systems)")
  92
  93 SET(PCRE_LINK_SIZE "2" CACHE STRING
  94     "Internal link size (2, 3 or 4 allowed). See LINK_SIZE in config.h.in for details.")
  95
  96 SET(PCRE_MATCH_LIMIT "10000000" CACHE STRING
  97     "Default limit on internal looping. See MATCH_LIMIT in config.h.in for details.")
  98
  99 SET(PCRE_MATCH_LIMIT_RECURSION "MATCH_LIMIT" CACHE STRING
 100     "Default limit on internal recursion. See MATCH_LIMIT_RECURSION in config.h.in for details.")
 101
 102 SET(PCRE_NEWLINE "LF" CACHE STRING
 103     "What to recognize as a newline (one of CR, LF, CRLF, ANY, ANYCRLF).")
 104
 105 SET(PCRE_NO_RECURSE OFF CACHE BOOL
 106     "If ON, then don't use stack recursion when matching. See NO_RECURSE in config.h.in for details.")
 107
 108 SET(PCRE_POSIX_MALLOC_THRESHOLD "10" CACHE STRING
 109     "Threshold for malloc() usage. See POSIX_MALLOC_THRESHOLD in config.h.in for details.")
 110
 111 SET(PCRE_SUPPORT_UNICODE_PROPERTIES OFF CACHE BOOL
 112     "Enable support for Unicode properties. (If set, UTF-8 support will be enabled as well)")
 113
 114 SET(PCRE_SUPPORT_UTF8 OFF CACHE BOOL
 115     "Enable support for the Unicode UTF-8 encoding.")
 116
 117 SET(PCRE_SUPPORT_BSR_ANYCRLF OFF CACHE BOOL
 118     "ON=Backslash-R matches only LF CR and CRLF, OFF=Backslash-R matches all Unicode Linebreaks")
 119
 120 OPTION(PCRE_SHOW_REPORT    "Show the final configuration report" ON)
 121 OPTION(PCRE_BUILD_PCREGREP "Build pcregrep" ON)
 122 OPTION(PCRE_BUILD_TESTS    "Build the tests" ON)
 123
 124 IF (PCRE_BUILD_TESTS)
 125   IF (NOT PCRE_BUILD_PCREGREP)
 126     MESSAGE(STATUS "** Building tests requires pcregrep: PCRE_BUILD_PCREGREP forced ON")
 127     SET(PCRE_BUILD_PCREGREP ON)
 128   ENDIF(NOT PCRE_BUILD_PCREGREP)
 129 ENDIF(PCRE_BUILD_TESTS)
 130
 131 IF (MINGW)
 132   OPTION(NON_STANDARD_LIB_PREFIX
 133          "ON=Shared libraries built in mingw will be named pcre.dll, etc., instead of libpcre.dll, etc."
 134          OFF)
 135
 136   OPTION(NON_STANDARD_LIB_SUFFIX
 137          "ON=Shared libraries built in mingw will be named libpcre-0.dll, etc., instead of libpcre.dll, etc."
 138          OFF)
 139 ENDIF(MINGW)
 140
 141 # bzip2 lib
 142 IF(BZIP2_FOUND)
 143   OPTION (PCRE_SUPPORT_LIBBZ2 "Enable support for linking pcregrep with libbz2." ON)
 144 ENDIF(BZIP2_FOUND)
 145 IF(PCRE_SUPPORT_LIBBZ2)
 146   INCLUDE_DIRECTORIES(${BZIP2_INCLUDE_DIR})
 147 ENDIF(PCRE_SUPPORT_LIBBZ2)
 148
 149 # zlib
 150 IF(ZLIB_FOUND)
 151   OPTION (PCRE_SUPPORT_LIBZ "Enable support for linking pcregrep with libz." ON)
 152 ENDIF(ZLIB_FOUND)
 153 IF(PCRE_SUPPORT_LIBZ)
 154   INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
 155 ENDIF(PCRE_SUPPORT_LIBZ)
 156
 157 # readline lib
 158 IF(READLINE_FOUND)
 159   OPTION (PCRE_SUPPORT_LIBREADLINE  "Enable support for linking pcretest with libreadline." ON)
 160 ENDIF(READLINE_FOUND)
 161 IF(PCRE_SUPPORT_LIBREADLINE)
 162   INCLUDE_DIRECTORIES(${READLINE_INCLUDE_DIR})
 163 ENDIF(PCRE_SUPPORT_LIBREADLINE)
 164
 165 # Prepare build configuration
 166
 167 SET(pcre_have_type_traits 0)
 168 SET(pcre_have_bits_type_traits 0)
 169
 170 IF(HAVE_TYPE_TRAITS_H)
 171         SET(pcre_have_type_traits 1)
 172 ENDIF(HAVE_TYPE_TRAITS_H)
 173
 174 IF(HAVE_BITS_TYPE_TRAITS_H)
 175         SET(pcre_have_bits_type_traits 1)
 176 ENDIF(HAVE_BITS_TYPE_TRAITS_H)
 177
 178 SET(pcre_have_long_long 0)
 179 SET(pcre_have_ulong_long 0)
 180
 181 IF(HAVE_LONG_LONG)
 182         SET(pcre_have_long_long 1)
 183 ENDIF(HAVE_LONG_LONG)
 184
 185 IF(HAVE_UNSIGNED_LONG_LONG)
 186         SET(pcre_have_ulong_long 1)
 187 ENDIF(HAVE_UNSIGNED_LONG_LONG)
 188
 189 IF(NOT BUILD_SHARED_LIBS)
 190         SET(PCRE_STATIC 1)
 191 ENDIF(NOT BUILD_SHARED_LIBS)
 192
 193 IF(PCRE_SUPPORT_BSR_ANYCRLF)
 194         SET(BSR_ANYCRLF 1)
 195 ENDIF(PCRE_SUPPORT_BSR_ANYCRLF)
 196
 197 IF(PCRE_SUPPORT_UTF8 OR PCRE_SUPPORT_UNICODE_PROPERTIES)
 198         SET(SUPPORT_UTF8 1)
 199 ENDIF(PCRE_SUPPORT_UTF8 OR PCRE_SUPPORT_UNICODE_PROPERTIES)
 200
 201 IF(PCRE_SUPPORT_UNICODE_PROPERTIES)
 202         SET(SUPPORT_UCP 1)
 203 ENDIF(PCRE_SUPPORT_UNICODE_PROPERTIES)
 204
 205 # This next one used to contain
 206 #       SET(PCRETEST_LIBS ${READLINE_LIBRARY})
 207 # but I was advised to add the NCURSES test as well, along with
 208 # some modifications to cmake/FindReadline.cmake which should
 209 # make it possible to override the default if necessary. PH
 210
 211 IF(PCRE_SUPPORT_LIBREADLINE)
 212         SET(SUPPORT_LIBREADLINE 1)
 213         SET(PCRETEST_LIBS ${READLINE_LIBRARY} ${NCURSES_LIBRARY})
 214 ENDIF(PCRE_SUPPORT_LIBREADLINE)
 215
 216 IF(PCRE_SUPPORT_LIBZ)
 217         SET(SUPPORT_LIBZ 1)
 218         SET(PCREGREP_LIBS ${PCREGREP_LIBS} ${ZLIB_LIBRARIES})
 219 ENDIF(PCRE_SUPPORT_LIBZ)
 220
 221 IF(PCRE_SUPPORT_LIBBZ2)
 222         SET(SUPPORT_LIBBZ2 1)
 223         SET(PCREGREP_LIBS ${PCREGREP_LIBS} ${BZIP2_LIBRARIES})
 224 ENDIF(PCRE_SUPPORT_LIBBZ2)
 225
 226 SET(NEWLINE "")
 227
 228 IF(PCRE_NEWLINE STREQUAL "LF")
 229         SET(NEWLINE "10")
 230 ENDIF(PCRE_NEWLINE STREQUAL "LF")
 231 IF(PCRE_NEWLINE STREQUAL "CR")
 232         SET(NEWLINE "13")
 233 ENDIF(PCRE_NEWLINE STREQUAL "CR")
 234 IF(PCRE_NEWLINE STREQUAL "CRLF")
 235         SET(NEWLINE "3338")
 236 ENDIF(PCRE_NEWLINE STREQUAL "CRLF")
 237 IF(PCRE_NEWLINE STREQUAL "ANY")
 238         SET(NEWLINE "-1")
 239 ENDIF(PCRE_NEWLINE STREQUAL "ANY")
 240 IF(PCRE_NEWLINE STREQUAL "ANYCRLF")
 241         SET(NEWLINE "-2")
 242 ENDIF(PCRE_NEWLINE STREQUAL "ANYCRLF")
 243
 244 IF(NEWLINE STREQUAL "")
 245         MESSAGE(FATAL_ERROR "The PCRE_NEWLINE variable must be set to one of the following values: \"LF\", \"CR\", \"CRLF\", \"ANY\", \"ANYCRLF\".")
 246 ENDIF(NEWLINE STREQUAL "")
 247
 248 IF(PCRE_EBCDIC)
 249         SET(EBCDIC 1)
 250 ENDIF(PCRE_EBCDIC)
 251
 252 IF(PCRE_NO_RECURSE)
 253         SET(NO_RECURSE 1)
 254 ENDIF(PCRE_NO_RECURSE)
 255
 256 # Output files
 257 CONFIGURE_FILE(config-cmake.h.in
 258                ${PROJECT_BINARY_DIR}/config.h
 259                @ONLY)
 260
 261 CONFIGURE_FILE(pcre.h.generic
 262                ${PROJECT_BINARY_DIR}/pcre.h
 263                COPYONLY)
 264
 265 # What about pcre-config and libpcre.pc?
 266
 267 IF(PCRE_BUILD_PCRECPP)
 268         CONFIGURE_FILE(pcre_stringpiece.h.in
 269                        ${PROJECT_BINARY_DIR}/pcre_stringpiece.h
 270                        @ONLY)
 271
 272         CONFIGURE_FILE(pcrecpparg.h.in
 273                        ${PROJECT_BINARY_DIR}/pcrecpparg.h
 274                        @ONLY)
 275 ENDIF(PCRE_BUILD_PCRECPP)
 276
 277 # Character table generation
 278
 279 OPTION(PCRE_REBUILD_CHARTABLES "Rebuild char tables" OFF)
 280 IF(PCRE_REBUILD_CHARTABLES)
 281   ADD_EXECUTABLE(dftables dftables.c)
 282
 283   GET_TARGET_PROPERTY(DFTABLES_EXE dftables LOCATION)
 284
 285   ADD_CUSTOM_COMMAND(
 286     COMMENT "Generating character tables (pcre_chartables.c) for current locale"
 287     DEPENDS dftables
 288     COMMAND ${DFTABLES_EXE}
 289     ARGS        ${PROJECT_BINARY_DIR}/pcre_chartables.c
 290     OUTPUT      ${PROJECT_BINARY_DIR}/pcre_chartables.c
 291   )
 292 ELSE(PCRE_REBUILD_CHARTABLES)
 293   CONFIGURE_FILE(${PROJECT_SOURCE_DIR}/pcre_chartables.c.dist
 294                     ${PROJECT_BINARY_DIR}/pcre_chartables.c
 295                     COPYONLY)
 296 ENDIF(PCRE_REBUILD_CHARTABLES)
 297
 298 # Source code
 299
 300 SET(PCRE_HEADERS ${PROJECT_BINARY_DIR}/pcre.h)
 301
 302 SET(PCRE_SOURCES
 303   ${PROJECT_BINARY_DIR}/pcre_chartables.c
 304   pcre_compile.c
 305   pcre_config.c
 306   pcre_dfa_exec.c
 307   pcre_exec.c
 308   pcre_fullinfo.c
 309   pcre_get.c
 310   pcre_globals.c
 311   pcre_info.c
 312   pcre_newline.c
 313   pcre_maketables.c
 314   pcre_ord2utf8.c
 315   pcre_refcount.c
 316   pcre_study.c
 317   pcre_tables.c
 318   pcre_try_flipped.c
 319   pcre_ucd.c
 320   pcre_valid_utf8.c
 321   pcre_version.c
 322   pcre_xclass.c
 323 )
 324
 325 SET(PCREPOSIX_HEADERS pcreposix.h)
 326
 327 SET(PCREPOSIX_SOURCES pcreposix.c)
 328
 329 SET(PCRECPP_HEADERS
 330   pcrecpp.h
 331   pcre_scanner.h
 332   ${PROJECT_BINARY_DIR}/pcrecpparg.h
 333   ${PROJECT_BINARY_DIR}/pcre_stringpiece.h
 334 )
 335
 336 SET(PCRECPP_SOURCES
 337         pcrecpp.cc
 338         pcre_scanner.cc
 339         pcre_stringpiece.cc
 340 )
 341
 342 # Build setup
 343
 344 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
 345
 346 IF(MSVC)
 347         ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
 348 ENDIF(MSVC)
 349
 350 SET(CMAKE_INCLUDE_CURRENT_DIR 1)
 351 # needed to make sure to not link debug libs
 352 # against release libs and vice versa
 353 IF(WIN32)
 354   SET(CMAKE_DEBUG_POSTFIX "d")
 355 ENDIF(WIN32)
 356
 357 SET(targets)
 358
 359 # Libraries
 360 # pcre
 361 ADD_LIBRARY(pcre ${PCRE_HEADERS} ${PCRE_SOURCES} ${PROJECT_BINARY_DIR}/config.h)
 362 SET(targets ${targets} pcre)
 363 ADD_LIBRARY(pcreposix ${PCREPOSIX_HEADERS} ${PCREPOSIX_SOURCES})
 364 SET(targets ${targets} pcreposix)
 365 TARGET_LINK_LIBRARIES(pcreposix pcre)
 366 IF(MINGW AND NOT PCRE_STATIC)
 367   IF(NON_STANDARD_LIB_PREFIX)
 368     SET_TARGET_PROPERTIES(pcre pcreposix
 369                         PROPERTIES PREFIX ""
 370     )
 371   ENDIF(NON_STANDARD_LIB_PREFIX)
 372
 373   IF(NON_STANDARD_LIB_SUFFIX)
 374     SET_TARGET_PROPERTIES(pcre pcreposix
 375                         PROPERTIES SUFFIX "-0.dll"
 376     )
 377   ENDIF(NON_STANDARD_LIB_SUFFIX)
 378 ENDIF(MINGW AND NOT PCRE_STATIC)
 379
 380
 381 # pcrecpp
 382 IF(PCRE_BUILD_PCRECPP)
 383   ADD_LIBRARY(pcrecpp ${PCRECPP_HEADERS} ${PCRECPP_SOURCES})
 384 SET(targets ${targets} pcrecpp)
 385   TARGET_LINK_LIBRARIES(pcrecpp pcre)
 386
 387   IF(MINGW AND NOT PCRE_STATIC)
 388     IF(NON_STANDARD_LIB_PREFIX)
 389       SET_TARGET_PROPERTIES(pcrecpp
 390                             PROPERTIES PREFIX ""
 391       )
 392     ENDIF(NON_STANDARD_LIB_PREFIX)
 393
 394     IF(NON_STANDARD_LIB_SUFFIX)
 395       SET_TARGET_PROPERTIES(pcrecpp
 396                           PROPERTIES SUFFIX "-0.dll"
 397       )
 398     ENDIF(NON_STANDARD_LIB_SUFFIX)
 399   ENDIF(MINGW AND NOT PCRE_STATIC)
 400 ENDIF(PCRE_BUILD_PCRECPP)
 401
 402
 403 # Executables
 404
 405 # Removed by PH (2008-01-23) because pcredemo shouldn't really be built
 406 # automatically, and it gave trouble in some environments anyway.
 407 # ADD_EXECUTABLE(pcredemo pcredemo.c)
 408 # TARGET_LINK_LIBRARIES(pcredemo pcreposix)
 409 # IF(NOT BUILD_SHARED_LIBS)
 410 #     # make sure to not use declspec(dllimport) in static mode on windows
 411 #         SET_TARGET_PROPERTIES(pcredemo PROPERTIES COMPILE_FLAGS "-DPCRE_STATIC")
 412 # ENDIF(NOT BUILD_SHARED_LIBS)
 413
 414 IF(PCRE_BUILD_PCREGREP)
 415   ADD_EXECUTABLE(pcregrep pcregrep.c)
 416   SET(targets ${targets} pcregrep)
 417   TARGET_LINK_LIBRARIES(pcregrep pcreposix ${PCREGREP_LIBS})
 418 ENDIF(PCRE_BUILD_PCREGREP)
 419
 420
 421 # Testing
 422 IF(PCRE_BUILD_TESTS)
 423   ENABLE_TESTING()
 424
 425   ADD_EXECUTABLE(pcretest pcretest.c)
 426   SET(targets ${targets} pcretest)
 427   TARGET_LINK_LIBRARIES(pcretest pcreposix ${PCRETEST_LIBS})
 428
 429   IF(PCRE_BUILD_PCRECPP)
 430     ADD_EXECUTABLE(pcrecpp_unittest pcrecpp_unittest.cc)
 431     SET(targets ${targets} pcrecpp_unittest)
 432     TARGET_LINK_LIBRARIES(pcrecpp_unittest pcrecpp)
 433     IF(MINGW AND NON_STANDARD_LIB_NAMES AND NOT PCRE_STATIC)
 434       SET_TARGET_PROPERTIES(pcrecpp
 435                         PROPERTIES PREFIX ""
 436       )
 437     ENDIF(MINGW AND NON_STANDARD_LIB_NAMES AND NOT PCRE_STATIC)
 438
 439
 440     ADD_EXECUTABLE(pcre_scanner_unittest pcre_scanner_unittest.cc)
 441     SET(targets ${targets} pcre_scanner_unittest)
 442     TARGET_LINK_LIBRARIES(pcre_scanner_unittest pcrecpp)
 443
 444     ADD_EXECUTABLE(pcre_stringpiece_unittest pcre_stringpiece_unittest.cc)
 445     SET(targets ${targets} pcre_stringpiece_unittest)
 446     TARGET_LINK_LIBRARIES(pcre_stringpiece_unittest pcrecpp)
 447   ENDIF(PCRE_BUILD_PCRECPP)
 448
 449   GET_TARGET_PROPERTY(PCREGREP_EXE pcregrep DEBUG_LOCATION)
 450   GET_TARGET_PROPERTY(PCRETEST_EXE pcretest DEBUG_LOCATION)
 451
 452   # Write out a CTest configuration file that sets some needed environment
 453   # variables for the test scripts.
 454   #
 455   FILE(WRITE ${PROJECT_BINARY_DIR}/CTestCustom.ctest
 456   "# This is a generated file.
 457   SET(ENV{srcdir} ${PROJECT_SOURCE_DIR})
 458   SET(ENV{pcregrep} ${PCREGREP_EXE})
 459   SET(ENV{pcretest} ${PCRETEST_EXE})
 460   ")
 461
 462   IF(UNIX)
 463           ADD_TEST(pcre_test      ${PROJECT_SOURCE_DIR}/RunTest)
 464           ADD_TEST(pcre_grep_test ${PROJECT_SOURCE_DIR}/RunGrepTest)
 465   ENDIF(UNIX)
 466   IF(WIN32)
 467           ADD_TEST(pcre_test cmd /C ${PROJECT_SOURCE_DIR}/RunTest.bat)
 468   ENDIF(WIN32)
 469
 470   GET_TARGET_PROPERTY(PCRECPP_UNITTEST_EXE
 471                       pcrecpp_unittest
 472                       DEBUG_LOCATION)
 473
 474   GET_TARGET_PROPERTY(PCRE_SCANNER_UNITTEST_EXE
 475                       pcre_scanner_unittest
 476                       DEBUG_LOCATION)
 477
 478   GET_TARGET_PROPERTY(PCRE_STRINGPIECE_UNITTEST_EXE
 479                       pcre_stringpiece_unittest
 480                       DEBUG_LOCATION)
 481
 482   ADD_TEST(pcrecpp_test          ${PCRECPP_UNITTEST_EXE})
 483   ADD_TEST(pcre_scanner_test     ${PCRE_SCANNER_UNITTEST_EXE})
 484   ADD_TEST(pcre_stringpiece_test ${PCRE_STRINGPIECE_UNITTEST_EXE})
 485 ENDIF(PCRE_BUILD_TESTS)
 486
 487 # Installation
 488 SET(CMAKE_INSTALL_ALWAYS 1)
 489
 490 INSTALL(TARGETS ${targets}
 491         RUNTIME DESTINATION bin
 492         LIBRARY DESTINATION lib
 493         ARCHIVE DESTINATION lib)
 494
 495 INSTALL(FILES ${PCRE_HEADERS} ${PCREPOSIX_HEADERS} DESTINATION include)
 496
 497 FILE(GLOB html ${PROJECT_SOURCE_DIR}/doc/html/*.html)
 498 FILE(GLOB man1 ${PROJECT_SOURCE_DIR}/doc/*.1)
 499 FILE(GLOB man3 ${PROJECT_SOURCE_DIR}/doc/*.3)
 500
 501 IF(PCRE_BUILD_PCRECPP)
 502         INSTALL(FILES ${PCRECPP_HEADERS} DESTINATION include)
 503 ELSE(PCRE_BUILD_PCRECPP)
 504         # Remove pcrecpp.3
 505         FOREACH(man ${man3})
 506                 GET_FILENAME_COMPONENT(man_tmp ${man} NAME)
 507                 IF(NOT man_tmp STREQUAL "pcrecpp.3")
 508                         SET(man3_new ${man3} ${man})
 509                 ENDIF(NOT man_tmp STREQUAL "pcrecpp.3")
 510         ENDFOREACH(man ${man3})
 511         SET(man3 ${man3_new})
 512 ENDIF(PCRE_BUILD_PCRECPP)
 513
 514
 515 INSTALL(FILES ${man1} DESTINATION man/man1)
 516 INSTALL(FILES ${man3} DESTINATION man/man3)
 517 INSTALL(FILES ${html} DESTINATION share/doc/pcre/html)
 518
 519 # help, only for nice output
 520 IF(BUILD_SHARED_LIBS)
 521   SET(BUILD_STATIC_LIBS OFF)
 522 ELSE(BUILD_SHARED_LIBS)
 523   SET(BUILD_STATIC_LIBS ON)
 524 ENDIF(BUILD_SHARED_LIBS)
 525
 526 IF(PCRE_SHOW_REPORT)
 527   STRING(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype)
 528   IF (CMAKE_C_FLAGS)
 529     SET(cfsp " ")
 530   ENDIF(CMAKE_C_FLAGS)
 531   IF (CMAKE_CXX_FLAGS)
 532     SET(cxxfsp " ")
 533   ENDIF(CMAKE_CXX_FLAGS)
 534   MESSAGE(STATUS "")
 535   MESSAGE(STATUS "")
 536   MESSAGE(STATUS "PCRE configuration summary:")
 537   MESSAGE(STATUS "")
 538   MESSAGE(STATUS "  Install prefix .................. : ${CMAKE_INSTALL_PREFIX}")
 539   MESSAGE(STATUS "  C compiler ...................... : ${CMAKE_C_COMPILER}")
 540   MESSAGE(STATUS "  C++ compiler .................... : ${CMAKE_CXX_COMPILER}")
 541   MESSAGE(STATUS "  C compiler flags ................ : ${CMAKE_C_FLAGS}${cfsp}${CMAKE_C_FLAGS_${buildtype}}")
 542   MESSAGE(STATUS "  C++ compiler flags .............. : ${CMAKE_CXX_FLAGS}${cxxfsp}${CMAKE_CXX_FLAGS_${buildtype}}")
 543   MESSAGE(STATUS "")
 544   MESSAGE(STATUS "  Build C++ library ............... : ${PCRE_BUILD_PCRECPP}")
 545   MESSAGE(STATUS "  Enable UTF-8 support ............ : ${PCRE_SUPPORT_UNICODE_PROPERTIES}")
 546   MESSAGE(STATUS "  Unicode properties .............. : ${PCRE_SUPPORT_UNICODE_PROPERTIES}")
 547   MESSAGE(STATUS "  Newline char/sequence ........... : ${PCRE_NEWLINE}")
 548   MESSAGE(STATUS "  \\R matches only ANYCRLF ......... : ${PCRE_SUPPORT_BSR_ANYCRLF}")
 549   MESSAGE(STATUS "  EBCDIC coding ................... : ${PCRE_EBCDIC}")
 550   MESSAGE(STATUS "  Rebuild char tables ............. : ${PCRE_REBUILD_CHARTABLES}")
 551   MESSAGE(STATUS "  No stack recursion .............. : ${PCRE_NO_RECURSE}")
 552   MESSAGE(STATUS "  POSIX mem threshold ............. : ${PCRE_POSIX_MALLOC_THRESHOLD}")
 553   MESSAGE(STATUS "  Internal link size .............. : ${PCRE_LINK_SIZE}")
 554   MESSAGE(STATUS "  Match limit ..................... : ${PCRE_MATCH_LIMIT}")
 555   MESSAGE(STATUS "  Match limit recursion ........... : ${PCRE_MATCH_LIMIT_RECURSION}")
 556   MESSAGE(STATUS "  Build shared libs ............... : ${BUILD_SHARED_LIBS}")
 557   MESSAGE(STATUS "  Build static libs ............... : ${BUILD_STATIC_LIBS}")
 558   MESSAGE(STATUS "  Build pcregrep .................. : ${PCRE_BUILD_PCREGREP}")
 559   MESSAGE(STATUS "  Build tests (implies pcretest) .. : ${PCRE_BUILD_TESTS}")
 560   IF(ZLIB_FOUND)
 561     MESSAGE(STATUS "  Link pcregrep with libz ......... : ${PCRE_SUPPORT_LIBZ}")
 562   ELSE(ZLIB_FOUND)
 563     MESSAGE(STATUS "  Link pcregrep with libz ......... : None" )
 564   ENDIF(ZLIB_FOUND)
 565   IF(BZIP2_FOUND)
 566     MESSAGE(STATUS "  Link pcregrep with libbz2 ....... : ${PCRE_SUPPORT_LIBBZ2}")
 567   ELSE(BZIP2_FOUND)
 568     MESSAGE(STATUS "  Link pcregrep with libbz2 ....... : None" )
 569   ENDIF(BZIP2_FOUND)
 570   IF(NOT PCRE_SUPPORT_LIBREADLINE)
 571     MESSAGE(STATUS "  Link pcretest with libreadline .. : None" )
 572   ELSE(NOT PCRE_SUPPORT_LIBREADLINE)
 573     MESSAGE(STATUS "  Link pcretest with libreadline .. : ${PCRE_SUPPORT_LIBREADLINE}")
 574   ENDIF(NOT PCRE_SUPPORT_LIBREADLINE)
 575   IF(MINGW AND NOT PCRE_STATIC)
 576     MESSAGE(STATUS "  Non-standard dll names (prefix) . : ${NON_STANDARD_LIB_PREFIX}")
 577     MESSAGE(STATUS "  Non-standard dll names (suffix) . : ${NON_STANDARD_LIB_SUFFIX}")
 578   ENDIF(MINGW AND NOT PCRE_STATIC)
 579   MESSAGE(STATUS "")
 580 ENDIF(PCRE_SHOW_REPORT)
 581
 582 # end CMakeLists.txt