configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([harfbuzz],
   3         [0.7.0],
   4         [http://bugs.freedesktop.org/enter_bug.cgi?product=harfbuzz],
   5         [harfbuzz],
   6         [http://harfbuzz.org/])
   7
   8 AC_CONFIG_SRCDIR([harfbuzz.pc.in])
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AM_INIT_AUTOMAKE([1.11.1 gnu dist-bzip2 no-dist-gzip -Wall no-define])
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AM_PROG_CC_C_O
  17 AC_PROG_CXX
  18
  19 # Initialize libtool
  20 LT_PREREQ([2.2])
  21 LT_INIT([disable-static])
  22
  23 # Version
  24 m4_define(hb_version_triplet,m4_split(AC_PACKAGE_VERSION,[[.]]))
  25 m4_define(hb_version_major,m4_argn(1,hb_version_triplet))
  26 m4_define(hb_version_minor,m4_argn(2,hb_version_triplet))
  27 m4_define(hb_version_micro,m4_argn(3,hb_version_triplet))
  28 HB_VERSION_MAJOR=hb_version_major
  29 HB_VERSION_MINOR=hb_version_minor
  30 HB_VERSION_MICRO=hb_version_micro
  31 HB_VERSION=AC_PACKAGE_VERSION
  32 AC_SUBST(HB_VERSION_MAJOR)
  33 AC_SUBST(HB_VERSION_MINOR)
  34 AC_SUBST(HB_VERSION_MICRO)
  35 AC_SUBST(HB_VERSION)
  36
  37 # Libtool version
  38 m4_define([hb_version_int],
  39           m4_eval(hb_version_major*10000 + hb_version_minor*100 + hb_version_micro))
  40 m4_if(m4_eval(hb_version_minor % 2), [1],
  41       dnl for unstable releases
  42       [m4_define([hb_libtool_revision], 0)],
  43       dnl for stable releases
  44       [m4_define([hb_libtool_revision], hb_version_micro)])
  45 m4_define([hb_libtool_age],
  46           m4_eval(hb_version_int - hb_libtool_revision))
  47 m4_define([hb_libtool_current],
  48           m4_eval(hb_version_major + hb_libtool_age))
  49 HB_LIBTOOL_VERSION_INFO=hb_libtool_current:hb_libtool_revision:hb_libtool_age
  50 AC_SUBST(HB_LIBTOOL_VERSION_INFO)
  51
  52 # Functions and headers
  53 AC_CHECK_FUNCS(mprotect sysconf getpagesize mmap)
  54 AC_CHECK_HEADERS(unistd.h sys/mman.h)
  55
  56 # Compiler flags
  57 AC_CANONICAL_HOST
  58 if test "x$GCC" = "xyes"; then
  59
  60         # Make symbols link locally
  61         LDFLAGS="$LDFLAGS -Bsymbolic-functions"
  62
  63         # Make sure we don't link to libstdc++
  64         CXXFLAGS="$CXXFLAGS -fno-rtti -fno-exceptions"
  65
  66         case "$host" in
  67                 arm-*-*)
  68                         # Request byte alignment on arm
  69                         CXXFLAGS="$CXXFLAGS -mstructure-size-boundary=8"
  70                 ;;
  71         esac
  72 fi
  73
  74 dnl ==========================================================================
  75
  76 PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.16, have_glib=true, have_glib=false)
  77 PKG_CHECK_MODULES(GTHREAD, gthread-2.0, , have_glib=false)
  78 if $have_glib; then
  79         AC_DEFINE(HAVE_GLIB, 1, [Have glib2 library])
  80 fi
  81 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
  82
  83 dnl ==========================================================================
  84
  85 PKG_CHECK_MODULES(CAIRO, cairo >= 1.8.0, have_cairo=true, have_cairo=false)
  86 if $have_cairo; then
  87         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo graphics library])
  88 fi
  89 AM_CONDITIONAL(HAVE_CAIRO, $have_cairo)
  90
  91 PKG_CHECK_MODULES(CAIRO_PNG, cairo-png, have_cairo_png=true, have_cairo_png=false)
  92 if $have_cairo_png; then
  93         AC_DEFINE(HAVE_CAIRO_PNG, 1, [Have cairo-png support in cairo graphics library])
  94 fi
  95 AM_CONDITIONAL(HAVE_CAIRO_PNG, $have_cairo_png)
  96
  97 PKG_CHECK_MODULES(CAIRO_FT, cairo-ft, have_cairo_ft=true, have_cairo_ft=false)
  98 if $have_cairo_ft; then
  99         AC_DEFINE(HAVE_CAIRO_FT, 1, [Have cairo-ft support in cairo graphics library])
 100 fi
 101 AM_CONDITIONAL(HAVE_CAIRO_FT, $have_cairo_ft)
 102
 103 dnl ==========================================================================
 104
 105 PKG_CHECK_MODULES(ICU, icu, have_icu=true, [
 106         AC_CHECK_PROG([have_icu], [icu-config], [true], [false])
 107         if $have_icu; then
 108                 icu_cflags=`icu-config --cppflags`
 109                 icu_libs=`icu-config --ldflags-libsonly`
 110                 AC_SUBST(ICU_CFLAGS, [$icu_cflags])
 111                 AC_SUBST(ICU_LIBS, [$icu_libs])
 112         fi
 113 ])
 114 if $have_icu; then
 115         AC_DEFINE(HAVE_ICU, 1, [Have ICU library])
 116 fi
 117 AM_CONDITIONAL(HAVE_ICU, $have_icu)
 118
 119 dnl ==========================================================================
 120
 121 PKG_CHECK_MODULES(FREETYPE, freetype2, have_freetype=true, have_freetype=false)
 122 if $have_freetype; then
 123         AC_DEFINE(HAVE_FREETYPE, 1, [Have FreeType 2 library])
 124         _save_libs="$LIBS"
 125         _save_cflags="$CFLAGS"
 126         LIBS="$LIBS $FREETYPE_LIBS"
 127         CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 128         AC_CHECK_FUNCS(FT_Face_GetCharVariantIndex)
 129         LIBS="$_save_libs"
 130         CFLAGS="$_save_cflags"
 131 fi
 132 AM_CONDITIONAL(HAVE_FREETYPE, $have_freetype)
 133
 134 dnl ===========================================================================
 135
 136 AC_CONFIG_FILES([
 137 Makefile
 138 harfbuzz.pc
 139 src/Makefile
 140 src/hb-version.h
 141 test/Makefile
 142 ])
 143
 144 AC_OUTPUT