scanner.l

   1 %{
   2 /*
   3  * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996, 1997
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that: (1) source code distributions
   8  * retain the above copyright notice and this paragraph in its entirety, (2)
   9  * distributions including binary code include the above copyright notice and
  10  * this paragraph in its entirety in the documentation or other materials
  11  * provided with the distribution, and (3) all advertising materials mentioning
  12  * features or use of this software display the following acknowledgement:
  13  * ``This product includes software developed by the University of California,
  14  * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15  * the University nor the names of its contributors may be used to endorse
  16  * or promote products derived from this software without specific prior
  17  * written permission.
  18  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19  * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21  */
  22
  23 #ifndef lint
  24 static const char rcsid[] _U_ =
  25     "@(#) $Header: /tcpdump/master/libpcap/scanner.l,v 1.112 2008-02-06 10:21:30 guy Exp $ (LBL)";
  26 #endif
  27
  28 #ifdef HAVE_CONFIG_H
  29 #include "config.h"
  30 #endif
  31
  32 #ifdef WIN32
  33 #include <pcap-stdinc.h>
  34 #else /* WIN32 */
  35 #if HAVE_INTTYPES_H
  36 #include <inttypes.h>
  37 #elif HAVE_STDINT_H
  38 #include <stdint.h>
  39 #endif
  40 #ifdef HAVE_SYS_BITYPES_H
  41 #include <sys/bitypes.h>
  42 #endif
  43 #include <sys/types.h>
  44 #endif /* WIN32 */
  45
  46 #include <ctype.h>
  47 #include <string.h>
  48
  49 #include "pcap-int.h"
  50
  51 #include "gencode.h"
  52 #ifdef INET6
  53 #ifdef WIN32
  54 #include <pcap-stdinc.h>
  55
  56 #ifdef __MINGW32__
  57 #include "IP6_misc.h"
  58 #endif
  59 #else /* WIN32 */
  60 #include <sys/socket.h> /* for "struct sockaddr" in "struct addrinfo" */
  61 #include <netdb.h>      /* for "struct addrinfo" */
  62 #endif /* WIN32 */
  63
  64 /* Workaround for AIX 4.3 */
  65 #if !defined(AI_NUMERICHOST)
  66 #define AI_NUMERICHOST 0x04
  67 #endif
  68 #endif /*INET6*/
  69 #include <pcap/namedb.h>
  70 #include "tokdefs.h"
  71
  72 #ifdef HAVE_OS_PROTO_H
  73 #include "os-proto.h"
  74 #endif
  75
  76 static int stoi(char *);
  77 static inline int xdtoi(int);
  78
  79 #ifdef FLEX_SCANNER
  80 #define YY_NO_UNPUT
  81 static YY_BUFFER_STATE in_buffer;
  82 #else
  83 static const char *in_buffer;
  84
  85 #undef getc
  86 #define getc(fp)  (*in_buffer == 0 ? EOF : *in_buffer++)
  87 #endif
  88
  89 #define yylval pcap_lval
  90 extern YYSTYPE yylval;
  91
  92 %}
  93
  94 N               ([0-9]+|(0X|0x)[0-9A-Fa-f]+)
  95 B               ([0-9A-Fa-f][0-9A-Fa-f]?)
  96 B2              ([0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f])
  97 W               ([0-9A-Fa-f][0-9A-Fa-f]?[0-9A-Fa-f]?[0-9A-Fa-f]?)
  98
  99 %a 18400
 100 %o 21500
 101 %e 7600
 102 %k 4550
 103 %p 27600
 104 %n 2000
 105
 106 V680            {W}:{W}:{W}:{W}:{W}:{W}:{W}:{W}
 107
 108 V670            ::{W}:{W}:{W}:{W}:{W}:{W}:{W}
 109 V671            {W}::{W}:{W}:{W}:{W}:{W}:{W}
 110 V672            {W}:{W}::{W}:{W}:{W}:{W}:{W}
 111 V673            {W}:{W}:{W}::{W}:{W}:{W}:{W}
 112 V674            {W}:{W}:{W}:{W}::{W}:{W}:{W}
 113 V675            {W}:{W}:{W}:{W}:{W}::{W}:{W}
 114 V676            {W}:{W}:{W}:{W}:{W}:{W}::{W}
 115 V677            {W}:{W}:{W}:{W}:{W}:{W}:{W}::
 116
 117 V660            ::{W}:{W}:{W}:{W}:{W}:{W}
 118 V661            {W}::{W}:{W}:{W}:{W}:{W}
 119 V662            {W}:{W}::{W}:{W}:{W}:{W}
 120 V663            {W}:{W}:{W}::{W}:{W}:{W}
 121 V664            {W}:{W}:{W}:{W}::{W}:{W}
 122 V665            {W}:{W}:{W}:{W}:{W}::{W}
 123 V666            {W}:{W}:{W}:{W}:{W}:{W}::
 124
 125 V650            ::{W}:{W}:{W}:{W}:{W}
 126 V651            {W}::{W}:{W}:{W}:{W}
 127 V652            {W}:{W}::{W}:{W}:{W}
 128 V653            {W}:{W}:{W}::{W}:{W}
 129 V654            {W}:{W}:{W}:{W}::{W}
 130 V655            {W}:{W}:{W}:{W}:{W}::
 131
 132 V640            ::{W}:{W}:{W}:{W}
 133 V641            {W}::{W}:{W}:{W}
 134 V642            {W}:{W}::{W}:{W}
 135 V643            {W}:{W}:{W}::{W}
 136 V644            {W}:{W}:{W}:{W}::
 137
 138 V630            ::{W}:{W}:{W}
 139 V631            {W}::{W}:{W}
 140 V632            {W}:{W}::{W}
 141 V633            {W}:{W}:{W}::
 142
 143 V620            ::{W}:{W}
 144 V621            {W}::{W}
 145 V622            {W}:{W}::
 146
 147 V610            ::{W}
 148 V611            {W}::
 149
 150 V600            ::
 151
 152 V6604           {W}:{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 153
 154 V6504           ::{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 155 V6514           {W}::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 156 V6524           {W}:{W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 157 V6534           {W}:{W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 158 V6544           {W}:{W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 159 V6554           {W}:{W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 160
 161 V6404           ::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 162 V6414           {W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 163 V6424           {W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 164 V6434           {W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 165 V6444           {W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 166
 167 V6304           ::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 168 V6314           {W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 169 V6324           {W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 170 V6334           {W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 171
 172 V6204           ::{W}:{W}:{N}\.{N}\.{N}\.{N}
 173 V6214           {W}::{W}:{N}\.{N}\.{N}\.{N}
 174 V6224           {W}:{W}::{N}\.{N}\.{N}\.{N}
 175
 176 V6104           ::{W}:{N}\.{N}\.{N}\.{N}
 177 V6114           {W}::{N}\.{N}\.{N}\.{N}
 178
 179 V6004           ::{N}\.{N}\.{N}\.{N}
 180
 181
 182 V6              ({V680}|{V670}|{V671}|{V672}|{V673}|{V674}|{V675}|{V676}|{V677}|{V660}|{V661}|{V662}|{V663}|{V664}|{V665}|{V666}|{V650}|{V651}|{V652}|{V653}|{V654}|{V655}|{V640}|{V641}|{V642}|{V643}|{V644}|{V630}|{V631}|{V632}|{V633}|{V620}|{V621}|{V622}|{V610}|{V611}|{V600}|{V6604}|{V6504}|{V6514}|{V6524}|{V6534}|{V6544}|{V6554}|{V6404}|{V6414}|{V6424}|{V6434}|{V6444}|{V6304}|{V6314}|{V6324}|{V6334}|{V6204}|{V6214}|{V6224}|{V6104}|{V6114}|{V6004})
 183
 184 MAC             ({B}:{B}:{B}:{B}:{B}:{B}|{B}\-{B}\-{B}\-{B}\-{B}\-{B}|{B}\.{B}\.{B}\.{B}\.{B}\.{B}|{B2}\.{B2}\.{B2}|{B2}{3})
 185
 186
 187
 188 %%
 189 dst             return DST;
 190 src             return SRC;
 191
 192 link|ether|ppp|slip  return LINK;
 193 fddi|tr|wlan    return LINK;
 194 arp             return ARP;
 195 rarp            return RARP;
 196 ip              return IP;
 197 sctp            return SCTP;
 198 tcp             return TCP;
 199 udp             return UDP;
 200 icmp            return ICMP;
 201 igmp            return IGMP;
 202 igrp            return IGRP;
 203 pim             return PIM;
 204 vrrp            return VRRP;
 205 radio           return RADIO;
 206
 207 ip6             {
 208 #ifdef INET6
 209                 return IPV6;
 210 #else
 211                 bpf_error("%s not supported", yytext);
 212 #endif
 213                 }
 214 icmp6           {
 215 #ifdef INET6
 216                 return ICMPV6;
 217 #else
 218                 bpf_error("%s not supported", yytext);
 219 #endif
 220                 }
 221 ah              return AH;
 222 esp             return ESP;
 223
 224 atalk           return ATALK;
 225 aarp            return AARP;
 226 decnet          return DECNET;
 227 lat             return LAT;
 228 sca             return SCA;
 229 moprc           return MOPRC;
 230 mopdl           return MOPDL;
 231
 232 iso             return ISO;
 233 esis            return ESIS;
 234 es-is           return ESIS;
 235 isis            return ISIS;
 236 is-is           return ISIS;
 237 l1              return L1;
 238 l2              return L2;
 239 iih             return IIH;
 240 lsp             return LSP;
 241 snp             return SNP;
 242 csnp            return CSNP;
 243 psnp            return PSNP;
 244
 245 clnp            return CLNP;
 246
 247 stp             return STP;
 248
 249 ipx             return IPX;
 250
 251 netbeui         return NETBEUI;
 252
 253 host            return HOST;
 254 net             return NET;
 255 mask            return NETMASK;
 256 port            return PORT;
 257 portrange       return PORTRANGE;
 258 proto           return PROTO;
 259 protochain      {
 260 #ifdef NO_PROTOCHAIN
 261                   bpf_error("%s not supported", yytext);
 262 #else
 263                   return PROTOCHAIN;
 264 #endif
 265                 }
 266
 267 gateway         return GATEWAY;
 268
 269 type            return TYPE;
 270 subtype         return SUBTYPE;
 271 direction|dir   return DIR;
 272 address1|addr1  return ADDR1;
 273 address2|addr2  return ADDR2;
 274 address3|addr3  return ADDR3;
 275 address4|addr4  return ADDR4;
 276
 277 less            return LESS;
 278 greater         return GREATER;
 279 byte            return CBYTE;
 280 broadcast       return TK_BROADCAST;
 281 multicast       return TK_MULTICAST;
 282
 283 and|"&&"        return AND;
 284 or|"||"         return OR;
 285 not             return '!';
 286
 287 len|length      return LEN;
 288 inbound         return INBOUND;
 289 outbound        return OUTBOUND;
 290
 291 vlan            return VLAN;
 292 mpls            return MPLS;
 293 pppoed          return PPPOED;
 294 pppoes          return PPPOES;
 295
 296 lane            return LANE;
 297 llc             return LLC;
 298 metac           return METAC;
 299 bcc             return BCC;
 300 oam             return OAM;
 301 oamf4           return OAMF4;
 302 oamf4ec         return OAMF4EC;
 303 oamf4sc         return OAMF4SC;
 304 sc              return SC;
 305 ilmic           return ILMIC;
 306 vpi             return VPI;
 307 vci             return VCI;
 308 connectmsg      return CONNECTMSG;
 309 metaconnect     return METACONNECT;
 310
 311 on|ifname       return PF_IFNAME;
 312 rset|ruleset    return PF_RSET;
 313 rnr|rulenum     return PF_RNR;
 314 srnr|subrulenum return PF_SRNR;
 315 reason          return PF_REASON;
 316 action          return PF_ACTION;
 317
 318 fisu            return FISU;
 319 lssu            return LSSU;
 320 lsu             return LSSU;
 321 msu             return MSU;
 322 sio             return SIO;
 323 opc             return OPC;
 324 dpc             return DPC;
 325 sls             return SLS;
 326
 327 [ \r\n\t]               ;
 328 [+\-*/:\[\]!<>()&|=]    return yytext[0];
 329 ">="                    return GEQ;
 330 "<="                    return LEQ;
 331 "!="                    return NEQ;
 332 "=="                    return '=';
 333 "<<"                    return LSH;
 334 ">>"                    return RSH;
 335 ${B}                    { yylval.e = pcap_ether_aton(((char *)yytext)+1);
 336                           return AID; }
 337 {MAC}                   { yylval.e = pcap_ether_aton((char *)yytext);
 338                           return EID; }
 339 {N}                     { yylval.i = stoi((char *)yytext); return NUM; }
 340 ({N}\.{N})|({N}\.{N}\.{N})|({N}\.{N}\.{N}\.{N}) {
 341                         yylval.s = sdup((char *)yytext); return HID; }
 342 {V6}                    {
 343 #ifdef INET6
 344                           struct addrinfo hints, *res;
 345                           memset(&hints, 0, sizeof(hints));
 346                           hints.ai_family = AF_INET6;
 347                           hints.ai_flags = AI_NUMERICHOST;
 348                           if (getaddrinfo(yytext, NULL, &hints, &res))
 349                                 bpf_error("bogus IPv6 address %s", yytext);
 350                           else {
 351                                 freeaddrinfo(res);
 352                                 yylval.s = sdup((char *)yytext); return HID6;
 353                           }
 354 #else
 355                           bpf_error("IPv6 address %s not supported", yytext);
 356 #endif /*INET6*/
 357                         }
 358 {B}:+({B}:+)+           { bpf_error("bogus ethernet address %s", yytext); }
 359 icmptype                { yylval.i = 0; return NUM; }
 360 icmpcode                { yylval.i = 1; return NUM; }
 361 icmp-echoreply          { yylval.i = 0; return NUM; }
 362 icmp-unreach            { yylval.i = 3; return NUM; }
 363 icmp-sourcequench       { yylval.i = 4; return NUM; }
 364 icmp-redirect           { yylval.i = 5; return NUM; }
 365 icmp-echo               { yylval.i = 8; return NUM; }
 366 icmp-routeradvert       { yylval.i = 9; return NUM; }
 367 icmp-routersolicit      { yylval.i = 10; return NUM; }
 368 icmp-timxceed           { yylval.i = 11; return NUM; }
 369 icmp-paramprob          { yylval.i = 12; return NUM; }
 370 icmp-tstamp             { yylval.i = 13; return NUM; }
 371 icmp-tstampreply        { yylval.i = 14; return NUM; }
 372 icmp-ireq               { yylval.i = 15; return NUM; }
 373 icmp-ireqreply          { yylval.i = 16; return NUM; }
 374 icmp-maskreq            { yylval.i = 17; return NUM; }
 375 icmp-maskreply          { yylval.i = 18; return NUM; }
 376 tcpflags                { yylval.i = 13; return NUM; }
 377 tcp-fin                 { yylval.i = 0x01; return NUM; }
 378 tcp-syn                 { yylval.i = 0x02; return NUM; }
 379 tcp-rst                 { yylval.i = 0x04; return NUM; }
 380 tcp-push                { yylval.i = 0x08; return NUM; }
 381 tcp-ack                 { yylval.i = 0x10; return NUM; }
 382 tcp-urg                 { yylval.i = 0x20; return NUM; }
 383 [A-Za-z0-9]([-_.A-Za-z0-9]*[.A-Za-z0-9])? {
 384                          yylval.s = sdup((char *)yytext); return ID; }
 385 "\\"[^ !()\n\t]+        { yylval.s = sdup((char *)yytext + 1); return ID; }
 386 [^ \[\]\t\n\-_.A-Za-z0-9!<>()&|=]+ {
 387                         bpf_error("illegal token: %s", yytext); }
 388 .                       { bpf_error("illegal char '%c'", *yytext); }
 389 %%
 390 void
 391 lex_init(buf)
 392         const char *buf;
 393 {
 394 #ifdef FLEX_SCANNER
 395         in_buffer = yy_scan_string(buf);
 396 #else
 397         in_buffer = buf;
 398 #endif
 399 }
 400
 401 /*
 402  * Do any cleanup necessary after parsing.
 403  */
 404 void
 405 lex_cleanup()
 406 {
 407 #ifdef FLEX_SCANNER
 408         if (in_buffer != NULL)
 409                 yy_delete_buffer(in_buffer);
 410         in_buffer = NULL;
 411 #endif
 412 }
 413
 414 /*
 415  * Also define a yywrap.  Note that if we're using flex, it will
 416  * define a macro to map this identifier to pcap_wrap.
 417  */
 418 int
 419 yywrap()
 420 {
 421         return 1;
 422 }
 423
 424 /* Hex digit to integer. */
 425 static inline int
 426 xdtoi(c)
 427         register int c;
 428 {
 429         if (isdigit(c))
 430                 return c - '0';
 431         else if (islower(c))
 432                 return c - 'a' + 10;
 433         else
 434                 return c - 'A' + 10;
 435 }
 436
 437 /*
 438  * Convert string to integer.  Just like atoi(), but checks for
 439  * preceding 0x or 0 and uses hex or octal instead of decimal.
 440  */
 441 static int
 442 stoi(s)
 443         char *s;
 444 {
 445         int base = 10;
 446         int n = 0;
 447
 448         if (*s == '0') {
 449                 if (s[1] == 'x' || s[1] == 'X') {
 450                         s += 2;
 451                         base = 16;
 452                 }
 453                 else {
 454                         base = 8;
 455                         s += 1;
 456                 }
 457         }
 458         while (*s)
 459                 n = n * base + xdtoi(*s++);
 460
 461         return n;
 462 }