configure.ac

   1 AC_INIT([libgee], [0.10.0], [https://bugzilla.gnome.org/enter_bug.cgi?product=libgee], [libgee])
   2 AC_CONFIG_SRCDIR([Makefile.am])
   3 AC_CONFIG_HEADERS(config.h)
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AM_INIT_AUTOMAKE([check-news dist-bzip2])
   6 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   7
   8 # Checks for programs.
   9 AC_PROG_CC
  10 AM_PROG_CC_C_O
  11 AC_DISABLE_STATIC
  12 AC_PROG_LIBTOOL
  13
  14 LIBGEE_LT_VERSION="4:0:2"
  15 AC_SUBST(LIBGEE_LT_VERSION)
  16
  17 GLIB_REQUIRED=2.32
  18
  19 AM_PROG_VALAC([0.17.5])
  20 AC_SUBST(VALAC)
  21
  22 VALAFLAGS=--target-glib=$GLIB_REQUIRED
  23
  24 AC_SUBST(VALAFLAGS)
  25
  26 AC_ARG_ENABLE(doc, AS_HELP_STRING([--enable-doc], [Enable documentation generation]), enable_doc=$enableval, enable_doc=no)
  27 AM_CONDITIONAL(ENABLE_DOC, test x$enable_doc = xyes)
  28
  29 AS_IF([test "x$enable_doc" != xno],
  30         [AC_PATH_PROG(VALADOC, valadoc, :)
  31          AC_SUBST(VALADOC)
  32          AS_IF([test "$VALADOC" = :],
  33                 [AC_MSG_ERROR([valadoc not found])])])
  34
  35 AC_ARG_ENABLE(coverage,
  36         AS_HELP_STRING([--enable-coverage],
  37         [compile with coverage profiling and debug (gcc only)]),
  38         enable_coverage=$enableval,enable_coverage=no)
  39 AM_CONDITIONAL(ENABLE_COVERAGE, test x$enable_coverage != xno)
  40
  41 AS_IF([test "x$enable_coverage" != xno],
  42         [COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
  43          COVERAGE_VALAFLAGS="-g"
  44          COVERAGE_LIBS="-lgcov"
  45          AC_SUBST(COVERAGE_CFLAGS)
  46          AC_SUBST(COVERAGE_VALAFLAGS)
  47          AC_SUBST(COVERAGE_LIBS)
  48
  49          AC_PATH_PROG(LCOV, lcov, :)
  50          AC_SUBST(LCOV)
  51          AS_IF([test "$LCOV" = :],
  52                 [AC_MSG_ERROR([lcov is necessary for testing code coverage (http://ltp.sourceforge.net/coverage/lcov.php)])])])
  53
  54 AC_ARG_ENABLE(benchmark, AS_HELP_STRING([--enable-benchmark], [Enable benchmark]), enable_benchmark=$enableval, enable_benchmark=no)
  55 AM_CONDITIONAL(ENABLE_BENCHMARK, test x$enable_benchmark = xyes)
  56
  57 PKG_CHECK_MODULES(GLIB, glib-2.0 >= $GLIB_REQUIRED gobject-2.0 >= $GLIB_REQUIRED)
  58 AC_SUBST(GLIB_CFLAGS)
  59 AC_SUBST(GLIB_LIBS)
  60
  61 GOBJECT_INTROSPECTION_CHECK([0.9.0])
  62
  63 AC_OUTPUT([Makefile
  64            gee-0.8.pc
  65            benchmark/Makefile
  66            doc/Makefile
  67            gee/Makefile
  68            tests/Makefile])