configure.ac

   1 AC_PREREQ([2.60])
   2 AC_INIT([lemolo], [0.1.1])
   3
   4 AM_INIT_AUTOMAKE([foreign subdir-objects])
   5 AM_CONFIG_HEADER([config.h])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   9
  10 PKG_PROG_PKG_CONFIG
  11
  12 AC_LANG_C
  13
  14 AC_USE_SYSTEM_EXTENSIONS
  15 AC_PROG_CC
  16 AM_PROG_CC_C_O
  17 AC_C___ATTRIBUTE__
  18
  19 AC_DISABLE_STATIC
  20 AC_PROG_LIBTOOL
  21
  22 EFL_COMPILER_FLAG
  23 EFL_COMPILER_FLAG([-Wall])
  24 EFL_COMPILER_FLAG([-Wextra])
  25 EFL_COMPILER_FLAG([-Wshadow])
  26 EFL_COMPILER_FLAG([-fvisibility=hidden])
  27
  28 PKG_CHECK_MODULES([EFL],
  29         [
  30                 elementary
  31                 edbus
  32                 dbus-1
  33          ])
  34
  35 EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
  36
  37 want_tizen="auto"
  38 have_tizen="no"
  39 AC_ARG_ENABLE([tizen],
  40    AC_HELP_STRING([--enable-tizen], [enable Tizen integration. @<:@default=auto@:>@]),
  41    [want_tizen="${enableval}"], [:])
  42
  43 if test "$want_tizen" != "no"; then
  44    PKG_CHECK_MODULES([TIZEN],
  45                 [
  46                         ecore-x
  47                         appcore-efl
  48                         ui-gadget-1
  49                         contacts-service2
  50                         vconf
  51                         capi-system-power
  52                         aul
  53                         appsvc
  54                         notification
  55                 ],
  56                 [have_tizen="yes"],
  57                 [have_tizen="no"])
  58 fi
  59
  60 if test "$want_tizen" = "yes" -a "$have_tizen" = "no"; then
  61    AC_MSG_ERROR([Want tizen, but not found])
  62 elif test "$have_tizen" = "yes"; then
  63      AC_DEFINE([HAVE_TIZEN], 1, [Tizen support])
  64 fi
  65
  66 AM_CONDITIONAL([HAVE_TIZEN], [test "$have_tizen" = "yes"])
  67
  68 with_max_log_level="EINA_LOG_LEVEL_DBG"
  69 AC_ARG_WITH(maximum-log-level,
  70    [AC_HELP_STRING([--with-maximum-log-level=NUMBER],
  71                    [limit log level, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
  72    [with_max_log_level="${withval}"], [:])
  73 AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${with_max_log_level}, [if set, logging is limited to this amount.])
  74
  75 with_dbusservicesdir=`pkg-config --variable=session_bus_services_dir dbus-1`
  76 AC_ARG_WITH(dbusservicesdir,
  77    [AC_HELP_STRING([--with-dbusservicesdir=PATH],
  78       [Where to place dbus services files])],
  79    [with_dbusservicesdir="${withval}"], [:])
  80 AC_SUBST(with_dbusservicesdir)
  81
  82 with_desktopicondir="/usr/share/icons/default/small"
  83 AC_ARG_WITH(desktopicondir,
  84    [AC_HELP_STRING([--with-desktopicondir=PATH],
  85       [Where to place desktop icon file. Default=/usr/share/icons/default/small/])],
  86    [with_desktopicondir="${withval}"], [:])
  87 AC_SUBST(with_desktopicondir)
  88
  89 with_desktopdir="/opt/share/applications"
  90 AC_ARG_WITH(desktopdir,
  91    [AC_HELP_STRING([--with-desktopdir=PATH],
  92       [Where to place desktop files. Default=/opt/share/applications/])],
  93    [with_desktopdir="${withval}"], [:])
  94 AC_SUBST(with_desktopdir)
  95
  96 eval "eval BIN_DIR=$bindir"
  97 AC_SUBST(BIN_DIR)
  98
  99 eval "eval DATA_DIR=$datadir"
 100 AC_SUBST(DATA_DIR)
 101
 102 AC_CONFIG_FILES([
 103 Makefile
 104 ])
 105
 106 AC_OUTPUT