configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [7])
   5 m4_define([v_mic], [99])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v '\(export\|Unversioned directory\)' || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eo], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_LIBTOOL_WIN32_DLL
  39 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  40 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  41 AC_PROG_LIBTOOL
  42
  43 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  46 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  47 AC_DEFINE_UNQUOTED([VMAJ], [v_maj], [Major version])
  48 AC_DEFINE_UNQUOTED([VMIN], [v_min], [Minor version])
  49 AC_DEFINE_UNQUOTED([VMIC], [v_mic], [Micro version])
  50 AC_DEFINE_UNQUOTED([VREV], [v_rev], [Revison])
  51 version_info="lt_cur:lt_rev:lt_age"
  52 release_info="v_rel"
  53 AC_SUBST([version_info])
  54 AC_SUBST([release_info])
  55 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 VMAJ=v_maj
  58 AC_SUBST([VMAJ])
  59
  60
  61 ### Needed information
  62
  63 AC_CANONICAL_HOST
  64
  65 EFL_EO_BUILD=""
  66 case "$host_os" in
  67    mingw*)
  68       EFL_EO_BUILD="-DEFL_EO_BUILD"
  69    ;;
  70 esac
  71 AC_SUBST([EFL_EO_BUILD])
  72
  73 requirements_pc_eo="eina"
  74
  75
  76 ### Additional options to configure
  77
  78 AC_ARG_ENABLE([coverage],
  79    [AC_HELP_STRING([--enable-coverage], [enable coverage profiling instrumentation @<:@default=disabled@:>@])],
  80    [
  81     if test "x${enableval}" = "xyes" ; then
  82        _efl_enable_coverage="yes"
  83     else
  84        _efl_enable_coverage="no"
  85     fi
  86    ],
  87    [_efl_enable_coverage="no"])
  88
  89 AC_MSG_CHECKING([whether to use profiling instrumentation])
  90 AC_MSG_RESULT([${_efl_enable_coverage}])
  91
  92
  93 ### Checks for programs
  94
  95 AC_PROG_CC
  96
  97 # pkg-config
  98 PKG_PROG_PKG_CONFIG
  99
 100 # Check whether pkg-config supports Requires.private
 101 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 102    pkgconfig_requires_private="Requires.private"
 103 else
 104    pkgconfig_requires_private="Requires"
 105 fi
 106 AC_SUBST(pkgconfig_requires_private)
 107
 108 # doxygen program for documentation building
 109
 110 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 111
 112 # lcov
 113
 114 if test "x$_efl_enable_coverage" = "xyes" ; then
 115    AC_CHECK_PROG(have_lcov, [lcov], [yes], [no])
 116    if test "x$have_lcov" = "xno" ; then
 117       _efl_enable_coverage="no"
 118    fi
 119 fi
 120
 121 AM_CONDITIONAL([EFL_ENABLE_COVERAGE], [test "x${_efl_enable_coverage}" = "xyes"])
 122
 123
 124 ### Checks for libraries
 125
 126 PKG_CHECK_MODULES([EO], [${requirements_pc_eo}])
 127
 128 PKG_CHECK_MODULES([ELM], [elementary >= 1.7.0], [have_elm="yes"], [have_elm="no"])
 129
 130 PKG_CHECK_MODULES([CHECK],
 131    [check >= 0.9.5],
 132    [_efl_enable_tests="yes"],
 133    [_efl_enable_tests="no"])
 134
 135 AM_CONDITIONAL([EO_BUILD_UNIT_TEST], [test "x${_efl_enable_tests}" = "xyes"])
 136 AM_CONDITIONAL([EO_BUILD_EXAMPLE_EVAS], [test "x${have_elm}" = "xyes"])
 137
 138
 139 ### Checks for header files
 140
 141 AC_CHECK_HEADERS([stdarg.h])
 142
 143
 144 ### Checks for types
 145
 146
 147 ### Checks for structures
 148
 149
 150 ### Checks for compiler characteristics
 151
 152 if test "x$_efl_enable_coverage" = "xyes" ; then
 153    EO_CFLAGS="${EO_CFLAGS} -fprofile-arcs -ftest-coverage"
 154    EO_LIBS="${EO_LIBS} -lgcov"
 155 fi
 156
 157
 158 ### Checks for linker characteristics
 159
 160 lt_enable_auto_import=""
 161 case "${host_os}" in
 162    mingw*)
 163       lt_enable_auto_import="-Wl,--enable-auto-import"
 164    ;;
 165 esac
 166 AC_SUBST([lt_enable_auto_import])
 167
 168 ### Checks for library functions
 169
 170 ### Make the debug preprocessor configurable
 171
 172
 173 AC_SUBST([requirements_pc_eo])
 174
 175 AC_CONFIG_FILES([
 176 Makefile
 177 eo.pc
 178 eo.spec
 179 doc/Doxyfile
 180 doc/Makefile
 181 src/Makefile
 182 src/benchmarks/Makefile
 183 src/examples/Makefile
 184 src/examples/eo_isa/Makefile
 185 src/examples/evas/Makefile
 186 src/examples/simple/Makefile
 187 src/lib/Makefile
 188 src/tests/Makefile
 189 src/tests/access/Makefile
 190 src/tests/composite_objects/Makefile
 191 src/tests/constructors/Makefile
 192 src/tests/eo_suite/Makefile
 193 src/tests/function_overrides/Makefile
 194 src/tests/interface/Makefile
 195 src/tests/mixin/Makefile
 196 src/tests/signals/Makefile
 197 ])
 198
 199 AC_OUTPUT
 200
 201 #####################################################################
 202 ## Info
 203
 204 echo
 205 echo
 206 echo
 207 echo "------------------------------------------------------------------------"
 208 echo "$PACKAGE $VERSION"
 209 echo "------------------------------------------------------------------------"
 210 echo
 211 echo
 212 echo "Configuration Options Summary:"
 213 echo
 214 echo "  Documentation........: ${build_doc}"
 215 echo "  Unit Tests...........:"
 216 echo "    unit testing.......: ${_efl_enable_tests}"
 217 echo "    coverage...........: ${_efl_enable_coverage}"
 218 echo "    build..............: make check"
 219 echo "  Examples.............: make examples"
 220 echo "  Benchmark............: make benchmark"
 221 echo
 222 echo "Compilation............: make (or gmake)"
 223 echo "  CPPFLAGS.............: $CPPFLAGS"
 224 echo "  CFLAGS...............: $CFLAGS"
 225 echo "  LDFLAGS..............: $LDFLAGS"
 226 echo
 227 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 228 echo "  prefix...............: $prefix"
 229 echo