configure.ac

   1 m4_define([weston_major_version], [1])
   2 m4_define([weston_minor_version], [6])
   3 m4_define([weston_micro_version], [0])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6
   7 AC_PREREQ([2.64])
   8 AC_INIT([weston],
   9         [weston_version],
  10         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  11         [weston],
  12         [http://wayland.freedesktop.org/])
  13
  14 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  15 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  16 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  17 AC_SUBST([WESTON_VERSION], [weston_version])
  18
  19 AC_CONFIG_AUX_DIR([build-aux])
  20 AC_CONFIG_HEADERS([config.h])
  21 AC_CONFIG_MACRO_DIR([m4])
  22
  23 AC_USE_SYSTEM_EXTENSIONS
  24 AC_SYS_LARGEFILE
  25
  26 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests subdir-objects])
  27
  28 AM_SILENT_RULES([yes])
  29
  30 # Check for programs
  31 AC_PROG_CC
  32 AC_PROG_SED
  33
  34 # Initialize libtool
  35 LT_PREREQ([2.2])
  36 LT_INIT([disable-static])
  37
  38 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  39            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  40 AC_ARG_VAR([WESTON_SHELL_CLIENT],
  41            [Set the default desktop shell client to load if none is specified in weston.ini. @<:@default=weston-desktop-shell@:>@])
  42
  43 PKG_PROG_PKG_CONFIG()
  44
  45 AC_CHECK_FUNC([dlopen], [],
  46               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  47 AC_SUBST(DLOPEN_LIBS)
  48
  49 AC_CHECK_DECL(SFD_CLOEXEC,[],
  50               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
  51               [[#include <sys/signalfd.h>]])
  52 AC_CHECK_DECL(TFD_CLOEXEC,[],
  53               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
  54               [[#include <sys/timerfd.h>]])
  55 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  56               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
  57               [[#include <time.h>]])
  58 AC_CHECK_HEADERS([execinfo.h])
  59
  60 AC_CHECK_FUNCS([mkostemp strchrnul initgroups posix_fallocate])
  61
  62 COMPOSITOR_MODULES="wayland-server >= 1.5.91 pixman-1 >= 0.25.2"
  63
  64 AC_ARG_ENABLE(egl, [  --disable-egl],,
  65               enable_egl=yes)
  66 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  67 if test x$enable_egl = xyes; then
  68         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  69         PKG_CHECK_MODULES(EGL, [egl >= 7.10 glesv2])
  70         PKG_CHECK_MODULES([EGL_TESTS], [egl >= 7.10 glesv2 wayland-client wayland-egl])
  71 fi
  72
  73 AC_ARG_ENABLE(xkbcommon,
  74               AS_HELP_STRING([--disable-xkbcommon], [Disable libxkbcommon
  75                               support: This is only useful in environments
  76                               where you do not have a hardware keyboard. If
  77                               libxkbcommon support is disabled clients will not
  78                               be sent a keymap and and must know how to
  79                               interpret the keycode sent for any key event.]),,
  80               enable_xkbcommon=yes)
  81 if test x$enable_xkbcommon = xyes; then
  82         AC_DEFINE(ENABLE_XKBCOMMON, [1], [Build Weston with libxkbcommon support])
  83         COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon >= 0.3.0"
  84 fi
  85
  86 AC_ARG_ENABLE([multiseat],
  87               [AC_HELP_STRING([--enable-multiseat],
  88                               [Enable multiseat feature])],
  89               [],
  90               [enable_multiseat=no])
  91
  92 if test "x$enable_multiseat" = "xyes"; then
  93   AC_DEFINE(HAVE_MULTISEAT, [1], [Enable multiseat feature])
  94 fi
  95 AM_CONDITIONAL(HAVE_MULTISEAT, test "x$enable_multiseat" = xyes)
  96
  97 AC_ARG_ENABLE([default-vkb],
  98               [AC_HELP_STRING([--enable-default-vkb],
  99                               [Enable default virtual keyboard])],
 100               [],
 101               [enable_default_vkb=yes])
 102 if test "x$enable_default_vkb" = "xyes"; then
 103   AC_DEFINE(HAVE_DEFAULT_VKB, [1], [Enable default virtual keyboard])
 104 fi
 105
 106 AC_ARG_ENABLE(sys-uid, [  --enable-sys-uid],,
 107               enable_sys_uid=no)
 108 if test x$enable_sys_uid = xyes; then
 109         AC_DEFINE(ENABLE_SYS_UID, [1], [Allow regular users to launch Weston])
 110 fi
 111
 112 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
 113               enable_setuid_install=yes)
 114 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
 115
 116
 117 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
 118               enable_xwayland=yes)
 119 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
 120               enable_xwayland_test=yes)
 121 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
 122 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
 123 if test x$enable_xwayland = xyes; then
 124   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcb-composite xcursor cairo-xcb)
 125   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
 126
 127   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
 128               [Path to X server]), [XSERVER_PATH="$withval"],
 129               [XSERVER_PATH="$bindir/Xwayland"])
 130   AC_SUBST([XSERVER_PATH])
 131   if test x$enable_xwayland_test = xyes; then
 132     PKG_CHECK_MODULES([XWAYLAND_TEST], xcb xcb-dri2 libdrm)
 133   fi
 134 fi
 135
 136 PKG_CHECK_MODULES(LIBDRM, [libdrm],
 137                   [AC_DEFINE(HAVE_LIBDRM, 1, [Define if libdrm is available]) have_libdrm=yes], have_libdrm=no)
 138
 139 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 140               enable_x11_compositor=yes)
 141 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 142 if test x$enable_x11_compositor = xyes; then
 143   PKG_CHECK_MODULES([XCB], xcb)
 144   xcb_save_LIBS=$LIBS
 145   xcb_save_CFLAGS=$CFLAGS
 146   CFLAGS=$XCB_CFLAGS
 147   LIBS=$XCB_LIBS
 148   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
 149   LIBS=$xcb_save_LIBS
 150   CFLAGS=$xcb_save_CFLAGS
 151
 152   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 153
 154   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
 155                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 156   if test "x$have_xcb_xkb" = xyes; then
 157         # Most versions of XCB have totally broken XKB bindings, where the
 158         # events don't work.  Make sure we can actually use them.
 159         xcb_xkb_save_CFLAGS=$CFLAGS
 160         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
 161         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
 162                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
 163         CFLAGS=$xcb_xkb_save_CFLAGS
 164   fi
 165   if test "x$have_xcb_xkb" = xyes; then
 166         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 167         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 168   fi
 169
 170   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 171   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 172 fi
 173
 174
 175 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 176               enable_drm_compositor=yes)
 177 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes)
 178 if test x$enable_drm_compositor = xyes; then
 179   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 180   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 181 fi
 182
 183
 184 AC_ARG_ENABLE(libinput-backend, [  --disable-libinput-backend],,
 185               enable_libinput_backend=yes)
 186 AM_CONDITIONAL([ENABLE_LIBINPUT_BACKEND], [test x$enable_libinput_backend = xyes])
 187 if test x$enable_libinput_backend = xyes; then
 188   AC_DEFINE([BUILD_LIBINPUT_BACKEND], [1], [Build the libinput input device backend])
 189   PKG_CHECK_MODULES(LIBINPUT_BACKEND, [libinput >= 0.6.0])
 190 fi
 191
 192
 193 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
 194
 195 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 196               enable_wayland_compositor=yes)
 197 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 198                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 199 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 200   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 201             [Build the Wayland (nested) compositor])
 202   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client >= 1.5.91 wayland-egl wayland-cursor])
 203 fi
 204
 205
 206 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 207               enable_headless_compositor=yes)
 208 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 209                test x$enable_headless_compositor = xyes)
 210
 211
 212 AC_ARG_ENABLE(rpi-compositor,
 213               AS_HELP_STRING([--disable-rpi-compositor],
 214                              [do not build the Raspberry Pi backend]),,
 215               enable_rpi_compositor=yes)
 216 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes")
 217 have_bcm_host="no"
 218 if test "x$enable_rpi_compositor" = "xyes"; then
 219   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 220   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 221   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 222                     [have_bcm_host="yes"
 223                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 224                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 225 fi
 226 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 227
 228
 229 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 230               enable_fbdev_compositor=yes)
 231 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 232                [test x$enable_fbdev_compositor = xyes])
 233 AS_IF([test x$enable_fbdev_compositor = xyes], [
 234   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 235   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 236 ])
 237
 238 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 239               enable_rdp_compositor=no)
 240 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 241                [test x$enable_rdp_compositor = xyes])
 242 if test x$enable_rdp_compositor = xyes; then
 243   AC_DEFINE([BUILD_RDP_COMPOSITOR], [1], [Build the RDP compositor])
 244   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0])
 245
 246   SAVED_CPPFLAGS="$CPPFLAGS"
 247   CPPFLAGS="$CPPFLAGS $RDP_COMPOSITOR_CFLAGS"
 248   AC_CHECK_HEADERS([freerdp/version.h])
 249   CPPFLAGS="$SAVED_CPPFLAGS"
 250 fi
 251
 252 AC_ARG_ENABLE([screen-sharing], [  --enable-screen-sharing],,
 253               enable_screen_sharing=no)
 254 AM_CONDITIONAL([ENABLE_SCREEN_SHARING],
 255                [test x$enable_screen_sharing = xyes])
 256 if test x$enable_screen_sharing = xyes; then
 257   PKG_CHECK_MODULES(SCREEN_SHARE, [wayland-client])
 258
 259   if test x$enable_rdp_compositor != xyes; then
 260     AC_MSG_WARN([The screen-share.so module requires the RDP backend.])
 261   fi
 262 fi
 263
 264 AC_ARG_WITH(cairo,
 265             AS_HELP_STRING([--with-cairo=@<:@image|gl|glesv2@:>@]
 266                            [Which Cairo renderer to use for the clients]),
 267                            [],[with_cairo="image"])
 268
 269 if test "x$with_cairo" = "ximage"; then
 270         cairo_modules="cairo"
 271 else
 272 if test "x$with_cairo" = "xgl"; then
 273         cairo_modules="cairo-gl"
 274 else
 275 if test "x$with_cairo" = "xglesv2"; then
 276         cairo_modules="cairo-glesv2"
 277 else
 278         AC_ERROR([Unknown cairo renderer requested])
 279 fi
 280 fi
 281 fi
 282
 283 # Included for legacy compat
 284 AC_ARG_WITH(cairo-glesv2,
 285             AS_HELP_STRING([--with-cairo-glesv2],
 286                            [Use GLESv2 cairo]))
 287 if test "x$with_cairo_glesv2" = "xyes"; then
 288   cairo_modules="cairo-glesv2"
 289   with_cairo="glesv2"
 290 fi
 291
 292 if test "x$cairo_modules" = "xcairo-glesv2"; then
 293 AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 294 fi
 295
 296 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 297 PKG_CHECK_MODULES(PNG, [libpng])
 298 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 299 AS_IF([test "x$have_webp" = "xyes"],
 300       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 301
 302 AC_ARG_ENABLE(vaapi-recorder, [  --enable-vaapi-recorder],,
 303               enable_vaapi_recorder=auto)
 304 if test x$enable_vaapi_recorder != xno; then
 305   PKG_CHECK_MODULES(LIBVA, [libva >= 0.34.0 libva-drm >= 0.34.0],
 306                     [have_libva=yes], [have_libva=no])
 307   if test "x$have_libva" = "xno" -a "x$enable_vaapi_recorder" = "xyes"; then
 308     AC_MSG_ERROR([vaapi-recorder explicitly enabled, but libva couldn't be found])
 309   fi
 310   AS_IF([test "x$have_libva" = "xyes"],
 311         [AC_DEFINE([BUILD_VAAPI_RECORDER], [1], [Build the vaapi recorder])])
 312 fi
 313 AM_CONDITIONAL(ENABLE_VAAPI_RECORDER, test "x$have_libva" = xyes)
 314
 315
 316 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 317 if test x$have_jpeglib = xyes; then
 318   JPEG_LIBS="-ljpeg"
 319 else
 320   AC_ERROR([libjpeg not found])
 321 fi
 322 AC_SUBST(JPEG_LIBS)
 323
 324 PKG_CHECK_MODULES(CAIRO, [cairo])
 325
 326 PKG_CHECK_MODULES(TEST_CLIENT, [wayland-client])
 327
 328 AC_ARG_ENABLE(simple-clients,
 329               AS_HELP_STRING([--disable-simple-clients],
 330                              [do not build the simple wl_shm clients]),,
 331               enable_simple_clients=yes)
 332 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 333 if test x$enable_simple_clients = xyes; then
 334   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 335 fi
 336
 337 AC_ARG_ENABLE(simple-egl-clients,
 338               AS_HELP_STRING([--disable-simple-egl-clients],
 339                              [do not build the simple EGL clients]),,
 340               enable_simple_egl_clients="$enable_egl")
 341 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes")
 342 if test x$enable_simple_egl_clients = xyes; then
 343   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 344                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 345 fi
 346
 347 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 348 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 349 if test x$enable_clients = xyes; then
 350   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 351
 352   PKG_CHECK_MODULES(CLIENT, [wayland-client >= 1.5.91 cairo >= 1.10.0 xkbcommon wayland-cursor])
 353   PKG_CHECK_MODULES(SERVER, [wayland-server])
 354   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client >= 1.5.91])
 355
 356   # Only check for cairo-egl if a GL or GLES renderer requested
 357   AS_IF([test "x$cairo_modules" = "xcairo-gl" -o "x$cairo_modules" = "xcairo-glesv2"], [
 358     PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 359                       [have_cairo_egl=yes], [have_cairo_egl=no])
 360     AS_IF([test "x$have_cairo_egl" = "xyes"],
 361           [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 362           [AC_ERROR([cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])],
 363   [have_cairo_egl=no])
 364
 365   PKG_CHECK_MODULES(PANGO, [pangocairo], [have_pango=yes], [have_pango=no])
 366 fi
 367
 368 AC_ARG_ENABLE(resize-optimization,
 369               AS_HELP_STRING([--disable-resize-optimization],
 370                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 371               enable_resize_optimization=yes)
 372 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 373       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 374
 375 PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login >= 198],
 376                   [have_systemd_login=yes], [have_systemd_login=no])
 377 AS_IF([test "x$have_systemd_login" = "xyes"],
 378       [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 379 AM_CONDITIONAL(HAVE_SYSTEMD_LOGIN, test "x$have_systemd_login" = "xyes")
 380
 381 PKG_CHECK_MODULES(SYSTEMD_LOGIN_209, [libsystemd-login >= 209],
 382                   [have_systemd_login_209=yes], [have_systemd_login_209=no])
 383 AS_IF([test "x$have_systemd_login_209" = "xyes"],
 384       [AC_DEFINE([HAVE_SYSTEMD_LOGIN_209], [1], [Have systemd-login >= 209])])
 385
 386 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 387 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 388 if test x$enable_weston_launch == xyes; then
 389   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 390   if test x$have_pam == xno; then
 391     AC_ERROR([weston-launch requires pam])
 392   fi
 393   PAM_LIBS=-lpam
 394   AC_SUBST(PAM_LIBS)
 395 fi
 396
 397 if test x$enable_egl = xyes; then
 398   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 399 fi
 400 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 401
 402 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 403
 404 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 405                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 406
 407 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 408                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 409
 410 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 411                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 412
 413 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 414
 415 AC_ARG_ENABLE(fullscreen-shell,
 416               AS_HELP_STRING([--disable-fullscreen-shell],
 417                              [do not build fullscreen-shell server plugin]),,
 418               enable_fullscreen_shell=yes)
 419 AM_CONDITIONAL(ENABLE_FULLSCREEN_SHELL,
 420                test "x$enable_fullscreen_shell" = "xyes")
 421
 422 # CMS modules
 423 AC_ARG_ENABLE(colord,
 424               AS_HELP_STRING([--disable-colord],
 425                              [do not build colord CMS support]),,
 426               enable_colord=auto)
 427 if test "x$enable_colord" != "xno"; then
 428         PKG_CHECK_MODULES(COLORD,
 429                           colord >= 0.1.27,
 430                           have_colord=yes,
 431                           have_colord=no)
 432         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 433           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 434         fi
 435         if test "x$have_colord" = "xyes"; then
 436              enable_colord=yes
 437         fi
 438 fi
 439 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 440
 441 # dbus support
 442 AC_ARG_ENABLE(dbus,
 443               AS_HELP_STRING([--disable-dbus],
 444                              [do not build with dbus support]),,
 445               enable_dbus=auto)
 446 if test "x$enable_dbus" != "xno"; then
 447         PKG_CHECK_MODULES(DBUS,
 448                           dbus-1 >= 1.6,
 449                           have_dbus=yes,
 450                           have_dbus=no)
 451         if test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"; then
 452                 AC_MSG_ERROR([dbus support explicitly requested, but libdbus couldn't be found])
 453         fi
 454         if test "x$have_dbus" = "xyes"; then
 455                 enable_dbus=yes
 456                 AC_DEFINE([HAVE_DBUS], [1], [Build with dbus support])
 457         else
 458                 enable_dbus=no
 459         fi
 460 fi
 461 AM_CONDITIONAL(ENABLE_DBUS, test "x$enable_dbus" = "xyes")
 462
 463 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 464 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 465 if test x$enable_wcap_tools = xyes; then
 466   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 467   PKG_CHECK_MODULES(WCAP, [cairo])
 468   WCAP_LIBS="$WCAP_LIBS -lm"
 469 fi
 470
 471 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 472 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 473
 474 if test "x$GCC" = "xyes"; then
 475         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 476                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 477                 -Wstrict-prototypes -Wmissing-prototypes -Wsign-compare"
 478 fi
 479 AC_SUBST(GCC_CFLAGS)
 480
 481 AC_ARG_ENABLE(libunwind,
 482               AS_HELP_STRING([--disable-libunwind],
 483                              [Disable libunwind usage for backtraces]),,
 484               enable_libunwind=auto)
 485 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$enable_libunwind" = xyes])
 486 if test "x$enable_libunwind" != "xno"; then
 487         PKG_CHECK_MODULES(LIBUNWIND,
 488                           libunwind,
 489                           have_libunwind=yes,
 490                           have_libunwind=no)
 491         if test "x$have_libunwind" = "xno" -a "x$enable_libunwind" = "xyes"; then
 492           AC_MSG_ERROR([libunwind support explicitly requested, but libunwind couldn't be found])
 493         fi
 494         if test "x$have_libunwind" = "xyes"; then
 495              enable_libunwind=yes
 496              AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 497         fi
 498 fi
 499
 500
 501 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 502         WESTON_NATIVE_BACKEND="drm-backend.so"
 503 fi
 504 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 505 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 506                    [The default backend to load, if not wayland nor x11.])
 507
 508 if test "x$WESTON_SHELL_CLIENT" = "x"; then
 509         WESTON_SHELL_CLIENT="weston-desktop-shell"
 510 fi
 511 AC_MSG_NOTICE([Weston's default desktop shell client: $WESTON_SHELL_CLIENT])
 512 AC_DEFINE_UNQUOTED([WESTON_SHELL_CLIENT], ["$WESTON_SHELL_CLIENT"],
 513                    [The default desktop shell client to load.])
 514
 515 AC_ARG_ENABLE(demo-clients-install,
 516               AS_HELP_STRING([--enable-demo-clients-install],
 517                              [Install demo clients built with weston]),,
 518                              enable_demo_clients_install=no)
 519 AM_CONDITIONAL(INSTALL_DEMO_CLIENTS, [test "x$enable_demo_clients_install" = "xyes"])
 520
 521 PKG_CHECK_MODULES(LCMS, lcms2,
 522                   [have_lcms=yes], [have_lcms=no])
 523 if test "x$have_lcms" = xyes; then
 524        AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 525 fi
 526 AM_CONDITIONAL(HAVE_LCMS, [test "x$have_lcms" = xyes])
 527
 528 AC_PATH_PROG([wayland_scanner], [wayland-scanner])
 529 if test x$wayland_scanner = x; then
 530         AC_MSG_ERROR([wayland-scanner is needed to compile weston])
 531 fi
 532
 533 PKG_CHECK_MODULES(WAYLAND_SCANNER, wayland-scanner)
 534
 535 AC_CONFIG_FILES([Makefile src/version.h src/weston.pc])
 536
 537 AM_CONDITIONAL([HAVE_GIT_REPO], [test -f $srcdir/.git/logs/HEAD])
 538
 539 AC_OUTPUT
 540
 541 AC_MSG_RESULT([
 542         Native Backend                  ${WESTON_NATIVE_BACKEND}
 543         setuid Install                  ${enable_setuid_install}
 544
 545         Cairo Renderer                  ${with_cairo}
 546         EGL                             ${enable_egl}
 547         libxkbcommon                    ${enable_xkbcommon}
 548         xcb_xkb                         ${have_xcb_xkb}
 549         XWayland                        ${enable_xwayland}
 550         dbus                            ${enable_dbus}
 551
 552         Build wcap utility              ${enable_wcap_tools}
 553         Build Fullscreen Shell          ${enable_fullscreen_shell}
 554
 555         weston-launch utility           ${enable_weston_launch}
 556         systemd-login support           ${have_systemd_login}
 557
 558         DRM Compositor                  ${enable_drm_compositor}
 559         X11 Compositor                  ${enable_x11_compositor}
 560         Wayland Compositor              ${enable_wayland_compositor}
 561         Headless Compositor             ${enable_headless_compositor}
 562         RPI Compositor                  ${enable_rpi_compositor}
 563         FBDEV Compositor                ${enable_fbdev_compositor}
 564         RDP Compositor                  ${enable_rdp_compositor}
 565         Screen Sharing                  ${enable_screen_sharing}
 566
 567         libinput Backend                ${enable_libinput_backend}
 568
 569         Raspberry Pi BCM headers        ${have_bcm_host}
 570
 571         Build Clients                   ${enable_clients}
 572         Build EGL Clients               ${have_cairo_egl}
 573         Build Simple Clients            ${enable_simple_clients}
 574         Build Simple EGL Clients        ${enable_simple_egl_clients}
 575
 576         Install Demo Clients            ${enable_demo_clients_install}
 577
 578         Colord Support                  ${have_colord}
 579         GLU Support                     ${have_glu}
 580         LCMS2 Support                   ${have_lcms}
 581         libwebp Support                 ${have_webp}
 582         libunwind Support               ${have_libunwind}
 583         VA H.264 encoding Support       ${have_libva}
 584 ])